CMakeLists.txt

   1 # CMake build for CompilerRT.
   2 #
   3 # This build assumes that CompilerRT is checked out into the
   4 # 'projects/compiler-rt' inside of an LLVM tree.
   5 # Standalone build system for CompilerRT is not yet ready.
   6 #
   7 # An important constraint of the build is that it only produces libraries
   8 # based on the ability of the host toolchain to target various platforms.
   9
  10 # Check if compiler-rt is built as a standalone project.
  11 if (CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR)
  12   project(CompilerRT)
  13   set(COMPILER_RT_STANDALONE_BUILD TRUE)
  14 else()
  15   set(COMPILER_RT_STANDALONE_BUILD FALSE)
  16 endif()
  17
  18 # The CompilerRT build system requires CMake version 2.8.8 or higher in order
  19 # to use its support for building convenience "libraries" as a collection of
  20 # .o files. This is particularly useful in producing larger, more complex
  21 # runtime libraries.
  22 if (NOT MSVC)
  23   cmake_minimum_required(VERSION 2.8.8)
  24 else()
  25   # Version 2.8.12.1 is required to build with Visual Studion 2013.
  26   cmake_minimum_required(VERSION 2.8.12.1)
  27 endif()
  28
  29 # FIXME: It may be removed when we use 2.8.12.
  30 if(CMAKE_VERSION VERSION_LESS 2.8.12)
  31   # Invalidate a couple of keywords.
  32   set(cmake_2_8_12_INTERFACE)
  33   set(cmake_2_8_12_PRIVATE)
  34 else()
  35   # Use ${cmake_2_8_12_KEYWORD} intead of KEYWORD in target_link_libraries().
  36   set(cmake_2_8_12_INTERFACE INTERFACE)
  37   set(cmake_2_8_12_PRIVATE PRIVATE)
  38   if(POLICY CMP0022)
  39     cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  40   endif()
  41 endif()
  42
  43 # Top level target used to build all compiler-rt libraries.
  44 add_custom_target(compiler-rt ALL)
  45
  46 if (NOT COMPILER_RT_STANDALONE_BUILD)
  47   # Compute the Clang version from the LLVM version.
  48   # FIXME: We should be able to reuse CLANG_VERSION variable calculated
  49   #        in Clang cmake files, instead of copying the rules here.
  50   string(REGEX MATCH "[0-9]+\\.[0-9]+(\\.[0-9]+)?" CLANG_VERSION
  51          ${PACKAGE_VERSION})
  52   # Setup the paths where compiler-rt runtimes and headers should be stored.
  53   set(COMPILER_RT_OUTPUT_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR}/clang/${CLANG_VERSION})
  54   set(COMPILER_RT_EXEC_OUTPUT_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
  55   set(COMPILER_RT_INSTALL_PATH lib${LLVM_LIBDIR_SUFFIX}/clang/${CLANG_VERSION})
  56   option(COMPILER_RT_INCLUDE_TESTS "Generate and build compiler-rt unit tests."
  57          ${LLVM_INCLUDE_TESTS})
  58  option(COMPILER_RT_ENABLE_WERROR "Fail and stop if warning is triggered"
  59         ${LLVM_ENABLE_WERROR})
  60   # Use just-built Clang to compile/link tests.
  61   set(COMPILER_RT_TEST_COMPILER ${LLVM_RUNTIME_OUTPUT_INTDIR}/clang)
  62   set(COMPILER_RT_TEST_COMPILER_ID Clang)
  63 else()
  64   # Take output dir and install path from the user.
  65   set(COMPILER_RT_OUTPUT_DIR ${CMAKE_CURRENT_BINARY_DIR} CACHE PATH
  66     "Path where built compiler-rt libraries should be stored.")
  67   set(COMPILER_RT_EXEC_OUTPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/bin CACHE PATH
  68     "Path where built compiler-rt executables should be stored.")
  69   set(COMPILER_RT_INSTALL_PATH ${CMAKE_INSTALL_PREFIX} CACHE PATH
  70     "Path where built compiler-rt libraries should be installed.")
  71   option(COMPILER_RT_INCLUDE_TESTS "Generate and build compiler-rt unit tests." OFF)
  72   option(COMPILER_RT_ENABLE_WERROR "Fail and stop if warning is triggered" OFF)
  73   # Use a host compiler to compile/link tests.
  74   set(COMPILER_RT_TEST_COMPILER ${CMAKE_C_COMPILER})
  75   set(COMPILER_RT_TEST_COMPILER_ID ${CMAKE_C_COMPILER_ID})
  76
  77   set(LLVM_CONFIG_PATH "" CACHE PATH "Path to llvm-config binary")
  78   if (NOT LLVM_CONFIG_PATH)
  79     find_program(LLVM_CONFIG_PATH "llvm-config")
  80     if (NOT LLVM_CONFIG_PATH)
  81       message(FATAL_ERROR "llvm-config not found: specify LLVM_CONFIG_PATH")
  82     endif()
  83   endif()
  84   execute_process(
  85     COMMAND ${LLVM_CONFIG_PATH} "--obj-root" "--bindir" "--libdir" "--src-root"
  86     RESULT_VARIABLE HAD_ERROR
  87     OUTPUT_VARIABLE CONFIG_OUTPUT)
  88   if (HAD_ERROR)
  89     message(FATAL_ERROR "llvm-config failed with status ${HAD_ERROR}")
  90   endif()
  91   string(REGEX REPLACE "[ \t]*[\r\n]+[ \t]*" ";" CONFIG_OUTPUT ${CONFIG_OUTPUT})
  92   list(GET CONFIG_OUTPUT 0 LLVM_BINARY_DIR)
  93   list(GET CONFIG_OUTPUT 1 LLVM_TOOLS_BINARY_DIR)
  94   list(GET CONFIG_OUTPUT 2 LLVM_LIBRARY_DIR)
  95   list(GET CONFIG_OUTPUT 3 LLVM_MAIN_SRC_DIR)
  96
  97   # Make use of LLVM CMake modules.
  98   set(LLVM_CMAKE_PATH "${LLVM_BINARY_DIR}/share/llvm/cmake")
  99   list(APPEND CMAKE_MODULE_PATH "${LLVM_CMAKE_PATH}")
 100   # Get some LLVM variables from LLVMConfig.
 101   include("${LLVM_CMAKE_PATH}/LLVMConfig.cmake")
 102
 103   set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib)
 104
 105   # Find Python interpreter.
 106   set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5)
 107   include(FindPythonInterp)
 108   if(NOT PYTHONINTERP_FOUND)
 109     message(FATAL_ERROR "
 110       Unable to find Python interpreter required testing. Please install Python
 111       or specify the PYTHON_EXECUTABLE CMake variable.")
 112   endif()
 113
 114   # Define default arguments to lit.
 115   set(LIT_ARGS_DEFAULT "-sv")
 116   if (MSVC OR XCODE)
 117     set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 118   endif()
 119   set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 120 endif()
 121
 122 string(TOLOWER ${CMAKE_SYSTEM_NAME} COMPILER_RT_OS_DIR)
 123 set(COMPILER_RT_LIBRARY_OUTPUT_DIR
 124   ${COMPILER_RT_OUTPUT_DIR}/lib/${COMPILER_RT_OS_DIR})
 125 set(COMPILER_RT_LIBRARY_INSTALL_DIR
 126   ${COMPILER_RT_INSTALL_PATH}/lib/${COMPILER_RT_OS_DIR})
 127
 128 # Add path for custom compiler-rt modules.
 129 set(CMAKE_MODULE_PATH
 130   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 131   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules"
 132   ${CMAKE_MODULE_PATH}
 133   )
 134 include(CompilerRTUtils)
 135
 136 set(COMPILER_RT_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
 137 set(COMPILER_RT_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
 138 # Setup custom SDK sysroots.
 139 set(COMPILER_RT_DARWIN_SDK_SYSROOT ${COMPILER_RT_SOURCE_DIR}/SDKs/darwin)
 140 set(COMPILER_RT_LINUX_SDK_SYSROOT ${COMPILER_RT_SOURCE_DIR}/SDKs/linux)
 141
 142 set(COMPILER_RT_EXTRA_ANDROID_HEADERS ${COMPILER_RT_SOURCE_DIR}/third_party/android/include)
 143
 144 # Detect whether the current target platform is 32-bit or 64-bit, and setup
 145 # the correct commandline flags needed to attempt to target 32-bit and 64-bit.
 146 if (NOT CMAKE_SIZEOF_VOID_P EQUAL 4 AND
 147     NOT CMAKE_SIZEOF_VOID_P EQUAL 8)
 148   message(FATAL_ERROR "Please use architecture with 4 or 8 byte pointers.")
 149 endif()
 150 if (NOT MSVC)
 151   set(TARGET_64_BIT_CFLAGS "-m64")
 152   set(TARGET_32_BIT_CFLAGS "-m32")
 153 else()
 154   set(TARGET_64_BIT_CFLAGS "")
 155   set(TARGET_32_BIT_CFLAGS "")
 156 endif()
 157
 158 # List of architectures we can target.
 159 set(COMPILER_RT_SUPPORTED_ARCH)
 160
 161 function(get_target_flags_for_arch arch out_var)
 162   list(FIND COMPILER_RT_SUPPORTED_ARCH ${arch} ARCH_INDEX)
 163   if(ARCH_INDEX EQUAL -1)
 164     message(FATAL_ERROR "Unsupported architecture: ${arch}")
 165   else()
 166     set(${out_var} ${TARGET_${arch}_CFLAGS} PARENT_SCOPE)
 167   endif()
 168 endfunction()
 169
 170 # Try to compile a very simple source file to ensure we can target the given
 171 # platform. We use the results of these tests to build only the various target
 172 # runtime libraries supported by our current compilers cross-compiling
 173 # abilities.
 174 set(SIMPLE_SOURCE ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/simple.c)
 175 file(WRITE ${SIMPLE_SOURCE} "#include <stdlib.h>\nint main() {}")
 176
 177 # test_target_arch(<arch> <target flags...>)
 178 # Sets the target flags for a given architecture and determines if this
 179 # architecture is supported by trying to build a simple file.
 180 macro(test_target_arch arch)
 181   set(TARGET_${arch}_CFLAGS ${ARGN})
 182   try_compile(CAN_TARGET_${arch} ${CMAKE_BINARY_DIR} ${SIMPLE_SOURCE}
 183               COMPILE_DEFINITIONS "${TARGET_${arch}_CFLAGS}"
 184               CMAKE_FLAGS "-DCMAKE_EXE_LINKER_FLAGS:STRING=${TARGET_${arch}_CFLAGS}")
 185   if(${CAN_TARGET_${arch}})
 186     list(APPEND COMPILER_RT_SUPPORTED_ARCH ${arch})
 187   endif()
 188 endmacro()
 189
 190 if(ANDROID_COMMON_FLAGS)
 191   test_target_arch(arm_android "${ANDROID_COMMON_FLAGS}")
 192 else()
 193   if("${LLVM_NATIVE_ARCH}" STREQUAL "X86")
 194     if (NOT MSVC)
 195       test_target_arch(x86_64 ${TARGET_64_BIT_CFLAGS})
 196     endif()
 197     test_target_arch(i386 ${TARGET_32_BIT_CFLAGS})
 198   elseif("${LLVM_NATIVE_ARCH}" STREQUAL "PowerPC")
 199     test_target_arch(powerpc64 ${TARGET_64_BIT_CFLAGS})
 200   elseif("${LLVM_NATIVE_ARCH}" STREQUAL "ARM")
 201     test_target_arch(arm "")
 202   endif()
 203 endif()
 204
 205 # We only support running instrumented tests when we're not cross compiling
 206 # and target a unix-like system. We can run tests on Android even when we are
 207 # cross-compiling.
 208 if(("${CMAKE_HOST_SYSTEM}" STREQUAL "${CMAKE_SYSTEM}" AND UNIX) OR ANDROID)
 209   option(COMPILER_RT_CAN_EXECUTE_TESTS "Can we execute instrumented tests" ON)
 210 else()
 211   option(COMPILER_RT_CAN_EXECUTE_TESTS "Can we execute instrumented tests" OFF)
 212 endif()
 213
 214 # Check if compiler-rt is built with libc++.
 215 find_flag_in_string("${CMAKE_CXX_FLAGS}" "-stdlib=libc++"
 216                     COMPILER_RT_USES_LIBCXX)
 217
 218 function(filter_available_targets out_var)
 219   set(archs)
 220   foreach(arch ${ARGN})
 221     list(FIND COMPILER_RT_SUPPORTED_ARCH ${arch} ARCH_INDEX)
 222     if(NOT (ARCH_INDEX EQUAL -1) AND CAN_TARGET_${arch})
 223       list(APPEND archs ${arch})
 224     endif()
 225   endforeach()
 226   set(${out_var} ${archs} PARENT_SCOPE)
 227 endfunction()
 228
 229 option(COMPILER_RT_DEBUG "Build runtimes with full debug info" OFF)
 230 # COMPILER_RT_DEBUG_PYBOOL is used by lit.common.configured.in.
 231 pythonize_bool(COMPILER_RT_DEBUG)
 232
 233 #================================
 234 # Setup Compiler Flags
 235 #================================
 236 include(config-ix)
 237
 238 if(COMPILER_RT_ENABLE_WERROR)
 239   add_definitions_if(COMPILER_RT_HAS_WERROR_FLAG -Werror)
 240   add_definitions_if(COMPILER_RT_HAS_WX_FLAG /WX)
 241 endif()
 242
 243 # Emulate C99 and C++11's __func__ for MSVC prior to 2013 CTP.
 244 if(NOT COMPILER_RT_HAS_FUNC_SYMBOL)
 245   add_definitions(-D__func__=__FUNCTION__)
 246 endif()
 247
 248 # Provide some common commmandline flags for Sanitizer runtimes.
 249 append_if(SANITIZER_COMMON_CFLAGS COMPILER_RT_HAS_FPIC_FLAG -fPIC)
 250 append_if(SANITIZER_COMMON_CFLAGS COMPILER_RT_HAS_FNO_BUILTIN_FLAG -fno-builtin)
 251 append_if(SANITIZER_COMMON_CFLAGS COMPILER_RT_HAS_FNO_EXCEPTIONS_FLAG -fno-exceptions)
 252 append_if(SANITIZER_COMMON_CFLAGS COMPILER_RT_HAS_FOMIT_FRAME_POINTER_FLAG -fomit-frame-pointer)
 253 append_if(SANITIZER_COMMON_CFLAGS COMPILER_RT_HAS_FUNWIND_TABLES_FLAG -funwind-tables)
 254 append_if(SANITIZER_COMMON_CFLAGS COMPILER_RT_HAS_FNO_STACK_PROTECTOR_FLAG -fno-stack-protector)
 255 append_if(SANITIZER_COMMON_CFLAGS COMPILER_RT_HAS_FVISIBILITY_HIDDEN_FLAG -fvisibility=hidden)
 256 append_if(SANITIZER_COMMON_CFLAGS COMPILER_RT_HAS_FNO_FUNCTION_SECTIONS_FLAG -fno-function-sections)
 257
 258 if(MSVC)
 259   # Remove /MD flag so that it doesn't conflict with /MT.
 260   if(COMPILER_RT_HAS_MT_FLAG)
 261     string(REGEX REPLACE "(^| ) */MD *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 262     list(APPEND SANITIZER_COMMON_CFLAGS /MT)
 263   endif()
 264   append_if(SANITIZER_COMMON_CFLAGS COMPILER_RT_HAS_Oy_FLAG /Oy-)
 265   append_if(SANITIZER_COMMON_CFLAGS COMPILER_RT_HAS_GS_FLAG /GS-)
 266 endif()
 267
 268 # Build with optimization, unless we're in debug mode.
 269 if(NOT COMPILER_RT_DEBUG)
 270   if(MSVC)
 271     list(APPEND SANITIZER_COMMON_CFLAGS /O2)
 272   else()
 273     list(APPEND SANITIZER_COMMON_CFLAGS -O3)
 274   endif()
 275 endif()
 276
 277 # Build sanitizer runtimes with debug info.
 278 if(COMPILER_RT_HAS_GLINE_TABLES_ONLY_FLAG)
 279   list(APPEND SANITIZER_COMMON_CFLAGS -gline-tables-only)
 280 elseif(COMPILER_RT_HAS_G_FLAG)
 281   list(APPEND SANITIZER_COMMON_CFLAGS -g)
 282 elseif(COMPILER_RT_HAS_Zi_FLAG)
 283   list(APPEND SANITIZER_COMMON_CFLAGS /Zi)
 284 endif()
 285
 286 # Turn off several warnings.
 287 append_if(SANITIZER_COMMON_CFLAGS COMPILER_RT_HAS_WNO_GNU_FLAG -Wno-gnu)
 288 append_if(SANITIZER_COMMON_CFLAGS COMPILER_RT_HAS_WNO_VARIADIC_MACROS_FLAG -Wno-variadic-macros)
 289 append_if(SANITIZER_COMMON_CFLAGS COMPILER_RT_HAS_WNO_C99_EXTENSIONS_FLAG -Wno-c99-extensions)
 290 append_if(SANITIZER_COMMON_CFLAGS COMPILER_RT_HAS_WNO_NON_VIRTUAL_DTOR_FLAG -Wno-non-virtual-dtor)
 291 append_if(SANITIZER_COMMON_CFLAGS COMPILER_RT_HAS_WD4722_FLAG /wd4722)
 292
 293 if(APPLE)
 294   # Obtain the iOS Simulator SDK path from xcodebuild.
 295   execute_process(
 296     COMMAND xcodebuild -version -sdk iphonesimulator Path
 297     OUTPUT_VARIABLE IOSSIM_SDK_DIR
 298     OUTPUT_STRIP_TRAILING_WHITESPACE
 299   )
 300   string(REGEX MATCH "-mmacosx-version-min="
 301          MACOSX_VERSION_MIN_FLAG "${CMAKE_CXX_FLAGS}")
 302   set(SANITIZER_COMMON_SUPPORTED_DARWIN_OS osx)
 303   if (IOSSIM_SDK_DIR AND NOT MACOSX_VERSION_MIN_FLAG)
 304     list(APPEND SANITIZER_COMMON_SUPPORTED_DARWIN_OS iossim)
 305   endif()
 306
 307   if(COMPILER_RT_USES_LIBCXX)
 308     set(SANITIZER_MIN_OSX_VERSION 10.7)
 309   else()
 310     set(SANITIZER_MIN_OSX_VERSION 10.6)
 311   endif()
 312   set(DARWIN_osx_CFLAGS -mmacosx-version-min=${SANITIZER_MIN_OSX_VERSION})
 313   set(DARWIN_iossim_CFLAGS
 314     -mios-simulator-version-min=7.0 -isysroot ${IOSSIM_SDK_DIR})
 315   set(DARWIN_osx_LINKFLAGS)
 316   set(DARWIN_iossim_LINKFLAGS
 317     -Wl,-ios_simulator_version_min,7.0.0
 318     -mios-simulator-version-min=7.0
 319     -isysroot ${IOSSIM_SDK_DIR})
 320 endif()
 321
 322 # Architectures supported by Sanitizer runtimes. Specific sanitizers may
 323 # support only subset of these (e.g. TSan works on x86_64 only).
 324 filter_available_targets(SANITIZER_COMMON_SUPPORTED_ARCH
 325   x86_64 i386 powerpc64 arm)
 326 filter_available_targets(ASAN_SUPPORTED_ARCH x86_64 i386 powerpc64)
 327 filter_available_targets(DFSAN_SUPPORTED_ARCH x86_64)
 328 filter_available_targets(LSAN_SUPPORTED_ARCH x86_64)
 329 filter_available_targets(MSAN_SUPPORTED_ARCH x86_64)
 330 filter_available_targets(TSAN_SUPPORTED_ARCH x86_64)
 331 filter_available_targets(UBSAN_SUPPORTED_ARCH x86_64 i386)
 332
 333 add_subdirectory(include)
 334
 335 set(COMPILER_RT_LIBCXX_PATH ${LLVM_MAIN_SRC_DIR}/projects/libcxx)
 336 if(EXISTS ${COMPILER_RT_LIBCXX_PATH}/)
 337   set(COMPILER_RT_HAS_LIBCXX_SOURCES TRUE)
 338 else()
 339   set(COMPILER_RT_HAS_LIBCXX_SOURCES FALSE)
 340 endif()
 341
 342 add_subdirectory(lib)
 343
 344 if(COMPILER_RT_INCLUDE_TESTS)
 345   add_subdirectory(unittests)
 346 endif()
 347 add_subdirectory(test)