bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([libbfd.c])
   7
   8 AC_CANONICAL_TARGET
   9 AC_ISC_POSIX
  10
  11 AM_INIT_AUTOMAKE(bfd, 2.18.50)
  12
  13 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  14 dnl to call AC_CHECK_PROG.
  15 AC_CHECK_TOOL(AR, ar)
  16 AC_CHECK_TOOL(RANLIB, ranlib, :)
  17
  18 dnl Default to a non shared library.  This may be overridden by the
  19 dnl configure option --enable-shared.
  20 AM_DISABLE_SHARED
  21
  22 AC_PROG_CC
  23 AC_GNU_SOURCE
  24
  25 AC_PROG_LIBTOOL
  26
  27 AC_ARG_ENABLE(64-bit-bfd,
  28 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  29 [case "${enableval}" in
  30   yes)  want64=true  ;;
  31   no)   want64=false ;;
  32   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  33 esac],[want64=false])dnl
  34 AC_ARG_ENABLE(targets,
  35 [  --enable-targets        alternative target configurations],
  36 [case "${enableval}" in
  37   yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
  38             ;;
  39   no)       enable_targets= ;;
  40   *)        enable_targets=$enableval ;;
  41 esac])dnl
  42 AC_ARG_ENABLE(commonbfdlib,
  43 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  44 [case "${enableval}" in
  45   yes) commonbfdlib=true ;;
  46   no)  commonbfdlib=false ;;
  47   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  48 esac])dnl
  49 AC_ARG_WITH(mmap,
  50 [  --with-mmap             try using mmap for BFD input files if available],
  51 [case "${withval}" in
  52   yes)  want_mmap=true ;;
  53   no)   want_mmap=false ;;
  54   *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
  55 esac],[want_mmap=false])dnl
  56
  57 AC_ARG_ENABLE(secureplt,
  58 [  --enable-secureplt      Default to creating read-only plt entries],
  59 [case "${enableval}" in
  60   yes)  use_secureplt=true  ;;
  61   no)   use_secureplt=false ;;
  62   *)    AC_MSG_ERROR(bad value ${enableval} for secureplt option) ;;
  63 esac],[use_secureplt=false])dnl
  64 if test $use_secureplt = true; then
  65   AC_DEFINE(USE_SECUREPLT, 1,
  66     [Define if we should default to creating read-only plt entries])
  67 fi
  68
  69 DEBUGDIR=${libdir}/debug
  70
  71 AC_ARG_WITH(separate-debug-dir,
  72   AS_HELP_STRING([--with-separate-debug-dir=DIR],
  73                  [Look for global separate debug info in DIR [[default=LIBDIR/debug]]]),
  74 [DEBUGDIR="${withval}"])
  75 AC_SUBST(DEBUGDIR)
  76
  77 ACX_PKGVERSION([GNU Binutils])
  78 ACX_BUGURL([http://www.sourceware.org/bugzilla/])
  79
  80 AM_BINUTILS_WARNINGS
  81
  82 AM_CONFIG_HEADER(config.h:config.in)
  83
  84 if test -z "$target" ; then
  85     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  86 fi
  87
  88 AM_MAINTAINER_MODE
  89 AM_CONDITIONAL(GENINSRC_NEVER, false)
  90 AM_INSTALL_LIBBFD
  91 AC_EXEEXT
  92
  93 host64=false
  94 target64=false
  95 bfd_default_target_size=32
  96
  97 # host stuff:
  98
  99 ALL_LINGUAS="fr tr ja es sv da zh_CN ro rw vi"
 100 ZW_GNU_GETTEXT_SISTER_DIR
 101 AM_PO_SUBDIRS
 102
 103 # Permit host specific settings.
 104 . ${srcdir}/configure.host
 105
 106 AC_SUBST(HDEFINES)
 107 AC_PROG_INSTALL
 108
 109 BFD_HOST_64BIT_LONG=0
 110 BFD_HOST_64BIT_LONG_LONG=0
 111 BFD_HOST_64_BIT_DEFINED=0
 112 BFD_HOST_64_BIT=
 113 BFD_HOST_U_64_BIT=
 114 BFD_HOSTPTR_T="unsigned long"
 115
 116 AC_CHECK_SIZEOF(long long)
 117 AC_CHECK_SIZEOF(void *)
 118 AC_CHECK_SIZEOF(long)
 119
 120 if test "x${ac_cv_sizeof_void_p}" = "x8"; then
 121   host64=true
 122 fi
 123
 124 if test "x${ac_cv_sizeof_long}" = "x8"; then
 125   BFD_HOST_64BIT_LONG=1
 126   test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long"
 127   test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long"
 128 elif test "x${ac_cv_sizeof_long_long}" = "x8"; then
 129   BFD_HOST_64BIT_LONG_LONG=1
 130   test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long long"
 131   test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long long"
 132   if test "x${ac_cv_sizeof_void_p}" = "x8"; then
 133     BFD_HOSTPTR_T="unsigned long long"
 134   fi
 135 fi
 136
 137 if test -n "${HOST_64BIT_TYPE}" -a -n "${HOST_U_64BIT_TYPE}"; then
 138   BFD_HOST_64_BIT_DEFINED=1
 139   BFD_HOST_64_BIT="${HOST_64BIT_TYPE}"
 140   BFD_HOST_U_64_BIT="${HOST_U_64BIT_TYPE}"
 141 fi
 142
 143 AC_SUBST(BFD_HOST_64BIT_LONG)
 144 AC_SUBST(BFD_HOST_64BIT_LONG_LONG)
 145 AC_SUBST(BFD_HOST_64_BIT_DEFINED)
 146 AC_SUBST(BFD_HOST_64_BIT)
 147 AC_SUBST(BFD_HOST_U_64_BIT)
 148 AC_SUBST(BFD_HOSTPTR_T)
 149
 150 BFD_CC_FOR_BUILD
 151
 152 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
 153 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h)
 154 GCC_HEADER_STDINT(bfd_stdint.h)
 155 AC_HEADER_TIME
 156 AC_HEADER_DIRENT
 157 ACX_HEADER_STRING
 158 AC_CHECK_FUNCS(fcntl getpagesize setitimer sysconf fdopen getuid getgid)
 159 AC_CHECK_FUNCS(strtoull)
 160
 161 AC_CHECK_DECLS(basename)
 162 AC_CHECK_DECLS(ftello)
 163 AC_CHECK_DECLS(ftello64)
 164 AC_CHECK_DECLS(fseeko)
 165 AC_CHECK_DECLS(fseeko64)
 166
 167 BFD_BINARY_FOPEN
 168
 169 AC_CHECK_DECLS(ffs)
 170 AC_CHECK_DECLS(free)
 171 AC_CHECK_DECLS(getenv)
 172 AC_CHECK_DECLS(malloc)
 173 AC_CHECK_DECLS(realloc)
 174 AC_CHECK_DECLS(stpcpy)
 175 AC_CHECK_DECLS(strstr)
 176 AC_CHECK_DECLS(snprintf)
 177 AC_CHECK_DECLS(vsnprintf)
 178
 179 # If we are configured native, pick a core file support file.
 180 COREFILE=
 181 COREFLAG=
 182 TRAD_HEADER=
 183 if test "${target}" = "${host}"; then
 184   case "${host}" in
 185   alpha*-*-freebsd* | alpha*-*-kfreebsd*-gnu)
 186         COREFILE=''
 187         ;;
 188   alpha*-*-linux-*)
 189         COREFILE=trad-core.lo
 190         TRAD_HEADER='"hosts/alphalinux.h"'
 191         ;;
 192   alpha*-*-netbsd* | alpha*-*-openbsd*)
 193         COREFILE=netbsd-core.lo
 194         ;;
 195   alpha*-*-*)           COREFILE=osf-core.lo ;;
 196   arm-*-freebsd* | arm-*-kfreebsd*-gnu)
 197                         COREFILE='' ;;
 198   arm-*-netbsd* | arm-*-openbsd*)
 199         COREFILE=netbsd-core.lo
 200         ;;
 201   arm-*-riscix)         COREFILE=trad-core.lo ;;
 202   hppa*-*-hpux*)        COREFILE=hpux-core.lo ;;
 203   hppa*-*-hiux*)        COREFILE=hpux-core.lo ;;
 204   hppa*-*-mpeix*)       COREFILE=hpux-core.lo ;;
 205   hppa*-*-bsd*)         COREFILE="hpux-core.lo hppabsd-core.lo"
 206                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 207   hppa*-*-netbsd* | hppa*-*-openbsd*)
 208         COREFILE=netbsd-core.lo
 209         ;;
 210
 211   i370-*-*)
 212         COREFILE=trad-core.lo
 213         TRAD_HEADER='"hosts/i370linux.h"'
 214         ;;
 215
 216 changequote(,)dnl
 217   i[3-7]86-sequent-bsd*)
 218 changequote([,])dnl
 219         COREFILE=trad-core.lo
 220         TRAD_HEADER='"hosts/symmetry.h"'
 221         ;;
 222 changequote(,)dnl
 223   i[3-7]86-sequent-sysv4*) ;;
 224   i[3-7]86-sequent-sysv*)
 225 changequote([,])dnl
 226         COREFILE=trad-core.lo
 227         TRAD_HEADER='"hosts/symmetry.h"'
 228         ;;
 229 changequote(,)dnl
 230   i[3-7]86-*-bsdi)
 231 changequote([,])dnl
 232         COREFILE=
 233         ;;
 234 changequote(,)dnl
 235   i[3-7]86-*-bsd* | i[3-7]86-*-freebsd[123] | i[3-7]86-*-freebsd[123]\.* | i[3-7]86-*-freebsd4\.[01234] | i[3-7]86-*-freebsd4\.[01234]\.* | i[3-7]86-*-freebsd*aout*)
 236 changequote([,])dnl
 237         COREFILE=trad-core.lo
 238         TRAD_HEADER='"hosts/i386bsd.h"'
 239         ;;
 240 changequote(,)dnl
 241   i[3-7]86-*-freebsd* | i[3-7]86-*-kfreebsd*-gnu | i[3-7]86-*-dragonfly*)
 242 changequote([,])dnl
 243         COREFILE=''
 244         TRAD_HEADER='"hosts/i386bsd.h"'
 245         ;;
 246 changequote(,)dnl
 247   i[3-7]86-*-netbsd* | i[3-7]86-*-knetbsd*-gnu | i[3-7]86-*-openbsd*)
 248 changequote([,])dnl
 249         COREFILE=netbsd-core.lo
 250         ;;
 251 changequote(,)dnl
 252   i[3-7]86-esix-sysv3*)
 253 changequote([,])dnl
 254         COREFILE=trad-core.lo
 255         TRAD_HEADER='"hosts/esix.h"'
 256         ;;
 257 changequote(,)dnl
 258   i[3-7]86-*-sco3.2v5*)
 259 changequote([,])dnl
 260         COREFILE=sco5-core.lo
 261         ;;
 262 changequote(,)dnl
 263   i[3-7]86-*-sco* | i[3-7]86-*-isc*)
 264 changequote([,])dnl
 265         COREFILE=trad-core.lo
 266         TRAD_HEADER='"hosts/i386sco.h"'
 267         ;;
 268 changequote(,)dnl
 269   i[3-7]86-*-mach3*)
 270 changequote([,])dnl
 271         COREFILE=trad-core.lo
 272         TRAD_HEADER='"hosts/i386mach3.h"'
 273         ;;
 274 changequote(,)dnl
 275   i[3-7]86-*-linux-*)
 276 changequote([,])dnl
 277         COREFILE=trad-core.lo
 278         TRAD_HEADER='"hosts/i386linux.h"'
 279         ;;
 280 changequote(,)dnl
 281   i[3-7]86-*-isc*)      COREFILE=trad-core.lo ;;
 282   i[3-7]86-*-aix*)      COREFILE=aix386-core.lo ;;
 283 changequote([,])dnl
 284   i860-*-mach3* | i860-*-osf1*)
 285         COREFILE=trad-core.lo
 286         TRAD_HEADER='"hosts/i860mach3.h"'
 287         ;;
 288   mips-*-netbsd* | mips*-*-openbsd*)
 289         COREFILE=netbsd-core.lo
 290         ;;
 291   mips-dec-*)
 292         COREFILE=trad-core.lo
 293         TRAD_HEADER='"hosts/decstation.h"'
 294         ;;
 295   mips-sgi-irix4*)      COREFILE=irix-core.lo ;;
 296   mips-sgi-irix5*)      COREFILE=irix-core.lo ;;
 297   mips-sgi-irix6*)      COREFILE=irix-core.lo ;;
 298   mips-*-sysv4*)        ;;
 299   mips-*-sysv* | mips-*-riscos*)
 300         COREFILE=trad-core.lo
 301         TRAD_HEADER='"hosts/riscos.h"'
 302         ;;
 303   mips-sony-bsd*)
 304         COREFILE=trad-core.lo
 305         TRAD_HEADER='"hosts/news-mips.h"'
 306         ;;
 307   m68*-bull*-sysv*)
 308         COREFILE=trad-core.lo
 309         TRAD_HEADER='"hosts/dpx2.h"'
 310         ;;
 311   m68*-hp-hpux*)        COREFILE=hpux-core.lo ;;
 312   m68*-hp-bsd*)
 313         COREFILE=trad-core.lo
 314         TRAD_HEADER='"hosts/hp300bsd.h"'
 315         ;;
 316   m68*-*-linux-*)
 317         COREFILE=trad-core.lo
 318         TRAD_HEADER='"hosts/m68klinux.h"'
 319         ;;
 320   m68*-motorola-sysv*)
 321         COREFILE=trad-core.lo
 322         TRAD_HEADER='"hosts/delta68.h"'
 323         ;;
 324   m68*-sony-*)
 325         COREFILE=trad-core.lo
 326         TRAD_HEADER='"hosts/news.h"'
 327         ;;
 328   m68*-*-netbsd* | m68*-*-openbsd*)
 329         COREFILE=netbsd-core.lo
 330         ;;
 331   m68*-apple-aux*)
 332         COREFILE=trad-core.lo
 333         TRAD_HEADER='"hosts/m68kaux.h"'
 334         ;;
 335   m88*-*-sysv4*)
 336         ;;
 337   m88*-motorola-sysv*)
 338         COREFILE=ptrace-core.lo
 339         ;;
 340   m88*-*-mach3*)
 341         COREFILE=trad-core.lo
 342         TRAD_HEADER='"hosts/m88kmach3.h"'
 343         ;;
 344   m88*-*-openbsd*)
 345         COREFILE=netbsd-core.lo
 346         ;;
 347   ns32k-pc532-mach)
 348         COREFILE=trad-core.lo
 349         TRAD_HEADER='"hosts/pc532mach.h"'
 350         ;;
 351   ns32k-*-netbsd* | ns32k-*-openbsd*)
 352         COREFILE=netbsd-core.lo
 353         ;;
 354   rs6000-*-lynx*)
 355         COREFILE=lynx-core.lo
 356         ;;
 357   rs6000-*-aix5.* | powerpc-*-aix5.*)
 358         COREFILE=rs6000-core.lo
 359         COREFLAG="$COREFLAG -DAIX_5_CORE -DAIX_CORE_DUMPX_CORE"
 360         ;;
 361 changequote(,)dnl
 362   rs6000-*-aix4.[3-9]* | powerpc-*-aix4.[3-9]*)
 363 changequote([,])dnl
 364         COREFILE=rs6000-core.lo
 365         COREFLAG="$COREFLAG -DAIX_CORE_DUMPX_CORE"
 366         # Not all versions of AIX with -DAIX_CORE_DUMPX_CORE
 367         # have c_impl as a member of struct core_dumpx
 368         AC_MSG_CHECKING([for c_impl in struct core_dumpx])
 369         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <core.h>]], [[struct core_dumpx c; c.c_impl = 0;]])],[AC_DEFINE(HAVE_ST_C_IMPL, 1,
 370             [Define if struct core_dumpx has member c_impl])
 371           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 372         ;;
 373   rs6000-*-aix4*)       COREFILE=rs6000-core.lo ;;
 374   rs6000-*-*)           COREFILE=rs6000-core.lo ;;
 375   powerpc-*-aix4*)      COREFILE=rs6000-core.lo ;;
 376   powerpc-*-aix*)       COREFILE=rs6000-core.lo ;;
 377   powerpc-*-beos*)      ;;
 378   powerpc-*-freebsd* | powerpc-*-kfreebsd*-gnu)
 379                         COREFILE='' ;;
 380   powerpc-*-netbsd*)    COREFILE=netbsd-core.lo ;;
 381   powerpc-*-*bsd*)      COREFILE=netbsd-core.lo ;;
 382   s390*-*-*)            COREFILE=trad-core.lo ;;
 383   sh*-*-netbsd* | sh*-*-openbsd*)
 384         COREFILE=netbsd-core.lo
 385         ;;
 386   sparc-*-netbsd* | sparc*-*-openbsd*)
 387         COREFILE=netbsd-core.lo
 388         ;;
 389   tahoe-*-*)
 390         COREFILE=trad-core.lo
 391         TRAD_HEADER='"hosts/tahoe.h"'
 392         ;;
 393   vax-*-netbsd* | vax-*-openbsd*)
 394         COREFILE=netbsd-core.lo
 395         ;;
 396   vax-*-ultrix2*)
 397         COREFILE=trad-core.lo
 398         TRAD_HEADER='"hosts/vaxult2.h"'
 399         ;;
 400   vax-*-ultrix*)
 401         COREFILE=trad-core.lo
 402         TRAD_HEADER='"hosts/vaxult2.h"'
 403         ;;
 404   vax-*-linux-*)
 405         COREFILE=trad-core.lo
 406         TRAD_HEADER='"hosts/vaxlinux.h"'
 407         ;;
 408   vax-*-*)
 409         COREFILE=trad-core.lo
 410         TRAD_HEADER='"hosts/vaxbsd.h"'
 411         ;;
 412   x86_64-*-netbsd* | x86_64-*-openbsd*)
 413         COREFILE=netbsd-core.lo
 414         ;;
 415   esac
 416
 417   case "$COREFILE" in
 418   aix386-core.lo)       COREFLAG=-DAIX386_CORE ;;
 419   hppabsd-core.lo)      COREFLAG=-DHPPABSD_CORE ;;
 420   hpux-core.lo)         COREFLAG=-DHPUX_CORE ;;
 421   irix-core.lo)         COREFLAG=-DIRIX_CORE ;;
 422   lynx-core.lo)         COREFLAG=-DLYNX_CORE ;;
 423   netbsd-core.lo)       COREFLAG=-DNETBSD_CORE ;;
 424   osf-core.lo)          COREFLAG=-DOSF_CORE ;;
 425   ptrace-core.lo)       COREFLAG=-DPTRACE_CORE ;;
 426   rs6000-core.lo)       COREFLAG="$COREFLAG -DAIX_CORE" ;;
 427   sco5-core.lo)         COREFLAG="$COREFLAG -DSCO5_CORE" ;;
 428   trad-core.lo)         COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 429   esac
 430
 431   # ELF corefile support has several flavors, but all of
 432   # them use something called <sys/procfs.h>
 433   AC_CHECK_HEADERS(sys/procfs.h)
 434   if test "$ac_cv_header_sys_procfs_h" = yes; then
 435     BFD_HAVE_SYS_PROCFS_TYPE(prstatus_t)
 436     BFD_HAVE_SYS_PROCFS_TYPE(prstatus32_t)
 437     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus_t, pr_who)
 438     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus32_t, pr_who)
 439     BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 440     BFD_HAVE_SYS_PROCFS_TYPE(pxstatus_t)
 441     BFD_HAVE_SYS_PROCFS_TYPE(pstatus32_t)
 442     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo_t)
 443     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo32_t)
 444     BFD_HAVE_SYS_PROCFS_TYPE(psinfo_t)
 445     BFD_HAVE_SYS_PROCFS_TYPE(psinfo32_t)
 446     BFD_HAVE_SYS_PROCFS_TYPE(lwpstatus_t)
 447     BFD_HAVE_SYS_PROCFS_TYPE(lwpxstatus_t)
 448     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_context)
 449     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_reg)
 450     BFD_HAVE_SYS_PROCFS_TYPE(win32_pstatus_t)
 451   fi
 452 fi
 453 AC_SUBST(COREFILE)
 454 AC_SUBST(COREFLAG)
 455 if test -n "$TRAD_HEADER"; then
 456   AC_DEFINE_UNQUOTED(TRAD_HEADER, $TRAD_HEADER,
 457     [Name of host specific header file to include in trad-core.c.])
 458 fi
 459
 460 # Horrible hacks to build DLLs on Windows.
 461 WIN32LDFLAGS=
 462 WIN32LIBADD=
 463 case "${host}" in
 464 *-*-cygwin*)
 465   if test "$enable_shared" = "yes"; then
 466     WIN32LDFLAGS="-no-undefined"
 467     WIN32LIBADD="-L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin -lkernel32"
 468   fi
 469   ;;
 470 *-*-linux*)
 471   # We borrow WIN32LIBADD so that the shared libbfd won't depend on
 472   # libiberty.a.
 473   case "${host}" in
 474   mips*-*-linux*)
 475     # Linux/MIPS uses PIC by default.
 476     if test "$enable_shared" = "yes"; then
 477       WIN32LIBADD="-L../libiberty -liberty"
 478     fi
 479     ;;
 480   *)
 481 changequote(,)dnl
 482     x=`sed -n -e 's/^[  ]*PICFLAG[      ]*=[    ]*//p' < ../libiberty/Makefile | sed -n '$p'`
 483 changequote([,])dnl
 484     if test -n "$x"; then
 485       WIN32LIBADD="-L../libiberty/pic -liberty"
 486     fi
 487   ;;
 488   esac
 489   ;;
 490 esac
 491 AC_SUBST(WIN32LDFLAGS)
 492 AC_SUBST(WIN32LIBADD)
 493
 494 # target stuff:
 495
 496 # Canonicalize the secondary target names.
 497 if test -n "$enable_targets" ; then
 498     for targ in `echo $enable_targets | sed 's/,/ /g'`
 499     do
 500         result=`$ac_config_sub $targ 2>/dev/null`
 501         if test -n "$result" ; then
 502             canon_targets="$canon_targets $result"
 503         else
 504             # Allow targets that config.sub doesn't recognize, like "all".
 505             canon_targets="$canon_targets $targ"
 506         fi
 507     done
 508 fi
 509
 510 all_targets=false
 511 defvec=
 512 selvecs=
 513 assocvecs=
 514 selarchs=
 515 TDEFINES=
 516 for targ in $target $canon_targets
 517 do
 518     if test "x$targ" = "xall"; then
 519         all_targets=true
 520         assocvecs="$assocvecs $targ_defvec $targ_selvecs"
 521     else
 522         . $srcdir/config.bfd
 523         if test "x$targ" = "x$target"; then
 524             defvec=$targ_defvec
 525         fi
 526         selvecs="$selvecs $targ_defvec $targ_selvecs"
 527         selarchs="$selarchs $targ_archs"
 528         TDEFINES="$TDEFINES $targ_cflags"
 529     fi
 530 done
 531 AC_SUBST(TDEFINES)
 532
 533 # This processing still needs to be done if we're to decide properly whether
 534 # 64-bit support needs to be compiled in.  Currently, it will be included if
 535 # the default or any other explicitly requested target requires it; it
 536 # will not be included on a 32-bit host if no 64-bit target is requested, and
 537 # no "--with-64-bit-bfd" option is given, even if "--enable-targets=all" is
 538 # used.
 539
 540 # uniq the default and selected vectors in all the configured targets.
 541 f=""
 542 for i in $selvecs ; do
 543     case " $f " in
 544     *" $i "*) ;;
 545     *) f="$f $i" ;;
 546     esac
 547 done
 548 selvecs="$f"
 549
 550
 551 # uniq the associated vectors in all the configured targets.
 552 f=""
 553 for i in $assocvecs ; do
 554     case " $f " in
 555     *" $i "*) ;;
 556     *) f="$f $i" ;;
 557     esac
 558 done
 559 assocvecs="$f"
 560
 561
 562 # uniq the architectures in all the configured targets.
 563 f=""
 564 for i in $selarchs ; do
 565     case " $f " in
 566     *" $i "*) ;;
 567     *) f="$f $i" ;;
 568     esac
 569 done
 570 selarchs="$f"
 571
 572 # Target backend .o files.
 573 tb=
 574
 575 elf="elf.lo elflink.lo elf-attrs.lo elf-strtab.lo elf-eh-frame.lo dwarf1.lo"
 576
 577 for vec in $selvecs
 578 do
 579     target_size=32
 580     case "$vec" in
 581     # This list is alphabetized to make it easy to compare
 582     # with the two vector lists in targets.c.  For the same reason,
 583     # use one entry per line, even though this leads to long lines.
 584     a_out_adobe_vec)            tb="$tb aout-adobe.lo aout32.lo" ;;
 585     aix5coff64_vec)             tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 586     aout0_big_vec)              tb="$tb aout0.lo aout32.lo" ;;
 587     aout_arm_big_vec)           tb="$tb aout-arm.lo aout32.lo" ;;
 588     aout_arm_little_vec)        tb="$tb aout-arm.lo aout32.lo" ;;
 589     apollocoff_vec)             tb="$tb coff-apollo.lo" ;;
 590     arm_epoc_pe_big_vec)        tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 591     arm_epoc_pe_little_vec)     tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 592     arm_epoc_pei_big_vec)       tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 593     arm_epoc_pei_little_vec)    tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 594     arm_wince_pe_big_vec)       tb="$tb pe-arm-wince.lo pe-arm.lo peigen.lo cofflink.lo " ;;
 595     arm_wince_pe_little_vec)    tb="$tb pe-arm-wince.lo pe-arm.lo peigen.lo cofflink.lo " ;;
 596     arm_wince_pei_big_vec)      tb="$tb pei-arm-wince.lo pei-arm.lo peigen.lo cofflink.lo " ;;
 597     arm_wince_pei_little_vec)   tb="$tb pei-arm-wince.lo pei-arm.lo peigen.lo cofflink.lo " ;;
 598     armcoff_big_vec)            tb="$tb coff-arm.lo cofflink.lo " ;;
 599     armcoff_little_vec)         tb="$tb coff-arm.lo cofflink.lo " ;;
 600     armnetbsd_vec)              tb="$tb armnetbsd.lo aout32.lo" ;;
 601     armpe_big_vec)              tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 602     armpe_little_vec)           tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 603     armpei_big_vec)             tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 604     armpei_little_vec)          tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 605     b_out_vec_big_host)         tb="$tb bout.lo aout32.lo" ;;
 606     b_out_vec_little_host)      tb="$tb bout.lo aout32.lo" ;;
 607     bfd_efi_app_ia32_vec)       tb="$tb efi-app-ia32.lo peigen.lo cofflink.lo" ;;
 608     bfd_efi_app_x86_64_vec)     tb="$tb efi-app-x86_64.lo pex64igen.lo cofflink.lo" ;target_size=64;;
 609     bfd_efi_app_ia64_vec)       tb="$tb efi-app-ia64.lo pepigen.lo cofflink.lo"; target_size=64 ;;
 610     bfd_elf32_am33lin_vec)      tb="$tb elf32-am33lin.lo elf32.lo $elf" ;;
 611     bfd_elf32_avr_vec)          tb="$tb elf32-avr.lo elf32.lo $elf" ;;
 612     bfd_elf32_bfin_vec)         tb="$tb elf32-bfin.lo elf32.lo $elf" ;;
 613     bfd_elf32_bfinfdpic_vec)    tb="$tb elf32-bfin.lo elf32.lo $elf" ;;
 614     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 615     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 616     bfd_elf32_bigarm_vec)       tb="$tb elf32-arm.lo elf32.lo elf-vxworks.lo $elf" ;;
 617     bfd_elf32_bigarm_symbian_vec)
 618                                 tb="$tb elf32-arm.lo elf32.lo elf-vxworks.lo $elf" ;;
 619     bfd_elf32_bigarm_vxworks_vec)
 620                                 tb="$tb elf32-arm.lo elf32.lo elf-vxworks.lo $elf" ;;
 621     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo" ;;
 622     bfd_elf32_bigmips_vxworks_vec)
 623                                 tb="$tb elf32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo" ;;
 624     bfd_elf32_cr16_vec)         tb="$tb elf32-cr16.lo elf32.lo $elf" ;;
 625     bfd_elf32_cr16c_vec)        tb="$tb elf32-cr16c.lo elf32.lo $elf" ;;
 626     bfd_elf32_cris_vec)         tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 627     bfd_elf32_crx_vec)          tb="$tb elf32-crx.lo elf32.lo $elf" ;;
 628     bfd_elf32_d10v_vec)         tb="$tb elf32-d10v.lo elf32.lo $elf" ;;
 629     bfd_elf32_d30v_vec)         tb="$tb elf32-d30v.lo elf32.lo $elf" ;;
 630     bfd_elf32_dlx_big_vec)      tb="$tb elf32-dlx.lo elf32.lo $elf" ;;
 631     bfd_elf32_fr30_vec)         tb="$tb elf32-fr30.lo elf32.lo $elf" ;;
 632     bfd_elf32_frv_vec)          tb="$tb elf32-frv.lo elf32.lo $elf" ;;
 633     bfd_elf32_frvfdpic_vec)     tb="$tb elf32-frv.lo elf32.lo $elf" ;;
 634     bfd_elf32_h8300_vec)        tb="$tb elf32-h8300.lo elf32.lo $elf" ;;
 635     bfd_elf32_hppa_linux_vec)   tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 636     bfd_elf32_hppa_nbsd_vec)    tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 637     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 638     bfd_elf32_i370_vec)         tb="$tb elf32-i370.lo elf32.lo $elf" ;;
 639     bfd_elf32_i386_dragonfly_vec)
 640                                 tb="$tb elf32-i386.lo elf-vxworks.lo elf32.lo $elf" ;;
 641     bfd_elf32_i386_freebsd_vec) tb="$tb elf32-i386.lo elf-vxworks.lo elf32.lo $elf" ;;
 642     bfd_elf32_i386_vxworks_vec) tb="$tb elf32-i386.lo elf-vxworks.lo elf32.lo $elf" ;;
 643     bfd_elf32_i386_vec)         tb="$tb elf32-i386.lo elf-vxworks.lo elf32.lo $elf" ;;
 644     bfd_elf32_i860_little_vec)  tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 645     bfd_elf32_i860_vec)         tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 646     bfd_elf32_i960_vec)         tb="$tb elf32-i960.lo elf32.lo $elf" ;;
 647     bfd_elf32_ia64_big_vec)     tb="$tb elf32-ia64.lo elf32.lo $elf" ;;
 648     bfd_elf32_ia64_hpux_big_vec) tb="$tb elf32-ia64.lo elf32.lo $elf";;
 649     bfd_elf32_ip2k_vec)         tb="$tb elf32-ip2k.lo elf32.lo $elf" ;;
 650     bfd_elf32_iq2000_vec)       tb="$tb elf32-iq2000.lo elf32.lo $elf" ;;
 651     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 652     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 653     bfd_elf32_littlearm_symbian_vec)
 654                                 tb="$tb elf32-arm.lo elf32.lo elf-vxworks.lo $elf" ;;
 655     bfd_elf32_littlearm_vxworks_vec)
 656                                 tb="$tb elf32-arm.lo elf32.lo elf-vxworks.lo $elf" ;;
 657     bfd_elf32_littlearm_vec)    tb="$tb elf32-arm.lo elf32.lo elf-vxworks.lo $elf" ;;
 658     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo" ;;
 659     bfd_elf32_littlemips_vxworks_vec)
 660                                 tb="$tb elf32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo" ;;
 661     bfd_elf32_m32c_vec)         tb="$tb elf32-m32c.lo elf32.lo $elf" ;;
 662     bfd_elf32_m32r_vec)         tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 663     bfd_elf32_m32rle_vec)       tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 664     bfd_elf32_m32rlin_vec)      tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 665     bfd_elf32_m32rlelin_vec)    tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 666     bfd_elf32_m68hc11_vec)      tb="$tb elf32-m68hc11.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
 667     bfd_elf32_m68hc12_vec)      tb="$tb elf32-m68hc12.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
 668     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.lo elf32.lo $elf" ;;
 669     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.lo elf32.lo $elf" ;;
 670     bfd_elf32_mcore_big_vec)    tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 671     bfd_elf32_mcore_little_vec) tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 672     bfd_elf32_mep_vec)          tb="$tb elf32-mep.lo elf32.lo $elf" ;;
 673     bfd_elf32_mep_little_vec)   tb="$tb elf32-mep.lo elf32.lo $elf" ;;
 674     bfd_elf32_mn10200_vec)      tb="$tb elf-m10200.lo elf32.lo $elf" ;;
 675     bfd_elf32_mn10300_vec)      tb="$tb elf-m10300.lo elf32.lo $elf" ;;
 676     bfd_elf32_mt_vec)           tb="$tb elf32-mt.lo elf32.lo $elf" ;;
 677     bfd_elf32_msp430_vec)       tb="$tb elf32-msp430.lo elf32.lo $elf" ;;
 678     bfd_elf32_nbigmips_vec)     tb="$tb elfn32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 679     bfd_elf32_nlittlemips_vec)  tb="$tb elfn32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 680     bfd_elf32_ntradbigmips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 681     bfd_elf32_ntradlittlemips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 682     bfd_elf32_openrisc_vec)     tb="$tb elf32-openrisc.lo elf32.lo $elf" ;;
 683     bfd_elf32_or32_big_vec)     tb="$tb elf32-or32.lo elf32.lo $elf" ;;
 684     bfd_elf32_pj_vec)           tb="$tb elf32-pj.lo elf32.lo $elf";;
 685     bfd_elf32_pjl_vec)          tb="$tb elf32-pj.lo elf32.lo $elf";;
 686     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.lo elf-vxworks.lo elf32.lo $elf" ;;
 687     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.lo elf-vxworks.lo elf32.lo $elf" ;;
 688     bfd_elf32_powerpc_vxworks_vec) tb="$tb elf32-ppc.lo elf-vxworks.lo elf32.lo $elf" ;;
 689     bfd_elf32_s390_vec)         tb="$tb elf32-s390.lo elf32.lo $elf" ;;
 690     bfd_elf32_bigscore_vec)     tb="$tb elf32-score.lo elf32.lo $elf" ;;
 691     bfd_elf32_littlescore_vec)  tb="$tb elf32-score.lo elf32.lo $elf" ;;
 692     # FIXME: We include cofflink.lo not because it's needed for
 693     # bfd_elf32_sh64[l]_vec, but because we include bfd_elf32_sh[l]_vec
 694     # which needs it but does not list it.  Should be fixed in right place.
 695     bfd_elf32_sh64_vec)         tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf-vxworks.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 696     bfd_elf32_sh64l_vec)        tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf-vxworks.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 697     bfd_elf32_sh64lin_vec)      tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf-vxworks.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 698     bfd_elf32_sh64blin_vec)     tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf-vxworks.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 699     bfd_elf32_sh64lnbsd_vec)    tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf-vxworks.lo elf32.lo $elf cofflink.lo" ;;
 700     bfd_elf32_sh64nbsd_vec)     tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf-vxworks.lo elf32.lo $elf cofflink.lo" ;;
 701     bfd_elf32_sh_vec)           tb="$tb elf32-sh.lo elf-vxworks.lo elf32.lo $elf coff-sh.lo" ;;
 702     bfd_elf32_shblin_vec)       tb="$tb elf32-sh.lo elf-vxworks.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 703     bfd_elf32_shl_vec)          tb="$tb elf32-sh.lo elf-vxworks.lo elf32.lo $elf coff-sh.lo" ;;
 704     bfd_elf32_shl_symbian_vec)  tb="$tb elf32-sh-symbian.lo elf32-sh64-com.lo elf-vxworks.lo elf32.lo $elf coff-sh.lo" ;;
 705     bfd_elf32_shlin_vec)        tb="$tb elf32-sh.lo elf-vxworks.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 706     bfd_elf32_shlnbsd_vec)      tb="$tb elf32-sh.lo elf-vxworks.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 707     bfd_elf32_shlvxworks_vec)   tb="$tb elf32-sh.lo elf-vxworks.lo elf32.lo $elf coff-sh.lo" ;;
 708     bfd_elf32_shnbsd_vec)       tb="$tb elf32-sh.lo elf-vxworks.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 709     bfd_elf32_shvxworks_vec)    tb="$tb elf32-sh.lo elf-vxworks.lo elf32.lo $elf coff-sh.lo" ;;
 710     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.lo elfxx-sparc.lo elf-vxworks.lo elf32.lo $elf" ;;
 711     bfd_elf32_sparc_vxworks_vec) tb="$tb elf32-sparc.lo elfxx-sparc.lo elf-vxworks.lo elf32.lo $elf" ;;
 712     bfd_elf32_spu_vec)          tb="$tb elf32-spu.lo elf32.lo $elf" ;;
 713     bfd_elf32_tradbigmips_vec)  tb="$tb elf32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo" ;;
 714     bfd_elf32_tradlittlemips_vec) tb="$tb elf32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo" ;;
 715     bfd_elf32_us_cris_vec)      tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 716     bfd_elf32_v850_vec)         tb="$tb elf32-v850.lo elf32.lo $elf" ;;
 717     bfd_elf32_vax_vec)          tb="$tb elf32-vax.lo elf32.lo $elf" ;;
 718     bfd_elf32_xstormy16_vec)    tb="$tb elf32-xstormy16.lo elf32.lo $elf" ;;
 719     bfd_elf32_xc16x_vec)                tb="$tb elf32-xc16x.lo elf32.lo $elf" ;;
 720     bfd_elf32_xtensa_le_vec)    tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
 721     bfd_elf32_xtensa_be_vec)    tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
 722     bfd_elf64_alpha_freebsd_vec) tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 723     bfd_elf64_alpha_vec)        tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 724     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 725     bfd_elf64_bigmips_vec)      tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 726     bfd_elf64_hppa_linux_vec)   tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 727     bfd_elf64_hppa_vec)         tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 728     bfd_elf64_ia64_big_vec)     tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 729     bfd_elf64_ia64_hpux_big_vec) tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 730     bfd_elf64_ia64_little_vec)  tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 731     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 732     bfd_elf64_littlemips_vec)   tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 733     bfd_elf64_mmix_vec)         tb="$tb elf64-mmix.lo elf64.lo $elf" target_size=64 ;;
 734     bfd_elf64_powerpc_vec)      tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 735     bfd_elf64_powerpcle_vec)    tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf" target_size=64 ;;
 736     bfd_elf64_s390_vec)         tb="$tb elf64-s390.lo elf64.lo $elf"; target_size=64 ;;
 737     bfd_elf64_sh64_vec)         tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 738     bfd_elf64_sh64l_vec)        tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 739     bfd_elf64_sh64lin_vec)      tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 740     bfd_elf64_sh64blin_vec)     tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 741     bfd_elf64_sh64lnbsd_vec)    tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 742     bfd_elf64_sh64nbsd_vec)     tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 743     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.lo elfxx-sparc.lo elf-vxworks.lo elf64.lo $elf"; target_size=64 ;;
 744     bfd_elf64_sparc_freebsd_vec) tb="$tb elf64-sparc.lo elfxx-sparc.lo elf-vxworks.lo elf64.lo $elf"; target_size=64 ;;
 745     bfd_elf64_tradbigmips_vec)  tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 746     bfd_elf64_tradlittlemips_vec) tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 747     bfd_elf64_x86_64_freebsd_vec) tb="$tb elf64-x86-64.lo elf64.lo $elf"; target_size=64 ;;
 748     bfd_elf64_x86_64_vec)       tb="$tb elf64-x86-64.lo elf64.lo $elf"; target_size=64 ;;
 749     bfd_mmo_vec)                tb="$tb mmo.lo" target_size=64 ;;
 750     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 751     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 752     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 753     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 754     cris_aout_vec)              tb="$tb aout-cris.lo" ;;
 755     demo_64_vec)                tb="$tb demo64.lo aout64.lo"; target_size=64 ;;
 756     ecoff_big_vec)              tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 757     ecoff_biglittle_vec)        tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 758     ecoff_little_vec)           tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 759     ecoffalpha_little_vec)      tb="$tb coff-alpha.lo ecoff.lo ecofflink.lo"; target_size=64 ;;
 760     go32coff_vec)               tb="$tb coff-go32.lo cofflink.lo" ;;
 761     go32stubbedcoff_vec)        tb="$tb coff-stgo32.lo cofflink.lo" ;;
 762     h8300coff_vec)              tb="$tb coff-h8300.lo reloc16.lo" ;;
 763     h8500coff_vec)              tb="$tb coff-h8500.lo reloc16.lo" ;;
 764     host_aout_vec)              tb="$tb host-aout.lo aout32.lo" ;;
 765     hp300bsd_vec)               tb="$tb hp300bsd.lo aout32.lo" ;;
 766     hp300hpux_vec)              tb="$tb hp300hpux.lo aout32.lo" ;;
 767     i386aout_vec)               tb="$tb i386aout.lo aout32.lo" ;;
 768     i386bsd_vec)                tb="$tb i386bsd.lo aout32.lo" ;;
 769     i386coff_vec)               tb="$tb coff-i386.lo cofflink.lo" ;;
 770     x86_64coff_vec)             tb="$tb coff-x86_64.lo cofflink.lo"; target_size=64 ;;
 771     i386dynix_vec)              tb="$tb i386dynix.lo aout32.lo" ;;
 772     i386freebsd_vec)            tb="$tb i386freebsd.lo aout32.lo" ;;
 773     i386linux_vec)              tb="$tb i386linux.lo aout32.lo" ;;
 774     i386lynx_aout_vec)          tb="$tb i386lynx.lo lynx-core.lo aout32.lo" ;;
 775     i386lynx_coff_vec)          tb="$tb cf-i386lynx.lo cofflink.lo lynx-core.lo" ;;
 776     i386mach3_vec)              tb="$tb i386mach3.lo aout32.lo" ;;
 777     i386msdos_vec)              tb="$tb i386msdos.lo" ;;
 778     i386netbsd_vec)             tb="$tb i386netbsd.lo aout32.lo" ;;
 779     i386os9k_vec)               tb="$tb i386os9k.lo aout32.lo" ;;
 780     i386pe_vec)                 tb="$tb pe-i386.lo peigen.lo cofflink.lo" ;;
 781     i386pei_vec)                tb="$tb pei-i386.lo peigen.lo cofflink.lo" ;;
 782     x86_64pe_vec)               tb="$tb pe-x86_64.lo pex64igen.lo cofflink.lo"; target_size=64 ;;
 783     x86_64pei_vec)              tb="$tb pei-x86_64.lo pex64igen.lo cofflink.lo"; target_size=64 ;;
 784     i860coff_vec)               tb="$tb coff-i860.lo cofflink.lo" ;;
 785     icoff_big_vec)              tb="$tb coff-i960.lo cofflink.lo" ;;
 786     icoff_little_vec)           tb="$tb coff-i960.lo cofflink.lo" ;;
 787     ieee_vec)                   tb="$tb ieee.lo" ;;
 788     m68k4knetbsd_vec)           tb="$tb m68k4knetbsd.lo aout32.lo" ;;
 789     m68kaux_coff_vec)           tb="$tb coff-aux.lo coff-m68k.lo cofflink.lo" ;;
 790     m68kcoff_vec)               tb="$tb coff-m68k.lo cofflink.lo" ;;
 791     m68kcoffun_vec)             tb="$tb coff-u68k.lo coff-m68k.lo cofflink.lo" ;;
 792     m68klinux_vec)              tb="$tb m68klinux.lo aout32.lo" ;;
 793     m68knetbsd_vec)             tb="$tb m68knetbsd.lo aout32.lo" ;;
 794     m68ksysvcoff_vec)           tb="$tb coff-svm68k.lo cofflink.lo" ;;
 795     m88kbcs_vec)                tb="$tb coff-m88k.lo" ;;
 796     m88kmach3_vec)              tb="$tb m88kmach3.lo aout32.lo" ;;
 797     m88kopenbsd_vec)            tb="$tb m88kopenbsd.lo aout32.lo" ;;
 798     maxqcoff_vec)               tb="$tb coff-maxq.lo" ;;
 799     mach_o_be_vec)              tb="$tb mach-o.lo" ;;
 800     mach_o_le_vec)              tb="$tb mach-o.lo" ;;
 801     mach_o_fat_vec)             tb="$tb mach-o.lo" ;;
 802     mcore_pe_big_vec)           tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 803     mcore_pe_little_vec)        tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 804     mcore_pei_big_vec)          tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 805     mcore_pei_little_vec)       tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 806     mipslpe_vec)                tb="$tb pe-mips.lo peigen.lo cofflink.lo" ;;
 807     mipslpei_vec)               tb="$tb pei-mips.lo peigen.lo cofflink.lo" ;;
 808     newsos3_vec)                tb="$tb newsos3.lo aout32.lo" ;;
 809     nlm32_alpha_vec)            tb="$tb nlm32-alpha.lo nlm32.lo nlm.lo"; target_size=64 ;;
 810     nlm32_i386_vec)             tb="$tb nlm32-i386.lo nlm32.lo nlm.lo" ;;
 811     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.lo nlm32.lo nlm.lo" ;;
 812     nlm32_sparc_vec)            tb="$tb nlm32-sparc.lo nlm32.lo nlm.lo" ;;
 813     or32coff_big_vec)           tb="$tb coff-or32.lo cofflink.lo" ;;
 814     pc532machaout_vec)          tb="$tb pc532-mach.lo aout-ns32k.lo" ;;
 815     pc532netbsd_vec)            tb="$tb ns32knetbsd.lo aout-ns32k.lo" ;;
 816     pef_vec)                    tb="$tb pef.lo" ;;
 817     pef_xlib_vec)               tb="$tb pef.lo" ;;
 818     pdp11_aout_vec)             tb="$tb pdp11.lo" ;;
 819     pmac_xcoff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 820     ppcboot_vec)                tb="$tb ppcboot.lo" ;;
 821     riscix_vec)                 tb="$tb aout32.lo riscix.lo" ;;
 822     rs6000coff64_vec)           tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 823     rs6000coff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 824     shcoff_small_vec)           tb="$tb coff-sh.lo cofflink.lo" ;;
 825     shcoff_vec)                 tb="$tb coff-sh.lo cofflink.lo" ;;
 826     shlcoff_small_vec)          tb="$tb coff-sh.lo cofflink.lo" ;;
 827     shlcoff_vec)                tb="$tb coff-sh.lo cofflink.lo" ;;
 828     shlpe_vec)                  tb="$tb pe-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 829     shlpei_vec)                 tb="$tb pei-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 830     som_vec)                    tb="$tb som.lo" ;;
 831     sparccoff_vec)              tb="$tb coff-sparc.lo" ;;
 832     sparcle_aout_vec)           tb="$tb aout-sparcle.lo aout32.lo" ;;
 833     sparclinux_vec)             tb="$tb sparclinux.lo aout32.lo" ;;
 834     sparclynx_aout_vec)         tb="$tb sparclynx.lo lynx-core.lo aout32.lo" ;;
 835     sparclynx_coff_vec)         tb="$tb cf-sparclynx.lo lynx-core.lo" ;;
 836     sparcnetbsd_vec)            tb="$tb sparcnetbsd.lo aout32.lo" ;;
 837     sunos_big_vec)              tb="$tb sunos.lo aout32.lo" ;;
 838     sym_vec)                    tb="$tb xsym.lo" ;;
 839     tic30_aout_vec)             tb="$tb aout-tic30.lo" ;;
 840     tic30_coff_vec)             tb="$tb coff-tic30.lo" ;;
 841     tic4x_coff0_vec)            tb="$tb coff-tic4x.lo" ;;
 842     tic4x_coff0_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 843     tic4x_coff1_vec)            tb="$tb coff-tic4x.lo" ;;
 844     tic4x_coff1_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 845     tic4x_coff2_vec)            tb="$tb coff-tic4x.lo" ;;
 846     tic4x_coff2_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 847     tic54x_coff0_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 848     tic54x_coff0_vec)           tb="$tb coff-tic54x.lo" ;;
 849     tic54x_coff1_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 850     tic54x_coff1_vec)           tb="$tb coff-tic54x.lo" ;;
 851     tic54x_coff2_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 852     tic54x_coff2_vec)           tb="$tb coff-tic54x.lo" ;;
 853     tic80coff_vec)              tb="$tb coff-tic80.lo cofflink.lo" ;;
 854     vaxnetbsd_vec)              tb="$tb vaxnetbsd.lo aout32.lo" ;;
 855     vax1knetbsd_vec)            tb="$tb vax1knetbsd.lo aout32.lo" ;;
 856     vaxbsd_vec)                 tb="$tb vaxbsd.lo aout32.lo" ;;
 857     versados_vec)               tb="$tb versados.lo" ;;
 858     vms_alpha_vec)              tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo"; target_size=64 ;;
 859     vms_vax_vec)                tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo" ;;
 860     w65_vec)                    tb="$tb coff-w65.lo reloc16.lo" ;;
 861     we32kcoff_vec)              tb="$tb coff-we32k.lo" ;;
 862     z80coff_vec)                tb="$tb coff-z80.lo reloc16.lo" ;;
 863     z8kcoff_vec)                tb="$tb coff-z8k.lo reloc16.lo cofflink.lo" ;;
 864
 865     # These appear out of order in targets.c
 866     srec_vec)                   tb="$tb srec.lo" ;;
 867     symbolsrec_vec)             tb="$tb srec.lo" ;;
 868     tekhex_vec)                 tb="$tb tekhex.lo" ;;
 869     cisco_core_big_vec)         tb="$tb cisco-core.lo" ;;
 870     cisco_core_little_vec)      tb="$tb cisco-core.lo" ;;
 871
 872     "")                 ;;
 873     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 874     esac
 875
 876     if test ${target_size} = 64; then
 877         target64=true
 878     fi
 879     if test x"${vec}" = x"${defvec}"; then
 880         bfd_default_target_size=${target_size}
 881     fi
 882 done
 883
 884 # Target architecture .o files.
 885 # A couple of CPUs use shorter file names to avoid problems on DOS
 886 # filesystems.
 887 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.lo/g -e s/mn10200/m10200/ -e s/mn10300/m10300/`
 888
 889 # Weed out duplicate .o files.
 890 f=""
 891 for i in $tb ; do
 892     case " $f " in
 893     *" $i "*) ;;
 894     *) f="$f $i" ;;
 895     esac
 896 done
 897 tb="$f"
 898
 899 f=""
 900 for i in $ta ; do
 901     case " $f " in
 902     *" $i "*) ;;
 903     *) f="$f $i" ;;
 904     esac
 905 done
 906 ta="$f"
 907
 908 bfd_backends="$tb"
 909 bfd_machines="$ta"
 910
 911 if test x${all_targets} = xtrue ; then
 912   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 913   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 914   selvecs=
 915   havevecs=
 916   selarchs=
 917   test -n "$assocvecs" &&
 918     assocvecs=`echo $assocvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 919 else    # all_targets is true
 920   # Only set these if they will be nonempty, for the clever echo.
 921   havevecs=
 922   assocvecs=
 923   test -n "$selvecs" &&
 924     havevecs=`echo $selvecs | sed -e 's/^/-DHAVE_/' -e 's/ \(.\)/ -DHAVE_\1/g'`
 925   test -n "$selvecs" &&
 926     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 927   test -n "$selarchs" &&
 928     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 929 fi      # all_targets is true
 930
 931 case ${host64}-${target64}-${want64} in
 932   *true*)
 933     wordsize=64
 934     bfd64_libs='$(BFD64_LIBS)'
 935     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 936     if test $BFD_HOST_64_BIT_DEFINED = 0; then
 937       AC_MSG_WARN([You have requested a 64 bit BFD configuration, but])
 938       AC_MSG_WARN([your compiler may not have a 64 bit integral type])
 939     fi
 940     if test -n "$GCC" ; then
 941        bad_64bit_gcc=no;
 942        AC_MSG_CHECKING([for gcc version with buggy 64-bit support])
 943        # Add more tests for gcc versions with non-working 64-bit support here.
 944        AC_EGREP_CPP([: 2 : 91 : 1 :],[:__GNUC__:__GNUC_MINOR__:__i386__:],
 945                     bad_64bit_gcc=yes;
 946                     AC_MSG_RESULT([yes: egcs-1.1.2 on ix86 spotted]),
 947                     AC_MSG_RESULT(no))
 948        if test $bad_64bit_gcc = yes ; then
 949          AC_MSG_ERROR([A newer version of gcc is needed for the requested 64-bit BFD configuration])
 950        fi
 951     fi
 952     ;;
 953   false-false-false)
 954     wordsize=32
 955     all_backends='$(BFD32_BACKENDS)'
 956     ;;
 957 esac
 958
 959 AC_SUBST(wordsize)
 960 AC_SUBST(bfd64_libs)
 961 AC_SUBST(all_backends)
 962 AC_SUBST(bfd_backends)
 963 AC_SUBST(bfd_machines)
 964 AC_SUBST(bfd_default_target_size)
 965
 966 # Determine the host dependant file_ptr a.k.a. off_t type.  In order
 967 # prefer: off64_t - if ftello64 and fseeko64, off_t - if ftello and
 968 # fseeko, long.  This assumes that sizeof off_t is .ge. sizeof long.
 969 # Hopefully a reasonable assumption since fseeko et.al. should be
 970 # upward compatible.
 971 AC_CHECK_FUNCS(ftello ftello64 fseeko fseeko64 fopen64)
 972 if test x"$ac_cv_func_ftello" = xyes -a x"$ac_cv_func_fseeko" = xyes; then
 973     AC_CHECK_SIZEOF(off_t)
 974 fi
 975 AC_MSG_CHECKING([file_ptr type])
 976 bfd_file_ptr="long"
 977 bfd_ufile_ptr="unsigned long"
 978 if test x"$ac_cv_func_ftello64" = xyes -a x"$ac_cv_func_fseeko64" = xyes \
 979         -o x"${ac_cv_sizeof_off_t}" = x8; then
 980     bfd_file_ptr=BFD_HOST_64_BIT
 981     bfd_ufile_ptr=BFD_HOST_U_64_BIT
 982 fi
 983 AC_MSG_RESULT($bfd_file_ptr)
 984 AC_SUBST(bfd_file_ptr)
 985 AC_SUBST(bfd_ufile_ptr)
 986
 987
 988 tdefaults=""
 989 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 990 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 991 test -n "${assocvecs}" && tdefaults="${tdefaults} -DASSOCIATED_VECS='${assocvecs}'"
 992 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 993 test -n "${havevecs}" && tdefaults="${tdefaults} ${havevecs}"
 994 AC_SUBST(tdefaults)
 995
 996 dnl AC_CHECK_HEADERS(sys/mman.h)
 997 AC_FUNC_MMAP
 998 AC_CHECK_FUNCS(madvise mprotect)
 999 case ${want_mmap}+${ac_cv_func_mmap_fixed_mapped} in
1000   true+yes )  AC_DEFINE(USE_MMAP, 1, [Use mmap if it's available?]) ;;
1001 esac
1002
1003 rm -f doc/config.status
1004 AC_CONFIG_FILES([Makefile doc/Makefile bfd-in3.h:bfd-in2.h po/Makefile.in:po/Make-in])
1005
1006 dnl We need this duplication, even though we use AM_PO_SUBDIRS, because of
1007 dnl our two separate POTFILES.  Yuck.
1008 AC_CONFIG_COMMANDS([default],
1009 [[
1010 case "$srcdir" in
1011   .) srcdirpre= ;;
1012   *) srcdirpre='$(srcdir)/' ;;
1013 esac
1014 POFILES=
1015 GMOFILES=
1016 for lang in dummy $OBSOLETE_ALL_LINGUAS; do
1017   if test $lang != dummy; then
1018     POFILES="$POFILES $srcdirpre$lang.po"
1019     GMOFILES="$GMOFILES $srcdirpre$lang.gmo"
1020   fi
1021 done
1022 sed -e '/SRC-POTFILES =/r po/SRC-POTFILES' \
1023     -e '/BLD-POTFILES =/r po/BLD-POTFILES' \
1024     -e "s,@POFILES@,$POFILES," \
1025     -e "s,@GMOFILES@,$GMOFILES," \
1026     po/Makefile.in > po/Makefile]],[[]])
1027
1028 dnl Required by html and install-html
1029 AC_SUBST(datarootdir)
1030 AC_SUBST(docdir)
1031 AC_SUBST(htmldir)
1032
1033 AC_OUTPUT
1034