ld/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 AC_PREREQ(2.59)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR(ldmain.c)
   6
   7 AC_CANONICAL_TARGET
   8 AC_CANONICAL_BUILD
   9 AC_ISC_POSIX
  10
  11 changequote(,)dnl
  12 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  13 changequote([,])dnl
  14 AM_INIT_AUTOMAKE(ld, ${BFD_VERSION})
  15 AM_MAINTAINER_MODE
  16
  17 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  18 AC_ARG_ENABLE(targets,
  19 [  --enable-targets        alternative target configurations],
  20 [case "${enableval}" in
  21   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  22             ;;
  23   no)       enable_targets= ;;
  24   *)        enable_targets=$enableval ;;
  25 esac])dnl
  26 AC_ARG_ENABLE(64-bit-bfd,
  27 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  28 [case "${enableval}" in
  29   yes)  want64=true  ;;
  30   no)   want64=false ;;
  31   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  32 esac],[want64=false])dnl
  33
  34 AC_ARG_WITH(sysroot,
  35 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  36 [
  37  case ${with_sysroot} in
  38  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  39  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  40  esac
  41
  42  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  43  use_sysroot=yes
  44
  45  if test "x$prefix" = xNONE; then
  46   test_prefix=/usr/local
  47  else
  48   test_prefix=$prefix
  49  fi
  50  if test "x$exec_prefix" = xNONE; then
  51   test_exec_prefix=$test_prefix
  52  else
  53   test_exec_prefix=$exec_prefix
  54  fi
  55  case ${TARGET_SYSTEM_ROOT} in
  56  "${test_prefix}"|"${test_prefix}/"*|\
  57  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  58  '${prefix}'|'${prefix}/'*|\
  59  '${exec_prefix}'|'${exec_prefix}/'*)
  60    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  61    TARGET_SYSTEM_ROOT_DEFINE="$t"
  62    ;;
  63  esac
  64 ], [
  65  use_sysroot=no
  66  TARGET_SYSTEM_ROOT=
  67  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  68 ])
  69 AC_SUBST(use_sysroot)
  70 AC_SUBST(TARGET_SYSTEM_ROOT)
  71 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  72
  73 dnl Use --enable-gold to decide if this linker should be the default.
  74 dnl "install_as_default" is set to false if gold is the default linker.
  75 dnl "installed_linker" is the installed BFD linker name.
  76 AC_ARG_ENABLE(gold,
  77 [[  --enable-gold[=ARG]     build gold [ARG={default,yes,no}]]],
  78 [case "${enableval}" in
  79  default)
  80    install_as_default=no
  81    installed_linker=ld.bfd
  82    ;;
  83  yes|no)
  84    install_as_default=yes
  85    installed_linker=ld.bfd
  86    ;;
  87  *)
  88    AC_MSG_ERROR([invalid --enable-gold argument])
  89    ;;
  90  esac],
  91 [install_as_default=yes
  92  installed_linker=ld.bfd])
  93 AC_SUBST(install_as_default)
  94 AC_SUBST(installed_linker)
  95
  96 AC_ARG_ENABLE([got],
  97 AS_HELP_STRING([--enable-got=<type>],
  98                [GOT handling scheme (target, single, negative, multigot)]),
  99 [case "${enableval}" in
 100   target | single | negative | multigot)  got_handling=$enableval ;;
 101   *)  AC_MSG_ERROR(bad value ${enableval} for --enable-got option) ;;
 102 esac],
 103 [got_handling=target])
 104
 105 case "${got_handling}" in
 106   target)
 107     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
 108               [Define to choose default GOT handling scheme]) ;;
 109   single)
 110     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
 111               [Define to choose default GOT handling scheme]) ;;
 112   negative)
 113     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
 114               [Define to choose default GOT handling scheme]) ;;
 115   multigot)
 116     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
 117               [Define to choose default GOT handling scheme]) ;;
 118   *)  AC_MSG_ERROR(bad value ${got_handling} for --enable-got option) ;;
 119 esac
 120
 121 AM_BINUTILS_WARNINGS
 122
 123 AC_CONFIG_HEADERS([config.h:config.in])
 124
 125 if test -z "$target" ; then
 126     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 127 fi
 128 if test -z "$host" ; then
 129     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 130 fi
 131
 132 # host-specific stuff:
 133
 134 AC_PROG_CC
 135 AC_GNU_SOURCE
 136 AC_USE_SYSTEM_EXTENSIONS
 137 ACX_LARGEFILE
 138 AC_PROG_INSTALL
 139
 140 LT_INIT
 141
 142 ALL_LINGUAS="fr sv tr es da vi zh_CN zh_TW ga fi id bg"
 143 ZW_GNU_GETTEXT_SISTER_DIR
 144 AM_PO_SUBDIRS
 145
 146 AC_EXEEXT
 147
 148 AC_PROG_YACC
 149 AM_PROG_LEX
 150
 151 AM_MAINTAINER_MODE
 152 AM_CONDITIONAL(GENINSRC_NEVER, false)
 153 ACX_PROG_CMP_IGNORE_INITIAL
 154
 155 . ${srcdir}/configure.host
 156
 157 AC_SUBST(HDEFINES)
 158 AC_SUBST(HOSTING_CRT0)
 159 AC_SUBST(HOSTING_LIBS)
 160 AC_SUBST(NATIVE_LIB_DIRS)
 161
 162 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h sys/param.h)
 163 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h sys/stat.h)
 164 AC_CHECK_FUNCS(glob mkstemp realpath sbrk waitpid)
 165 AC_CHECK_FUNCS(open lseek close)
 166 AC_HEADER_DIRENT
 167
 168 # Check for dlopen support and enable plugins if possible.
 169 enable_plugins=yes
 170 AC_CHECK_HEADER([dlfcn.h],[],[enable_plugins=no],[AC_INCLUDES_DEFAULT])
 171 AC_SEARCH_LIBS([dlopen],[dl],[],[enable_plugins=no],[])
 172 AC_CHECK_FUNCS([dlopen dlsym dlclose],[],[enable_plugins=no])
 173 # We also support plugins on Windows (MinGW).
 174 if test x$enable_plugins = xno ; then
 175   AC_CHECK_HEADERS([Windows.h],[enable_plugins=yes],[],[AC_INCLUDES_DEFAULT])
 176 fi
 177 AM_CONDITIONAL([ENABLE_PLUGINS], [test x$enable_plugins = xyes])
 178
 179 AC_ARG_ENABLE(initfini-array,
 180         [  --enable-initfini-array      use .init_array/.fini_array sections],
 181         [], [
 182 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
 183                  gcc_cv_initfini_array, [dnl
 184   if test "x${build}" = "x${target}" ; then
 185     AC_RUN_IFELSE([AC_LANG_SOURCE([
 186 static int x = -1;
 187 int main (void) { return x; }
 188 int foo (void) { x = 0; }
 189 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;])],
 190              [gcc_cv_initfini_array=yes], [gcc_cv_initfini_array=no],
 191              [gcc_cv_initfini_array=no])
 192    else
 193      gcc_cv_initfini_array=no
 194    fi])
 195   enable_initfini_array=$gcc_cv_initfini_array
 196 ])
 197 AC_SUBST(enable_initfini_array)
 198 if test $enable_initfini_array = yes; then
 199   AC_DEFINE(HAVE_INITFINI_ARRAY, 1,
 200     [Define .init_array/.fini_array sections are available and working.])
 201 fi
 202
 203 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 204 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 205 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 206 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 207 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 208 if test $ld_cv_decl_getopt_unistd_h = yes; then
 209   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 210             [Is the prototype for getopt in <unistd.h> in the expected format?])
 211 fi
 212
 213 BFD_BINARY_FOPEN
 214
 215 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 216
 217 # Link in zlib if we can.  This is needed only for the bootstrap tests
 218 # right now, since those tests use libbfd, which depends on zlib.
 219 AC_SEARCH_LIBS(zlibVersion, z, [AC_CHECK_HEADERS(zlib.h)])
 220
 221 # When converting linker scripts into strings for use in emulation
 222 # files, use astring.sed if the compiler supports ANSI string
 223 # concatenation, or ostring.sed otherwise.  This is to support the
 224 # broken Microsoft MSVC compiler, which limits the length of string
 225 # constants, while still supporting pre-ANSI compilers which do not
 226 # support string concatenation.
 227 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 228 AC_CACHE_VAL(ld_cv_string_concatenation,
 229 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [char *a = "a" "a";])],
 230   ld_cv_string_concatenation=yes,
 231   ld_cv_string_concatenation=no)])
 232 AC_MSG_RESULT($ld_cv_string_concatenation)
 233 if test "$ld_cv_string_concatenation" = "yes"; then
 234   STRINGIFY=astring.sed
 235 else
 236   STRINGIFY=ostring.sed
 237 fi
 238 AC_SUBST(STRINGIFY)
 239
 240 # target-specific stuff:
 241
 242 all_targets=
 243 EMUL=
 244 all_emuls=
 245 all_emul_extras=
 246 all_libpath=
 247
 248 dnl We need to get an arbitrary number of tdir definitions into
 249 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 250 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 251 dnl file.
 252 rm -f tdirs
 253
 254 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 255 do
 256   if test "$targ_alias" = "all"; then
 257     all_targets=true
 258   else
 259     # Canonicalize the secondary target names.
 260     result=`$ac_config_sub $targ_alias 2>/dev/null`
 261     if test -n "$result"; then
 262         targ=$result
 263     else
 264         targ=$targ_alias
 265     fi
 266
 267     . ${srcdir}/configure.tgt
 268
 269     if test "$targ" = "$target"; then
 270       EMUL=$targ_emul
 271     fi
 272
 273     if test x${want64} = xfalse; then
 274       . ${srcdir}/../bfd/config.bfd
 275     fi
 276
 277     if test x${want64} = xtrue; then
 278       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 279       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 280     fi
 281
 282     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 283         case " $all_emuls " in
 284         *" e${i}.o "*) ;;
 285         *)
 286           all_emuls="$all_emuls e${i}.o"
 287           eval result=\$tdir_$i
 288           test -z "$result" && result=$targ_alias
 289           echo tdir_$i=$result >> tdirs
 290           ;;
 291         esac
 292     done
 293
 294     for i in $targ_emul $targ_extra_libpath; do
 295         case " $all_libpath " in
 296         *" ${i} "*) ;;
 297         *)
 298           if test -z "$all_libpath"; then
 299             all_libpath=${i}
 300           else
 301             all_libpath="$all_libpath ${i}"
 302           fi
 303           ;;
 304         esac
 305     done
 306
 307     for i in $targ_extra_ofiles; do
 308         case " $all_emul_extras " in
 309         *" ${i} "*) ;;
 310         *)
 311           all_emul_extras="$all_emul_extras ${i}"
 312           ;;
 313         esac
 314     done
 315   fi
 316 done
 317
 318 AC_SUBST(EMUL)
 319
 320 TDIRS=tdirs
 321 AC_SUBST_FILE(TDIRS)
 322
 323 if test x${all_targets} = xtrue; then
 324   if test x${want64} = xfalse; then
 325     AC_CHECK_SIZEOF(long)
 326     if test "x${ac_cv_sizeof_long}" = "x8"; then
 327       want64=true
 328     fi
 329   fi
 330   if test x${want64} = xtrue; then
 331     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 332   else
 333     EMULATION_OFILES='$(ALL_EMULATIONS)'
 334   fi
 335   EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 336 else
 337   EMULATION_OFILES=$all_emuls
 338   EMUL_EXTRA_OFILES=$all_emul_extras
 339 fi
 340 AC_SUBST(EMULATION_OFILES)
 341 AC_SUBST(EMUL_EXTRA_OFILES)
 342 AC_SUBST(LIB_PATH)
 343
 344 EMULATION_LIBPATH=$all_libpath
 345 AC_SUBST(EMULATION_LIBPATH)
 346
 347 if test x${enable_static} = xno; then
 348   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 349 else
 350   TESTBFDLIB="../bfd/.libs/libbfd.a"
 351 fi
 352 AC_SUBST(TESTBFDLIB)
 353
 354 target_vendor=${target_vendor=$host_vendor}
 355 case "$target_vendor" in
 356   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 357   *)  EXTRA_SHLIB_EXTENSION= ;;
 358 esac
 359
 360 case "$target_os" in
 361   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 362 esac
 363
 364 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 365   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 366    [Additional extension a shared object might have.])
 367 fi
 368
 369 dnl Required by html, pdf, install-pdf and install-html
 370 AC_SUBST(datarootdir)
 371 AC_SUBST(docdir)
 372 AC_SUBST(htmldir)
 373 AC_SUBST(pdfdir)
 374
 375 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 376 AC_OUTPUT