gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.57)
   9 AC_INIT(as.h)
  10
  11 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  12 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  13 dnl gas/ instead of gas/../.
  14 AC_CONFIG_AUX_DIR(..)
  15 AC_CANONICAL_SYSTEM
  16 AC_ISC_POSIX
  17
  18 changequote(,)dnl
  19 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  20 changequote([,])dnl
  21 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  22
  23 AC_PROG_CC
  24 AC_GNU_SOURCE
  25
  26 AM_PROG_LIBTOOL
  27
  28 AC_ARG_ENABLE(targets,
  29 [  --enable-targets        alternative target configurations besides the primary],
  30 [case "${enableval}" in
  31   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  32             ;;
  33   no)       enable_targets= ;;
  34   *)        enable_targets=$enableval ;;
  35 esac])dnl
  36
  37 AC_ARG_ENABLE(commonbfdlib,
  38 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  39 [case "${enableval}" in
  40   yes) commonbfdlib=true ;;
  41   no)  commonbfdlib=false ;;
  42   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  43 esac])dnl
  44
  45 ac_checking=yes
  46 if grep '^RELEASE=y' ${srcdir}/../bfd/Makefile.am >/dev/null 2>/dev/null ; then
  47   ac_checking=
  48 fi
  49 AC_ARG_ENABLE(checking,
  50 [  --enable-checking       enable run-time checks],
  51 [case "${enableval}" in
  52   no|none)  ac_checking= ;;
  53   *)        ac_checking=yes ;;
  54 esac])dnl
  55 if test x$ac_checking != x ; then
  56   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  57 fi
  58
  59 using_cgen=no
  60
  61 AM_BINUTILS_WARNINGS
  62
  63 # Generate a header file
  64 AM_CONFIG_HEADER(config.h:config.in)
  65
  66 # If we are on a DOS filesystem, we must use gdb.ini rather than
  67 # .gdbinit.
  68 case "${host}" in
  69   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  70     GDBINIT="gdb.ini"
  71     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
  72     ;;
  73   *)
  74     GDBINIT=".gdbinit"
  75     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
  76     ;;
  77 esac
  78 AC_SUBST(GDBINIT)
  79
  80 #We need this for the host.  BOUT header is in host order.
  81 AC_C_BIGENDIAN
  82
  83 te_file=generic
  84
  85 # Makefile target for installing gas in $(tooldir)/bin.
  86 install_tooldir=install-exec-tooldir
  87
  88 canon_targets=""
  89 all_targets=no
  90 if test -n "$enable_targets" ; then
  91   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  92     if test $t = "all"; then
  93       all_targets=yes
  94       continue
  95     fi
  96     result=`$ac_config_sub $t 2>/dev/null`
  97     if test -n "$result" ; then
  98       canon_targets="$canon_targets $result"
  99 #    else
 100 #      # Permit "all", etc.  We don't support it yet though.
 101 #      canon_targets="$canon_targets $t"
 102     fi
 103   done
 104   GAS_UNIQ(canon_targets)
 105 fi
 106
 107 emulations=""
 108
 109 for this_target in $target $canon_targets ; do
 110
 111     targ=${this_target}
 112     . ${srcdir}/configure.tgt
 113
 114     case ${target_cpu} in
 115       crisv32)
 116         AC_DEFINE_UNQUOTED(DEFAULT_CRIS_ARCH, $arch,
 117                            [Default CRIS architecture.])
 118         ;;
 119     esac
 120
 121     if test ${this_target} = $target ; then
 122       target_cpu_type=${cpu_type}
 123     elif test ${target_cpu_type} != ${cpu_type} ; then
 124       continue
 125     fi
 126
 127     generic_target=${cpu_type}-${target_vendor}-${target_os}
 128     case ${generic_target} in
 129       i386-*-sco3.2v5*)
 130         if test ${this_target} = $target; then
 131           AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 132         fi
 133         ;;
 134
 135       i386-*-msdosdjgpp* \
 136       | i386-*-go32* \
 137       | i386-go32-rtems*)
 138         AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 139         ;;
 140
 141       i860-*-*)
 142         AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress)
 143         ;;
 144
 145       mips-sony-bsd*)
 146         ;;
 147       mips-*-bsd*)
 148         AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.)
 149         ;;
 150
 151       ppc-*-aix5.*)
 152         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 153                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 154         ;;
 155       ppc-*-linux-*)
 156         case "$endian" in
 157           big)  ;;
 158           *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 159         esac
 160         ;;
 161       ppc-*-solaris*)
 162         if test ${this_target} = $target; then
 163           AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 164                     [Define if default target is PowerPC Solaris.])
 165         fi
 166         if test x${endian} = xbig; then
 167           AC_MSG_ERROR(Solaris must be configured little endian)
 168         fi
 169         ;;
 170
 171       sh*-*-symbianelf*)
 172         AC_DEFINE(TARGET_SYMBIAN, 1, [Define if target is Symbian OS.])
 173         ;;
 174     esac
 175
 176     if test ${this_target} = $target ; then
 177       endian_def=
 178       if test x${endian} = xbig; then
 179         endian_def=1
 180       elif test x${endian} = xlittle; then
 181         endian_def=0
 182       fi
 183       if test x${endian_def} != x; then
 184         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 185                            [Define as 1 if big endian.])
 186       fi
 187     fi
 188
 189 # Other random stuff.
 190
 191     case ${cpu_type} in
 192       mips)
 193         # Set mips_cpu to the name of the default CPU.
 194         case ${target_cpu} in
 195           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 196             mips_cpu=from-abi
 197             ;;
 198           mipsisa32 | mipsisa32el)
 199             mips_cpu=mips32
 200             ;;
 201           mipsisa32r2 | mipsisa32r2el)
 202             mips_cpu=mips32r2
 203             ;;
 204           mipsisa64 | mipsisa64el)
 205             mips_cpu=mips64
 206             ;;
 207           mipsisa64r2 | mipsisa64r2el)
 208             mips_cpu=mips64r2
 209             ;;
 210           mipstx39 | mipstx39el)
 211             mips_cpu=r3900
 212             ;;
 213           mips64vr | mips64vrel)
 214             mips_cpu=vr4100
 215             ;;
 216           mipsisa32r2* | mipsisa64r2*)
 217 changequote(,)dnl
 218             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 219 changequote([,])dnl
 220             ;;
 221           mips64* | mipsisa64* | mipsisa32*)
 222 changequote(,)dnl
 223             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 224 changequote([,])dnl
 225             ;;
 226           *)
 227             AC_ERROR($target_cpu isn't a supported MIPS CPU name)
 228             ;;
 229         esac
 230         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 231         # binaries.  It's a GNU extension that some OSes don't understand.
 232         # The value only matters on ELF targets.
 233         case ${target} in
 234           *-*-irix*)
 235             use_e_mips_abi_o32=0
 236             ;;
 237           *)
 238             use_e_mips_abi_o32=1
 239             ;;
 240         esac
 241         # Decide whether to generate 32-bit or 64-bit code by default.
 242         # Used to resolve -march=from-abi when an embedded ABI is selected.
 243         case ${target} in
 244           mips64*-*-* | mipsisa64*-*-*)
 245             mips_default_64bit=1
 246             ;;
 247           *)
 248             mips_default_64bit=0
 249             ;;
 250         esac
 251         # Decide which ABI to target by default.
 252         case ${target} in
 253           mips64*-linux* | mips-sgi-irix6*)
 254             mips_default_abi=N32_ABI
 255             ;;
 256           mips*-linux*)
 257             mips_default_abi=O32_ABI
 258             ;;
 259           mips64*-openbsd*)
 260             mips_default_abi=N64_ABI
 261             ;;
 262           *)
 263             mips_default_abi=NO_ABI
 264             ;;
 265         esac
 266         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 267                            [Default CPU for MIPS targets. ])
 268         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 269                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 270         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 271                            [Generate 64-bit code by default on MIPS targets. ])
 272         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 273                            [Choose a default ABI for MIPS targets. ])
 274         ;;
 275     esac
 276
 277     # Do we need the opcodes library?
 278     case ${cpu_type} in
 279       vax | tic30)
 280         ;;
 281
 282       *)
 283         need_opcodes=yes
 284
 285         case "${enable_shared}" in
 286         yes) shared_opcodes=true ;;
 287         *opcodes*) shared_opcodes=true ;;
 288         *) shared_opcodes=false ;;
 289         esac
 290         ;;
 291     esac
 292
 293     # Any other special object files needed ?
 294     case ${cpu_type} in
 295
 296       bfin)
 297         echo ${extra_objects} | grep -s "bfin-parse.o"
 298         if test $? -ne 0 ; then
 299           extra_objects="$extra_objects bfin-parse.o"
 300         fi
 301
 302         echo ${extra_objects} | grep -s "bfin-lex.o"
 303         if test $? -ne 0 ; then
 304           extra_objects="$extra_objects bfin-lex.o"
 305         fi
 306         ;;
 307
 308       fr30 | ip2k | iq2000 | m32r | openrisc)
 309         using_cgen=yes
 310         ;;
 311
 312       m32c)
 313         using_cgen=yes
 314         ;;
 315       frv)
 316         using_cgen=yes
 317         ;;
 318       m68k)
 319         case ${extra_objects} in
 320         *m68k-parse.o*) ;;
 321         *) extra_objects="$extra_objects m68k-parse.o" ;;
 322         esac
 323         ;;
 324
 325       mep)
 326         using_cgen=yes
 327         ;;
 328
 329       mips)
 330         echo ${extra_objects} | grep -s "itbl-parse.o"
 331         if test $? -ne 0 ; then
 332           extra_objects="$extra_objects itbl-parse.o"
 333         fi
 334
 335         echo ${extra_objects} | grep -s "itbl-lex.o"
 336         if test $? -ne 0 ; then
 337           extra_objects="$extra_objects itbl-lex.o"
 338         fi
 339
 340         echo ${extra_objects} | grep -s "itbl-ops.o"
 341         if test $? -ne 0 ; then
 342           extra_objects="$extra_objects itbl-ops.o"
 343         fi
 344         ;;
 345
 346       mt)
 347         using_cgen=yes
 348         ;;
 349
 350       i386 | s390 | sparc)
 351         if test $this_target = $target ; then
 352           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 353         fi
 354         ;;
 355
 356       xstormy16)
 357         using_cgen=yes
 358         ;;
 359
 360       xc16x)
 361         using_cgen=yes
 362         ;;
 363
 364       xtensa)
 365         echo ${extra_objects} | grep -s "xtensa-relax.o"
 366         if test $? -ne 0 ; then
 367           extra_objects="$extra_objects xtensa-relax.o"
 368         fi
 369         ;;
 370
 371       *)
 372         ;;
 373     esac
 374
 375     if test $using_cgen = yes ; then
 376         case "x${extra_objects}" in
 377         *cgen.o*) ;;
 378         *) extra_objects="$extra_objects cgen.o" ;;
 379         esac
 380     fi
 381
 382 # See if we really can support this configuration with the emulation code.
 383
 384     if test $this_target = $target ; then
 385       obj_format=$fmt
 386       te_file=$em
 387     fi
 388
 389 # From target name and format, produce a list of supported emulations.
 390
 391     case ${generic_target}-${fmt} in
 392       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 393       mips*-*-linux*-*) case "$endian" in
 394                         big)    emulation="mipsbelf mipslelf mipself" ;;
 395                         *)      emulation="mipslelf mipsbelf mipself" ;;
 396                         esac ;;
 397       mips-*-lnews*-ecoff) ;;
 398       mips-*-*-ecoff)   case "$endian" in
 399                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 400                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 401                         esac ;;
 402       mips-*-*-elf)     case "$endian" in
 403                         big)    emulation="mipsbelf mipslelf mipself" ;;
 404                         *)      emulation="mipslelf mipsbelf mipself" ;;
 405                         esac ;;
 406       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 407       # i386-pc-pe-coff != i386-pc-coff.
 408       i386-*-pe-coff)   ;;
 409       # Uncommenting the next line will turn on support for i386 AOUT
 410       # for the default linux configuration
 411       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 412       #
 413       i386-*-aout)      emulation="i386aout" ;;
 414       i386-*-coff)      emulation="i386coff" ;;
 415       i386-*-elf)       emulation="i386elf" ;;
 416
 417       # Always all formats.  The first stated emulation becomes the default.
 418       cris-*-*aout*)    emulation="crisaout criself" ;;
 419       cris-*-*)         emulation="criself crisaout" ;;
 420     esac
 421
 422     emulations="$emulations $emulation"
 423
 424 done
 425
 426 # Turn on all targets if possible
 427 if test ${all_targets} = "yes"; then
 428   case ${target_cpu_type} in
 429   i386)
 430     case ${obj_format} in
 431     aout)
 432       emulations="$emulations i386coff i386elf"
 433       ;;
 434     coff)
 435       emulations="$emulations i386aout i386elf"
 436     ;;
 437     elf)
 438       emulations="$emulations i386aout i386coff"
 439       ;;
 440     esac
 441   ;;
 442   x86_64)
 443     case ${obj_format} in
 444     aout)
 445       emulations="$emulations i386coff i386elf"
 446       ;;
 447     coff)
 448       emulations="$emulations i386aout i386elf"
 449     ;;
 450     elf)
 451       emulations="$emulations i386aout i386coff"
 452       ;;
 453     esac
 454   ;;
 455   esac
 456 fi
 457
 458 # Assign floating point type.  Most processors with FP support
 459 # IEEE FP.  On those that don't support FP at all, usually IEEE
 460 # is emulated.
 461 case ${target_cpu} in
 462   vax | pdp11 ) atof=vax ;;
 463   *)            atof=ieee ;;
 464 esac
 465
 466 case "${obj_format}" in
 467   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 468 esac
 469
 470 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 471 cgen_cpu_prefix=""
 472 if test $using_cgen = yes ; then
 473   case ${target_cpu} in
 474     *) cgen_cpu_prefix=${target_cpu} ;;
 475   esac
 476   AC_SUBST(cgen_cpu_prefix)
 477   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 478 fi
 479
 480 dnl
 481 dnl Make sure the desired support files exist.
 482 dnl
 483
 484 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 485   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 486 fi
 487
 488 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 489   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 490 fi
 491
 492 # Some COFF configurations want these random other flags set.
 493 case ${obj_format} in
 494   coff)
 495     case ${target_cpu_type} in
 496       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 497       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 498       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 499       x86_64) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 500     esac
 501     ;;
 502 esac
 503
 504 # Getting this done right is going to be a bitch.  Each configuration specified
 505 # with --enable-targets=... should be checked for environment, format, cpu
 506 # setting.
 507 #
 508 # For each configuration, the necessary object file support code must be linked
 509 # in.  This might be only one, it might be up to four.  The necessary emulation
 510 # code needs to be provided, too.
 511 #
 512 # And then there's "--enable-targets=all"....
 513 #
 514 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 515
 516 formats="${obj_format}"
 517 emfiles=""
 518 EMULATIONS=""
 519 GAS_UNIQ(emulations)
 520 for em in . $emulations ; do
 521   case $em in
 522     .)  continue ;;
 523     mipsbelf | mipslelf | mipself)
 524         fmt=elf   file=mipself ;;
 525     mipsbecoff | mipslecoff | mipsecoff)
 526         fmt=ecoff file=mipsecoff ;;
 527     *coff)
 528         fmt=coff  file=$em ;;
 529     *aout)
 530         fmt=aout file=$em ;;
 531     *elf)
 532         fmt=elf file=$em ;;
 533   esac
 534   formats="$formats $fmt"
 535   emfiles="$emfiles e-$file.o"
 536   EMULATIONS="$EMULATIONS &$em,"
 537 done
 538 GAS_UNIQ(formats)
 539 GAS_UNIQ(emfiles)
 540 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 541   for fmt in $formats ; do
 542     case $fmt in
 543       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 544       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 545       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 546       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 547       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 548       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 549       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 550     esac
 551     extra_objects="$extra_objects obj-$fmt.o"
 552   done
 553   obj_format=multi
 554 fi
 555 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 556   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 557   # e-mips* has more than one emulation per file, e-i386* has just one at the
 558   # moment.  If only one emulation is specified, then don't define
 559   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 560   case "${obj_format}${emfiles}" in
 561     multi* | *mips*)
 562       extra_objects="$extra_objects $emfiles"
 563       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 564   esac
 565 fi
 566 AC_SUBST(extra_objects)
 567 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 568 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 569                    [Default emulation.])
 570
 571 reject_dev_configs=yes
 572
 573 case ${reject_dev_configs}-${dev} in
 574   yes-yes) # Oops.
 575     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 576     ;;
 577 esac
 578
 579 AC_SUBST(target_cpu_type)
 580 AC_SUBST(obj_format)
 581 AC_SUBST(te_file)
 582 AC_SUBST(install_tooldir)
 583 AC_SUBST(atof)
 584 dnl AC_SUBST(emulation)
 585
 586 # do we need the opcodes library?
 587 case "${need_opcodes}" in
 588 yes)
 589   OPCODES_LIB=../opcodes/libopcodes.la
 590   ;;
 591 esac
 592
 593 AC_SUBST(OPCODES_LIB)
 594
 595 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 596 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 597 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 598 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 599 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 600
 601 AC_PROG_YACC
 602 AM_PROG_LEX
 603
 604 ALL_LINGUAS="fr tr es rw"
 605 ZW_GNU_GETTEXT_SISTER_DIR
 606 AM_PO_SUBDIRS
 607
 608 AM_MAINTAINER_MODE
 609 AM_CONDITIONAL(GENINSRC_NEVER, false)
 610 AC_EXEEXT
 611
 612 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h limits.h)
 613
 614 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 615 # people who are not cross-compiling but are compiling cross-assemblers.
 616 AC_MSG_CHECKING(whether compiling a cross-assembler)
 617 if test "${host}" = "${target}"; then
 618   cross_gas=no
 619 else
 620   cross_gas=yes
 621   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 622 fi
 623 AC_MSG_RESULT($cross_gas)
 624
 625 dnl ansidecl.h will deal with const
 626 dnl AC_CONST
 627 AC_FUNC_ALLOCA
 628 AC_C_INLINE
 629
 630 # VMS doesn't have unlink.
 631 AC_CHECK_FUNCS(unlink remove, break)
 632
 633 # Some systems don't have sbrk().
 634 AC_CHECK_FUNCS(sbrk)
 635
 636 # do we need the math library?
 637 case "${need_libm}" in
 638 yes)
 639   AC_CHECK_LIBM
 640   AC_SUBST(LIBM)
 641   ;;
 642 esac
 643
 644 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 645 # enough, but on some of those systems, the assert macro relies on requoting
 646 # working properly!
 647 GAS_WORKING_ASSERT
 648
 649 # On some systems, the system header files may not declare malloc, realloc,
 650 # and free.  There are places where gas needs these functions to have been
 651 # declared -- such as when taking their addresses.
 652 gas_test_headers="
 653 #ifdef HAVE_MEMORY_H
 654 #include <memory.h>
 655 #endif
 656 #ifdef HAVE_STRING_H
 657 #include <string.h>
 658 #else
 659 #ifdef HAVE_STRINGS_H
 660 #include <strings.h>
 661 #endif
 662 #endif
 663 #ifdef HAVE_STDLIB_H
 664 #include <stdlib.h>
 665 #endif
 666 #ifdef HAVE_UNISTD_H
 667 #include <unistd.h>
 668 #endif
 669 "
 670
 671 # Does errno.h declare errno, or do we have to add a separate declaration
 672 # for it?
 673 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 674 #ifdef HAVE_ERRNO_H
 675 #include <errno.h>
 676 #endif
 677 ])
 678
 679 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 680 AC_CACHE_VAL(gas_cv_decl_getopt_unistd_h,
 681 [AC_TRY_COMPILE([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);],
 682 gas_cv_decl_getopt_unistd_h=yes, gas_cv_decl_getopt_unistd_h=no)])
 683 AC_MSG_RESULT($gas_cv_decl_getopt_unistd_h)
 684 if test $gas_cv_decl_getopt_unistd_h = yes; then
 685   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 686             [Is the prototype for getopt in <unistd.h> in the expected format?])
 687 fi
 688
 689 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 690 GAS_CHECK_DECL_NEEDED(ffs, f, int (*f)(int), $gas_test_headers)
 691 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 692 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 693 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 694 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 695
 696 AC_CHECK_DECLS([vsnprintf])
 697
 698 BFD_BINARY_FOPEN
 699
 700 dnl Required for html and install-html targets.
 701 AC_SUBST(datarootdir)
 702 AC_SUBST(docdir)
 703 AC_SUBST(htmldir)
 704
 705 dnl This must come last.
 706
 707 dnl We used to make symlinks to files in the source directory, but now
 708 dnl we just use the right name for .c files, and create .h files in
 709 dnl the build directory which include the right .h file.  Make sure
 710 dnl the old symlinks don't exist, so that a reconfigure in an existing
 711 dnl directory behaves reasonably.
 712
 713 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
 714 AC_CONFIG_COMMANDS([default],
 715 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
 716  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
 717  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
 718  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
 719  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
 720  if test "x$cgen_cpu_prefix" != x ; then
 721    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
 722  fi],
 723 [target_cpu_type=${target_cpu_type}
 724  cgen_cpu_prefix=${cgen_cpu_prefix}
 725  obj_format=${obj_format}
 726  te_file=${te_file}])
 727
 728 AC_OUTPUT