bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.13)
   5 AC_INIT(libbfd.c)
   6
   7 AC_CANONICAL_SYSTEM
   8 AC_ISC_POSIX
   9
  10 AM_INIT_AUTOMAKE(bfd, 2.12.90)
  11 # Uncomment the next line to remove the date from the reported bfd version
  12 #is_release=y
  13
  14 changequote(,)dnl
  15 bfd_version=`echo "${VERSION}" | sed -e 's/\([^\.]*\)\.*\([^\.]*\)\.*\([^\.]*\)\.*\([^\.]*\)\.*\([^\.]*\).*/\1.00\2.00\3.00\4.00\5/' -e 's/\([^\.]*\)\..*\(..\)\..*\(..\)\..*\(..\)\..*\(..\)$/\1\2\3\4\5/'`
  16 changequote([,])dnl
  17
  18 bfd_version_string="\"${VERSION}\""
  19 bfd_version_date=`sed -e 's/.*DATE //' < ${srcdir}/version.h`
  20 if test x${is_release} = x; then
  21 dnl Sad, but we can't use XSTRING here to pick up the date from version.h
  22 dnl because traditional C doesn't allow it.
  23   bfd_version_string="\"${VERSION} ${bfd_version_date}\""
  24 fi
  25 dnl Since we need to edit bfd-in3.h to get the date for bfd_version_string,
  26 dnl we may as well substitute for bfd_version_date too.  That way we don't
  27 dnl need to #include version.h
  28 AC_SUBST(bfd_version)
  29 AC_SUBST(bfd_version_date)
  30 AC_SUBST(bfd_version_string)
  31
  32 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  33 dnl to call AC_CHECK_PROG.
  34 AC_CHECK_TOOL(AR, ar)
  35 AC_CHECK_TOOL(RANLIB, ranlib, :)
  36
  37 dnl Default to a non shared library.  This may be overridden by the
  38 dnl configure option --enable-shared.
  39 AM_DISABLE_SHARED
  40
  41 AM_PROG_LIBTOOL
  42
  43 AC_ARG_ENABLE(64-bit-bfd,
  44 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  45 [case "${enableval}" in
  46   yes)  want64=true  ;;
  47   no)   want64=false ;;
  48   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  49 esac],[want64=false])dnl
  50 AC_ARG_ENABLE(targets,
  51 [  --enable-targets        alternative target configurations],
  52 [case "${enableval}" in
  53   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  54             ;;
  55   no)       enable_targets= ;;
  56   *)        enable_targets=$enableval ;;
  57 esac])dnl
  58 AC_ARG_ENABLE(commonbfdlib,
  59 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  60 [case "${enableval}" in
  61   yes) commonbfdlib=true ;;
  62   no)  commonbfdlib=false ;;
  63   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  64 esac])dnl
  65 AC_ARG_WITH(mmap,
  66 [  --with-mmap             try using mmap for BFD input files if available],
  67 [case "${withval}" in
  68   yes)  want_mmap=true ;;
  69   no)   want_mmap=false ;;
  70   *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
  71 esac],[want_mmap=false])dnl
  72
  73 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  74 AC_ARG_ENABLE(build-warnings,
  75 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  76 [case "${enableval}" in
  77   yes)  ;;
  78   no)   build_warnings="-w";;
  79   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  80         build_warnings="${build_warnings} ${t}";;
  81   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  82         build_warnings="${t} ${build_warnings}";;
  83   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  84 esac
  85 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  86   echo "Setting warning flags = $build_warnings" 6>&1
  87 fi])dnl
  88 WARN_CFLAGS=""
  89 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  90     WARN_CFLAGS="${build_warnings}"
  91 fi
  92 AC_SUBST(WARN_CFLAGS)
  93
  94 AM_CONFIG_HEADER(config.h:config.in)
  95
  96 if test -z "$target" ; then
  97     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  98 fi
  99
 100 AM_MAINTAINER_MODE
 101 AC_EXEEXT
 102
 103 host64=false
 104 target64=false
 105 bfd_default_target_size=32
 106
 107 # host stuff:
 108
 109 AC_PROG_CC
 110
 111 ALL_LINGUAS="fr tr ja es sv"
 112 CY_GNU_GETTEXT
 113
 114 # Permit host specific settings.
 115 . ${srcdir}/configure.host
 116
 117 AC_SUBST(HDEFINES)
 118 AC_PROG_INSTALL
 119
 120 BFD_HOST_64BIT_LONG=0
 121 BFD_HOST_64_BIT_DEFINED=0
 122 BFD_HOST_64_BIT=
 123 BFD_HOST_U_64_BIT=
 124 if test "x${HOST_64BIT_TYPE}" = "xlong"; then
 125   BFD_HOST_64BIT_LONG=1
 126 elif test "x${HOST_64BIT_TYPE}" != "x"; then
 127   BFD_HOST_64_BIT_DEFINED=1
 128   BFD_HOST_64_BIT=${HOST_64BIT_TYPE}
 129   BFD_HOST_U_64_BIT=${HOST_U_64BIT_TYPE}
 130 fi
 131 AC_SUBST(BFD_HOST_64BIT_LONG)
 132 AC_SUBST(BFD_HOST_64_BIT_DEFINED)
 133 AC_SUBST(BFD_HOST_64_BIT)
 134 AC_SUBST(BFD_HOST_U_64_BIT)
 135
 136 BFD_CC_FOR_BUILD
 137
 138 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
 139 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h)
 140 AC_HEADER_TIME
 141 AC_HEADER_DIRENT
 142 AC_CHECK_FUNCS(fcntl getpagesize setitimer sysconf fdopen getuid getgid)
 143
 144 BFD_BINARY_FOPEN
 145
 146 BFD_NEED_DECLARATION(strstr)
 147 BFD_NEED_DECLARATION(malloc)
 148 BFD_NEED_DECLARATION(realloc)
 149 BFD_NEED_DECLARATION(free)
 150 BFD_NEED_DECLARATION(getenv)
 151
 152 # If we are configured native, pick a core file support file.
 153 COREFILE=
 154 COREFLAG=
 155 TRAD_HEADER=
 156 if test "${target}" = "${host}"; then
 157   case "${host}" in
 158   alpha*-*-freebsd*)
 159         COREFILE=''
 160         ;;
 161   alpha*-*-linux-gnu*)
 162         COREFILE=trad-core.lo
 163         TRAD_HEADER='"hosts/alphalinux.h"'
 164         ;;
 165   alpha*-*-netbsd* | alpha*-*-openbsd*)
 166         COREFILE=netbsd-core.lo
 167         ;;
 168   alpha*-*-*)           COREFILE=osf-core.lo ;;
 169   arm-*-freebsd*)       COREFILE='' ;;
 170   arm-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 171   arm-*-riscix)         COREFILE=trad-core.lo ;;
 172   hppa*-*-hpux*)        COREFILE=hpux-core.lo ;;
 173   hppa*-*-hiux*)        COREFILE=hpux-core.lo ;;
 174   hppa*-*-mpeix*)       COREFILE=hpux-core.lo ;;
 175   hppa*-*-bsd*)         COREFILE="hpux-core.lo hppabsd-core.lo"
 176                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 177   i370-*-*)
 178         COREFILE=trad-core.lo
 179         TRAD_HEADER='"hosts/i370linux.h"'
 180         ;;
 181
 182 changequote(,)dnl
 183   i[3456]86-sequent-bsd*)
 184 changequote([,])dnl
 185         COREFILE=trad-core.lo
 186         TRAD_HEADER='"hosts/symmetry.h"'
 187         ;;
 188 changequote(,)dnl
 189   i[3456]86-sequent-sysv4*) ;;
 190   i[3456]86-sequent-sysv*)
 191 changequote([,])dnl
 192         COREFILE=trad-core.lo
 193         TRAD_HEADER='"hosts/symmetry.h"'
 194         ;;
 195 changequote(,)dnl
 196   i[3456]86-*-bsdi)
 197 changequote([,])dnl
 198         COREFILE=
 199         ;;
 200 changequote(,)dnl
 201   i[3456]86-*-bsd* | i[34567]86-*-freebsd[123] | i[34567]86-*-freebsd[123]\.* | i[34567]86-*-freebsd4\.[01234]* | i[34567]86-*-freebsd*aout*)
 202 changequote([,])dnl
 203         COREFILE=trad-core.lo
 204         TRAD_HEADER='"hosts/i386bsd.h"'
 205         ;;
 206 changequote(,)dnl
 207   i[3456]86-*-freebsd*)
 208 changequote([,])dnl
 209         COREFILE=''
 210         TRAD_HEADER='"hosts/i386bsd.h"'
 211         ;;
 212 changequote(,)dnl
 213   i[3456]86-*-netbsd* | i[3456]86-*-openbsd*)
 214 changequote([,])dnl
 215         COREFILE=netbsd-core.lo
 216         ;;
 217 changequote(,)dnl
 218   i[3456]86-esix-sysv3*)
 219 changequote([,])dnl
 220         COREFILE=trad-core.lo
 221         TRAD_HEADER='"hosts/esix.h"'
 222         ;;
 223 changequote(,)dnl
 224   i[3456]86-*-sco3.2v5*)
 225 changequote([,])dnl
 226         COREFILE=sco5-core.lo
 227         ;;
 228 changequote(,)dnl
 229   i[3456]86-*-sco* | i[3456]86-*-isc*)
 230 changequote([,])dnl
 231         COREFILE=trad-core.lo
 232         TRAD_HEADER='"hosts/i386sco.h"'
 233         ;;
 234 changequote(,)dnl
 235   i[3456]86-*-mach3*)
 236 changequote([,])dnl
 237         COREFILE=trad-core.lo
 238         TRAD_HEADER='"hosts/i386mach3.h"'
 239         ;;
 240 changequote(,)dnl
 241   i[3456]86-*-linux-gnu*)
 242 changequote([,])dnl
 243         COREFILE=trad-core.lo
 244         TRAD_HEADER='"hosts/i386linux.h"'
 245         ;;
 246 changequote(,)dnl
 247   i[3456]86-*-isc*)     COREFILE=trad-core.lo ;;
 248   i[3456]86-*-aix*)     COREFILE=aix386-core.lo ;;
 249 changequote([,])dnl
 250   i860-*-mach3* | i860-*-osf1*)
 251         COREFILE=trad-core.lo
 252         TRAD_HEADER='"hosts/i860mach3.h"'
 253         ;;
 254   mips-dec-bsd*)
 255         COREFILE=trad-core.lo
 256         TRAD_HEADER='"hosts/mipsbsd.h"'
 257         ;;
 258   mips-dec-mach3*)
 259         COREFILE=trad-core.lo
 260         TRAD_HEADER='"hosts/mipsmach3.h"'
 261         ;;
 262   mips-*-netbsd* | mips*-*-openbsd*)
 263         COREFILE=netbsd-core.lo
 264         ;;
 265   mips-dec-*)
 266         COREFILE=trad-core.lo
 267         TRAD_HEADER='"hosts/decstation.h"'
 268         ;;
 269   mips-sgi-irix4*)      COREFILE=irix-core.lo ;;
 270   mips-sgi-irix5*)      COREFILE=irix-core.lo ;;
 271   mips-sgi-irix6*)      COREFILE=irix-core.lo ;;
 272   mips-*-mach3*)
 273         COREFILE=trad-core.lo
 274         TRAD_HEADER='"hosts/mipsmach3.h"'
 275         ;;
 276   mips-*-sysv4*)        ;;
 277   mips-*-sysv* | mips-*-riscos*)
 278         COREFILE=trad-core.lo
 279         TRAD_HEADER='"hosts/riscos.h"'
 280         ;;
 281   mips-sony-bsd*)
 282         COREFILE=trad-core.lo
 283         TRAD_HEADER='"hosts/news-mips.h"'
 284         ;;
 285   m68*-bull*-sysv*)
 286         COREFILE=trad-core.lo
 287         TRAD_HEADER='"hosts/dpx2.h"'
 288         ;;
 289   m68*-hp-hpux*)        COREFILE=hpux-core.lo ;;
 290   m68*-hp-bsd*)
 291         COREFILE=trad-core.lo
 292         TRAD_HEADER='"hosts/hp300bsd.h"'
 293         ;;
 294   m68*-*-linux-gnu*)
 295         COREFILE=trad-core.lo
 296         TRAD_HEADER='"hosts/m68klinux.h"'
 297         ;;
 298   m68*-motorola-sysv*)
 299         COREFILE=trad-core.lo
 300         TRAD_HEADER='"hosts/delta68.h"'
 301         ;;
 302   m68*-sony-*)
 303         COREFILE=trad-core.lo
 304         TRAD_HEADER='"hosts/news.h"'
 305         ;;
 306   m68*-*-netbsd* | m68*-*-openbsd*)
 307         COREFILE=netbsd-core.lo
 308         ;;
 309   m68*-apple-aux*)
 310         COREFILE=trad-core.lo
 311         TRAD_HEADER='"hosts/m68kaux.h"'
 312         ;;
 313   m88*-*-sysv4*)
 314         ;;
 315   m88*-motorola-sysv*)
 316         COREFILE=ptrace-core.lo
 317         ;;
 318   m88*-*-mach3*)
 319         COREFILE=trad-core.lo
 320         TRAD_HEADER='"hosts/m88kmach3.h"'
 321         ;;
 322   ns32k-pc532-mach)
 323         COREFILE=trad-core.lo
 324         TRAD_HEADER='"hosts/pc532mach.h"'
 325         ;;
 326   ns32k-*-netbsd* | ns32k-*-openbsd*)
 327         COREFILE=netbsd-core.lo
 328         ;;
 329   rs6000-*-lynx*)
 330         COREFILE=lynx-core.lo
 331         ;;
 332   rs6000-*-aix5.* | powerpc-*-aix5.*)
 333         COREFILE=rs6000-core.lo
 334         COREFLAG="$COREFLAG -DAIX_5_CORE -DAIX_CORE_DUMPX_CORE"
 335         ;;
 336 changequote(,)dnl
 337   rs6000-*-aix4.[3-9]* | powerpc-*-aix4.[3-9]*)
 338 changequote([,])dnl
 339         COREFILE=rs6000-core.lo
 340         COREFLAG="$COREFLAG -DAIX_CORE_DUMPX_CORE"
 341         # Not all versions of AIX with -DAIX_CORE_DUMPX_CORE
 342         # have c_impl as a member of struct core_dumpx
 343         AC_MSG_CHECKING([for c_impl in struct core_dumpx])
 344         AC_TRY_COMPILE([#include <core.h>],
 345           [struct core_dumpx c; c.c_impl = 0;],
 346           [AC_DEFINE(HAVE_ST_C_IMPL, 1,
 347             [Define if struct core_dumpx has member c_impl])
 348           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 349         ;;
 350   rs6000-*-aix4*)       COREFILE=rs6000-core.lo ;;
 351   rs6000-*-*)           COREFILE=rs6000-core.lo ;;
 352   powerpc-*-aix4*)      COREFILE=rs6000-core.lo ;;
 353   powerpc-*-aix*)       COREFILE=rs6000-core.lo ;;
 354   powerpc-*-beos*)      ;;
 355   powerpc-*-freebsd*)   COREFILE='' ;;
 356   powerpc-*-netbsd*)    COREFILE=netbsd-core.lo ;;
 357   powerpc-*-*bsd*)      COREFILE=netbsd-core.lo ;;
 358   s390*-*-*)            COREFILE=trad-core.lo ;;
 359   sh*-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 360   sparc-*-netbsd* | sparc*-*-openbsd*)
 361         COREFILE=netbsd-core.lo
 362         ;;
 363   tahoe-*-*)
 364         COREFILE=trad-core.lo
 365         TRAD_HEADER='"hosts/tahoe.h"'
 366         ;;
 367   vax-*-ultrix2*)
 368         COREFILE=trad-core.lo
 369         TRAD_HEADER='"hosts/vaxult2.h"'
 370         ;;
 371   vax-*-ultrix*)
 372         COREFILE=trad-core.lo
 373         TRAD_HEADER='"hosts/vaxult2.h"'
 374         ;;
 375   vax-*-*)
 376         COREFILE=trad-core.lo
 377         TRAD_HEADER='"hosts/vaxbsd.h"'
 378         ;;
 379   x86_64-*-netbsd*)     COREFILE=netbsd-core.lo ;;
 380   esac
 381
 382   case "$COREFILE" in
 383   aix386-core.lo)       COREFLAG=-DAIX386_CORE ;;
 384   hppabsd-core.lo)      COREFLAG=-DHPPABSD_CORE ;;
 385   hpux-core.lo)         COREFLAG=-DHPUX_CORE ;;
 386   irix-core.lo)         COREFLAG=-DIRIX_CORE ;;
 387   lynx-core.lo)         COREFLAG=-DLYNX_CORE ;;
 388   netbsd-core.lo)       COREFLAG=-DNETBSD_CORE ;;
 389   osf-core.lo)          COREFLAG=-DOSF_CORE ;;
 390   ptrace-core.lo)       COREFLAG=-DPTRACE_CORE ;;
 391   rs6000-core.lo)       COREFLAG="$COREFLAG -DAIX_CORE" ;;
 392   sco5-core.lo)         COREFLAG="$COREFLAG -DSCO5_CORE" ;;
 393   trad-core.lo)         COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 394   esac
 395
 396   # ELF corefile support has several flavors, but all of
 397   # them use something called <sys/procfs.h>
 398   AC_CHECK_HEADERS(sys/procfs.h)
 399   if test "$ac_cv_header_sys_procfs_h" = yes; then
 400     BFD_HAVE_SYS_PROCFS_TYPE(prstatus_t)
 401     BFD_HAVE_SYS_PROCFS_TYPE(prstatus32_t)
 402     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus_t, pr_who)
 403     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus32_t, pr_who)
 404     BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 405     BFD_HAVE_SYS_PROCFS_TYPE(pxstatus_t)
 406     BFD_HAVE_SYS_PROCFS_TYPE(pstatus32_t)
 407     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo_t)
 408     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo32_t)
 409     BFD_HAVE_SYS_PROCFS_TYPE(psinfo_t)
 410     BFD_HAVE_SYS_PROCFS_TYPE(psinfo32_t)
 411     BFD_HAVE_SYS_PROCFS_TYPE(lwpstatus_t)
 412     BFD_HAVE_SYS_PROCFS_TYPE(lwpxstatus_t)
 413     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_context)
 414     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_reg)
 415     BFD_HAVE_SYS_PROCFS_TYPE(win32_pstatus_t)
 416   fi
 417 fi
 418 AC_SUBST(COREFILE)
 419 AC_SUBST(COREFLAG)
 420 if test -n "$TRAD_HEADER"; then
 421   AC_DEFINE_UNQUOTED(TRAD_HEADER, $TRAD_HEADER,
 422     [Name of host specific header file to include in trad-core.c.])
 423 fi
 424
 425 # Horrible hacks to build DLLs on Windows.
 426 WIN32LDFLAGS=
 427 WIN32LIBADD=
 428 case "${host}" in
 429 *-*-cygwin*)
 430   if test "$enable_shared" = "yes"; then
 431     WIN32LDFLAGS="-no-undefined"
 432     WIN32LIBADD="-L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin -lkernel32"
 433   fi
 434   ;;
 435 *-*-linux*)
 436   # We borrow WIN32LIBADD so that the shared libbfd won't depend on
 437   # libiberty.a.
 438   case "${host}" in
 439   mips*-*-linux*)
 440     # Linux/MIPS uses PIC by default.
 441     if test "$enable_shared" = "yes"; then
 442       WIN32LIBADD="-L../libiberty -liberty"
 443     fi
 444     ;;
 445   *)
 446 changequote(,)dnl
 447     x=`sed -n -e 's/^[  ]*PICFLAG[      ]*=[    ]*//p' < ../libiberty/Makefile | tail -1`
 448 changequote([,])dnl
 449     if test -n "$x"; then
 450       WIN32LIBADD="-L../libiberty/pic -liberty"
 451     fi
 452   ;;
 453   esac
 454   ;;
 455 esac
 456 AC_SUBST(WIN32LDFLAGS)
 457 AC_SUBST(WIN32LIBADD)
 458
 459 # target stuff:
 460
 461 # Canonicalize the secondary target names.
 462 if test -n "$enable_targets" ; then
 463     for targ in `echo $enable_targets | sed 's/,/ /g'`
 464     do
 465         result=`$ac_config_sub $targ 2>/dev/null`
 466         if test -n "$result" ; then
 467             canon_targets="$canon_targets $result"
 468         else
 469             # Allow targets that config.sub doesn't recognize, like "all".
 470             canon_targets="$canon_targets $targ"
 471         fi
 472     done
 473 fi
 474
 475 all_targets=false
 476 defvec=
 477 selvecs=
 478 selarchs=
 479 TDEFINES=
 480 for targ in $target $canon_targets
 481 do
 482     if test "x$targ" = "xall"; then
 483         all_targets=true
 484     else
 485         . $srcdir/config.bfd
 486         if test "x$targ" = "x$target"; then
 487             defvec=$targ_defvec
 488         fi
 489         selvecs="$selvecs $targ_defvec $targ_selvecs"
 490         selarchs="$selarchs $targ_archs"
 491         TDEFINES="$TDEFINES $targ_cflags"
 492     fi
 493 done
 494 AC_SUBST(TDEFINES)
 495
 496 # This processing still needs to be done if we're to decide properly whether
 497 # 64-bit support needs to be compiled in.  Currently, it will be included if
 498 # the default or any other explicitly requested target requires it; it
 499 # will not be included on a 32-bit host if no 64-bit target is requested, and
 500 # no "--with-64-bit-bfd" option is given, even if "--enable-targets=all" is
 501 # used.
 502
 503 # uniq the default and selected vectors in all the configured targets.
 504 f=""
 505 for i in $selvecs ; do
 506     case " $f " in
 507     *" $i "*) ;;
 508     *) f="$f $i" ;;
 509     esac
 510 done
 511 selvecs="$f"
 512
 513
 514 # uniq the architectures in all the configured targets.
 515 f=""
 516 for i in $selarchs ; do
 517     case " $f " in
 518     *" $i "*) ;;
 519     *) f="$f $i" ;;
 520     esac
 521 done
 522 selarchs="$f"
 523
 524 # Target backend .o files.
 525 tb=
 526
 527 elf="elf.lo elflink.lo elf-strtab.lo elf-eh-frame.lo dwarf1.lo"
 528
 529 for vec in $selvecs
 530 do
 531     target_size=32
 532     case "$vec" in
 533     # This list is alphabetized to make it easy to compare
 534     # with the two vector lists in targets.c.  For the same reason,
 535     # use one entry per line, even though this leads to long lines.
 536     a29kcoff_big_vec)           tb="$tb coff-a29k.lo cofflink.lo" ;;
 537     a_out_adobe_vec)            tb="$tb aout-adobe.lo aout32.lo" ;;
 538     aout0_big_vec)              tb="$tb aout0.lo aout32.lo" ;;
 539     aout_arm_big_vec)           tb="$tb aout-arm.lo aout32.lo" ;;
 540     aout_arm_little_vec)        tb="$tb aout-arm.lo aout32.lo" ;;
 541     aout_mips_big_vec)          tb="$tb mipsbsd.lo aout32.lo" ;;
 542     aout_mips_little_vec)       tb="$tb mipsbsd.lo aout32.lo" ;;
 543     apollocoff_vec)             tb="$tb coff-apollo.lo" ;;
 544     arm_epoc_pe_big_vec)        tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 545     arm_epoc_pe_little_vec)     tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 546     arm_epoc_pei_big_vec)       tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 547     arm_epoc_pei_little_vec)    tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 548     armcoff_big_vec)            tb="$tb coff-arm.lo cofflink.lo " ;;
 549     armcoff_little_vec)         tb="$tb coff-arm.lo cofflink.lo " ;;
 550     armnetbsd_vec)              tb="$tb armnetbsd.lo aout32.lo" ;;
 551     armpe_big_vec)              tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 552     armpe_little_vec)           tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 553     armpei_big_vec)             tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 554     armpei_little_vec)          tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 555     b_out_vec_big_host)         tb="$tb bout.lo aout32.lo" ;;
 556     b_out_vec_little_host)      tb="$tb bout.lo aout32.lo" ;;
 557     bfd_efi_app_ia32_vec)       tb="$tb efi-app-ia32.lo peigen.lo cofflink.lo" ;;
 558     bfd_efi_app_ia64_vec)       tb="$tb efi-app-ia64.lo pepigen.lo cofflink.lo"; target_size=64 ;;
 559     bfd_elf32_avr_vec)          tb="$tb elf32-avr.lo elf32.lo $elf" ;;
 560     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 561     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 562     bfd_elf32_bigarm_oabi_vec)  tb="$tb elfarm-oabi.lo elf32.lo $elf" ;;
 563     bfd_elf32_bigarm_vec)       tb="$tb elfarm-nabi.lo elf32.lo $elf" ;;
 564     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 565     bfd_elf32_cris_vec)         tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 566     bfd_elf32_d10v_vec)         tb="$tb elf32-d10v.lo elf32.lo $elf" ;;
 567     bfd_elf32_d30v_vec)         tb="$tb elf32-d30v.lo elf32.lo $elf" ;;
 568     bfd_elf32_fr30_vec)         tb="$tb elf32-fr30.lo elf32.lo $elf" ;;
 569     bfd_elf32_h8300_vec)        tb="$tb elf32-h8300.lo elf32.lo $elf" ;;
 570     bfd_elf32_hppa_linux_vec)   tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 571     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 572     bfd_elf32_i370_vec)         tb="$tb elf32-i370.lo elf32.lo $elf" ;;
 573     bfd_elf32_i386_vec)         tb="$tb elf32-i386.lo elf32.lo $elf" ;;
 574     bfd_elf32_i860_little_vec)  tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 575     bfd_elf32_i860_vec)         tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 576     bfd_elf32_i960_vec)         tb="$tb elf32-i960.lo elf32.lo $elf" ;;
 577     bfd_elf32_ia64_big_vec)     tb="$tb elf32-ia64.lo elf32.lo $elf" ;;
 578     bfd_elf32_ia64_hpux_big_vec) tb="$tb elf32-ia64.lo elf32.lo $elf";;
 579     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 580     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 581     bfd_elf32_littlearm_oabi_vec) tb="$tb elfarm-oabi.lo elf32.lo $elf" ;;
 582     bfd_elf32_littlearm_vec)    tb="$tb elfarm-nabi.lo elf32.lo $elf" ;;
 583     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 584     bfd_elf32_m32r_vec)         tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 585     bfd_elf32_m68hc11_vec)      tb="$tb elf32-m68hc11.lo elf32.lo $elf" ;;
 586     bfd_elf32_m68hc12_vec)      tb="$tb elf32-m68hc12.lo elf32.lo $elf" ;;
 587     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.lo elf32.lo $elf" ;;
 588     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.lo elf32.lo $elf" ;;
 589     bfd_elf32_mcore_big_vec)    tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 590     bfd_elf32_mcore_little_vec) tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 591     bfd_elf32_mn10200_vec)      tb="$tb elf-m10200.lo elf32.lo $elf" ;;
 592     bfd_elf32_mn10300_vec)      tb="$tb elf-m10300.lo elf32.lo $elf" ;;
 593     bfd_elf32_openrisc_vec)     tb="$tb elf32-openrisc.lo elf32.lo $elf" ;;
 594     bfd_elf32_or32_big_vec)     tb="$tb elf32-or32.lo elf32.lo $elf" ;;
 595     bfd_elf32_pj_vec)           tb="$tb elf32-pj.lo elf32.lo $elf";;
 596     bfd_elf32_pjl_vec)          tb="$tb elf32-pj.lo elf32.lo $elf";;
 597     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 598     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 599     bfd_elf32_s390_vec)         tb="$tb elf32-s390.lo elf32.lo $elf" ;;
 600     bfd_elf32_sh_vec)           tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 601     bfd_elf32_shblin_vec)       tb="$tb elf32-sh-lin.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 602     bfd_elf32_shl_vec)          tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 603     bfd_elf32_shlin_vec)        tb="$tb elf32-sh-lin.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 604     bfd_elf32_shlnbsd_vec)      tb="$tb elf32-sh-nbsd.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 605     bfd_elf32_shnbsd_vec)       tb="$tb elf32-sh-nbsd.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 606     # FIXME: We include cofflink.lo not because it's needed for
 607     # bfd_elf32_sh64[l]_vec, but because we include bfd_elf32_sh[l]_vec
 608     # which needs it but does not list it.  Should be fixed in right place.
 609     bfd_elf32_sh64_vec)         tb="$tb elf32-sh64.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 610     bfd_elf32_sh64l_vec)        tb="$tb elf32-sh64.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 611     bfd_elf64_sh64_vec)         tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 612     bfd_elf64_sh64l_vec)        tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 613     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.lo elf32.lo $elf" ;;
 614     bfd_elf32_tradbigmips_vec)  tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 615     bfd_elf32_tradlittlemips_vec) tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 616     bfd_elf32_us_cris_vec)      tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 617     bfd_elf32_v850_vec)         tb="$tb elf32-v850.lo elf32.lo $elf" ;;
 618     bfd_elf32_xstormy16_vec)    tb="$tb elf32-xstormy16.lo elf32.lo $elf" ;;
 619     bfd_elf64_alpha_vec)        tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 620     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 621     bfd_elf64_bigmips_vec)      tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 622     bfd_elf64_hppa_linux_vec)   tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 623     bfd_elf64_hppa_vec)         tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 624     bfd_elf64_ia64_aix_big_vec) tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 625     bfd_elf64_ia64_aix_little_vec) tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 626     bfd_elf64_ia64_big_vec)     tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 627     bfd_elf64_ia64_hpux_big_vec) tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 628     bfd_elf64_ia64_little_vec)  tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 629     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 630     bfd_elf64_littlemips_vec)   tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 631     bfd_elf64_mmix_vec)         tb="$tb elf64-mmix.lo elf64.lo $elf" target_size=64 ;;
 632     bfd_elf64_powerpc_vec)      tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 633     bfd_elf64_powerpcle_vec)    tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf" target_size=64 ;;
 634     bfd_elf64_s390_vec)         tb="$tb elf64-s390.lo elf64.lo $elf"; target_size=64 ;;
 635     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.lo elf64.lo $elf"; target_size=64 ;;
 636     bfd_elf64_tradbigmips_vec)  tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 637     bfd_elf64_tradlittlemips_vec) tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 638     bfd_elf64_x86_64_vec)       tb="$tb elf64-x86-64.lo elf64.lo $elf"; target_size=64 ;;
 639     bfd_mmo_vec)                tb="$tb mmo.lo" target_size=64 ;;
 640     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 641     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 642     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 643     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 644     cisco_core_big_vec)         tb="$tb cisco-core.lo" ;;
 645     cisco_core_little_vec)      tb="$tb cisco-core.lo" ;;
 646     cris_aout_vec)              tb="$tb aout-cris.lo" ;;
 647     demo_64_vec)                tb="$tb demo64.lo aout64.lo"; target_size=64 ;;
 648     ecoff_big_vec)              tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 649     ecoff_biglittle_vec)        tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 650     ecoff_little_vec)           tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 651     ecoffalpha_little_vec)      tb="$tb coff-alpha.lo ecoff.lo ecofflink.lo"; target_size=64 ;;
 652     go32coff_vec)               tb="$tb coff-go32.lo cofflink.lo" ;;
 653     go32stubbedcoff_vec)        tb="$tb coff-stgo32.lo cofflink.lo" ;;
 654     h8300coff_vec)              tb="$tb coff-h8300.lo reloc16.lo" ;;
 655     h8500coff_vec)              tb="$tb coff-h8500.lo reloc16.lo" ;;
 656     host_aout_vec)              tb="$tb host-aout.lo aout32.lo" ;;
 657     hp300bsd_vec)               tb="$tb hp300bsd.lo aout32.lo" ;;
 658     hp300hpux_vec)              tb="$tb hp300hpux.lo aout32.lo" ;;
 659     i386aout_vec)               tb="$tb i386aout.lo aout32.lo" ;;
 660     i386bsd_vec)                tb="$tb i386bsd.lo aout32.lo" ;;
 661     i386coff_vec)               tb="$tb coff-i386.lo cofflink.lo" ;;
 662     i386dynix_vec)              tb="$tb i386dynix.lo aout32.lo" ;;
 663     i386freebsd_vec)            tb="$tb i386freebsd.lo aout32.lo" ;;
 664     i386linux_vec)              tb="$tb i386linux.lo aout32.lo" ;;
 665     i386lynx_aout_vec)          tb="$tb i386lynx.lo lynx-core.lo aout32.lo" ;;
 666     i386lynx_coff_vec)          tb="$tb cf-i386lynx.lo cofflink.lo lynx-core.lo" ;;
 667     i386mach3_vec)              tb="$tb i386mach3.lo aout32.lo" ;;
 668     i386msdos_vec)              tb="$tb i386msdos.lo" ;;
 669     i386netbsd_vec)             tb="$tb i386netbsd.lo aout32.lo" ;;
 670     i386os9k_vec)               tb="$tb i386os9k.lo aout32.lo" ;;
 671     i386pe_vec)                 tb="$tb pe-i386.lo peigen.lo cofflink.lo" ;;
 672     i386pei_vec)                tb="$tb pei-i386.lo peigen.lo cofflink.lo" ;;
 673     i860coff_vec)               tb="$tb coff-i860.lo cofflink.lo" ;;
 674     icoff_big_vec)              tb="$tb coff-i960.lo cofflink.lo" ;;
 675     icoff_little_vec)           tb="$tb coff-i960.lo cofflink.lo" ;;
 676     ieee_vec)                   tb="$tb ieee.lo" ;;
 677     m68k4knetbsd_vec)           tb="$tb m68k4knetbsd.lo aout32.lo" ;;
 678     m68kaux_coff_vec)           tb="$tb coff-aux.lo coff-m68k.lo cofflink.lo" ;;
 679     m68kcoff_vec)               tb="$tb coff-m68k.lo cofflink.lo" ;;
 680     m68kcoffun_vec)             tb="$tb coff-u68k.lo coff-m68k.lo cofflink.lo" ;;
 681     m68klinux_vec)              tb="$tb m68klinux.lo aout32.lo" ;;
 682     m68klynx_aout_vec)          tb="$tb m68klynx.lo lynx-core.lo aout32.lo" ;;
 683     m68klynx_coff_vec)          tb="$tb cf-m68klynx.lo coff-m68k.lo cofflink.lo lynx-core.lo" ;;
 684     m68knetbsd_vec)             tb="$tb m68knetbsd.lo aout32.lo" ;;
 685     m68ksysvcoff_vec)           tb="$tb coff-svm68k.lo cofflink.lo" ;;
 686     m88kbcs_vec)                tb="$tb coff-m88k.lo" ;;
 687     mcore_pe_big_vec)           tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 688     mcore_pe_little_vec)        tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 689     mcore_pei_big_vec)          tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 690     mcore_pei_little_vec)       tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 691     mipslpe_vec)                tb="$tb pe-mips.lo peigen.lo cofflink.lo" ;;
 692     mipslpei_vec)               tb="$tb pei-mips.lo peigen.lo cofflink.lo" ;;
 693     newsos3_vec)                tb="$tb newsos3.lo aout32.lo" ;;
 694     nlm32_alpha_vec)            tb="$tb nlm32-alpha.lo nlm32.lo nlm.lo"; target_size=64 ;;
 695     nlm32_i386_vec)             tb="$tb nlm32-i386.lo nlm32.lo nlm.lo" ;;
 696     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.lo nlm32.lo nlm.lo" ;;
 697     nlm32_sparc_vec)            tb="$tb nlm32-sparc.lo nlm32.lo nlm.lo" ;;
 698     or32coff_big_vec)           tb="$tb coff-or32.lo cofflink.lo" ;;
 699     pc532machaout_vec)          tb="$tb pc532-mach.lo aout-ns32k.lo" ;;
 700     pc532netbsd_vec)            tb="$tb ns32knetbsd.lo aout-ns32k.lo" ;;
 701     pdp11_aout_vec)             tb="$tb pdp11.lo" ;;
 702     pmac_xcoff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 703     ppcboot_vec)                tb="$tb ppcboot.lo" ;;
 704     riscix_vec)                 tb="$tb aout32.lo riscix.lo" ;;
 705     rs6000coff64_vec)           tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 706     aix5coff64_vec)             tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 707     rs6000coff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 708     shcoff_small_vec)           tb="$tb coff-sh.lo cofflink.lo" ;;
 709     shcoff_vec)                 tb="$tb coff-sh.lo cofflink.lo" ;;
 710     shlcoff_small_vec)          tb="$tb coff-sh.lo cofflink.lo" ;;
 711     shlcoff_vec)                tb="$tb coff-sh.lo cofflink.lo" ;;
 712     shlpe_vec)                  tb="$tb pe-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 713     shlpei_vec)                 tb="$tb pei-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 714     som_vec)                    tb="$tb som.lo" ;;
 715     sparccoff_vec)              tb="$tb coff-sparc.lo" ;;
 716     sparcle_aout_vec)           tb="$tb aout-sparcle.lo aout32.lo" ;;
 717     sparclinux_vec)             tb="$tb sparclinux.lo aout32.lo" ;;
 718     sparclynx_aout_vec)         tb="$tb sparclynx.lo lynx-core.lo aout32.lo" ;;
 719     sparclynx_coff_vec)         tb="$tb cf-sparclynx.lo lynx-core.lo" ;;
 720     sparcnetbsd_vec)            tb="$tb sparcnetbsd.lo aout32.lo" ;;
 721     srec_vec)                   tb="$tb srec.lo" ;;
 722     sunos_big_vec)              tb="$tb sunos.lo aout32.lo" ;;
 723     symbolsrec_vec)             tb="$tb srec.lo" ;;
 724     tekhex_vec)                 tb="$tb tekhex.lo" ;;
 725     tic30_aout_vec)             tb="$tb aout-tic30.lo" ;;
 726     tic30_coff_vec)             tb="$tb coff-tic30.lo" ;;
 727     tic54x_coff0_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 728     tic54x_coff0_vec)           tb="$tb coff-tic54x.lo" ;;
 729     tic54x_coff1_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 730     tic54x_coff1_vec)           tb="$tb coff-tic54x.lo" ;;
 731     tic54x_coff2_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 732     tic54x_coff2_vec)           tb="$tb coff-tic54x.lo" ;;
 733     tic80coff_vec)              tb="$tb coff-tic80.lo cofflink.lo" ;;
 734     versados_vec)               tb="$tb versados.lo" ;;
 735     vms_alpha_vec)              tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo"; target_size=64 ;;
 736     vms_vax_vec)                tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo" ;;
 737     w65_vec)                    tb="$tb coff-w65.lo reloc16.lo" ;;
 738     we32kcoff_vec)              tb="$tb coff-we32k.lo" ;;
 739     z8kcoff_vec)                tb="$tb coff-z8k.lo reloc16.lo" ;;
 740
 741     "")                 ;;
 742     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 743     esac
 744
 745     if test ${target_size} = 64; then
 746         target64=true
 747     fi
 748     if test x"${vec}" = x"${defvec}"; then
 749         bfd_default_target_size=${target_size}
 750     fi
 751 done
 752
 753 # Target architecture .o files.
 754 # A couple of CPUs use shorter file names to avoid problems on DOS
 755 # filesystems.
 756 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.lo/g -e s/mn10200/m10200/ -e s/mn10300/m10300/`
 757
 758 # Weed out duplicate .o files.
 759 f=""
 760 for i in $tb ; do
 761     case " $f " in
 762     *" $i "*) ;;
 763     *) f="$f $i" ;;
 764     esac
 765 done
 766 tb="$f"
 767
 768 f=""
 769 for i in $ta ; do
 770     case " $f " in
 771     *" $i "*) ;;
 772     *) f="$f $i" ;;
 773     esac
 774 done
 775 ta="$f"
 776
 777 bfd_backends="$tb"
 778 bfd_machines="$ta"
 779
 780 if test x${all_targets} = xtrue ; then
 781   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 782   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 783   selvecs=
 784   havevecs=
 785   selarchs=
 786 else    # all_targets is true
 787   # Only set these if they will be nonempty, for the clever echo.
 788   havevecs=
 789   test -n "$selvecs" &&
 790     havevecs=`echo $selvecs | sed -e 's/^/-DHAVE_/' -e 's/ \(.\)/ -DHAVE_\1/g'`
 791   test -n "$selvecs" &&
 792     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 793   test -n "$selarchs" &&
 794     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 795 fi      # all_targets is true
 796
 797 case ${host64}-${target64}-${want64} in
 798   *true*)
 799     wordsize=64
 800     bfd_libs='$(BFD64_LIBS) $(BFD32_LIBS)'
 801     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 802     if test -z "$GCC" && test "$BFD_HOST_64BIT_LONG" = "0" && test "$BFD_HOST_64_BIT_DEFINED" = "0"; then
 803       AC_MSG_WARN([You have requested a 64 bit BFD configuration, but])
 804       AC_MSG_WARN([your compiler may not have a 64 bit integral type])
 805     fi
 806     if test -n "$GCC" ; then
 807        bad_64bit_gcc=no;
 808        AC_MSG_CHECKING([for gcc version with buggy 64-bit support])
 809        # Add more tests for gcc versions with non-working 64-bit support here.
 810        AC_EGREP_CPP([: 2 : 91 : 1 :],[:__GNUC__:__GNUC_MINOR__:__i386__:],
 811                     bad_64bit_gcc=yes;
 812                     AC_MSG_RESULT([yes: egcs-1.1.2 on ix86 spotted]),
 813                     AC_MSG_RESULT(no))
 814        if test $bad_64bit_gcc = yes ; then
 815          AC_ERROR([A newer version of gcc is needed for the requested 64-bit BFD configuration])
 816        fi
 817     fi
 818     ;;
 819   false-false-false)
 820     wordsize=32
 821     bfd_libs='$(BFD32_LIBS)'
 822     all_backends='$(BFD32_BACKENDS)'
 823     ;;
 824 esac
 825
 826 AC_SUBST(wordsize)
 827 AC_SUBST(bfd_libs)
 828 AC_SUBST(all_backends)
 829 AC_SUBST(bfd_backends)
 830 AC_SUBST(bfd_machines)
 831 AC_SUBST(bfd_default_target_size)
 832
 833 tdefaults=""
 834 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 835 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 836 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 837 test -n "${havevecs}" && tdefaults="${tdefaults} ${havevecs}"
 838 AC_SUBST(tdefaults)
 839
 840 dnl AC_CHECK_HEADERS(sys/mman.h)
 841 AC_FUNC_MMAP
 842 AC_CHECK_FUNCS(madvise mprotect)
 843 case ${want_mmap}+${ac_cv_func_mmap_fixed_mapped} in
 844   true+yes )  AC_DEFINE(USE_MMAP, 1, [Use mmap if it's available?]) ;;
 845 esac
 846
 847 rm -f doc/config.status
 848 AC_OUTPUT(Makefile doc/Makefile bfd-in3.h:bfd-in2.h po/Makefile.in:po/Make-in,
 849 [sed -e '/SRC-POTFILES =/r po/SRC-POTFILES' -e '/BLD-POTFILES =/r po/BLD-POTFILES' po/Makefile.in > po/Makefile])
 850