gas/testsuite/lib/gas-defs.exp

   1 # Copyright (C) 1993, 1994, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   2 # 2004, 2005, 2007, 2008, 2009  Free Software Foundation, Inc.
   3
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 3 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston,
  17 # MA 02110-1301, USA.
  18
  19 # Please email any bugs, comments, and/or additions to this file to:
  20 # dejagnu@gnu.org
  21
  22 # This file was written by Ken Raeburn (raeburn@cygnus.com).
  23
  24 proc gas_version {} {
  25     global AS
  26     if [is_remote host] then {
  27         remote_exec host "$AS -version < /dev/null" "" "" "gas.version"
  28         remote_exec host "which $AS" "" "" "gas.which"
  29
  30         remote_upload host "gas.version"
  31         remote_upload host "gas.which"
  32
  33         set which_as [file_contents "gas.which"]
  34         set tmp [file_contents "gas.version"]
  35
  36         remote_file build delete "gas.version"
  37         remote_file build delete "gas.which"
  38         remote_file host delete "gas.version"
  39         remote_file host delete "gas.which"
  40     } else {
  41         set which_as [which $AS]
  42         catch "exec $AS -version < /dev/null" tmp
  43     }
  44
  45     # Should find a way to discard constant parts, keep whatever's
  46     # left, so the version string could be almost anything at all...
  47     regexp "\[^\n\]* (cygnus-|)(\[-0-9.a-zA-Z-\]+)\[\r\n\].*" $tmp version cyg number
  48     if ![info exists number] then {
  49         return "$which_as (no version number)\n"
  50     }
  51     clone_output "$which_as $number\n"
  52     unset version
  53 }
  54
  55 proc gas_host_run { cmd redir } {
  56     verbose "Executing $cmd $redir"
  57     set return_contents_of ""
  58     if [regexp ">& */dev/null" $redir] then {
  59         set output_file ""
  60         set command "$cmd $redir"
  61     } elseif [regexp "> */dev/null" $redir] then {
  62         set output_file ""
  63         set command "$cmd 2>gas.stderr"
  64         set return_contents_of "gas.stderr"
  65     } elseif [regexp ">&.*" $redir] then {
  66         # See PR 5322 for why the following line is used.
  67         regsub ">&" $redir "" output_file
  68         set command "$cmd 2>&1"
  69     } elseif [regexp "2>.*" $redir] then {
  70         set output_file "gas.out"
  71         set command "$cmd $redir"
  72         set return_contents_of "gas.out"
  73     } elseif [regexp ">.*" $redir] then {
  74         set output_file ""
  75         set command "$cmd $redir 2>gas.stderr"
  76         set return_contents_of "gas.stderr"
  77     } elseif { "$redir" == "" } then {
  78         set output_file "gas.out"
  79         set command "$cmd 2>&1"
  80         set return_contents_of "gas.out"
  81     } else {
  82         fail "gas_host_run: unknown form of redirection string"
  83     }
  84
  85     set status [remote_exec host [concat sh -c [list $command]] "" "/dev/null" "$output_file"]
  86     set to_return ""
  87     if { "$return_contents_of" != "" } then {
  88         remote_upload host "$return_contents_of"
  89         set to_return [file_contents "$return_contents_of"]
  90         regsub "\n$" $to_return "" to_return
  91     }
  92
  93     if { [lindex $status 0] == 0 && "$output_file" != ""
  94          && "$output_file" != "$return_contents_of" } then {
  95         remote_upload host "$output_file"
  96     }
  97
  98     return [list [lindex $status 0] "$to_return"]
  99 }
 100
 101 proc gas_run { prog as_opts redir } {
 102     global AS
 103     global ASFLAGS
 104     global comp_output
 105     global srcdir
 106     global subdir
 107     global host_triplet
 108
 109     set status [gas_host_run "$AS $ASFLAGS $as_opts $srcdir/$subdir/$prog" "$redir"]
 110     set comp_output [lindex $status 1]
 111     if { [lindex $status 0] != 0 && [regexp "2>.*" $redir] } then {
 112         append comp_output "child process exited abnormally"
 113     }
 114     set comp_output [prune_warnings $comp_output]
 115     verbose "output was $comp_output"
 116     return [list $comp_output ""]
 117 }
 118
 119 proc gas_run_stdin { prog as_opts redir } {
 120     global AS
 121     global ASFLAGS
 122     global comp_output
 123     global srcdir
 124     global subdir
 125     global host_triplet
 126
 127     set status [gas_host_run "$AS $ASFLAGS $as_opts < $srcdir/$subdir/$prog" "$redir"]
 128     set comp_output [lindex $status 1]
 129     if { [lindex $status 0] != 0 && [regexp "2>.*" $redir] } then {
 130         append comp_output "child process exited abnormally"
 131     }
 132     set comp_output [prune_warnings $comp_output]
 133     verbose "output was $comp_output"
 134     return [list $comp_output ""]
 135 }
 136
 137 proc all_ones { args } {
 138     foreach x $args { if [expr $x!=1] { return 0 } }
 139     return 1
 140 }
 141
 142 # ${tool}_finish (gas_finish) will be called by runtest.exp.  But
 143 # gas_finish should only be used with gas_start.  We use gas_started
 144 # to tell gas_finish if gas_start has been called so that runtest.exp
 145 # can call gas_finish without closing the wrong fd.
 146 set gas_started 0
 147
 148 proc gas_start { prog as_opts } {
 149     global AS
 150     global ASFLAGS
 151     global srcdir
 152     global subdir
 153     global spawn_id
 154     global gas_started
 155
 156     set gas_started 1
 157
 158     verbose -log "Starting $AS $ASFLAGS $as_opts $prog" 2
 159     set status [gas_host_run "$AS $ASFLAGS $as_opts $srcdir/$subdir/$prog" ">&gas.out"]
 160     spawn -noecho -nottycopy cat gas.out
 161 }
 162
 163 proc gas_finish { } {
 164     global spawn_id
 165     global gas_started
 166
 167     if { $gas_started == 1 } {
 168         catch "close"
 169         catch "wait"
 170         set gas_started 0
 171     }
 172 }
 173
 174 proc want_no_output { testname } {
 175     global comp_output
 176
 177     if ![string match "" $comp_output] then {
 178         send_log "$comp_output\n"
 179         verbose "$comp_output" 3
 180     }
 181     if [string match "" $comp_output] then {
 182         pass "$testname"
 183         return 1
 184     } else {
 185         fail "$testname"
 186         return 0
 187     }
 188 }
 189
 190 proc gas_test_old { file as_opts testname } {
 191     gas_run $file $as_opts ""
 192     return [want_no_output $testname]
 193 }
 194
 195 proc gas_test { file as_opts var_opts testname } {
 196     global comp_output
 197
 198     set i 0
 199     foreach word $var_opts {
 200         set ignore_stdout($i) [string match "*>" $word]
 201         set opt($i) [string trim $word {>}]
 202         incr i
 203     }
 204     set max [expr 1<<$i]
 205     for {set i 0} {[expr $i<$max]} {incr i} {
 206         set maybe_ignore_stdout ""
 207         set extra_opts ""
 208         for {set bit 0} {(1<<$bit)<$max} {incr bit} {
 209             set num [expr 1<<$bit]
 210             if [expr $i&$num] then {
 211                 set extra_opts "$extra_opts $opt($bit)"
 212                 if $ignore_stdout($bit) then {
 213                     set maybe_ignore_stdout ">/dev/null"
 214                 }
 215             }
 216         }
 217         set extra_opts [string trim $extra_opts]
 218         gas_run $file "$as_opts $extra_opts" $maybe_ignore_stdout
 219
 220         # Should I be able to use a conditional expression here?
 221         if [string match "" $extra_opts] then {
 222             want_no_output $testname
 223         } else {
 224             want_no_output "$testname ($extra_opts)"
 225         }
 226     }
 227     if [info exists errorInfo] then {
 228         unset errorInfo
 229     }
 230 }
 231
 232 proc gas_test_ignore_stdout { file as_opts testname } {
 233     global comp_output
 234
 235     gas_run $file $as_opts ">/dev/null"
 236     want_no_output $testname
 237 }
 238
 239 proc gas_test_error { file as_opts testname } {
 240     global comp_output
 241
 242     gas_run $file $as_opts ">/dev/null"
 243     send_log "$comp_output\n"
 244     verbose "$comp_output" 3
 245     if { ![string match "" $comp_output]
 246          && ![string match "*Assertion failure*" $comp_output]
 247          && ![string match "*Internal error*" $comp_output] } then {
 248         pass "$testname"
 249     } else {
 250         fail "$testname"
 251     }
 252 }
 253
 254 proc gas_exit {} {}
 255
 256 proc gas_init { args } {
 257     global target_cpu
 258     global target_cpu_family
 259     global target_family
 260     global target_vendor
 261     global target_os
 262     global stdoptlist
 263
 264     case "$target_cpu" in {
 265         "m68???"                { set target_cpu_family m68k }
 266         "i[3-7]86"              { set target_cpu_family i386 }
 267         default                 { set target_cpu_family $target_cpu }
 268     }
 269
 270     set target_family "$target_cpu_family-$target_vendor-$target_os"
 271     set stdoptlist "-a>"
 272
 273     if ![istarget "*-*-*"] {
 274         perror "Target name [istarget] is not a triple."
 275     }
 276     # Need to return an empty string.
 277     return
 278 }
 279
 280 #
 281 # is_elf_format
 282 #       true if the object format is known to be ELF
 283 #
 284 proc is_elf_format {} {
 285     if { ![istarget *-*-sysv4*] \
 286          && ![istarget *-*-unixware*] \
 287          && ![istarget *-*-elf*] \
 288          && ![istarget *-*-eabi*] \
 289          && ![istarget hppa*64*-*-hpux*] \
 290          && ![istarget *-*-linux*] \
 291          && ![istarget frv-*-uclinux*] \
 292          && ![istarget sh*-*-uclinux*] \
 293          && ![istarget *-*-irix5*] \
 294          && ![istarget *-*-irix6*] \
 295          && ![istarget *-*-netbsd*] \
 296          && ![istarget *-*-openbsd*] \
 297          && ![istarget *-*-solaris2*] } {
 298         return 0
 299     }
 300
 301     if { [istarget *-*-linux*aout*] \
 302          || [istarget *-*-linux*oldld*] } {
 303         return 0
 304     }
 305
 306     if { ![istarget *-*-netbsdelf*] \
 307          && ([istarget *-*-netbsd*aout*] \
 308              || [istarget *-*-netbsdpe*] \
 309              || [istarget arm*-*-netbsd*] \
 310              || [istarget sparc-*-netbsd*] \
 311              || [istarget i*86-*-netbsd*] \
 312              || [istarget m68*-*-netbsd*] \
 313              || [istarget vax-*-netbsd*] \
 314              || [istarget ns32k-*-netbsd*]) } {
 315         return 0
 316     }
 317
 318     if { [istarget arm-*-openbsd*] \
 319          || [istarget i386-*-openbsd\[0-2\].*] \
 320          || [istarget i386-*-openbsd3.\[0-3\]] \
 321          || [istarget m68*-*-openbsd*] \
 322          || [istarget ns32k-*-openbsd*] \
 323          || [istarget sparc-*-openbsd\[0-2\].*] \
 324          || [istarget sparc-*-openbsd3.\[0-1\]] \
 325          || [istarget vax-*-openbsd*] } {
 326         return 0
 327     }
 328
 329     return 1
 330 }
 331
 332 # True if the object format is known to be PE COFF.
 333 #
 334 proc is_pecoff_format {} {
 335     if { ![istarget *-*-mingw*] \
 336          && ![istarget *-*-cygwin*] \
 337          && ![istarget *-*-pe*] } {
 338         return 0
 339     }
 340
 341     return 1
 342 }
 343
 344 # run_dump_tests TESTCASES EXTRA_OPTIONS
 345 # Wrapper for run_dump_test, which is suitable for invoking as
 346 #   run_dump_tests [lsort [glob -nocomplain $srcdir/$subdir/*.d]]
 347 # EXTRA_OPTIONS are passed down to run_dump_test.  Honors runtest_file_p.
 348 # Body cribbed from dg-runtest.
 349
 350 proc run_dump_tests { testcases {extra_options {}} } {
 351     global runtests
 352
 353     foreach testcase $testcases {
 354         # If testing specific files and this isn't one of them, skip it.
 355         if ![runtest_file_p $runtests $testcase] {
 356             continue
 357         }
 358         run_dump_test [file rootname [file tail $testcase]] $extra_options
 359     }
 360 }
 361
 362
 363 # run_dump_test FILE (optional:) EXTRA_OPTIONS
 364 #
 365 # Assemble a .s file, then run some utility on it and check the output.
 366 #
 367 # There should be an assembly language file named FILE.s in the test
 368 # suite directory, and a pattern file called FILE.d.  `run_dump_test'
 369 # will assemble FILE.s, run some tool like `objdump', `objcopy', or
 370 # `nm' on the .o file to produce textual output, and then analyze that
 371 # with regexps.  The FILE.d file specifies what program to run, and
 372 # what to expect in its output.
 373 #
 374 # The FILE.d file begins with zero or more option lines, which specify
 375 # flags to pass to the assembler, the program to run to dump the
 376 # assembler's output, and the options it wants.  The option lines have
 377 # the syntax:
 378 #
 379 #         # OPTION: VALUE
 380 #
 381 # OPTION is the name of some option, like "name" or "objdump", and
 382 # VALUE is OPTION's value.  The valid options are described below.
 383 # Whitespace is ignored everywhere, except within VALUE.  The option
 384 # list ends with the first line that doesn't match the above syntax.
 385 # However, a line within the options that begins with a #, but doesn't
 386 # have a recognizable option name followed by a colon, is considered a
 387 # comment and entirely ignored.
 388 #
 389 # The optional EXTRA_OPTIONS argument to `run_dump_test' is a list of
 390 # two-element lists.  The first element of each is an option name, and
 391 # the second additional arguments to be added on to the end of the
 392 # option list as given in FILE.d.  (If omitted, no additional options
 393 # are added.)
 394 #
 395 # The interesting options are:
 396 #
 397 #   name: TEST-NAME
 398 #       The name of this test, passed to DejaGNU's `pass' and `fail'
 399 #       commands.  If omitted, this defaults to FILE, the root of the
 400 #       .s and .d files' names.
 401 #
 402 #   as: FLAGS
 403 #       When assembling FILE.s, pass FLAGS to the assembler.
 404 #
 405 #   nm: FLAGS
 406 #   objcopy: FLAGS
 407 #   objdump: FLAGS
 408 #   readelf: FLAGS
 409 #       Use the specified program to analyze the .o file, and pass it
 410 #       FLAGS, in addition to the .o file name.  Note that they are run
 411 #       with LC_ALL=C in the environment to give consistent sorting
 412 #       of symbols.  If no FLAGS are needed then use:
 413 #        PROG: [nm objcopy objdump readelf]
 414 #       instead.
 415 #
 416 #   source: SOURCE
 417 #       Assemble the file SOURCE.s.  If omitted, this defaults to FILE.s.
 418 #       This is useful if several .d files want to share a .s file.
 419 #
 420 #   target: GLOBS...
 421 #       Run this test only on a specified list of targets.  More precisely,
 422 #       each glob in the space-separated list is passed to "istarget"; if
 423 #       it evaluates true for any of them, the test will be run, otherwise
 424 #       it will be marked unsupported.
 425 #
 426 #   not-target: GLOBS...
 427 #       Do not run this test on a specified list of targets.  Again,
 428 #       the each glob in the space-separated list is passed to
 429 #       "istarget", and the test is run if it evaluates *false* for
 430 #       *all* of them.  Otherwise it will be marked unsupported.
 431 #
 432 #   skip: GLOBS...
 433 #   not-skip: GLOBS...
 434 #       These are exactly the same as "not-target" and "target",
 435 #       respectively, except that they do nothing at all if the check
 436 #       fails.  They should only be used in groups, to construct a single
 437 #       test which is run on all targets but with variant options or
 438 #       expected output on some targets.  (For example, see
 439 #       gas/arm/inst.d and gas/arm/wince_inst.d.)
 440 #
 441 #   error: REGEX
 442 #       An error with message matching REGEX must be emitted for the test
 443 #       to pass.  The PROG, objdump, nm and objcopy options have no
 444 #       meaning and need not supplied if this is present.
 445 #
 446 #   warning: REGEX
 447 #       Expect a gas warning matching REGEX.  It is an error to issue
 448 #       both "error" and "warning".
 449 #
 450 #   stderr: FILE
 451 #       FILE contains regexp lines to be matched against the diagnostic
 452 #       output of the assembler.  This does not preclude the use of
 453 #       PROG, nm, objdump, or objcopy.
 454 #
 455 #   error-output: FILE
 456 #       Means the same as 'stderr', but also indicates that the assembler
 457 #       is expected to exit unsuccessfully (therefore PROG, objdump, nm,
 458 #       and objcopy have no meaning and should not be supplied).
 459 #
 460 # Each option may occur at most once.
 461 #
 462 # After the option lines come regexp lines.  `run_dump_test' calls
 463 # `regexp_diff' to compare the output of the dumping tool against the
 464 # regexps in FILE.d.  `regexp_diff' is defined later in this file; see
 465 # further comments there.
 466
 467 proc run_dump_test { name {extra_options {}} } {
 468     global subdir srcdir
 469     global OBJDUMP NM AS OBJCOPY READELF
 470     global OBJDUMPFLAGS NMFLAGS ASFLAGS OBJCOPYFLAGS READELFFLAGS
 471     global host_triplet
 472     global env
 473
 474     if [string match "*/*" $name] {
 475         set file $name
 476         set name [file tail $name]
 477     } else {
 478         set file "$srcdir/$subdir/$name"
 479     }
 480     set opt_array [slurp_options "${file}.d"]
 481     if { $opt_array == -1 } {
 482         perror "error reading options from $file.d"
 483         unresolved $subdir/$name
 484         return
 485     }
 486     set opts(as) {}
 487     set opts(objdump) {}
 488     set opts(nm) {}
 489     set opts(objcopy) {}
 490     set opts(readelf) {}
 491     set opts(name) {}
 492     set opts(PROG) {}
 493     set opts(source) {}
 494     set opts(stderr) {}
 495     set opts(error) {}
 496     set opts(error-output) {}
 497     set opts(warning) {}
 498     set opts(target) {}
 499     set opts(not-target) {}
 500     set opts(skip) {}
 501     set opts(not-skip) {}
 502
 503     foreach i $opt_array {
 504         set opt_name [lindex $i 0]
 505         set opt_val [lindex $i 1]
 506         if ![info exists opts($opt_name)] {
 507             perror "unknown option $opt_name in file $file.d"
 508             unresolved $subdir/$name
 509             return
 510         }
 511         if [string length $opts($opt_name)] {
 512             perror "option $opt_name multiply set in $file.d"
 513             unresolved $subdir/$name
 514             return
 515         }
 516         if { $opt_name == "as" } {
 517             set opt_val [subst $opt_val]
 518         }
 519         set opts($opt_name) $opt_val
 520     }
 521
 522     foreach i $extra_options {
 523         set opt_name [lindex $i 0]
 524         set opt_val [lindex $i 1]
 525         if ![info exists opts($opt_name)] {
 526             perror "unknown option $opt_name given in extra_opts"
 527             unresolved $subdir/$name
 528             return
 529         }
 530         # add extra option to end of existing option, adding space
 531         # if necessary.
 532         if [string length $opts($opt_name)] {
 533             append opts($opt_name) " "
 534         }
 535         append opts($opt_name) $opt_val
 536     }
 537
 538     if { $opts(name) == "" } {
 539         set testname "$subdir/$name"
 540     } else {
 541         set testname $opts(name)
 542     }
 543     verbose "Testing $testname"
 544
 545     if { (($opts(warning) != "") && ($opts(error) != "")) \
 546          || (($opts(warning) != "") && ($opts(stderr) != "")) \
 547          || (($opts(error-output) != "") && ($opts(stderr) != "")) \
 548          || (($opts(error-output) != "") && ($opts(error) != "")) \
 549          || (($opts(error-output) != "") && ($opts(warning) != "")) } {
 550         perror "$testname: bad mix of stderr, error-output, error, and warning test-directives"
 551         unresolved $testname
 552         return
 553     }
 554     if { $opts(error-output) != "" } then {
 555         set opts(stderr) $opts(error-output)
 556     }
 557
 558     set program ""
 559     # It's meaningless to require an output-testing method when we
 560     # expect an error.
 561     if { $opts(error) == "" && $opts(error-output) == "" } {
 562         if {$opts(PROG) != ""} {
 563             switch -- $opts(PROG) {
 564                 objdump { set program objdump }
 565                 nm      { set program nm }
 566                 objcopy { set program objcopy }
 567                 readelf { set program readelf }
 568                 default {
 569                     perror "unrecognized program option $opts(PROG) in $file.d"
 570                     unresolved $testname
 571                     return }
 572             }
 573         } else {
 574             # Guess which program to run, by seeing which option was specified.
 575             foreach p {objdump objcopy nm readelf} {
 576                 if {$opts($p) != ""} {
 577                     if {$program != ""} {
 578                         perror "ambiguous dump program in $file.d"
 579                         unresolved $testname
 580                         return
 581                     } else {
 582                         set program $p
 583                     }
 584                 }
 585             }
 586         }
 587         if { $program == "" && $opts(warning) == "" } {
 588             perror "dump program unspecified in $file.d"
 589             unresolved $testname
 590             return
 591         }
 592     }
 593
 594     # Handle skipping the test on specified targets.
 595     # You can have both skip/not-skip and target/not-target, but you can't
 596     # have both skip and not-skip, or target and not-target, in the same file.
 597     if { $opts(skip) != "" } then {
 598         if { $opts(not-skip) != "" } then {
 599             perror "$testname: mixing skip and not-skip directives is invalid"
 600             unresolved $testname
 601             return
 602         }
 603         foreach glob $opts(skip) {
 604             if {[istarget $glob]} { return }
 605         }
 606     }
 607     if { $opts(not-skip) != "" } then {
 608         set skip 1
 609         foreach glob $opts(not-skip) {
 610             if {[istarget $glob]} {
 611                 set skip 0
 612                 break
 613             }
 614         }
 615         if {$skip} { return }
 616     }
 617     if { $opts(target) != "" } then {
 618         if { $opts(not-target) != "" } then {
 619             perror "$testname: mixing target and not-target directives is invalid"
 620             unresolved $testname
 621             return
 622         }
 623         set skip 1
 624         foreach glob $opts(target) {
 625             if {[istarget $glob]} {
 626                 set skip 0
 627                 break
 628             }
 629         }
 630         if {$skip} {
 631             unsupported $testname
 632             return
 633         }
 634     }
 635     if { $opts(not-target) != "" } then {
 636         foreach glob $opts(not-target) {
 637             if {[istarget $glob]} {
 638                 unsupported $testname
 639                 return
 640             }
 641         }
 642     }
 643
 644
 645     if { $opts(source) == "" } {
 646         set sourcefile ${file}.s
 647     } else {
 648         set sourcefile $srcdir/$subdir/$opts(source)
 649     }
 650
 651     set cmd "$AS $ASFLAGS $opts(as) -o dump.o $sourcefile"
 652     send_log "$cmd\n"
 653     set status [gas_host_run $cmd ""]
 654     set cmdret [lindex $status 0]
 655     set comp_output [prune_warnings [lindex $status 1]]
 656
 657     set expmsg $opts(error)
 658     if { $opts(warning) != "" } {
 659         set expmsg $opts(warning)
 660     }
 661     if { $cmdret != 0 || $comp_output != "" || $expmsg != "" } then {
 662         # If the executed program writes to stderr and stderr is not
 663         # redirected, exec *always* returns failure, regardless of the
 664         # program exit code.  Thankfully, we can retrieve the true
 665         # return status from a special variable.  Redirection would
 666         # cause a tcl-specific message to be appended, and we'd rather
 667         # not deal with that if we can help it.
 668         global errorCode
 669         if { $cmdret != 0 && [lindex $errorCode 0] == "NONE" } {
 670             set cmdret 0
 671         }
 672
 673         set exitstat "succeeded"
 674         if { $cmdret != 0 } { set exitstat "failed" }
 675
 676         send_log "$comp_output\n"
 677         verbose "$comp_output" 3
 678         if { $opts(stderr) == "" }  then {
 679             if { [regexp $expmsg $comp_output] \
 680                     && (($cmdret == 0) == ($opts(warning) != "")) } {
 681                 # We have the expected output from gas.
 682                 # Return if there's nothing more to do.
 683                 if { $opts(error) != "" || $program == "" } {
 684                     pass $testname
 685                     return
 686                 }
 687             } else {
 688                 verbose -log "$exitstat with: <$comp_output>, expected: <$expmsg>"
 689
 690                 fail $testname
 691                 return
 692             }
 693         } else {
 694             catch {write_file dump.stderr "$comp_output"} write_output
 695             if ![string match "" $write_output] then {
 696                 send_log "error writing dump.stderr: $write_output\n"
 697                 verbose "error writing dump.stderr: $write_output" 3
 698                 send_log "$comp_output\n"
 699                 verbose "$comp_output" 3
 700                 fail $testname
 701                 return
 702             }
 703             set stderrfile $srcdir/$subdir/$opts(stderr)
 704             verbose "wrote pruned stderr to dump.stderr" 3
 705             if { [regexp_diff "dump.stderr" "$stderrfile"] } then {
 706                 if { $opts(error) != "" } {
 707                     verbose -log "$exitstat with: <$comp_output>, expected: <$opts(error)>"
 708                     if [regexp $opts(error) $comp_output] {
 709                         pass $testname
 710                         return
 711                     }
 712                 }
 713                 fail $testname
 714                 verbose "pruned stderr is [file_contents "dump.stderr"]" 2
 715                 return
 716             } elseif { $opts(error-output) != "" } then {
 717                 pass $testname
 718                 return
 719             }
 720         }
 721     } else {
 722         if { $opts(error) != "" || $opts(error-output) != "" } {
 723             fail $testname
 724         }
 725     }
 726
 727     if { $program == "" } {
 728         return
 729     }
 730     set progopts1 $opts($program)
 731     eval set progopts \$[string toupper $program]FLAGS
 732     eval set binary \$[string toupper $program]
 733
 734     if { ![is_remote host] && [which $binary] == 0 } {
 735         untested $testname
 736         return
 737     }
 738
 739     if { $progopts1 == "" } { set $progopts1 "-r" }
 740     verbose "running $binary $progopts $progopts1" 3
 741
 742     # Objcopy, unlike the other two, won't send its output to stdout,
 743     # so we have to run it specially.
 744     set cmd "$binary $progopts $progopts1 dump.o"
 745     set redir ">dump.out"
 746     if { $program == "objcopy" } {
 747         set cmd "$binary $progopts $progopts1 dump.o dump.out"
 748         set redir ""
 749     }
 750
 751     # Ensure consistent sorting of symbols
 752     if {[info exists env(LC_ALL)]} {
 753         set old_lc_all $env(LC_ALL)
 754     }
 755     set env(LC_ALL) "C"
 756     send_log "$cmd\n"
 757     set status [gas_host_run "$cmd" "$redir"]
 758     set comp_output [prune_warnings [lindex $status 1]]
 759     if {[info exists old_lc_all]} {
 760         set env(LC_ALL) $old_lc_all
 761     } else {
 762         unset env(LC_ALL)
 763     }
 764     set comp_output [prune_warnings $comp_output]
 765     if ![string match "" $comp_output] then {
 766         send_log "$comp_output\n"
 767         fail $testname
 768         return
 769     }
 770
 771     verbose_eval {[file_contents "dump.out"]} 3
 772     if { [regexp_diff "dump.out" "${file}.d"] } then {
 773         fail $testname
 774         verbose "output is [file_contents "dump.out"]" 2
 775         return
 776     }
 777
 778     pass $testname
 779 }
 780
 781 proc slurp_options { file } {
 782     if [catch { set f [open $file r] } x] {
 783         #perror "couldn't open `$file': $x"
 784         perror "$x"
 785         return -1
 786     }
 787     set opt_array {}
 788     # whitespace expression
 789     set ws  {[  ]*}
 790     set nws {[^         ]*}
 791     # whitespace is ignored anywhere except within the options list;
 792     # option names are alphabetic plus dash
 793     set pat "^#${ws}(\[a-zA-Z-\]*)$ws:${ws}(.*)$ws\$"
 794     while { [gets $f line] != -1 } {
 795         set line [string trim $line]
 796         # Whitespace here is space-tab.
 797         if [regexp $pat $line xxx opt_name opt_val] {
 798             # match!
 799             lappend opt_array [list $opt_name $opt_val]
 800         } elseif {![regexp "^#" $line ]} {
 801             break
 802         }
 803     }
 804     close $f
 805     return $opt_array
 806 }
 807
 808 proc objdump { opts } {
 809     global OBJDUMP
 810     global comp_output
 811     global host_triplet
 812
 813     set status [gas_host_run "$OBJDUMP $opts" ""]
 814     set comp_output [prune_warnings [lindex $status 1]]
 815     verbose "objdump output=$comp_output\n" 3
 816 }
 817
 818 proc objdump_start_no_subdir { prog opts } {
 819     global OBJDUMP
 820     global srcdir
 821     global spawn_id
 822
 823     verbose "Starting $OBJDUMP $opts $prog" 2
 824     set status [gas_host_run "$OBJDUMP $opts $prog" ">&gas.out"]
 825     spawn -noecho -nottycopy cat gas.out
 826 }
 827
 828 proc objdump_finish { } {
 829     global spawn_id
 830
 831     catch "close"
 832     catch "wait"
 833 }
 834
 835 # Default timeout is 10 seconds, loses on a slow machine.  But some
 836 # configurations of dejagnu may override it.
 837 if {$timeout<120} then { set timeout 120 }
 838
 839 expect_after -i {
 840     timeout                     { perror "timeout" }
 841     "virtual memory exhausted"  { perror "virtual memory exhausted" }
 842     buffer_full                 { perror "buffer full" }
 843     eof                         { perror "eof" }
 844 }
 845
 846 # regexp_diff, based on simple_diff taken from ld test suite
 847 #       compares two files line-by-line
 848 #       file1 contains strings, file2 contains regexps and #-comments
 849 #       blank lines are ignored in either file
 850 #       returns non-zero if differences exist
 851 #
 852 proc regexp_diff { file_1 file_2 } {
 853
 854     set eof -1
 855     set end_1 0
 856     set end_2 0
 857     set differences 0
 858     set diff_pass 0
 859
 860     if [file exists $file_1] then {
 861         set file_a [open $file_1 r]
 862     } else {
 863         perror "$file_1 doesn't exist"
 864         return 1
 865     }
 866
 867     if [file exists $file_2] then {
 868         set file_b [open $file_2 r]
 869     } else {
 870         perror "$file_2 doesn't exist"
 871         close $file_a
 872         return 1
 873     }
 874
 875     verbose " Regexp-diff'ing: $file_1 $file_2" 2
 876
 877     while { 1 } {
 878         set line_a ""
 879         set line_b ""
 880         while { [string length $line_a] == 0 } {
 881             if { [gets $file_a line_a] == $eof } {
 882                 set end_1 1
 883                 break
 884             }
 885         }
 886         while { [string length $line_b] == 0 || [string match "#*" $line_b] } {
 887             if [ string match "#pass" $line_b ] {
 888                 set end_2 1
 889                 set diff_pass 1
 890                 break
 891             } elseif [ string match "#..." $line_b ] {
 892                 if { [gets $file_b line_b] == $eof } {
 893                     set end_2 1
 894                     set diff_pass 1
 895                     break
 896                 }
 897                 verbose "looking for \"^$line_b$\"" 3
 898                 while { ![regexp "^$line_b$" "$line_a"] } {
 899                     verbose "skipping    \"$line_a\"" 3
 900                     if { [gets $file_a line_a] == $eof } {
 901                         set end_1 1
 902                         break
 903                     }
 904                 }
 905                 break
 906             }
 907             if { [gets $file_b line_b] == $eof } {
 908                 set end_2 1
 909                 break
 910             }
 911         }
 912
 913         if { $diff_pass } {
 914             break
 915         } elseif { $end_1 && $end_2 } {
 916             break
 917         } elseif { $end_1 } {
 918             send_log "extra regexps in $file_2 starting with \"^$line_b$\"\nEOF from $file_1\n"
 919             verbose "extra regexps in $file_2 starting with \"^$line_b$\"\nEOF from $file_1" 3
 920             set differences 1
 921             break
 922         } elseif { $end_2 } {
 923             send_log "extra lines in $file_1 starting with \"^$line_a$\"\nEOF from $file_2\n"
 924             verbose "extra lines in $file_1 starting with \"^$line_a$\"\nEOF from $file_2\n" 3
 925             set differences 1
 926             break
 927         } else {
 928             verbose "regexp \"^$line_b$\"\nline   \"$line_a\"" 3
 929             if ![regexp "^$line_b$" "$line_a"] {
 930                 send_log "regexp_diff match failure\n"
 931                 send_log "regexp \"^$line_b$\"\nline   \"$line_a\"\n"
 932                 verbose "regexp_diff match failure\n" 3
 933                 set differences 1
 934             }
 935         }
 936     }
 937
 938     if { $differences == 0 && !$diff_pass && [eof $file_a] != [eof $file_b] } {
 939         send_log "$file_1 and $file_2 are different lengths\n"
 940         verbose "$file_1 and $file_2 are different lengths" 3
 941         set differences 1
 942     }
 943
 944     close $file_a
 945     close $file_b
 946
 947     return $differences
 948 }
 949
 950 proc file_contents { filename } {
 951     set file [open $filename r]
 952     set contents [read $file]
 953     close $file
 954     return $contents
 955 }
 956
 957 proc write_file { filename contents } {
 958     set file [open $filename w]
 959     puts $file "$contents"
 960     close $file
 961 }
 962
 963 proc verbose_eval { expr { level 1 } } {
 964     global verbose
 965     if $verbose>$level then { eval verbose "$expr" $level }
 966 }
 967
 968 # This definition is taken from an unreleased version of DejaGnu.  Once
 969 # that version gets released, and has been out in the world for a few
 970 # months at least, it may be safe to delete this copy.
 971 if ![string length [info proc prune_warnings]] {
 972     #
 973     # prune_warnings -- delete various system verbosities from TEXT.
 974     #
 975     # An example is:
 976     # ld.so: warning: /usr/lib/libc.so.1.8.1 has older revision than expected 9
 977     #
 978     # Sites with particular verbose os's may wish to override this in site.exp.
 979     #
 980     proc prune_warnings { text } {
 981         # This is from sun4's.  Do it for all machines for now.
 982         # The "\\1" is to try to preserve a "\n" but only if necessary.
 983         regsub -all "(^|\n)(ld.so: warning:\[^\n\]*\n?)+" $text "\\1" text
 984
 985         # It might be tempting to get carried away and delete blank lines, etc.
 986         # Just delete *exactly* what we're ask to, and that's it.
 987         return $text
 988     }
 989 }
 990
 991 # run_list_test NAME (optional): OPTS TESTNAME
 992 #
 993 # Assemble the file "NAME.s" with command line options OPTS and
 994 # compare the assembler standard error output against the regular
 995 # expressions given in the file "NAME.l".  If TESTNAME is provided,
 996 # it will be used as the name of the test.
 997
 998 proc run_list_test { name {opts {}} {testname {}} } {
 999     global srcdir subdir
1000     if { [string length $testname] == 0 } then {
1001         set testname "[file tail $subdir] $name"
1002     }
1003     set file $srcdir/$subdir/$name
1004     gas_run ${name}.s $opts ">&dump.out"
1005     if { [regexp_diff "dump.out" "${file}.l"] } then {
1006         fail $testname
1007         verbose "output is [file_contents "dump.out"]" 2
1008         return
1009     }
1010     pass $testname
1011 }
1012
1013 # run_list_test_stdin NAME (optional): OPTS TESTNAME
1014 #
1015 # Similar to run_list_test, but use stdin as input.
1016
1017 proc run_list_test_stdin { name {opts {}} {testname {}} } {
1018     global srcdir subdir
1019     if { [string length $testname] == 0 } then {
1020         set testname "[file tail $subdir] $name"
1021     }
1022     set file $srcdir/$subdir/$name
1023     gas_run_stdin ${name}.s $opts ">&dump.out"
1024     if { [regexp_diff "dump.out" "${file}.l"] } then {
1025         fail $testname
1026         verbose "output is [file_contents "dump.out"]" 2
1027         return
1028     }
1029     pass $testname
1030 }