ld/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 AC_PREREQ(2.57)
   4 AC_INIT(ldmain.c)
   5
   6 AC_CANONICAL_SYSTEM
   7 AC_ISC_POSIX
   8
   9 changequote(,)dnl
  10 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  11 changequote([,])dnl
  12 AM_INIT_AUTOMAKE(ld, ${BFD_VERSION})
  13
  14 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  15 AC_ARG_ENABLE(targets,
  16 [  --enable-targets        alternative target configurations],
  17 [case "${enableval}" in
  18   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  19             ;;
  20   no)       enable_targets= ;;
  21   *)        enable_targets=$enableval ;;
  22 esac])dnl
  23 AC_ARG_ENABLE(64-bit-bfd,
  24 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  25 [case "${enableval}" in
  26   yes)  want64=true  ;;
  27   no)   want64=false ;;
  28   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  29 esac],[want64=false])dnl
  30
  31 AC_ARG_WITH(sysroot,
  32 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  33 [
  34  case ${with_sysroot} in
  35  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  36  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  37  esac
  38
  39  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  40  use_sysroot=yes
  41
  42  if test "x$prefix" = xNONE; then
  43   test_prefix=/usr/local
  44  else
  45   test_prefix=$prefix
  46  fi
  47  if test "x$exec_prefix" = xNONE; then
  48   test_exec_prefix=$test_prefix
  49  else
  50   test_exec_prefix=$exec_prefix
  51  fi
  52  case ${TARGET_SYSTEM_ROOT} in
  53  "${test_prefix}"|"${test_prefix}/"*|\
  54  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  55  '${prefix}'|'${prefix}/'*|\
  56  '${exec_prefix}'|'${exec_prefix}/'*)
  57    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  58    TARGET_SYSTEM_ROOT_DEFINE="$t"
  59    ;;
  60  esac
  61 ], [
  62  use_sysroot=no
  63  TARGET_SYSTEM_ROOT=
  64  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  65 ])
  66 AC_SUBST(use_sysroot)
  67 AC_SUBST(TARGET_SYSTEM_ROOT)
  68 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  69
  70 AC_ARG_ENABLE([got],
  71 AS_HELP_STRING([--enable-got=<type>],
  72                [GOT handling scheme (target, single, negative, multigot)]),
  73 [case "${enableval}" in
  74   target | single | negative | multigot)  got_handling=$enableval ;;
  75   *)  AC_ERROR(bad value ${enableval} for --enable-got option) ;;
  76 esac],
  77 [got_handling=target])
  78
  79 case "${got_handling}" in
  80   target)
  81     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
  82               [Define to choose default GOT handling scheme]) ;;
  83   single)
  84     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
  85               [Define to choose default GOT handling scheme]) ;;
  86   negative)
  87     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
  88               [Define to choose default GOT handling scheme]) ;;
  89   multigot)
  90     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
  91               [Define to choose default GOT handling scheme]) ;;
  92   *)  AC_ERROR(bad value ${got_handling} for --enable-got option) ;;
  93 esac
  94
  95 AM_BINUTILS_WARNINGS
  96
  97 AM_CONFIG_HEADER(config.h:config.in)
  98
  99 if test -z "$target" ; then
 100     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 101 fi
 102 if test -z "$host" ; then
 103     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 104 fi
 105
 106 # host-specific stuff:
 107
 108 AC_PROG_CC
 109 AC_GNU_SOURCE
 110 AC_USE_SYSTEM_EXTENSIONS
 111 AC_PROG_INSTALL
 112
 113 AM_PROG_LIBTOOL
 114
 115 ALL_LINGUAS="fr sv tr es da vi zh_CN zh_TW ga fi"
 116 ZW_GNU_GETTEXT_SISTER_DIR
 117 AM_PO_SUBDIRS
 118
 119 AC_EXEEXT
 120
 121 AC_PROG_YACC
 122 AM_PROG_LEX
 123
 124 AM_MAINTAINER_MODE
 125 AM_CONDITIONAL(GENINSRC_NEVER, false)
 126
 127 . ${srcdir}/configure.host
 128
 129 AC_SUBST(HDEFINES)
 130 AC_SUBST(HOSTING_CRT0)
 131 AC_SUBST(HOSTING_LIBS)
 132 AC_SUBST(NATIVE_LIB_DIRS)
 133
 134 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h sys/param.h)
 135 AC_CHECK_FUNCS(glob mkstemp realpath sbrk waitpid)
 136 AC_HEADER_DIRENT
 137
 138 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 139 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 140 [AC_TRY_COMPILE([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);],
 141 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 142 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 143 if test $ld_cv_decl_getopt_unistd_h = yes; then
 144   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 145             [Is the prototype for getopt in <unistd.h> in the expected format?])
 146 fi
 147
 148 BFD_BINARY_FOPEN
 149
 150 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 151
 152 # Link in zlib if we can.  This is needed only for the bootstrap tests
 153 # right now, since those tests use libbfd, which depends on zlib.
 154 AC_SEARCH_LIBS(zlibVersion, z, [AC_CHECK_HEADERS(zlib.h)])
 155
 156 # When converting linker scripts into strings for use in emulation
 157 # files, use astring.sed if the compiler supports ANSI string
 158 # concatenation, or ostring.sed otherwise.  This is to support the
 159 # broken Microsoft MSVC compiler, which limits the length of string
 160 # constants, while still supporting pre-ANSI compilers which do not
 161 # support string concatenation.
 162 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 163 AC_CACHE_VAL(ld_cv_string_concatenation,
 164 [AC_TRY_COMPILE(,[char *a = "a" "a";],
 165   [ld_cv_string_concatenation=yes],
 166   [ld_cv_string_concatenation=no])])
 167 AC_MSG_RESULT($ld_cv_string_concatenation)
 168 if test "$ld_cv_string_concatenation" = "yes"; then
 169   STRINGIFY=astring.sed
 170 else
 171   STRINGIFY=ostring.sed
 172 fi
 173 AC_SUBST(STRINGIFY)
 174
 175 # target-specific stuff:
 176
 177 all_targets=
 178 EMUL=
 179 all_emuls=
 180 all_emul_extras=
 181 all_libpath=
 182
 183 dnl We need to get an arbitrary number of tdir definitions into
 184 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 185 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 186 dnl file.
 187 rm -f tdirs
 188
 189 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 190 do
 191   if test "$targ_alias" = "all"; then
 192     all_targets=true
 193   else
 194     # Canonicalize the secondary target names.
 195     result=`$ac_config_sub $targ_alias 2>/dev/null`
 196     if test -n "$result"; then
 197         targ=$result
 198     else
 199         targ=$targ_alias
 200     fi
 201
 202     . ${srcdir}/configure.tgt
 203
 204     if test "$targ" = "$target"; then
 205       EMUL=$targ_emul
 206     fi
 207
 208     if test x${want64} = xfalse; then
 209       . ${srcdir}/../bfd/config.bfd
 210     fi
 211
 212     if test x${want64} = xtrue; then
 213       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 214       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 215     fi
 216
 217     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 218         case " $all_emuls " in
 219         *" e${i}.o "*) ;;
 220         *)
 221           all_emuls="$all_emuls e${i}.o"
 222           eval result=\$tdir_$i
 223           test -z "$result" && result=$targ_alias
 224           echo tdir_$i=$result >> tdirs
 225           ;;
 226         esac
 227     done
 228
 229     for i in $targ_emul $targ_extra_libpath; do
 230         case " $all_libpath " in
 231         *" ${i} "*) ;;
 232         *)
 233           if test -z "$all_libpath"; then
 234             all_libpath=${i}
 235           else
 236             all_libpath="$all_libpath ${i}"
 237           fi
 238           ;;
 239         esac
 240     done
 241
 242     for i in $targ_extra_ofiles; do
 243         case " $all_emul_extras " in
 244         *" ${i} "*) ;;
 245         *)
 246           all_emul_extras="$all_emul_extras ${i}"
 247           ;;
 248         esac
 249     done
 250   fi
 251 done
 252
 253 AC_SUBST(EMUL)
 254
 255 TDIRS=tdirs
 256 AC_SUBST_FILE(TDIRS)
 257
 258 if test x${all_targets} = xtrue; then
 259   if test x${want64} = xfalse; then
 260     AC_CHECK_SIZEOF(long)
 261     if test "x${ac_cv_sizeof_long}" = "x8"; then
 262       want64=true
 263     fi
 264   fi
 265   if test x${want64} = xtrue; then
 266     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 267   else
 268     EMULATION_OFILES='$(ALL_EMULATIONS)'
 269   fi
 270   EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 271 else
 272   EMULATION_OFILES=$all_emuls
 273   EMUL_EXTRA_OFILES=$all_emul_extras
 274 fi
 275 AC_SUBST(EMULATION_OFILES)
 276 AC_SUBST(EMUL_EXTRA_OFILES)
 277 AC_SUBST(LIB_PATH)
 278
 279 EMULATION_LIBPATH=$all_libpath
 280 AC_SUBST(EMULATION_LIBPATH)
 281
 282 if test x${enable_static} = xno; then
 283   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 284 else
 285   TESTBFDLIB="../bfd/.libs/libbfd.a"
 286 fi
 287 AC_SUBST(TESTBFDLIB)
 288
 289 target_vendor=${target_vendor=$host_vendor}
 290 case "$target_vendor" in
 291   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 292   *)  EXTRA_SHLIB_EXTENSION= ;;
 293 esac
 294
 295 case "$target_os" in
 296   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 297 esac
 298
 299 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 300   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 301    [Additional extension a shared object might have.])
 302 fi
 303
 304 dnl Required by html and install-html
 305 AC_SUBST(datarootdir)
 306 AC_SUBST(docdir)
 307 AC_SUBST(htmldir)
 308
 309 AC_OUTPUT(Makefile po/Makefile.in:po/Make-in)