binutils/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_PREREQ(2.57)
   4 AC_INIT(ar.c)
   5
   6 AC_CANONICAL_SYSTEM
   7 AC_ISC_POSIX
   8
   9 changequote(,)dnl
  10 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  11 changequote([,])dnl
  12 AM_INIT_AUTOMAKE(binutils, ${BFD_VERSION})
  13
  14 AC_PROG_CC
  15 AC_GNU_SOURCE
  16 AC_PROG_LIBTOOL
  17
  18 AC_ARG_ENABLE(targets,
  19 [  --enable-targets        alternative target configurations],
  20 [case "${enableval}" in
  21   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  22             ;;
  23   no)       enable_targets= ;;
  24   *)        enable_targets=$enableval ;;
  25 esac])dnl
  26 AC_ARG_ENABLE(commonbfdlib,
  27 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  28 [case "${enableval}" in
  29   yes) commonbfdlib=true ;;
  30   no)  commonbfdlib=false ;;
  31   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  32 esac])dnl
  33
  34 AM_BINUTILS_WARNINGS
  35
  36 AM_CONFIG_HEADER(config.h:config.in)
  37
  38 if test -z "$target" ; then
  39     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  40 fi
  41 if test -z "$host" ; then
  42     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  43 fi
  44
  45 AC_PROG_YACC
  46 AM_PROG_LEX
  47
  48 ALL_LINGUAS="fr tr ja es sv da zh_CN ru ro rw zh_TW fi vi"
  49 ZW_GNU_GETTEXT_SISTER_DIR
  50 AM_PO_SUBDIRS
  51
  52 AM_MAINTAINER_MODE
  53 AM_CONDITIONAL(GENINSRC_NEVER, false)
  54 AC_EXEEXT
  55 if test -n "$EXEEXT"; then
  56   AC_DEFINE(HAVE_EXECUTABLE_SUFFIX, 1,
  57             [Does the platform use an executable suffix?])
  58 fi
  59 AC_DEFINE_UNQUOTED(EXECUTABLE_SUFFIX, "${EXEEXT}",
  60                    [Suffix used for executables, if any.])
  61
  62 # host-specific stuff:
  63
  64 HDEFINES=
  65
  66 . ${srcdir}/../bfd/configure.host
  67
  68 AC_SUBST(HDEFINES)
  69 AR=${AR-ar}
  70 AC_SUBST(AR)
  71 AC_PROG_RANLIB
  72 AC_PROG_INSTALL
  73
  74 BFD_CC_FOR_BUILD
  75
  76 DEMANGLER_NAME=c++filt
  77 case "${host}" in
  78   *-*-go32* | *-*-msdos*)
  79     DEMANGLER_NAME=cxxfilt
  80 esac
  81 AC_SUBST(DEMANGLER_NAME)
  82
  83 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h fcntl.h sys/file.h limits.h sys/param.h)
  84 AC_HEADER_SYS_WAIT
  85 AC_FUNC_ALLOCA
  86 AC_CHECK_FUNCS(sbrk utimes setmode getc_unlocked strcoll)
  87 AC_CHECK_FUNC([mkstemp],
  88               AC_DEFINE([HAVE_MKSTEMP], 1,
  89               [Define to 1 if you have the `mkstemp' function.]))
  90 AC_CHECK_FUNC([mkdtemp],
  91               AC_DEFINE([HAVE_MKDTEMP], 1,
  92               [Define to 1 if you have the `mkdtemp' function.]))
  93
  94 # Check whether fopen64 is available and whether _LARGEFILE64_SOURCE
  95 # needs to be defined for it
  96 AC_MSG_CHECKING([for fopen64])
  97 AC_CACHE_VAL(bu_cv_have_fopen64,
  98 [AC_TRY_LINK([#include <stdio.h>], [FILE *f = fopen64 ("/tmp/foo","r");],
  99 bu_cv_have_fopen64=yes,
 100 [saved_CPPFLAGS=$CPPFLAGS
 101  CPPFLAGS="$CPPFLAGS -D_LARGEFILE64_SOURCE"
 102  AC_TRY_LINK([#include <stdio.h>], [FILE *f = fopen64 ("/tmp/foo","r");],
 103 bu_cv_have_fopen64="need -D_LARGEFILE64_SOURCE",
 104 bu_cv_have_fopen64=no)
 105  CPPFLAGS=$saved_CPPFLAGS])])
 106 AC_MSG_RESULT($bu_cv_have_fopen64)
 107 if test "$bu_cv_have_fopen64" != no; then
 108   AC_DEFINE([HAVE_FOPEN64], 1,
 109             [Is fopen64 available?])
 110 fi
 111 AC_MSG_CHECKING([for stat64])
 112 AC_CACHE_VAL(bu_cv_have_stat64,
 113 [AC_TRY_LINK([#include <sys/stat.h>], [struct stat64 st; stat64 ("/tmp/foo", &st);],
 114 bu_cv_have_stat64=yes,
 115 [saved_CPPFLAGS=$CPPFLAGS
 116  CPPFLAGS="$CPPFLAGS -D_LARGEFILE64_SOURCE"
 117  AC_TRY_LINK([#include <sys/stat.h>], [struct stat64 st; stat64 ("/tmp/foo", &st);],
 118 bu_cv_have_stat64="need -D_LARGEFILE64_SOURCE",
 119 bu_cv_have_stat64=no)
 120  CPPFLAGS=$saved_CPPFLAGS])])
 121 AC_MSG_RESULT($bu_cv_have_stat64)
 122 if test "$bu_cv_have_stat64" != no; then
 123   AC_DEFINE([HAVE_STAT64], 1,
 124             [Is stat64 available?])
 125 fi
 126 if test "$bu_cv_have_fopen64" = "need -D_LARGEFILE64_SOURCE" \
 127    || test "$bu_cv_have_stat64" = "need -D_LARGEFILE64_SOURCE"; then
 128   AC_DEFINE([_LARGEFILE64_SOURCE], 1,
 129             [Enable LFS])
 130   CPPFLAGS="$CPPFLAGS -D_LARGEFILE64_SOURCE"
 131 fi
 132
 133 # Some systems have frexp only in -lm, not in -lc.
 134 AC_SEARCH_LIBS(frexp, m)
 135
 136 AC_MSG_CHECKING(for time_t in time.h)
 137 AC_CACHE_VAL(bu_cv_decl_time_t_time_h,
 138 [AC_TRY_COMPILE([#include <time.h>], [time_t i;],
 139 bu_cv_decl_time_t_time_h=yes, bu_cv_decl_time_t_time_h=no)])
 140 AC_MSG_RESULT($bu_cv_decl_time_t_time_h)
 141 if test $bu_cv_decl_time_t_time_h = yes; then
 142   AC_DEFINE([HAVE_TIME_T_IN_TIME_H], 1,
 143             [Is the type time_t defined in <time.h>?])
 144 fi
 145
 146 AC_MSG_CHECKING(for time_t in sys/types.h)
 147 AC_CACHE_VAL(bu_cv_decl_time_t_types_h,
 148 [AC_TRY_COMPILE([#include <sys/types.h>], [time_t i;],
 149 bu_cv_decl_time_t_types_h=yes, bu_cv_decl_time_t_types_h=no)])
 150 AC_MSG_RESULT($bu_cv_decl_time_t_types_h)
 151 if test $bu_cv_decl_time_t_types_h = yes; then
 152   AC_DEFINE([HAVE_TIME_T_IN_TYPES_H], 1,
 153             [Is the type time_t defined in <sys/types.h>?])
 154 fi
 155
 156 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 157 AC_CACHE_VAL(bu_cv_decl_getopt_unistd_h,
 158 [AC_TRY_COMPILE([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);],
 159 bu_cv_decl_getopt_unistd_h=yes, bu_cv_decl_getopt_unistd_h=no)])
 160 AC_MSG_RESULT($bu_cv_decl_getopt_unistd_h)
 161 if test $bu_cv_decl_getopt_unistd_h = yes; then
 162   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 163             [Is the prototype for getopt in <unistd.h> in the expected format?])
 164 fi
 165
 166 # Under Next 3.2 <utime.h> apparently does not define struct utimbuf
 167 # by default.
 168 AC_MSG_CHECKING([for utime.h])
 169 AC_CACHE_VAL(bu_cv_header_utime_h,
 170 [AC_TRY_COMPILE([#include <sys/types.h>
 171 #ifdef HAVE_TIME_H
 172 #include <time.h>
 173 #endif
 174 #include <utime.h>],
 175 [struct utimbuf s;],
 176 bu_cv_header_utime_h=yes, bu_cv_header_utime_h=no)])
 177 AC_MSG_RESULT($bu_cv_header_utime_h)
 178 if test $bu_cv_header_utime_h = yes; then
 179   AC_DEFINE(HAVE_GOOD_UTIME_H, 1, [Does <utime.h> define struct utimbuf?])
 180 fi
 181
 182 AC_CHECK_DECLS([fprintf, stpcpy, strstr, sbrk, getenv, environ, getc_unlocked,
 183                 snprintf, vsnprintf])
 184
 185 BFD_BINARY_FOPEN
 186
 187 # target-specific stuff:
 188
 189 # Canonicalize the secondary target names.
 190 if test -n "$enable_targets"; then
 191     for targ in `echo $enable_targets | sed 's/,/ /g'`
 192     do
 193         result=`$ac_config_sub $targ 2>/dev/null`
 194         if test -n "$result"; then
 195             canon_targets="$canon_targets $result"
 196         else
 197             # Allow targets that config.sub doesn't recognize, like "all".
 198             canon_targets="$canon_targets $targ"
 199         fi
 200     done
 201 fi
 202
 203 all_targets=false
 204 BUILD_NLMCONV=
 205 NLMCONV_DEFS=
 206 BUILD_SRCONV=
 207 BUILD_DLLTOOL=
 208 DLLTOOL_DEFS=
 209 DLLTOOL_DEFAULT=
 210 BUILD_WINDRES=
 211 BUILD_DLLWRAP=
 212 BUILD_MISC=
 213 BUILD_INSTALL_MISC=
 214 OBJDUMP_DEFS=
 215
 216 for targ in $target $canon_targets
 217 do
 218     if test "x$targ" = "xall"; then
 219         all_targets=true
 220         BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 221         BUILD_SRCONV='$(SRCONV_PROG)'
 222         NLMCONV_DEFS="-DNLMCONV_I386 -DNLMCONV_ALPHA -DNLMCONV_POWERPC -DNLMCONV_SPARC"
 223         BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 224     else
 225         case $targ in
 226 changequote(,)dnl
 227         i[3-7]86*-*-netware*)
 228 changequote([,])dnl
 229           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 230           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_I386"
 231           ;;
 232         alpha*-*-netware*)
 233           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 234           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_ALPHA"
 235           ;;
 236         powerpc*-*-netware*)
 237           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 238           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_POWERPC"
 239           ;;
 240         sparc*-*-netware*)
 241           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 242           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_SPARC"
 243           ;;
 244         esac
 245         case $targ in
 246         *-*-hms*) BUILD_SRCONV='$(SRCONV_PROG)' ;;
 247         esac
 248         case $targ in
 249         arm-epoc-pe*)
 250           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 251           if test -z "$DLLTOOL_DEFAULT"; then
 252             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM_EPOC"
 253           fi
 254           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_EPOC -DDLLTOOL_ARM"
 255           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 256           ;;
 257         arm-wince-pe* | arm-*-wince)
 258           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 259           if test -z "$DLLTOOL_DEFAULT"; then
 260             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM_WINCE"
 261           fi
 262           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_WINCE -DDLLTOOL_ARM"
 263           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 264           ;;
 265         arm-*-pe*)
 266           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 267           if test -z "$DLLTOOL_DEFAULT"; then
 268             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM"
 269           fi
 270           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 271           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 272           ;;
 273         thumb-*-pe*)
 274           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 275           if test -z "$DLLTOOL_DEFAULT"; then
 276             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM"
 277           fi
 278           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 279           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 280           ;;
 281         x86_64-*-mingw*)
 282           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 283           if test -z "$DLLTOOL_DEFAULT"; then
 284             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MX86_64"
 285           fi
 286           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MX86_64"
 287           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 288           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 289           ;;
 290 changequote(,)dnl
 291         i[3-7]86-*-pe* | i[3-7]86-*-cygwin* | i[3-7]86-*-mingw32** | i[3-7]86-*-netbsdpe*)
 292 changequote([,])dnl
 293           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 294           if test -z "$DLLTOOL_DEFAULT"; then
 295             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 296           fi
 297           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 298           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 299           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 300           ;;
 301 changequote(,)dnl
 302         i[3-7]86-*-interix)
 303 changequote([,])dnl
 304           BUILD_DLLTOOL='$(DLLTOOL_PROG)'
 305           if test -z "$DLLTOOL_DEFAULT"; then
 306             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 307           fi
 308           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 309           ;;
 310 changequote(,)dnl
 311         powerpc*-aix5.[01])
 312 changequote([,])dnl
 313           ;;
 314         powerpc*-aix5.*)
 315           OBJDUMP_DEFS="-DAIX_WEAK_SUPPORT"
 316           ;;
 317         powerpc*-*-pe* | powerpc*-*-cygwin*)
 318           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 319           if test -z "$DLLTOOL_DEFAULT"; then
 320             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_PPC"
 321           fi
 322           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_PPC"
 323           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 324           ;;
 325         powerpc*-*-linux* | powerpc*-*-elf*)
 326           BUILD_INSTALL_MISC="${BUILD_INSTALL_MISC} embedspu"
 327           ;;
 328         sh*-*-pe)
 329           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 330           if test -z "$DLLTOOL_DEFAULT"; then
 331             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_SH"
 332           fi
 333           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_SH"
 334           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 335           ;;
 336         spu-*-*)
 337           BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 338           ;;
 339         mips*-*-pe)
 340           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 341           if test -z "$DLLTOOL_DEFAULT"; then
 342             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MIPS"
 343           fi
 344           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MIPS"
 345           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 346           ;;
 347         mcore-*-pe)
 348           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 349           if test -z "$DLLTOOL_DEFAULT"; then
 350             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE"
 351           fi
 352           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE"
 353           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 354           ;;
 355         mcore-*-elf)
 356           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 357           if test -z "$DLLTOOL_DEFAULT"; then
 358             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE_ELF"
 359           fi
 360           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE_ELF"
 361           ;;
 362         mep-*)
 363           OBJDUMP_DEFS="-DSKIP_ZEROES=256 -DSKIP_ZEROES_AT_END=0"
 364           ;;
 365         esac
 366     fi
 367 done
 368
 369 DLLTOOL_DEFS="$DLLTOOL_DEFS $DLLTOOL_DEFAULT"
 370
 371 if test "${with_windres+set}" = set; then
 372           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 373 fi
 374
 375 AC_SUBST(NLMCONV_DEFS)
 376 AC_SUBST(BUILD_NLMCONV)
 377 AC_SUBST(BUILD_SRCONV)
 378 AC_SUBST(BUILD_DLLTOOL)
 379 AC_SUBST(DLLTOOL_DEFS)
 380 AC_SUBST(BUILD_WINDRES)
 381 AC_SUBST(BUILD_DLLWRAP)
 382 AC_SUBST(BUILD_MISC)
 383 AC_SUBST(BUILD_INSTALL_MISC)
 384 AC_SUBST(OBJDUMP_DEFS)
 385
 386 AC_DEFINE_UNQUOTED(TARGET, "${target}", [Configured target name.])
 387
 388 targ=$target
 389 . $srcdir/../bfd/config.bfd
 390 if test "x$targ_underscore" = "xyes"; then
 391     UNDERSCORE=1
 392 else
 393     UNDERSCORE=0
 394 fi
 395 AC_DEFINE_UNQUOTED(TARGET_PREPENDS_UNDERSCORE, $UNDERSCORE,
 396  [Define to 1 if user symbol names have a leading underscore, 0 if not.])
 397
 398 # Emulation
 399 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 400 do
 401   # Canonicalize the secondary target names.
 402  result=`$ac_config_sub $targ_alias 2>/dev/null`
 403  if test -n "$result"; then
 404    targ=$result
 405  else
 406    targ=$targ_alias
 407  fi
 408
 409  . ${srcdir}/configure.tgt
 410
 411   EMULATION=$targ_emul
 412   EMULATION_VECTOR=$targ_emul_vector
 413 done
 414
 415 AC_SUBST(EMULATION)
 416 AC_SUBST(EMULATION_VECTOR)
 417
 418 # Required for html and install-html
 419 AC_SUBST(datarootdir)
 420 AC_SUBST(docdir)
 421 AC_SUBST(htmldir)
 422
 423 AC_OUTPUT(Makefile doc/Makefile po/Makefile.in:po/Make-in)