ld/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 AC_PREREQ(2.13)
   4 AC_INIT(ldmain.c)
   5
   6 AC_CANONICAL_SYSTEM
   7 AC_ISC_POSIX
   8
   9 changequote(,)dnl
  10 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  11 changequote([,])dnl
  12 AM_INIT_AUTOMAKE(ld, ${BFD_VERSION})
  13
  14 AM_PROG_LIBTOOL
  15
  16 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  17 AC_ARG_ENABLE(targets,
  18 [  --enable-targets        alternative target configurations],
  19 [case "${enableval}" in
  20   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  21             ;;
  22   no)       enable_targets= ;;
  23   *)        enable_targets=$enableval ;;
  24 esac])dnl
  25 AC_ARG_ENABLE(64-bit-bfd,
  26 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  27 [case "${enableval}" in
  28   yes)  want64=true  ;;
  29   no)   want64=false ;;
  30   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  31 esac],[want64=false])dnl
  32
  33 AC_ARG_WITH(sysroot,
  34 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  35 [
  36  case ${with_sysroot} in
  37  yes) AC_ERROR(with-sysroot must specify path) ;;
  38  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  39  esac
  40
  41  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  42  use_sysroot=yes
  43
  44  if test "x$exec_prefix" = xNONE; then
  45   if test "x$prefix" = xNONE; then
  46    test_prefix=/usr/local
  47   else
  48    test_prefix=$prefix
  49   fi
  50  else
  51   test_prefix=$exec_prefix
  52  fi
  53  case ${TARGET_SYSTEM_ROOT} in
  54  ${test_prefix}*)
  55    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  56    TARGET_SYSTEM_ROOT_DEFINE="$t"
  57    ;;
  58  esac
  59 ], [
  60  use_sysroot=no
  61  TARGET_SYSTEM_ROOT=
  62  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  63 ])
  64 AC_SUBST(use_sysroot)
  65 AC_SUBST(TARGET_SYSTEM_ROOT)
  66 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  67
  68 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  69 AC_ARG_ENABLE(build-warnings,
  70 [  --enable-build-warnings enable build-time compiler warnings if gcc is used],
  71 [case "${enableval}" in
  72   yes)  ;;
  73   no)   build_warnings="-w";;
  74   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  75         build_warnings="${build_warnings} ${t}";;
  76   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  77         build_warnings="${t} ${build_warnings}";;
  78   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  79 esac
  80 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  81   echo "Setting warning flags = $build_warnings" 6>&1
  82 fi])dnl
  83 WARN_CFLAGS=""
  84 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  85     WARN_CFLAGS="${build_warnings}"
  86 fi
  87 AC_SUBST(WARN_CFLAGS)
  88
  89 AM_CONFIG_HEADER(config.h:config.in)
  90
  91 if test -z "$target" ; then
  92     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  93 fi
  94 if test -z "$host" ; then
  95     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  96 fi
  97
  98 # host-specific stuff:
  99
 100 AC_PROG_CC
 101 AC_PROG_INSTALL
 102
 103 ALL_LINGUAS="fr sv tr es da"
 104 CY_GNU_GETTEXT
 105
 106 AC_EXEEXT
 107
 108 AC_PROG_YACC
 109 AM_PROG_LEX
 110
 111 AM_MAINTAINER_MODE
 112
 113 . ${srcdir}/configure.host
 114
 115 AC_SUBST(HDEFINES)
 116 AC_SUBST(HOSTING_CRT0)
 117 AC_SUBST(HOSTING_LIBS)
 118 AC_SUBST(NATIVE_LIB_DIRS)
 119
 120 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h)
 121 AC_CHECK_FUNCS(sbrk realpath)
 122 AC_HEADER_DIRENT
 123
 124 BFD_BINARY_FOPEN
 125
 126 BFD_NEED_DECLARATION(strstr)
 127 BFD_NEED_DECLARATION(free)
 128 BFD_NEED_DECLARATION(sbrk)
 129 BFD_NEED_DECLARATION(getenv)
 130 BFD_NEED_DECLARATION(environ)
 131
 132 # When converting linker scripts into strings for use in emulation
 133 # files, use astring.sed if the compiler supports ANSI string
 134 # concatenation, or ostring.sed otherwise.  This is to support the
 135 # broken Microsoft MSVC compiler, which limits the length of string
 136 # constants, while still supporting pre-ANSI compilers which do not
 137 # support string concatenation.
 138 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 139 AC_CACHE_VAL(ld_cv_string_concatenation,
 140 [AC_TRY_COMPILE(,[char *a = "a" "a";],
 141   [ld_cv_string_concatenation=yes],
 142   [ld_cv_string_concatenation=no])])
 143 AC_MSG_RESULT($ld_cv_string_concatenation)
 144 if test "$ld_cv_string_concatenation" = "yes"; then
 145   STRINGIFY=astring.sed
 146 else
 147   STRINGIFY=ostring.sed
 148 fi
 149 AC_SUBST(STRINGIFY)
 150
 151 # target-specific stuff:
 152
 153 all_targets=
 154 EMUL=
 155 all_emuls=
 156 all_emul_extras=
 157 all_libpath=
 158
 159 dnl We need to get an arbitrary number of tdir definitions into
 160 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 161 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 162 dnl file.
 163 rm -f tdirs
 164
 165 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 166 do
 167   if test "$targ_alias" = "all"; then
 168     all_targets=true
 169   else
 170     # Canonicalize the secondary target names.
 171     result=`$ac_config_sub $targ_alias 2>/dev/null`
 172     if test -n "$result"; then
 173         targ=$result
 174     else
 175         targ=$targ_alias
 176     fi
 177
 178     . ${srcdir}/configure.tgt
 179
 180     if test "$targ" = "$target"; then
 181       EMUL=$targ_emul
 182     fi
 183
 184     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 185         case " $all_emuls " in
 186         *" e${i}.o "*) ;;
 187         *)
 188           all_emuls="$all_emuls e${i}.o"
 189           eval result=\$tdir_$i
 190           test -z "$result" && result=$targ_alias
 191           echo tdir_$i=$result >> tdirs
 192           ;;
 193         esac
 194     done
 195
 196     for i in $targ_emul $targ_extra_libpath; do
 197         case " $all_libpath " in
 198         *" ${i} "*) ;;
 199         *)
 200           if test -z "$all_libpath"; then
 201             all_libpath=${i}
 202           else
 203             all_libpath="$all_libpath ${i}"
 204           fi
 205           ;;
 206         esac
 207     done
 208
 209     for i in $targ_extra_ofiles; do
 210         case " $all_emul_extras " in
 211         *" ${i} "*) ;;
 212         *)
 213           all_emul_extras="$all_emul_extras ${i}"
 214           ;;
 215         esac
 216     done
 217   fi
 218 done
 219
 220 AC_SUBST(EMUL)
 221
 222 TDIRS=tdirs
 223 AC_SUBST_FILE(TDIRS)
 224
 225 dnl FIXME: We will build a 64 bit BFD for a 64 bit host or a 64 bit
 226 dnl target, and in those cases we should also build the 64 bit
 227 dnl emulations.
 228 if test x${all_targets} = xtrue; then
 229   if test x${want64} = xtrue; then
 230     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 231   else
 232     EMULATION_OFILES='$(ALL_EMULATIONS)'
 233   fi
 234   EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 235 else
 236   EMULATION_OFILES=$all_emuls
 237   EMUL_EXTRA_OFILES=$all_emul_extras
 238 fi
 239 AC_SUBST(EMULATION_OFILES)
 240 AC_SUBST(EMUL_EXTRA_OFILES)
 241 AC_SUBST(LIB_PATH)
 242
 243 EMULATION_LIBPATH=$all_libpath
 244 AC_SUBST(EMULATION_LIBPATH)
 245
 246 if test x${enable_static} = xno; then
 247   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 248 else
 249   TESTBFDLIB="../bfd/.libs/libbfd.a"
 250 fi
 251 AC_SUBST(TESTBFDLIB)
 252
 253 target_vendor=${target_vendor=$host_vendor}
 254 case "$target_vendor" in
 255   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 256   *)  EXTRA_SHLIB_EXTENSION= ;;
 257 esac
 258 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 259   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 260    [Additional extension a shared object might have.])
 261 fi
 262
 263 AC_OUTPUT(Makefile po/Makefile.in:po/Make-in,
 264 [sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile])