configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT([bbkeys], [1.0.0git], [http://bbkeys.sourceforge.net])
   3 AC_CONFIG_SRCDIR([src/main.cpp])
   4 AM_INIT_AUTOMAKE
   5 AM_MAINTAINER_MODE
   6 AC_PREFIX_DEFAULT([/usr/local])
   7
   8 AC_CHECK_PROGS(regex_cmd, sed)
   9 if test x$regex_cmd = "x"; then
  10  AC_MSG_ERROR([error. sed is required to build the default bbtoolsrc file.])
  11 fi
  12
  13 dnl get the debug values right
  14 AC_DEFUN([AC_SET_DEBUG],
  15 [
  16   _CFLAGS="-g -Wall -DDEBUG"
  17   _CXXFLAGS="-g -Wall -DDEBUG"
  18   _LDFLAGS=""
  19   case $host_os in
  20   [*solaris*)]
  21     dnl On solaris, we get a ton of multiply-defined errors if we don't include
  22     dnl this parameter
  23     _LDFLAGS="$_LDFLAGS -z muldefs"
  24     ;;
  25   esac
  26   test "$CFLAGS" = "" && CFLAGS=$_CFLAGS
  27   test "$CXXFLAGS" = "" && CXXFLAGS=$_CXXFLAGS
  28   test "$LDFLAGS" = "" && LDFLAGS=$_LDFLAGS
  29 ])
  30
  31 AC_DEFUN([AC_SET_NODEBUG],
  32 [
  33   _CFLAGS="-DNDEBUG"
  34   _CXXFLAGS="-DNDEBUG"
  35   _LDFLAGS=""
  36   case $host_os in
  37   [*solaris*)]
  38      _CFLAGS="$_CFLAGS -O"
  39      _CXXFLAGS="$_CXXFLAGS -O"
  40      dnl On solaris, we get a ton of multiply-defined errors if we don't include
  41      dnl this parameter
  42      _LDFLAGS="$_LDFLAGS -z muldefs"
  43      ;;
  44   [*)]
  45      _CFLAGS="$_CFLAGS -O2"
  46      _CXXFLAGS="$_CXXFLAGS -O2"
  47      ;;
  48   esac
  49   test "$CFLAGS" = "" && CFLAGS=$_CFLAGS
  50   test "$CXXFLAGS" = "" && CXXFLAGS=$_CXXFLAGS
  51   test "$LDFLAGS" = "" && LDFLAGS=$_LDFLAGS
  52 ])
  53
  54 AC_ARG_ENABLE(debug,[  --enable-debug   create debugging code [default=no]],
  55 [
  56 if test $enableval = "no";
  57  then AC_SET_NODEBUG
  58  else AC_SET_DEBUG
  59 fi
  60 ],
  61 AC_SET_NODEBUG)
  62
  63 dnl Checks for programs.
  64 AC_PROG_CC
  65 AC_PROG_CXX
  66 AC_PROG_CPP
  67 AC_PROG_AWK
  68 AC_PROG_INSTALL
  69 AC_PROG_LN_S
  70 AC_PROG_MAKE_SET
  71
  72 dnl minimum version we can live with
  73 PERL_VERSION=5.004
  74 dnl check for perl for our command-line configurator
  75 AC_PATH_PROGS(PERL, $PERL perl5 perl )
  76 if test -z "$PERL" || test "$PERL" = ":"; then
  77     AC_MSG_ERROR([perl not found in \$PATH])
  78 fi
  79
  80 AC_MSG_CHECKING([for minimum required perl version >= $PERL_VERSION])
  81 _perl_version=`PERL_VERSION=$PERL_VERSION $PERL -e 'print "$]"; if ($] >= $ENV{PERL_VERSION}) { exit(0); } else { exit(1); }' 2>&5`
  82 _perl_res=$?
  83 AC_MSG_RESULT([$_perl_version])
  84
  85 if test "$_perl_res" != 0; then
  86     AC_MSG_ERROR([Perl $PERL_VERSION or higher is required.])
  87 fi
  88
  89 AC_MSG_CHECKING([for full perl installation])
  90 _perl_archlib=`$PERL -e 'use Config; if ( -d $Config{archlib} ) { exit(0); } else { exit(1); }' 2>&5`
  91 _perl_res=$?
  92 if test "$_perl_res" != 0; then
  93     AC_MSG_RESULT([no])
  94     AC_MSG_ERROR([Cannot find Config.pm or \$Config{archlib}.  A full perl installation is required.])
  95 else
  96     AC_MSG_RESULT([yes])
  97 fi
  98
  99
 100 # Checks for header files.
 101 AC_PATH_XTRA
 102 AC_HEADER_STDC
 103 AC_HEADER_SYS_WAIT
 104 AC_CHECK_HEADERS(ctype.h strings.h fcntl.h libgen.h locale.h process.h signal.h stdio.h time.h errno.h unistd.h sys/signal.h sys/param.h sys/select.h sys/stat.h sys/time.h sys/types.h sys/wait.h stdlib.h string.h malloc.h)
 105
 106 # Checks for typedefs, structures, and compiler characteristics.
 107 AC_C_CONST
 108 AC_C_INLINE
 109 AC_HEADER_TIME
 110 AC_STRUCT_TM
 111
 112 # Checks for library functions.
 113 dnl AC_FUNC_FORK
 114 dnl AC_FUNC_MALLOC
 115 AC_TYPE_SIGNAL
 116 dnl AC_FUNC_STAT
 117 AC_CHECK_FUNCS(setlocale sigaction strftime gettimeofday memset strcasecmp strchr strcspn strdup strncasecmp select strstr)
 118
 119 dnl these have to be here for X tests...
 120 CFLAGS="$CFLAGS $X_CFLAGS"
 121 CXXFLAGS="$CXXFLAGS $X_CFLAGS"
 122 LDFLAGS="$LDFLAGS $X_LIBS $X_PRE_LIBS"
 123
 124
 125 dnl Checks for X libraries.
 126 AC_CHECK_LIB(X11, XOpenDisplay, LIBS="-lX11",
 127              AC_MSG_ERROR(XOpenDisplay not found in -lX11))
 128
 129 dnl Checks for Xextension
 130 AC_CHECK_LIB(Xext, XMissingExtension, LIBS="$LIBS -lXext",
 131              AC_MSG_ERROR(XMissingExtension not found in -lXext))
 132
 133 dnl pkgconfig checks for blackbox library
 134 PKG_CHECK_MODULES(LIBBT, libbt)
 135 CXXFLAGS="$CXXFLAGS $LIBBT_CFLAGS"
 136 LIBS="$LIBS $LIBBT_LIBS"
 137
 138 dnl generate the config header
 139 AC_CONFIG_HEADERS([config.h])
 140
 141 dnl Output files
 142 AC_CONFIG_FILES([
 143 version.h
 144 Makefile
 145 src/Makefile
 146 doc/Makefile
 147 data/Makefile
 148 doc/bbkeys.1
 149 rpm/Makefile
 150 rpm/bbkeys.spec
 151 ])
 152 AC_OUTPUT
 153
 154 dnl Print results
 155 AC_MSG_RESULT([])
 156 AC_MSG_RESULT([ $PACKAGE version $VERSION configured successfully.])
 157 AC_MSG_RESULT([])
 158 AC_MSG_RESULT([Using '$prefix' for installation.])
 159 AC_MSG_RESULT([Using '$CXX' for C++ compiler.])
 160 AC_MSG_RESULT([Building with '$CXXFLAGS' for C++ compiler flags.])
 161 AC_MSG_RESULT([Building with '$LDFLAGS' for linker flags.])
 162 AC_MSG_RESULT([Building with '$LIBS' libraries.])
 163 AC_MSG_RESULT([])