configure.in

   1 AC_INIT
   2 AM_INIT_AUTOMAKE(barvinok, 0.28)
   3 AC_PROG_CC
   4 gl_EARLY
   5
   6 AC_PROG_CXX
   7 AM_PROG_LEX
   8 AC_PROG_YACC
   9 AC_SUBST(versioninfo)
  10 versioninfo=17:1:0
  11
  12 AC_CANONICAL_HOST
  13 AC_LIBTOOL_WIN32_DLL
  14 AC_SUBST(BV_LDFLAGS)
  15 case $host in
  16         *-*-cygwin* | *-*-mingw* | *-*-pw32* | *-*-os2*)
  17         if test "$enable_shared" = yes; then
  18                 BV_LDFLAGS="-no-undefined"
  19         fi
  20         ;;
  21 esac
  22
  23 AC_PROG_LIBTOOL
  24
  25 gl_MODULES(argp progname)
  26 gl_INIT
  27
  28 PKG_PROG_PKG_CONFIG
  29
  30 AC_CHECK_HEADERS(getopt.h)
  31 AC_CHECK_HEADERS(sys/times.h)
  32
  33 AC_MSG_CHECKING(whether to build shared libbarvinok)
  34 AC_ARG_ENABLE(shared_barvinok,
  35         AS_HELP_STRING([--enable-shared-barvinok],
  36                        [build shared barvinok library]),
  37         [bv_cv_shared_barvinok=$enableval], [bv_cv_shared_barvinok="no"])
  38 AC_MSG_RESULT($bv_cv_shared_barvinok)
  39 if test "x$bv_cv_shared_barvinok" != "xyes" ; then
  40         BV_LDFLAGS="$BV_LDFLAGS -static"
  41 fi
  42
  43 AC_CXX_GNUCXX_HASHMAP
  44
  45 AC_ARG_WITH(default-prefix,
  46         AS_HELP_STRING([--with-default-prefix=DIR],
  47             [Default installation prefix of optional packages]))
  48 if test "${with_default_prefix+set}" = set; then
  49         if test "${with_ginac_prefix+set}" != set -a \
  50            -f "$with_default_prefix/lib/pkgconfig/ginac.pc"; then
  51                 with_ginac_prefix=$with_default_prefix
  52         fi
  53         if test "${with_libgmp+set}" != set -a \
  54            -f "$with_default_prefix/include/gmp.h"; then
  55                 with_libgmp=$with_default_prefix
  56         fi
  57         if test "${with_ntl+set}" != set -a \
  58            -f "$with_default_prefix/include/NTL/ZZ.h"; then
  59                 with_ntl=$with_default_prefix
  60         fi
  61         if test "${with_cddlib+set}" != set -a \
  62            -f "$with_default_prefix/include/cddmp.h"; then
  63                 with_cddlib=$with_default_prefix
  64         fi
  65         if test "${with_glpk+set}" != set -a \
  66            -f "$with_default_prefix/include/glpk.h"; then
  67                 with_glpk=$with_default_prefix
  68         fi
  69         if test "${with_topcom+set}" != set -a \
  70            -f "$with_default_prefix/bin/points2triangs"; then
  71                 with_topcom=$with_default_prefix
  72         fi
  73 fi
  74
  75 dnl Check for GMP library
  76 AC_MSG_CHECKING(whether to use GMP)
  77 AC_ARG_WITH(libgmp,
  78         [  --with-libgmp           DIR Location of the GMP Distribution],
  79         gmp_package=$withval, gmp_package=yes)
  80 if test "x$gmp_package" = "xno"; then
  81         AC_MSG_RESULT(no)
  82         AC_MSG_ERROR(Need gmp)
  83 else
  84         AC_MSG_RESULT(yes)
  85         if test "x$gmp_package" = "xyes"; then
  86                 bv_configure_args="$bv_configure_args --with-libgmp --with-gmp"
  87         else
  88             bv_configure_args="$bv_configure_args --with-libgmp=$gmp_package"
  89             bv_configure_args="$bv_configure_args --with-gmp=$gmp_package"
  90             GMP_DIR=$gmp_package
  91             if test ! -d "$GMP_DIR"; then
  92                 AC_ERROR(Directory given for GMP Distribution is not a directory)
  93             fi
  94             CPPFLAGS="-I$GMP_DIR/include $CPPFLAGS"
  95             LDFLAGS="-L$GMP_DIR/lib $LDFLAGS"
  96         fi
  97         poly_cv_gmpfatal="no"
  98         AC_CHECK_HEADER(gmp.h,
  99                 [AC_CHECK_LIB(gmp,main,
 100                     [],
 101                     [poly_cv_gmpfatal="yes"])],
 102                 [poly_cv_gmpfatal="yes"])
 103         if test "$poly_cv_gmpfatal" = "yes"; then
 104                 AC_MSG_ERROR([GMP not found])
 105         fi
 106 fi
 107 AC_CHECK_DECL(mpz_divisible_p,[],[AC_LIBOBJ(mpz_divisible_p)],[#include <gmp.h>])
 108
 109 # BV_SUBMODULE(SUBMODULE)
 110 AC_DEFUN([BV_SUBMODULE],[
 111         AC_ARG_WITH($1,
 112                 [AS_HELP_STRING([--with-$1=bundled|system],
 113                                 [Which $1 to use])])
 114         AC_ARG_WITH($1_prefix,
 115                 [AS_HELP_STRING([--with-$1-prefix=DIR],
 116                                 [Location of system $1])])
 117         if test "x$with_$1_prefix" != "x"; then
 118                 if test "x$with_$1" != "x" -a "x$with_$1" != "xsystem"; then
 119                         AC_MSG_ERROR([Setting $with_$1_prefix implies use of system $1])
 120                 fi
 121                 with_$1="system"
 122         fi
 123         case "$with_$1" in
 124         no)
 125                 if test "$2" = "required"; then
 126                         AC_MSG_ERROR(Need $1)
 127                 fi
 128                 ;;
 129         bundled|system)
 130                 ;;
 131         *)
 132                 if test -d $srcdir/.git -a \
 133                         -d $srcdir/$1 -a \
 134                         ! -d $srcdir/$1/.git; then
 135                         AC_MSG_WARN(
 136 [git repo detected, but submodule $1 not initialized])
 137                         AC_MSG_WARN([You may want to run])
 138                         AC_MSG_WARN([   git submodule init])
 139                         AC_MSG_WARN([   git submodule update])
 140                         AC_MSG_WARN([   sh autogen.sh])
 141                 fi
 142                 if test -f $srcdir/$1/configure; then
 143                         with_$1="bundled"
 144                 elif test "$2" = "required"; then
 145                         with_$1="system"
 146                 else
 147                         with_$1="no"
 148                 fi
 149                 ;;
 150         esac
 151 ])
 152
 153 BV_SUBMODULE(polylib,required)
 154 AC_MSG_CHECKING([which PolyLib to use])
 155 AC_MSG_RESULT($with_polylib)
 156
 157 AC_SUBST(POLYLIB_CPPFLAGS)
 158 AC_SUBST(POLYLIB_LDFLAGS)
 159 AC_SUBST(POLYLIB_LIBS)
 160 if test "$with_polylib" = "bundled"; then
 161         bv_configure_args="$bv_configure_args --with-polylib-builddir=../polylib"
 162         POLYLIB_CPPFLAGS="-I\$(top_builddir)/polylib/include -I\$(top_srcdir)/polylib/include"
 163 else
 164         POLYLIB_LIBS="-lpolylibgmp"
 165         if test "x$with_polylib_prefix" != "x"; then
 166                 POLYLIB_CPPFLAGS="-I$with_polylib_prefix/include"
 167                 POLYLIB_LDFLAGS="-L$with_polylib_prefix/lib"
 168         fi
 169         SAVE_CPPFLAGS="$CPPFLAGS"
 170         CPPFLAGS="$POLYLIB_CPPFLAGS $CPPFLAGS"
 171         AC_CHECK_HEADERS([polylib/polylibgmp.h], [], [
 172                 AC_MSG_ERROR(Need PolyLib)
 173         ])
 174         CPPFLAGS="$SAVE_CPPFLAGS"
 175 fi
 176
 177 AM_CONDITIONAL(BUNDLED_POLYLIB, test $with_polylib = bundled)
 178
 179 BV_SUBMODULE(piplib,required)
 180 AC_MSG_CHECKING([which piplib to use])
 181 AC_MSG_RESULT($with_piplib)
 182
 183 AC_SUBST(PIPLIB_CPPFLAGS)
 184 AC_SUBST(PIPLIB_LDFLAGS)
 185 AC_SUBST(PIPLIB_LIBS)
 186 if test "$with_piplib" = "bundled"; then
 187         bv_configure_args="$bv_configure_args --with-piplib-builddir=../piplib"
 188         bv_configure_args="$bv_configure_args --enable-mp-version"
 189         PIPLIB_CPPFLAGS="-I$srcdir/piplib/include"
 190 else
 191         PIPLIB_LIBS="-lpiplibMP"
 192         if test "x$with_piplib_prefix" != "x"; then
 193                 PIPLIB_CPPFLAGS="-I$with_piplib_prefix/include"
 194                 PIPLIB_LDFLAGS="-L$with_piplib_prefix/lib"
 195         fi
 196         SAVE_CPPFLAGS="$CPPFLAGS"
 197         SAVE_LDFLAGS="$LDFLAGS"
 198         CPPFLAGS="$PIPLIB_CPPFLAGS $CPPFLAGS"
 199         LDFLAGS="$PIPLIB_LDFLAGS $LDFLAGS"
 200         AC_CHECK_LIB(piplibMP, pip_solve,[
 201             AC_CHECK_MEMBER(PipOptions.Urs_parms, [], [
 202                 AC_MSG_ERROR([Piplib too old; please install version 1.3.6 or newer])
 203             ],[#include <stdio.h>
 204                #include <piplib/piplibMP.h>])
 205         ],[
 206             AC_MSG_ERROR([Piplib not found])
 207         ])
 208         CPPFLAGS="$SAVE_CPPFLAGS"
 209         LDFLAGS="$SAVE_LDFLAGS"
 210 fi
 211 AM_CONDITIONAL(BUNDLED_PIPLIB, test $with_piplib = bundled)
 212
 213 AC_MSG_CHECKING(if the fractional representation should be used)
 214 AC_ARG_ENABLE(fractional, [AS_HELP_STRING([--disable-fractional],
 215                                           [Don't use fractional representation])],
 216             [bv_cv_fractional=$enableval], [bv_cv_fractional="yes"])
 217 AC_ARG_ENABLE(modulo, [AS_HELP_STRING([--disable-modulo],
 218                                       [Don't use fractional representation])],
 219             [bv_cv_modulo=$enableval], [bv_cv_modulo="$bv_cv_fractional"])
 220 AC_MSG_RESULT($bv_cv_modulo)
 221 if test "x$bv_cv_modulo" != "xno" ; then
 222         AC_DEFINE(USE_MODULO,[], [Use fractional representation])
 223 fi
 224
 225 AC_MSG_CHECKING(whether to use incremental algorithm)
 226 AC_ARG_ENABLE(incremental,
 227         [AS_HELP_STRING([--enable-incremental@<:@=bf|df@:>@],
 228                         [Enable incremental algorithm [bf]])],
 229         [bv_cv_incremental=$enableval], [bv_cv_incremental="no"])
 230 AC_MSG_RESULT($bv_cv_incremental)
 231 case $bv_cv_incremental in
 232         yes | bf)
 233                 AC_DEFINE(USE_INCREMENTAL_BF,[],
 234                           [Use breadth-first incremental algorithm])
 235         ;;
 236         df)
 237                 AC_DEFINE(USE_INCREMENTAL_DF,[],
 238                           [Use depth-first incremental algorithm])
 239         ;;
 240 esac
 241
 242 AC_ARG_WITH(ntl,
 243             [  --with-ntl=DIR          DIR Location of NTL],
 244             [ echo "Package ntl : $withval" && ntl_package=$withval],
 245             [ ntl_package=yes ])
 246
 247 if test "$ntl_package" = "no"; then
 248     AC_MSG_ERROR(Need ntl)
 249 fi
 250
 251 AC_SUBST(NTL_CPPFLAGS)
 252 AC_SUBST(NTL_LDFLAGS)
 253 if test "$ntl_package" != "yes"; then
 254     NTL_CPPFLAGS="-I$ntl_package/include"
 255     NTL_LDFLAGS="-L$ntl_package/lib"
 256 fi
 257
 258 SAVE_CPPFLAGS="$CPPFLAGS"
 259 SAVE_LDFLAGS="$LDFLAGS"
 260 CPPFLAGS="$NTL_CPPFLAGS $CPPFLAGS"
 261 LDFLAGS="$NTL_LDFLAGS $LDFLAGS"
 262 AC_EGREP_CPP(yes, [
 263     #include <NTL/ZZ.h>
 264     #ifdef NTL_GMP_LIP
 265     yes
 266     #endif
 267     ],:,AC_MSG_ERROR(ntl not compiled with gmp support))
 268
 269 AC_CHECK_LIB(ntl, main,[],[
 270     AC_MSG_ERROR(Need ntl)
 271 ])
 272 CPPFLAGS="$SAVE_CPPFLAGS"
 273 LDFLAGS="$SAVE_LDFLAGS"
 274
 275 AC_SUBST(bv_cone_hilbert_basis)
 276 AC_MSG_CHECKING(whether to compile zsolve)
 277 AC_ARG_WITH(bernstein,
 278             [AS_HELP_STRING([--without-zsolve],[do not compile zsolve])],
 279             [ with_zsolve=$withval],  [ with_zsolve=yes ])
 280 AC_MSG_RESULT($with_zsolve)
 281
 282 use_zsolve=false
 283 if test "$with_zsolve" != "no"; then
 284         if test "$GCC" = "yes"; then
 285                 $CC --version |
 286                 sed -e 's/.* \(@<:@0-9@:>@@<:@0-9@:>@*\)\.\(@<:@0-9@:>@@<:@0-9@:>@*\).*/\1 \2/' |
 287                 (read major minor
 288                         if test $major -gt 3; then
 289                                 exit 0
 290                         fi
 291                         if test $major -eq 3 -a $minor -ge 4; then
 292                                 exit 0
 293                         fi
 294                         exit 1
 295                 ) && use_zsolve=true
 296         fi
 297         if test "$use_zsolve" = false; then
 298                 AC_MSG_WARN(gcc 3.4 required to compile zsolve)
 299         else
 300                 AC_DEFINE(USE_ZSOLVE,[],[use zsolve])
 301                 bv_cone_hilbert_basis="cone_hilbert_basis\$(EXEEXT)"
 302         fi
 303 fi
 304 AM_CONDITIONAL(USE_ZSOLVE, test x$use_zsolve = xtrue)
 305
 306 AC_MSG_CHECKING(whether to compile bernstein)
 307 AC_ARG_WITH(bernstein,
 308             [AS_HELP_STRING([--without-bernstein],[do not compile bernstein])],
 309             [ with_bernstein=$withval],  [ with_bernstein=yes ])
 310 AC_MSG_RESULT($with_bernstein)
 311
 312 AC_ARG_WITH(ginac_prefix,
 313         [AS_HELP_STRING([--with-ginac-prefix=DIR],[Installation prefix of GiNaC])])
 314 if test "x$with_ginac_prefix" != "x"; then
 315         export PKG_CONFIG_PATH=$with_ginac_prefix/lib/pkgconfig:$PKG_CONFIG_PATH
 316 fi
 317
 318 AC_SUBST(bv_barvinok_bound)
 319 have_ginac=false
 320 if test "$with_bernstein" != "no"; then
 321         PKG_CHECK_EXISTS([ginac], [
 322                 PKG_CHECK_MODULES(ginac, ginac)
 323                 have_ginac=true
 324                 AC_DEFINE(HAVE_GINAC,[],[use GiNaC])
 325                 EXTRA_PACKAGE_LIBS="-lbernstein $EXTRA_PACKAGE_LIBS"
 326                 bv_barvinok_bound="barvinok_bound\$(EXEEXT) test_bound\$(EXEEXT)"
 327         ])
 328 fi
 329 AM_CONDITIONAL(HAVE_GINAC, test x$have_ginac = xtrue)
 330
 331 BV_SUBMODULE(omega,optional)
 332 AC_MSG_CHECKING([which omega to use])
 333 AC_MSG_RESULT($with_omega)
 334
 335 AC_SUBST(OMEGA_CPPFLAGS)
 336 AC_SUBST(OMEGA_LDFLAGS)
 337 AC_SUBST(OMEGA_LIBS)
 338 AC_SUBST(OMEGA_CODEGEN_LIBS)
 339 AC_SUBST(bv_omega_programs)
 340 have_omega=false
 341 have_codegen=false
 342 case "$with_omega" in
 343 bundled)
 344         have_omega=true
 345         have_codegen=true
 346         OMEGA_CPPFLAGS="-I\$(top_srcdir)/omega/omega_lib/include"
 347         OMEGA_CPPFLAGS="$OMEGA_CPPFLAGS -I\$(top_srcdir)/omega/basic/include"
 348         OMEGA_CPPFLAGS="$OMEGA_CPPFLAGS -I\$(top_srcdir)/omega/code_gen/include"
 349         OMEGA_CPPFLAGS="$OMEGA_CPPFLAGS -I\$(top_srcdir)/omega/omega_calc/include"
 350         ;;
 351 system)
 352     if test "x$omega_package" != "xyes"; then
 353         OMEGA_CPPFLAGS="-I$omega_package/include/omega"
 354         OMEGA_LDFLAGS="-L$omega_package/lib"
 355     else
 356         for i in /usr/include /usr/local/include; do
 357             if test -f $i/omega/omega.h; then
 358                 OMEGA_CPPFLAGS="-I$i/omega"
 359             fi
 360         done
 361     fi
 362
 363     AC_LANG_PUSH(C++)
 364     SAVE_CPPFLAGS="$CPPFLAGS"
 365     SAVE_LDFLAGS="$LDFLAGS"
 366     CPPFLAGS="$OMEGA_CPPFLAGS $CPPFLAGS"
 367     LDFLAGS="$OMEGA_LDFLAGS $LDFLAGS"
 368     AC_CHECK_HEADERS([omega.h],[
 369         OMEGA_LIBS="-lomega"
 370         AC_CHECK_LIB(code_gen,main,[
 371                 OMEGA_CODEGEN_LIBS="-lcode_gen -lomega"
 372                 have_codegen=true
 373         ])
 374         have_omega=true
 375     ],[AC_MSG_WARN(Omega not found)])
 376     CPPFLAGS="$SAVE_CPPFLAGS"
 377     LDFLAGS="$SAVE_LDFLAGS"
 378     AC_LANG_POP
 379     ;;
 380 esac
 381 if test "$have_omega" = true; then
 382         AC_DEFINE(HAVE_OMEGA,[],[use omega])
 383 fi
 384 if test "$have_codegen" = true -a x$have_ginac = xtrue; then
 385         bv_omega_programs="occ $bv_omega_programs"
 386 fi
 387 AM_CONDITIONAL(HAVE_OMEGA, test x$have_omega = xtrue)
 388 AM_CONDITIONAL(BUNDLED_OMEGA, test $with_omega = bundled)
 389
 390 use_parker=false
 391 AC_MSG_CHECKING(whether to compile parker)
 392 AC_ARG_WITH(parker,
 393             [AS_HELP_STRING([--without-zsolve],[do not compile zsolve])],
 394             [ with_parker=$withval],  [ with_parker=yes ])
 395 AC_MSG_RESULT($with_parker)
 396
 397 if test "$with_parker" != "no"; then
 398         AC_MSG_CHECKING(for mona)
 399         AC_ARG_WITH(mona,
 400                 [AS_HELP_STRING([--with-mona=DIR],[mona *source* directory])],
 401                                 [], [AC_MSG_RESULT(not specified)])
 402
 403         if test "x$with_mona" != "x"; then
 404                 AC_SUBST(MONAPATH)
 405                 MONAPATH=$with_mona
 406                 AC_MSG_RESULT($MONAPATH)
 407                 use_parker=true
 408                 AC_DEFINE(USE_PARKER,[],[use parker])
 409         fi
 410
 411         if test "x$with_mona" = "x"; then
 412                 AC_MSG_WARN(mona source directory required to compile parker)
 413                 AC_MSG_WARN(http://www.brics.dk/mona/download)
 414         fi
 415 fi
 416 AM_CONDITIONAL(USE_PARKER, test x$use_parker = xtrue)
 417
 418 AC_MSG_CHECKING(whether to use cddlib)
 419 AC_ARG_WITH(cddlib, [AS_HELP_STRING([--with-cddlib=DIR],[DIR Location of cddlib])],
 420             [ cddlib_package=$withval],  [ cddlib_package=yes ])
 421 AC_MSG_RESULT($cddlib_package)
 422
 423 have_cddlib=false
 424 if test "$cddlib_package" != "no"; then
 425     if test "x$cddlib_package" != "xyes"; then
 426         CPPFLAGS="-I$cddlib_package/include $CPPFLAGS"
 427         LDFLAGS="-L$cddlib_package/lib $LDFLAGS"
 428     fi
 429     AC_TRY_LINK([
 430 #define GMPRATIONAL
 431 #include <setoper.h>
 432 #include <cddmp.h>
 433 ], [
 434     mytype a;
 435     dd_init(a); ], [
 436         have_cddlib=true
 437         AC_CHECK_LIB(cddgmp, main,[
 438                 SAVE_LIBS="$LIBS"
 439                 LIBS="-lcddgmp $LIBS"
 440                 AC_DEFINE_UNQUOTED([SRCDIR], ["$srcdir"], [srcdir])
 441                 AC_LANG_PUSH(C++)
 442                 AC_RUN_IFELSE(AC_LANG_PROGRAM([[#define GMPRATIONAL
 443 #include <setoper.h>
 444 #include <cdd.h>]],
 445                 [[
 446         const char *filename = SRCDIR"/cdd94e-test";
 447         FILE *f;
 448         dd_MatrixPtr M;
 449         dd_LPType *lp;
 450         dd_ErrorType err = dd_NoError;
 451
 452         dd_set_global_constants();
 453
 454         f = fopen(filename, "r");
 455         M = dd_PolyFile2Matrix(f, &err);
 456         lp = dd_Matrix2LP(M, &err);
 457         dd_LPSolve(lp, dd_DualSimplex, &err);
 458         return lp->LPS == dd_Inconsistent;
 459                 ]]),[
 460                         AC_DEFINE(HAVE_LIBCDDGMP, [], [Define to 1 if you have the `cddgmp' library (-lcddgmp).])
 461                 ],[
 462                         AC_MSG_WARN(please upgrade cddlib to 0.94e or later)
 463                         LIBS="$SAVE_LIBS"
 464                         have_cddlib=false
 465                 ])
 466                 AC_LANG_POP
 467         ],[have_cddlib=false])
 468     ])
 469 fi
 470 AM_CONDITIONAL(HAVE_CDDLIB, test x$have_cddlib = xtrue)
 471
 472
 473
 474 AC_MSG_CHECKING(whether to use GLPK)
 475 AC_ARG_WITH(glpk, [AS_HELP_STRING([--with-glpk=DIR],[DIR Location of GLPK])],
 476             [ glpk_package=$withval],  [ glpk_package=yes ])
 477 AC_MSG_RESULT($glpk_package)
 478
 479 have_glpk=false
 480 if test "$glpk_package" != "no"; then
 481     if test "x$glpk_package" != "xyes"; then
 482         CPPFLAGS="-I$glpk_package/include $CPPFLAGS"
 483         LDFLAGS="-L$glpk_package/lib $LDFLAGS"
 484     fi
 485     AC_CHECK_HEADERS([glpk.h],[
 486         have_glpk=true
 487         AC_CHECK_LIB(glpk, main,[],[have_glpk=false])
 488     ])
 489 fi
 490 AM_CONDITIONAL(HAVE_GLPK, test x$have_glpk = xtrue)
 491
 492 AC_MSG_CHECKING(location of TOPCOM)
 493 AC_ARG_WITH(topcom, [AS_HELP_STRING([--with-topcom=DIR],[Location of TOPCOM])],
 494             [topcom_package=$withval], [topcom_package=unspecified])
 495 AC_MSG_RESULT($topcom_package)
 496 have_topcom=false
 497 if test "$topcom_package" != no; then
 498         topcom_path="$PATH"
 499         if test "$topcom_package" != unspecified; then
 500                 topcom_path="$topcom_package/bin"
 501         fi
 502         AC_PATH_PROG([POINTS2TRIANGS], [points2triangs], [], [$topcom_path])
 503         if test -n "$POINTS2TRIANGS"; then
 504                 have_topcom=true
 505                 AC_DEFINE_UNQUOTED(POINTS2TRIANGS_PATH, ["$POINTS2TRIANGS"],
 506                                     [Path of points2triangs])
 507         fi
 508 fi
 509 AM_CONDITIONAL(HAVE_TOPCOM, test x$have_topcom = xtrue)
 510
 511 AC_SUBST(GIT_HEAD_ID)
 512 AC_SUBST(GIT_HEAD)
 513 AC_SUBST(GIT_HEAD_VERSION)
 514 if test -f $srcdir/.git/HEAD; then
 515     GIT_HEAD="$srcdir/.git/index"
 516     GIT_REPO="$srcdir/.git"
 517     GIT_HEAD_ID=`GIT_DIR=$GIT_REPO git describe`
 518 elif test -f $srcdir/GIT_HEAD_ID; then
 519     GIT_HEAD_ID=`cat $srcdir/GIT_HEAD_ID`
 520 else
 521     mysrcdir=`(cd $srcdir; pwd)`
 522     head=`basename $mysrcdir | sed -e 's/.*-//'`
 523     head2=`echo $head | sed -e 's/[^0-9a-f]//'`
 524     head3=`echo $head2 | sed -e 's/........................................//'`
 525     base=`basename $mysrcdir | sed -e 's/-.*//'`
 526     if test "x$head3" = "x" -a "x$head" = "x$head2"; then
 527         GIT_HEAD_ID="barvinok-$VERSION-$head
 528     elif test "x$base" = "xbarvinok-$VERSION" -a "x$head" != "x"; then
 529         GIT_HEAD_ID="barvinok-$VERSION-$head
 530     else
 531         GIT_HEAD_ID="UNKNOWN"
 532     fi
 533 fi
 534 if test -z "$GIT_REPO" ; then
 535     GIT_HEAD_VERSION="$GIT_HEAD_ID"
 536 else
 537     GIT_HEAD_VERSION="\`GIT_DIR=$GIT_REPO git describe\`"
 538 fi
 539 echo '#define GIT_HEAD_ID "'$GIT_HEAD_ID'"' > version.h
 540
 541 AC_LANG_PUSH(C++)
 542 AC_TRY_COMPILE([
 543                 #include <set>
 544                 void negate();
 545         ], [negate()],
 546         suffix="normal", suffix="broken")
 547 AC_CONFIG_COMMANDS([barvinok/set.h],
 548                    [cp $srcdir/barvinok/set.h.$suffix barvinok/set.h],
 549                    [suffix="$suffix"])
 550 AC_CONFIG_COMMANDS([barvinok/NTL.h],
 551                    [cp $srcdir/barvinok/NTL.h.$suffix barvinok/NTL.h],
 552                    [suffix="$suffix"])
 553 use_fdstream=false
 554 SAVE_CPPFLAGS="$CPPFLAGS"
 555 CPPFLAGS="-I$srcdir $CPPFLAGS"
 556 AC_TRY_COMPILE([#include "fdstream.h"],[],
 557         [AC_DEFINE(USE_FDSTREAM,[],[use fdstream])
 558         use_fdstream=true])
 559 CPPFLAGS="$SAVE_CPPFLAGS"
 560 AC_LANG_POP
 561 AM_CONDITIONAL(USE_FDSTREAM, [test "$use_fdstream" = true])
 562
 563 PACKAGE_LIBS="-lbarvinok -lbarvinok-core $EXTRA_PACKAGE_LIBS -lpolylibgmp -lpiplibMP"
 564 AX_CREATE_PKGCONFIG_INFO
 565
 566 AC_CONFIG_HEADERS(config.h)
 567 AC_CONFIG_FILES(Makefile lib/Makefile zsolve/Makefile doc/Makefile)
 568 AC_CONFIG_FILES(omega_interface/Makefile)
 569 AC_CONFIG_FILES(parker/Makefile)
 570 if test $with_polylib = bundled; then
 571         AC_CONFIG_SUBDIRS(polylib)
 572 fi
 573 if test $with_piplib = bundled; then
 574         AC_CONFIG_SUBDIRS(piplib)
 575 fi
 576 if test x$have_ginac = xtrue; then
 577     AC_CONFIG_SUBDIRS(bernstein)
 578 fi
 579 if test $with_omega = bundled; then
 580         AC_CONFIG_SUBDIRS(omega)
 581 fi
 582 AC_CONFIG_COMMANDS_POST([
 583         dnl pass on arguments to subdir configures, but don't
 584         dnl add them to config.status
 585         ac_configure_args="$ac_configure_args $bv_configure_args"
 586 ])
 587 AC_OUTPUT