configure.in

   1 AC_INIT
   2 AM_INIT_AUTOMAKE(barvinok, 0.24)
   3 AC_PROG_CC
   4 gl_EARLY
   5
   6 AC_PROG_CXX
   7 AM_PROG_LEX
   8 AC_PROG_YACC
   9 AC_SUBST(versioninfo)
  10 versioninfo=14:0:1
  11
  12 AC_CANONICAL_HOST
  13 AC_LIBTOOL_WIN32_DLL
  14 AC_SUBST(BV_LDFLAGS)
  15 case $host in
  16         *-*-cygwin* | *-*-mingw* | *-*-pw32* | *-*-os2*)
  17         if test "$enable_shared" = yes; then
  18                 BV_LDFLAGS="-no-undefined"
  19         fi
  20         ;;
  21 esac
  22
  23 AC_DISABLE_SHARED
  24 AC_PROG_LIBTOOL
  25
  26 gl_MODULES(argp progname)
  27 gl_INIT
  28
  29 AC_CHECK_HEADERS(getopt.h)
  30 AC_CHECK_HEADERS(sys/times.h)
  31
  32 AC_ARG_WITH(default-prefix,
  33         AS_HELP_STRING([--with-default-prefix=DIR],
  34             [Default installation prefix of optional packages]))
  35 if test "${with_default_prefix+set}" = set; then
  36         if test "${with_ginac_prefix+set}" != set -a \
  37            "${with_ginac_exec_prefix+set}" != set -a \
  38            -f "$with_default_prefix/bin/ginac-config"; then
  39                 with_ginac_prefix=$with_default_prefix
  40         fi
  41         if test "${with_libgmp+set}" != set -a \
  42            -f "$with_default_prefix/include/gmp.h"; then
  43                 with_libgmp=$with_default_prefix
  44         fi
  45         if test "${with_polylib_prefix+set}" != set -a \
  46            -f "$with_default_prefix/include/polylib/polylibgmp.h"; then
  47                 with_polylib_prefix=$with_default_prefix
  48         fi
  49         if test "${with_piplib+set}" != set -a \
  50            -f "$with_default_prefix/include/piplib/piplibMP.h"; then
  51                 with_piplib=$with_default_prefix
  52         fi
  53         if test "${with_ntl+set}" != set -a \
  54            -f "$with_default_prefix/include/NTL/ZZ.h"; then
  55                 with_ntl=$with_default_prefix
  56         fi
  57         if test "${with_omega+set}" != set -a \
  58            -f "$with_default_prefix/include/omega/omega.h"; then
  59                 with_omega=$with_default_prefix
  60         fi
  61         if test "${with_cddlib+set}" != set -a \
  62            -f "$with_default_prefix/include/cddmp.h"; then
  63                 with_cddlib=$with_default_prefix
  64         fi
  65         if test "${with_glpk+set}" != set -a \
  66            -f "$with_default_prefix/include/glpk.h"; then
  67                 with_glpk=$with_default_prefix
  68         fi
  69         if test "${with_topcom+set}" != set -a \
  70            -f "$with_default_prefix/bin/points2triangs"; then
  71                 with_topcom=$with_default_prefix
  72         fi
  73 fi
  74
  75 dnl Check for GMP library
  76 AC_MSG_CHECKING(whether to use GMP)
  77 AC_ARG_WITH(libgmp,
  78         [  --with-libgmp           DIR Location of the GMP Distribution],
  79         gmp_package=$withval, gmp_package=yes)
  80 if test "x$gmp_package" = "xno"; then
  81         AC_MSG_RESULT(no)
  82         AC_MSG_ERROR(Need gmp)
  83 else
  84         AC_MSG_RESULT(yes)
  85         if test "x$gmp_package" = "xyes"; then
  86                 bv_configure_args="$bv_configure_args --with-libgmp --with-gmp"
  87         else
  88             bv_configure_args="$bv_configure_args --with-gmp=$gmp_package"
  89             GMP_DIR=$gmp_package
  90             if test ! -d "$GMP_DIR"; then
  91                 AC_ERROR(Directory given for GMP Distribution is not a directory)
  92             fi
  93             CPPFLAGS="-I$GMP_DIR/include $CPPFLAGS"
  94             LDFLAGS="-L$GMP_DIR/lib $LDFLAGS"
  95         fi
  96         poly_cv_gmpfatal="no"
  97         AC_CHECK_HEADER(gmp.h,
  98                 [AC_CHECK_LIB(gmp,main,
  99                     [],
 100                     [poly_cv_gmpfatal="yes"])],
 101                 [poly_cv_gmpfatal="yes"])
 102         if test "$poly_cv_gmpfatal" = "yes"; then
 103                 AC_MSG_ERROR([GMP not found])
 104         fi
 105 fi
 106 AC_CHECK_DECL(mpz_divisible_p,[],[AC_LIBOBJ(mpz_divisible_p)],[#include <gmp.h>])
 107
 108 # BV_SUBMODULE(SUBMODULE)
 109 AC_DEFUN([BV_SUBMODULE],[
 110         case "$with_$1" in
 111         no)
 112                 AC_MSG_ERROR(Need $1)
 113                 ;;
 114         bundled|system)
 115                 ;;
 116         *)
 117                 if test -d $srcdir/.git -a \
 118                         ! -d $srcdir/$1/.git; then
 119                         AC_MSG_WARN(
 120 [git repo detected, but submodule $1 not initialized])
 121                         AC_MSG_WARN([You may want to run])
 122                         AC_MSG_WARN([   git submodule init])
 123                         AC_MSG_WARN([   git submodule update])
 124                         AC_MSG_WARN([   sh autogen.sh])
 125                 fi
 126                 if test -f $srcdir/$1/configure; then
 127                         with_$1="bundled"
 128                 else
 129                         with_$1="system"
 130                 fi
 131                 ;;
 132         esac
 133 ])
 134
 135 AC_ARG_WITH(polylib,
 136         [AS_HELP_STRING([--with-polylib=bundled|system],[Which PolyLib to use])])
 137 AC_ARG_WITH(polylib_prefix,
 138         [AS_HELP_STRING([--with-polylib-prefix=DIR],[Location of system PolyLib])])
 139
 140 if test "x$with_polylib_prefix" != "x"; then
 141         with_polylib="system"
 142 fi
 143 BV_SUBMODULE(polylib)
 144 AC_MSG_CHECKING([which PolyLib to use])
 145 AC_MSG_RESULT($with_polylib)
 146
 147 AC_SUBST(POLYLIB_CPPFLAGS)
 148 AC_SUBST(POLYLIB_LDFLAGS)
 149 AC_SUBST(POLYLIB_LIBS)
 150 if test "$with_polylib" = "bundled"; then
 151         bv_configure_args="$bv_configure_args --with-polylib-builddir=../polylib"
 152         POLYLIB_CPPFLAGS="-Ipolylib/include -I$srcdir/polylib/include"
 153 else
 154         POLYLIB_LIBS="-lpolylibgmp"
 155         if test "x$with_polylib_prefix" != "x"; then
 156                 POLYLIB_CPPFLAGS="-I$with_polylib_prefix/include"
 157                 POLYLIB_LDFLAGS="-L$with_polylib_prefix/lib"
 158         fi
 159         SAVE_CPPFLAGS="$CPPFLAGS"
 160         CPPFLAGS="$POLYLIB_CPPFLAGS $CPPFLAGS"
 161         AC_CHECK_HEADERS([polylib/polylibgmp.h], [], [
 162                 AC_MSG_ERROR(Need PolyLib)
 163         ])
 164         CPPFLAGS="$SAVE_CPPFLAGS"
 165 fi
 166
 167 AM_CONDITIONAL(BUNDLED_POLYLIB, test $with_polylib = bundled)
 168
 169 AC_ARG_WITH(piplib,
 170         [AS_HELP_STRING([--with-piplib=bundled|system],[Which piplib to use])])
 171 AC_ARG_WITH(piplib_prefix,
 172         [AS_HELP_STRING([--with-piplib-prefix=DIR],[Location of system piplib])])
 173
 174 if test "x$with_piplib_prefix" != "x"; then
 175         with_piplib="system"
 176 fi
 177 BV_SUBMODULE(piplib)
 178 AC_MSG_CHECKING([which piplib to use])
 179 AC_MSG_RESULT($with_piplib)
 180
 181 AC_SUBST(PIPLIB_CPPFLAGS)
 182 AC_SUBST(PIPLIB_LDFLAGS)
 183 AC_SUBST(PIPLIB_LIBS)
 184 if test "$with_piplib" = "bundled"; then
 185         bv_configure_args="$bv_configure_args --with-piplib-builddir=../piplib"
 186         bv_configure_args="$bv_configure_args --enable-mp-version"
 187         PIPLIB_CPPFLAGS="-I$srcdir/piplib/include"
 188 else
 189         PIPLIB_LIBS="-lpiplibMP"
 190         if test "x$with_piplib_prefix" != "x"; then
 191                 PIPLIB_CPPFLAGS="-I$with_piplib_prefix/include"
 192                 PIPLIB_LDFLAGS="-L$with_piplib_prefix/lib"
 193         fi
 194         SAVE_CPPFLAGS="$CPPFLAGS"
 195         SAVE_LDFLAGS="$LDFLAGS"
 196         CPPFLAGS="$PIPLIB_CPPFLAGS $CPPFLAGS"
 197         LDFLAGS="$PIPLIB_LDFLAGS $LDFLAGS"
 198         AC_CHECK_LIB(piplibMP, pip_solve,[
 199             AC_CHECK_MEMBER(PipOptions.Urs_parms, [], [
 200                 AC_MSG_ERROR([Piplib too old; please install version 1.3.6 or newer])
 201             ],[#include <stdio.h>
 202                #include <piplib/piplibMP.h>])
 203         ],[
 204             AC_MSG_ERROR([Piplib not found])
 205         ])
 206         CPPFLAGS="$SAVE_CPPFLAGS"
 207         LDFLAGS="$SAVE_LDFLAGS"
 208 fi
 209 AM_CONDITIONAL(BUNDLED_PIPLIB, test $with_piplib = bundled)
 210
 211 AC_MSG_CHECKING(if the fractional representation should be used)
 212 AC_ARG_ENABLE(fractional, [AS_HELP_STRING([--disable-fractional],
 213                                           [Don't use fractional representation])],
 214             [bv_cv_fractional=$enableval], [bv_cv_fractional="yes"])
 215 AC_ARG_ENABLE(modulo, [AS_HELP_STRING([--disable-modulo],
 216                                       [Don't use fractional representation])],
 217             [bv_cv_modulo=$enableval], [bv_cv_modulo="$bv_cv_fractional"])
 218 AC_MSG_RESULT($bv_cv_modulo)
 219 if test "x$bv_cv_modulo" != "xno" ; then
 220         AC_DEFINE(USE_MODULO,[], [Use fractional representation])
 221 fi
 222
 223 AC_MSG_CHECKING(whether to use incremental algorithm)
 224 AC_ARG_ENABLE(incremental,
 225         [AS_HELP_STRING([--enable-incremental@<:@=bf|df@:>@],
 226                         [Enable incremental algorithm [bf]])],
 227         [bv_cv_incremental=$enableval], [bv_cv_incremental="no"])
 228 AC_MSG_RESULT($bv_cv_incremental)
 229 case $bv_cv_incremental in
 230         yes | bf)
 231                 AC_DEFINE(USE_INCREMENTAL_BF,[],
 232                           [Use breadth-first incremental algorithm])
 233         ;;
 234         df)
 235                 AC_DEFINE(USE_INCREMENTAL_DF,[],
 236                           [Use depth-first incremental algorithm])
 237         ;;
 238 esac
 239
 240 AC_ARG_WITH(ntl,
 241             [  --with-ntl=DIR          DIR Location of NTL],
 242             [ echo "Package ntl : $withval" && ntl_package=$withval],
 243             [ ntl_package=yes ])
 244
 245 if test "$ntl_package" = "no"; then
 246     AC_MSG_ERROR(Need ntl)
 247 fi
 248
 249 if test "$ntl_package" != "yes"; then
 250     CPPFLAGS="-I$ntl_package/include $CPPFLAGS"
 251     LDFLAGS="-L$ntl_package/lib $LDFLAGS"
 252 fi
 253
 254 AC_EGREP_CPP(yes, [
 255     #include <NTL/ZZ.h>
 256     #ifdef NTL_GMP_LIP
 257     yes
 258     #endif
 259     ],:,AC_MSG_ERROR(ntl not compiled with gmp support))
 260
 261 AC_CHECK_LIB(ntl, main,[],[
 262     AC_MSG_ERROR(Need ntl)
 263 ])
 264
 265 AC_MSG_CHECKING(whether to compile bernstein)
 266 AC_ARG_WITH(bernstein,
 267             [AS_HELP_STRING([--without-bernstein],[do not compile bernstein])],
 268             [ with_bernstein=$withval],  [ with_bernstein=yes ])
 269 AC_MSG_RESULT($with_bernstein)
 270
 271 AC_SUBST(bv_barvinok_maximize)
 272 have_ginac=false
 273 if test "$with_bernstein" != "no"; then
 274         AC_LANG_PUSH(C++)
 275         AM_PATH_GINAC(1.3.3, [
 276                 have_ginac=true
 277                 AC_DEFINE(HAVE_GINAC,[],[use GiNaC])
 278                 EXTRA_PACKAGE_LIBS="-lbernstein $EXTRA_PACKAGE_LIBS"
 279                 bv_barvinok_maximize="barvinok_maximize\$(EXEEXT)"
 280         ])
 281         AC_LANG_POP
 282 fi
 283 AM_CONDITIONAL(HAVE_GINAC, test x$have_ginac = xtrue)
 284
 285 AC_MSG_CHECKING(whether to use Omega)
 286 AC_ARG_WITH(omega, [AS_HELP_STRING([--with-omega=DIR],[DIR Location of Omega])],
 287             [ omega_package=$withval],  [ omega_package=yes ])
 288 AC_MSG_RESULT($omega_package)
 289
 290 AC_SUBST(OMEGA_CPPFLAGS)
 291 AC_SUBST(OMEGA_LDFLAGS)
 292 AC_SUBST(OMEGA_LIBS)
 293 AC_SUBST(bv_omega_programs)
 294 have_omega=false
 295 if test "$omega_package" != "no"; then
 296     if test "x$omega_package" != "xyes"; then
 297         OMEGA_CPPFLAGS="-I$omega_package/include/omega"
 298         OMEGA_LDFLAGS="-L$omega_package/lib"
 299     else
 300         for i in /usr/include /usr/local/include; do
 301             if test -f $i/omega/omega.h; then
 302                 OMEGA_CPPFLAGS="-I$i/omega"
 303             fi
 304         done
 305     fi
 306
 307     AC_LANG_PUSH(C++)
 308     SAVE_CPPFLAGS="$CPPFLAGS"
 309     CPPFLAGS="$OMEGA_CPPFLAGS $CPPFLAGS"
 310     AC_CHECK_HEADERS([omega.h],[
 311         if test x$have_ginac = xtrue; then
 312             bv_omega_programs="occ $bv_omega_programs"
 313         fi
 314         AC_DEFINE(HAVE_OMEGA,[],[use omega])
 315         OMEGA_LIBS="-lcode_gen -lomega"
 316         have_omega=true
 317     ],[AC_MSG_WARN(Omega not found)])
 318     CPPFLAGS="$SAVE_CPPFLAGS"
 319     AC_LANG_POP
 320 fi
 321 AM_CONDITIONAL(HAVE_OMEGA, test x$have_omega = xtrue)
 322
 323
 324 AC_MSG_CHECKING(whether to use cddlib)
 325 AC_ARG_WITH(cddlib, [AS_HELP_STRING([--with-cddlib=DIR],[DIR Location of cddlib])],
 326             [ cddlib_package=$withval],  [ cddlib_package=yes ])
 327 AC_MSG_RESULT($cddlib_package)
 328
 329 have_cddlib=false
 330 if test "$cddlib_package" != "no"; then
 331     if test "x$cddlib_package" != "xyes"; then
 332         CPPFLAGS="-I$cddlib_package/include $CPPFLAGS"
 333         LDFLAGS="-L$cddlib_package/lib $LDFLAGS"
 334     fi
 335     AC_TRY_LINK([
 336 #define GMPRATIONAL
 337 #include <setoper.h>
 338 #include <cddmp.h>
 339 ], [
 340     mytype a;
 341     dd_init(a); ], [
 342         have_cddlib=true
 343         AC_CHECK_LIB(cddgmp, main,[],[have_cddlib=false])
 344     ])
 345 fi
 346 AM_CONDITIONAL(HAVE_CDDLIB, test x$have_cddlib = xtrue)
 347
 348
 349
 350 AC_MSG_CHECKING(whether to use GLPK)
 351 AC_ARG_WITH(glpk, [AS_HELP_STRING([--with-glpk=DIR],[DIR Location of GLPK])],
 352             [ glpk_package=$withval],  [ glpk_package=yes ])
 353 AC_MSG_RESULT($glpk_package)
 354
 355 have_glpk=false
 356 if test "$glpk_package" != "no"; then
 357     if test "x$glpk_package" != "xyes"; then
 358         CPPFLAGS="-I$glpk_package/include $CPPFLAGS"
 359         LDFLAGS="-L$glpk_package/lib $LDFLAGS"
 360     fi
 361     AC_CHECK_HEADERS([glpk.h],[
 362         have_glpk=true
 363         AC_CHECK_LIB(glpk, main,[],[have_glpk=false])
 364     ])
 365 fi
 366 AM_CONDITIONAL(HAVE_GLPK, test x$have_glpk = xtrue)
 367
 368 AC_MSG_CHECKING(location of TOPCOM)
 369 AC_ARG_WITH(topcom, [AS_HELP_STRING([--with-topcom=DIR],[Location of TOPCOM])],
 370             [topcom_package=$withval], [topcom_package=unspecified])
 371 AC_MSG_RESULT($topcom_package)
 372 have_topcom=false
 373 if test "$topcom_package" != no; then
 374         topcom_path="$PATH"
 375         if test "$topcom_package" != unspecified; then
 376                 topcom_path="$topcom_package/bin"
 377         fi
 378         AC_PATH_PROG([POINTS2TRIANGS], [points2triangs], [], [$topcom_path])
 379         if test -n "$POINTS2TRIANGS"; then
 380                 have_topcom=true
 381                 AC_DEFINE_UNQUOTED(POINTS2TRIANGS_PATH, ["$POINTS2TRIANGS"],
 382                                     [Path of points2triangs])
 383         fi
 384 fi
 385 AM_CONDITIONAL(HAVE_TOPCOM, test x$have_topcom = xtrue)
 386
 387 AC_SUBST(GIT_HEAD_ID)
 388 AC_SUBST(GIT_HEAD)
 389 AC_SUBST(GIT_HEAD_VERSION)
 390 if test -f $srcdir/.git/HEAD; then
 391     GIT_HEAD="$srcdir/.git/index"
 392     GIT_REPO="$srcdir/.git"
 393     GIT_HEAD_ID=`GIT_DIR=$GIT_REPO git describe`
 394 elif test -f $srcdir/GIT_HEAD_ID; then
 395     GIT_HEAD_ID=`cat $srcdir/GIT_HEAD_ID`
 396 else
 397     mysrcdir=`(cd $srcdir; pwd)`
 398     head=`basename $mysrcdir | sed -e 's/.*-//'`
 399     head2=`echo $head | sed -e 's/[^0-9a-f]//'`
 400     head3=`echo $head2 | sed -e 's/........................................//'`
 401     base=`basename $mysrcdir | sed -e 's/-.*//'`
 402     if test "x$head3" = "x" -a "x$head" = "x$head2"; then
 403         GIT_HEAD_ID="barvinok-$VERSION-$head
 404     elif test "x$base" = "xbarvinok-$VERSION" -a "x$head" != "x"; then
 405         GIT_HEAD_ID="barvinok-$VERSION-$head
 406     else
 407         GIT_HEAD_ID="UNKNOWN"
 408     fi
 409 fi
 410 if test -z "$GIT_REPO" ; then
 411     GIT_HEAD_VERSION="$GIT_HEAD_ID"
 412 else
 413     GIT_HEAD_VERSION="\`GIT_DIR=$GIT_REPO git describe\`"
 414 fi
 415 echo '#define GIT_HEAD_ID "'$GIT_HEAD_ID'"' > version.h
 416
 417 AC_LANG_PUSH(C++)
 418 AC_TRY_COMPILE([
 419                 #include <set>
 420                 void negate();
 421         ], [negate()],
 422         suffix="normal", suffix="broken")
 423 AC_CONFIG_COMMANDS([barvinok/set.h],
 424                    [cp $srcdir/barvinok/set.h.$suffix barvinok/set.h],
 425                    [suffix="$suffix"])
 426 AC_CONFIG_COMMANDS([barvinok/NTL.h],
 427                    [cp $srcdir/barvinok/NTL.h.$suffix barvinok/NTL.h],
 428                    [suffix="$suffix"])
 429 use_fdstream=false
 430 SAVE_CPPFLAGS="$CPPFLAGS"
 431 CPPFLAGS="-I$srcdir $CPPFLAGS"
 432 AC_TRY_COMPILE([#include "fdstream.h"],[],
 433         [AC_DEFINE(USE_FDSTREAM,[],[use fdstream])
 434         use_fdstream=true])
 435 CPPFLAGS="$SAVE_CPPFLAGS"
 436 AC_LANG_POP
 437 AM_CONDITIONAL(USE_FDSTREAM, [test "$use_fdstream" = true])
 438
 439 PACKAGE_LIBS="-lbarvinok $EXTRA_PACKAGE_LIBS -lpolylibgmp -lpiplibMP"
 440 AX_CREATE_PKGCONFIG_INFO
 441
 442 AC_CONFIG_HEADERS(config.h)
 443 AC_CONFIG_FILES(Makefile lib/Makefile doc/Makefile omega/Makefile)
 444 if test $with_polylib = bundled; then
 445         AC_CONFIG_SUBDIRS(polylib)
 446 fi
 447 if test $with_piplib = bundled; then
 448         AC_CONFIG_SUBDIRS(piplib)
 449 fi
 450 if test x$have_ginac = xtrue; then
 451     AC_CONFIG_SUBDIRS(bernstein)
 452 fi
 453 AC_CONFIG_COMMANDS_POST([
 454         dnl pass on arguments to subdir configures, but don't
 455         dnl add them to config.status
 456         ac_configure_args="$ac_configure_args $bv_configure_args"
 457 ])
 458 AC_OUTPUT