configure.in

   1 AC_INIT
   2 AC_CONFIG_MACRO_DIR([m4])
   3 AM_INIT_AUTOMAKE(barvinok, 0.30)
   4 AC_PROG_CC
   5 gl_EARLY
   6
   7 AC_PROG_CXX
   8 AM_PROG_LEX
   9 AC_PROG_YACC
  10 AC_SUBST(versioninfo)
  11 versioninfo=19:0:2
  12
  13 AC_CANONICAL_HOST
  14 AC_LIBTOOL_WIN32_DLL
  15 AC_SUBST(BV_LDFLAGS)
  16 case $host in
  17         *-*-cygwin* | *-*-mingw* | *-*-pw32* | *-*-os2*)
  18         if test "$enable_shared" = yes; then
  19                 BV_LDFLAGS="-no-undefined"
  20         fi
  21         ;;
  22 esac
  23
  24 AC_PROG_LIBTOOL
  25
  26 PKG_PROG_PKG_CONFIG
  27
  28 AC_CHECK_HEADERS(getopt.h)
  29 AC_CHECK_HEADERS(sys/times.h)
  30
  31 AC_MSG_CHECKING(whether to build shared libbarvinok)
  32 AC_ARG_ENABLE(shared_barvinok,
  33         AS_HELP_STRING([--enable-shared-barvinok],
  34                        [build shared barvinok library]),
  35         [bv_cv_shared_barvinok=$enableval], [bv_cv_shared_barvinok="no"])
  36 AC_MSG_RESULT($bv_cv_shared_barvinok)
  37 if test "x$bv_cv_shared_barvinok" != "xyes" ; then
  38         BV_LDFLAGS="$BV_LDFLAGS -static"
  39 fi
  40
  41 AC_CXX_GNUCXX_HASHMAP
  42
  43 AC_ARG_WITH(default-prefix,
  44         AS_HELP_STRING([--with-default-prefix=DIR],
  45             [Default installation prefix of optional packages]))
  46 if test "${with_default_prefix+set}" = set; then
  47         if test "${with_libgmp+set}" != set -a \
  48            -f "$with_default_prefix/include/gmp.h"; then
  49                 with_libgmp=$with_default_prefix
  50         fi
  51         if test "${with_ntl+set}" != set -a \
  52            -f "$with_default_prefix/include/NTL/ZZ.h"; then
  53                 with_ntl=$with_default_prefix
  54         fi
  55         if test "${with_cddlib+set}" != set -a \
  56            -f "$with_default_prefix/include/cddmp.h"; then
  57                 with_cddlib=$with_default_prefix
  58         fi
  59         if test "${with_glpk+set}" != set -a \
  60            -f "$with_default_prefix/include/glpk.h"; then
  61                 with_glpk=$with_default_prefix
  62         fi
  63         if test "${with_topcom+set}" != set -a \
  64            -f "$with_default_prefix/bin/points2triangs"; then
  65                 with_topcom=$with_default_prefix
  66         fi
  67 fi
  68
  69 dnl Check for GMP library
  70 AC_MSG_CHECKING(whether to use GMP)
  71 AC_ARG_WITH(libgmp,
  72         [  --with-libgmp           DIR Location of the GMP Distribution],
  73         gmp_package=$withval, gmp_package=yes)
  74 if test "x$gmp_package" = "xno"; then
  75         AC_MSG_RESULT(no)
  76         AC_MSG_ERROR(Need gmp)
  77 else
  78         AC_MSG_RESULT(yes)
  79         if test "x$gmp_package" = "xyes"; then
  80                 bv_configure_args="$bv_configure_args --with-libgmp --with-gmp"
  81         else
  82             bv_configure_args="$bv_configure_args --with-libgmp=$gmp_package"
  83             bv_configure_args="$bv_configure_args --with-gmp-prefix=$gmp_package"
  84             GMP_DIR=$gmp_package
  85             if test ! -d "$GMP_DIR"; then
  86                 AC_ERROR(Directory given for GMP Distribution is not a directory)
  87             fi
  88             CPPFLAGS="-I$GMP_DIR/include $CPPFLAGS"
  89             LDFLAGS="-L$GMP_DIR/lib $LDFLAGS"
  90         fi
  91         poly_cv_gmpfatal="no"
  92         AC_CHECK_HEADER(gmp.h,
  93                 [AC_CHECK_LIB(gmp,main,
  94                     [],
  95                     [poly_cv_gmpfatal="yes"])],
  96                 [poly_cv_gmpfatal="yes"])
  97         if test "$poly_cv_gmpfatal" = "yes"; then
  98                 AC_MSG_ERROR([GMP not found])
  99         fi
 100 fi
 101 AC_CHECK_DECL(mpz_divisible_p,[],[AC_LIBOBJ(mpz_divisible_p)],[#include <gmp.h>])
 102
 103 AX_SUBMODULE(polylib,build|bundled|system,bundled)
 104
 105 AC_SUBST(POLYLIB_CPPFLAGS)
 106 AC_SUBST(POLYLIB_LDFLAGS)
 107 AC_SUBST(POLYLIB_LIBS)
 108 case "$with_polylib" in
 109 bundled)
 110         bv_configure_args="$bv_configure_args --with-polylib-builddir=../polylib"
 111         POLYLIB_CPPFLAGS="-I\$(top_builddir)/polylib/include -I\$(top_srcdir)/polylib/include"
 112         ;;
 113 build)
 114         with_polylib_builddir=`echo @abs_builddir@ | $with_polylib_builddir/config.status --file=-`
 115         POLYLIB_CPPFLAGS="-I$polylib_srcdir/include -I$with_polylib_builddir/include"
 116         POLYLIB_LIBS="$with_polylib_builddir/libpolylibgmp.la"
 117         ;;
 118 system)
 119         POLYLIB_LIBS="-lpolylibgmp"
 120         if test "x$with_polylib_prefix" != "x"; then
 121                 POLYLIB_CPPFLAGS="-I$with_polylib_prefix/include"
 122                 POLYLIB_LDFLAGS="-L$with_polylib_prefix/lib"
 123         fi
 124         SAVE_CPPFLAGS="$CPPFLAGS"
 125         CPPFLAGS="$POLYLIB_CPPFLAGS $CPPFLAGS"
 126         AC_CHECK_HEADERS([polylib/polylibgmp.h], [], [
 127                 AC_MSG_ERROR(Need PolyLib)
 128         ])
 129         CPPFLAGS="$SAVE_CPPFLAGS"
 130 esac
 131
 132 AM_CONDITIONAL(BUNDLED_POLYLIB, test $with_polylib = bundled)
 133
 134 AX_SUBMODULE(piplib,bundled|system,bundled)
 135
 136 AC_SUBST(PIPLIB_CPPFLAGS)
 137 AC_SUBST(PIPLIB_LDFLAGS)
 138 AC_SUBST(PIPLIB_LIBS)
 139 if test "$with_piplib" = "bundled"; then
 140         bv_configure_args="$bv_configure_args --with-piplib-builddir=../piplib"
 141         bv_configure_args="$bv_configure_args --with-bits=gmp"
 142         PIPLIB_CPPFLAGS="-I$srcdir/piplib/include"
 143 else
 144         PIPLIB_LIBS="-lpiplibMP"
 145         if test "x$with_piplib_prefix" != "x"; then
 146                 PIPLIB_CPPFLAGS="-I$with_piplib_prefix/include"
 147                 PIPLIB_LDFLAGS="-L$with_piplib_prefix/lib"
 148         fi
 149         SAVE_CPPFLAGS="$CPPFLAGS"
 150         SAVE_LDFLAGS="$LDFLAGS"
 151         CPPFLAGS="$PIPLIB_CPPFLAGS $CPPFLAGS"
 152         LDFLAGS="$PIPLIB_LDFLAGS $LDFLAGS"
 153         AC_CHECK_LIB(piplibMP, pip_solve,[
 154             AC_CHECK_MEMBER(PipOptions.Urs_parms, [], [
 155                 AC_MSG_ERROR([Piplib too old; please install version 1.3.6 or newer])
 156             ],[#include <stdio.h>
 157                #include <piplib/piplibMP.h>])
 158         ],[
 159             AC_MSG_ERROR([Piplib not found])
 160         ])
 161         CPPFLAGS="$SAVE_CPPFLAGS"
 162         LDFLAGS="$SAVE_LDFLAGS"
 163 fi
 164 AM_CONDITIONAL(BUNDLED_PIPLIB, test $with_piplib = bundled)
 165
 166 AX_SUBMODULE(isl,build|bundled|system,bundled)
 167
 168 AC_SUBST(ISL_CFLAGS)
 169 AC_SUBST(ISL_LIBS)
 170 case "$with_isl" in
 171 bundled)
 172         ISL_CFLAGS="-I\$(top_srcdir)/isl/include -I\$(top_builddir)/isl/include"
 173         bv_configure_args="$bv_configure_args --with-isl-builddir=../isl"
 174         PACKAGE_CFLAGS_ISL="-I$prefix/include/isl"
 175         ;;
 176 build)
 177         with_isl_builddir=`echo @abs_builddir@ | $with_isl_builddir/config.status --file=-`
 178         ISL_CFLAGS="-I$isl_srcdir/include -I$with_isl_builddir/include"
 179         ISL_LIBS="$with_isl_builddir/libisl.la"
 180         PACKAGE_CFLAGS_ISL="-I$prefix/include/isl"
 181         ;;
 182 system)
 183         PKG_CHECK_MODULES([ISL], [isl])
 184         PACKAGE_CFLAGS_ISL="$ISL_CFLAGS"
 185 esac
 186 AM_CONDITIONAL(BUNDLED_ISL, test $with_isl = bundled)
 187
 188 AX_SUBMODULE(isl-polylib,build|bundled|system,bundled)
 189
 190 AC_SUBST(ISL_POLYLIB_CFLAGS)
 191 AC_SUBST(ISL_POLYLIB_LIBS)
 192 case "$with_isl_polylib" in
 193 bundled)
 194         ISL_POLYLIB_CFLAGS="-I\$(top_srcdir)/isl-polylib/include -I\$(top_builddir)/isl-polylib/include"
 195         ;;
 196 build)
 197         ISL_POLYLIB_CFLAGS="-I$isl_polylib_srcdir/include -I$with_isl_polylib_builddir/include"
 198         ISL_POLYLIB_LIBS="$with_isl_polylib_builddir/libisl-polylib.la"
 199         ;;
 200 system)
 201         PKG_CHECK_MODULES([ISL_POLYLIB], [isl-polylib])
 202 esac
 203 AM_CONDITIONAL(BUNDLED_ISL_POLYLIB, test $with_isl_polylib = bundled)
 204
 205 AC_MSG_CHECKING(if the fractional representation should be used)
 206 AC_ARG_ENABLE(fractional, [AS_HELP_STRING([--disable-fractional],
 207                                           [Don't use fractional representation])],
 208             [bv_cv_fractional=$enableval], [bv_cv_fractional="yes"])
 209 AC_ARG_ENABLE(modulo, [AS_HELP_STRING([--disable-modulo],
 210                                       [Don't use fractional representation])],
 211             [bv_cv_modulo=$enableval], [bv_cv_modulo="$bv_cv_fractional"])
 212 AC_MSG_RESULT($bv_cv_modulo)
 213 if test "x$bv_cv_modulo" != "xno" ; then
 214         AC_DEFINE(USE_MODULO,[], [Use fractional representation])
 215 fi
 216
 217 AC_MSG_CHECKING(whether to use incremental algorithm)
 218 AC_ARG_ENABLE(incremental,
 219         [AS_HELP_STRING([--enable-incremental@<:@=bf|df@:>@],
 220                         [Enable incremental algorithm [bf]])],
 221         [bv_cv_incremental=$enableval], [bv_cv_incremental="no"])
 222 AC_MSG_RESULT($bv_cv_incremental)
 223 case $bv_cv_incremental in
 224         yes | bf)
 225                 AC_DEFINE(USE_INCREMENTAL_BF,[],
 226                           [Use breadth-first incremental algorithm])
 227         ;;
 228         df)
 229                 AC_DEFINE(USE_INCREMENTAL_DF,[],
 230                           [Use depth-first incremental algorithm])
 231         ;;
 232 esac
 233
 234 AC_ARG_WITH(ntl,
 235             [  --with-ntl=DIR          DIR Location of NTL],
 236             [ echo "Package ntl : $withval" && ntl_package=$withval],
 237             [ ntl_package=yes ])
 238
 239 if test "$ntl_package" = "no"; then
 240     AC_MSG_ERROR(Need ntl)
 241 fi
 242
 243 AC_SUBST(NTL_CPPFLAGS)
 244 AC_SUBST(NTL_LDFLAGS)
 245 if test "$ntl_package" != "yes"; then
 246     NTL_CPPFLAGS="-I$ntl_package/include"
 247     NTL_LDFLAGS="-L$ntl_package/lib"
 248 fi
 249
 250 SAVE_CPPFLAGS="$CPPFLAGS"
 251 SAVE_LDFLAGS="$LDFLAGS"
 252 CPPFLAGS="$NTL_CPPFLAGS $CPPFLAGS"
 253 LDFLAGS="$NTL_LDFLAGS $LDFLAGS"
 254 AC_EGREP_CPP(yes, [
 255     #include <NTL/ZZ.h>
 256     #ifdef NTL_GMP_LIP
 257     yes
 258     #endif
 259     ],:,AC_MSG_ERROR(ntl not compiled with gmp support))
 260
 261 AC_CHECK_LIB(ntl, main,[],[
 262     AC_MSG_ERROR(Need ntl)
 263 ])
 264 CPPFLAGS="$SAVE_CPPFLAGS"
 265 LDFLAGS="$SAVE_LDFLAGS"
 266
 267 AC_SUBST(bv_cone_hilbert_basis)
 268 AC_MSG_CHECKING(whether to compile zsolve)
 269 AC_ARG_WITH(zsolve,
 270             [AS_HELP_STRING([--without-zsolve],[do not compile zsolve])],
 271             [ with_zsolve=$withval],  [ with_zsolve=yes ])
 272 AC_MSG_RESULT($with_zsolve)
 273
 274 use_zsolve=false
 275 if test "$with_zsolve" != "no"; then
 276         if test "$GCC" = "yes"; then
 277                 $CC --version |
 278                 sed -e 's/.* \(@<:@0-9@:>@@<:@0-9@:>@*\)\.\(@<:@0-9@:>@@<:@0-9@:>@*\).*/\1 \2/' |
 279                 (read major minor
 280                         if test $major -gt 3; then
 281                                 exit 0
 282                         fi
 283                         if test $major -eq 3 -a $minor -ge 4; then
 284                                 exit 0
 285                         fi
 286                         exit 1
 287                 ) && use_zsolve=true
 288         fi
 289         if test "$use_zsolve" = false; then
 290                 AC_MSG_WARN(gcc 3.4 required to compile zsolve)
 291         else
 292                 AC_DEFINE(USE_ZSOLVE,[],[use zsolve])
 293                 bv_cone_hilbert_basis="cone_hilbert_basis\$(EXEEXT)"
 294         fi
 295 fi
 296 AM_CONDITIONAL(USE_ZSOLVE, test x$use_zsolve = xtrue)
 297
 298 AX_SUBMODULE(omega,no|bundled|system,bundled)
 299
 300 AC_SUBST(OMEGA_CPPFLAGS)
 301 AC_SUBST(OMEGA_LDFLAGS)
 302 AC_SUBST(OMEGA_LIBS)
 303 AC_SUBST(OMEGA_CODEGEN_LIBS)
 304 have_omega=false
 305 have_codegen=false
 306 case "$with_omega" in
 307 bundled)
 308         have_omega=true
 309         have_codegen=true
 310         OMEGA_CPPFLAGS="-I\$(top_srcdir)/omega/omega_lib/include"
 311         OMEGA_CPPFLAGS="$OMEGA_CPPFLAGS -I\$(top_srcdir)/omega/basic/include"
 312         OMEGA_CPPFLAGS="$OMEGA_CPPFLAGS -I\$(top_srcdir)/omega/code_gen/include"
 313         OMEGA_CPPFLAGS="$OMEGA_CPPFLAGS -I\$(top_srcdir)/omega/omega_calc/include"
 314         ;;
 315 system)
 316     if test "x$omega_package" != "xyes"; then
 317         OMEGA_CPPFLAGS="-I$omega_package/include/omega"
 318         OMEGA_LDFLAGS="-L$omega_package/lib"
 319     else
 320         for i in /usr/include /usr/local/include; do
 321             if test -f $i/omega/omega.h; then
 322                 OMEGA_CPPFLAGS="-I$i/omega"
 323             fi
 324         done
 325     fi
 326
 327     AC_LANG_PUSH(C++)
 328     SAVE_CPPFLAGS="$CPPFLAGS"
 329     SAVE_LDFLAGS="$LDFLAGS"
 330     CPPFLAGS="$OMEGA_CPPFLAGS $CPPFLAGS"
 331     LDFLAGS="$OMEGA_LDFLAGS $LDFLAGS"
 332     AC_CHECK_HEADERS([omega.h],[
 333         OMEGA_LIBS="-lomega"
 334         AC_CHECK_LIB(code_gen,main,[
 335                 OMEGA_CODEGEN_LIBS="-lcode_gen -lomega"
 336                 have_codegen=true
 337         ])
 338         have_omega=true
 339     ],[AC_MSG_WARN(Omega not found)])
 340     CPPFLAGS="$SAVE_CPPFLAGS"
 341     LDFLAGS="$SAVE_LDFLAGS"
 342     AC_LANG_POP
 343     ;;
 344 esac
 345 if test "$have_omega" = true; then
 346         AC_DEFINE(HAVE_OMEGA,[],[use omega])
 347 fi
 348 AM_CONDITIONAL(HAVE_OMEGA, test x$have_omega = xtrue)
 349 AM_CONDITIONAL(BUNDLED_OMEGA, test $with_omega = bundled)
 350
 351 use_parker=false
 352 AC_MSG_CHECKING(whether to compile parker)
 353 AC_ARG_WITH(parker,
 354             [AS_HELP_STRING([--without-zsolve],[do not compile zsolve])],
 355             [ with_parker=$withval],  [ with_parker=yes ])
 356 AC_MSG_RESULT($with_parker)
 357
 358 if test "$with_parker" != "no"; then
 359         AC_MSG_CHECKING(for mona)
 360         AC_ARG_WITH(mona,
 361                 [AS_HELP_STRING([--with-mona=DIR],[mona *source* directory])],
 362                                 [], [AC_MSG_RESULT(not specified)])
 363
 364         if test "x$with_mona" != "x"; then
 365                 AC_SUBST(MONAPATH)
 366                 MONAPATH=$with_mona
 367                 AC_MSG_RESULT($MONAPATH)
 368                 use_parker=true
 369                 AC_DEFINE(USE_PARKER,[],[use parker])
 370         fi
 371
 372         if test "x$with_mona" = "x"; then
 373                 AC_MSG_WARN(mona source directory required to compile parker)
 374                 AC_MSG_WARN(http://www.brics.dk/mona/download)
 375         fi
 376 fi
 377 AM_CONDITIONAL(USE_PARKER, test x$use_parker = xtrue)
 378
 379 AC_MSG_CHECKING(whether to use cddlib)
 380 AC_ARG_WITH(cddlib, [AS_HELP_STRING([--with-cddlib=DIR],[DIR Location of cddlib])],
 381             [ cddlib_package=$withval],  [ cddlib_package=yes ])
 382 AC_MSG_RESULT($cddlib_package)
 383
 384 have_cddlib=false
 385 if test "$cddlib_package" != "no"; then
 386     if test "x$cddlib_package" != "xyes"; then
 387         CPPFLAGS="-I$cddlib_package/include $CPPFLAGS"
 388         LDFLAGS="-L$cddlib_package/lib $LDFLAGS"
 389     fi
 390     AC_TRY_LINK([
 391 #define GMPRATIONAL
 392 #include <setoper.h>
 393 #include <cddmp.h>
 394 ], [
 395     mytype a;
 396     dd_init(a); ], [
 397         have_cddlib=true
 398         AC_CHECK_LIB(cddgmp, main,[
 399                 SAVE_LIBS="$LIBS"
 400                 LIBS="-lcddgmp $LIBS"
 401                 AC_DEFINE_UNQUOTED([SRCDIR], ["$srcdir"], [srcdir])
 402                 AC_LANG_PUSH(C++)
 403                 AC_RUN_IFELSE(AC_LANG_PROGRAM([[#define GMPRATIONAL
 404 #include <setoper.h>
 405 #include <cdd.h>]],
 406                 [[
 407         const char *filename = SRCDIR"/cdd94e-test";
 408         FILE *f;
 409         dd_MatrixPtr M;
 410         dd_LPType *lp;
 411         dd_ErrorType err = dd_NoError;
 412
 413         dd_set_global_constants();
 414
 415         f = fopen(filename, "r");
 416         M = dd_PolyFile2Matrix(f, &err);
 417         lp = dd_Matrix2LP(M, &err);
 418         dd_LPSolve(lp, dd_DualSimplex, &err);
 419         return lp->LPS == dd_Inconsistent;
 420                 ]]),[
 421                         AC_DEFINE(HAVE_LIBCDDGMP, [], [Define to 1 if you have the `cddgmp' library (-lcddgmp).])
 422                 ],[
 423                         AC_MSG_WARN(please upgrade cddlib to 0.94e or later)
 424                         LIBS="$SAVE_LIBS"
 425                         have_cddlib=false
 426                 ])
 427                 AC_LANG_POP
 428         ],[have_cddlib=false])
 429     ])
 430 fi
 431 AM_CONDITIONAL(HAVE_CDDLIB, test x$have_cddlib = xtrue)
 432
 433
 434
 435 AC_MSG_CHECKING(whether to use GLPK)
 436 AC_ARG_WITH(glpk, [AS_HELP_STRING([--with-glpk=DIR],[DIR Location of GLPK])],
 437             [ glpk_package=$withval],  [ glpk_package=yes ])
 438 AC_MSG_RESULT($glpk_package)
 439
 440 have_glpk=false
 441 if test "$glpk_package" != "no"; then
 442     if test "x$glpk_package" != "xyes"; then
 443         CPPFLAGS="-I$glpk_package/include $CPPFLAGS"
 444         LDFLAGS="-L$glpk_package/lib $LDFLAGS"
 445     fi
 446     AC_CHECK_HEADERS([glpk.h],[
 447         have_glpk=true
 448         AC_CHECK_LIB(glpk, main,[],[have_glpk=false])
 449     ])
 450 fi
 451 AM_CONDITIONAL(HAVE_GLPK, test x$have_glpk = xtrue)
 452
 453 AC_MSG_CHECKING(location of TOPCOM)
 454 AC_ARG_WITH(topcom, [AS_HELP_STRING([--with-topcom=DIR],[Location of TOPCOM])],
 455             [topcom_package=$withval], [topcom_package=unspecified])
 456 AC_MSG_RESULT($topcom_package)
 457 have_topcom=false
 458 if test "$topcom_package" != no; then
 459         topcom_path="$PATH"
 460         if test "$topcom_package" != unspecified; then
 461                 topcom_path="$topcom_package/bin"
 462         fi
 463         AC_PATH_PROG([POINTS2TRIANGS], [points2triangs], [], [$topcom_path])
 464         if test -n "$POINTS2TRIANGS"; then
 465                 have_topcom=true
 466                 AC_DEFINE_UNQUOTED(POINTS2TRIANGS_PATH, ["$POINTS2TRIANGS"],
 467                                     [Path of points2triangs])
 468         fi
 469 fi
 470 AM_CONDITIONAL(HAVE_TOPCOM, test x$have_topcom = xtrue)
 471
 472 AC_SUBST(GIT_HEAD_ID)
 473 AC_SUBST(GIT_HEAD)
 474 AC_SUBST(GIT_HEAD_VERSION)
 475 if test -f $srcdir/.git/HEAD; then
 476     GIT_HEAD="$srcdir/.git/index"
 477     GIT_REPO="$srcdir/.git"
 478     GIT_HEAD_ID=`GIT_DIR=$GIT_REPO git describe`
 479 elif test -f $srcdir/GIT_HEAD_ID; then
 480     GIT_HEAD_ID=`cat $srcdir/GIT_HEAD_ID`
 481 else
 482     mysrcdir=`(cd $srcdir; pwd)`
 483     head=`basename $mysrcdir | sed -e 's/.*-//'`
 484     head2=`echo $head | sed -e 's/[^0-9a-f]//'`
 485     head3=`echo $head2 | sed -e 's/........................................//'`
 486     base=`basename $mysrcdir | sed -e 's/-.*//'`
 487     if test "x$head3" = "x" -a "x$head" = "x$head2"; then
 488         GIT_HEAD_ID="barvinok-$VERSION-$head
 489     elif test "x$base" = "xbarvinok-$VERSION" -a "x$head" != "x"; then
 490         GIT_HEAD_ID="barvinok-$VERSION-$head
 491     else
 492         GIT_HEAD_ID="UNKNOWN"
 493     fi
 494 fi
 495 if test -z "$GIT_REPO" ; then
 496     GIT_HEAD_VERSION="$GIT_HEAD_ID"
 497 else
 498     GIT_HEAD_VERSION="\`GIT_DIR=$GIT_REPO git describe\`"
 499 fi
 500 echo '#define GIT_HEAD_ID "'$GIT_HEAD_ID'"' > version.h
 501
 502 AC_LANG_PUSH(C++)
 503 AC_TRY_COMPILE([
 504                 #include <set>
 505                 void negate();
 506         ], [negate()],
 507         suffix="normal", suffix="broken")
 508 AC_CONFIG_COMMANDS([barvinok/set.h],
 509                    [cp $srcdir/barvinok/set.h.$suffix barvinok/set.h],
 510                    [suffix="$suffix"])
 511 AC_CONFIG_COMMANDS([barvinok/NTL.h],
 512                    [cp $srcdir/barvinok/NTL.h.$suffix barvinok/NTL.h],
 513                    [suffix="$suffix"])
 514 use_fdstream=false
 515 SAVE_CPPFLAGS="$CPPFLAGS"
 516 CPPFLAGS="-I$srcdir $CPPFLAGS"
 517 AC_TRY_COMPILE([#include "fdstream.h"],[],
 518         [AC_DEFINE(USE_FDSTREAM,[],[use fdstream])
 519         use_fdstream=true])
 520 CPPFLAGS="$SAVE_CPPFLAGS"
 521 AC_LANG_POP
 522 AM_CONDITIONAL(USE_FDSTREAM, [test "$use_fdstream" = true])
 523
 524 PACKAGE_CFLAGS="$PACKAGE_CFLAGS_ISL"
 525 PACKAGE_LIBS="-lbarvinok -lbarvinok-core $EXTRA_PACKAGE_LIBS -lisl-polylib -lpolylibgmp -lpiplibMP -lisl"
 526 AX_CREATE_PKGCONFIG_INFO
 527
 528 AC_CONFIG_HEADERS(config.h)
 529 AC_CONFIG_FILES(Makefile zsolve/Makefile doc/Makefile)
 530 AC_CONFIG_FILES(parker/Makefile)
 531 if test $with_polylib = bundled; then
 532         AC_CONFIG_SUBDIRS(polylib)
 533 fi
 534 if test $with_piplib = bundled; then
 535         AC_CONFIG_SUBDIRS(piplib)
 536 fi
 537 if test $with_isl = bundled; then
 538         AC_CONFIG_SUBDIRS(isl)
 539 fi
 540 if test $with_isl_polylib = bundled; then
 541         AC_CONFIG_SUBDIRS(isl-polylib)
 542 fi
 543 if test $with_omega = bundled; then
 544         AC_CONFIG_SUBDIRS(omega)
 545 fi
 546 AC_CONFIG_COMMANDS_POST([
 547         dnl pass on arguments to subdir configures, but don't
 548         dnl add them to config.status
 549         ac_configure_args="$ac_configure_args $bv_configure_args"
 550 ])
 551 AC_OUTPUT