configure.in

   1 AC_INIT
   2 AM_INIT_AUTOMAKE(barvinok, 0.24)
   3 AC_PROG_CC
   4 gl_EARLY
   5
   6 AC_PROG_CXX
   7 AM_PROG_LEX
   8 AC_PROG_YACC
   9 AC_SUBST(versioninfo)
  10 versioninfo=14:0:1
  11
  12 AC_CANONICAL_HOST
  13 AC_LIBTOOL_WIN32_DLL
  14 AC_SUBST(BV_LDFLAGS)
  15 case $host in
  16         *-*-cygwin* | *-*-mingw* | *-*-pw32* | *-*-os2*)
  17         if test "$enable_shared" = yes; then
  18                 BV_LDFLAGS="-no-undefined"
  19         fi
  20         ;;
  21 esac
  22
  23 AC_DISABLE_SHARED
  24 AC_PROG_LIBTOOL
  25
  26 gl_MODULES(argp progname)
  27 gl_INIT
  28
  29 AC_CHECK_HEADERS(getopt.h)
  30 AC_CHECK_HEADERS(sys/times.h)
  31
  32 AC_ARG_WITH(default-prefix,
  33         AS_HELP_STRING([--with-default-prefix=DIR],
  34             [Default installation prefix of optional packages]))
  35 if test "${with_default_prefix+set}" = set; then
  36         if test "${with_ginac_prefix+set}" != set -a \
  37            "${with_ginac_exec_prefix+set}" != set -a \
  38            -f "$with_default_prefix/bin/ginac-config"; then
  39                 with_ginac_prefix=$with_default_prefix
  40         fi
  41         if test "${with_libgmp+set}" != set -a \
  42            -f "$with_default_prefix/include/gmp.h"; then
  43                 with_libgmp=$with_default_prefix
  44         fi
  45         if test "${with_polylib_prefix+set}" != set -a \
  46            -f "$with_default_prefix/include/polylib/polylibgmp.h"; then
  47                 with_polylib_prefix=$with_default_prefix
  48         fi
  49         if test "${with_piplib+set}" != set -a \
  50            -f "$with_default_prefix/include/piplib/piplibMP.h"; then
  51                 with_piplib=$with_default_prefix
  52         fi
  53         if test "${with_ntl+set}" != set -a \
  54            -f "$with_default_prefix/include/NTL/ZZ.h"; then
  55                 with_ntl=$with_default_prefix
  56         fi
  57         if test "${with_omega+set}" != set -a \
  58            -f "$with_default_prefix/include/omega/omega.h"; then
  59                 with_omega=$with_default_prefix
  60         fi
  61         if test "${with_cddlib+set}" != set -a \
  62            -f "$with_default_prefix/include/cddmp.h"; then
  63                 with_cddlib=$with_default_prefix
  64         fi
  65         if test "${with_glpk+set}" != set -a \
  66            -f "$with_default_prefix/include/glpk.h"; then
  67                 with_glpk=$with_default_prefix
  68         fi
  69 fi
  70
  71 dnl Check for GMP library
  72 AC_MSG_CHECKING(whether to use GMP)
  73 AC_ARG_WITH(libgmp,
  74         [  --with-libgmp           DIR Location of the GMP Distribution],
  75         gmp_package=$withval, gmp_package=yes)
  76 if test "x$gmp_package" = "xno"; then
  77         AC_MSG_RESULT(no)
  78         AC_MSG_ERROR(Need gmp)
  79 else
  80         AC_MSG_RESULT(yes)
  81         if test "x$gmp_package" = "xyes"; then
  82                 bv_configure_args="$bv_configure_args --with-libgmp --with-gmp"
  83         else
  84             bv_configure_args="$bv_configure_args --with-gmp=$gmp_package"
  85             GMP_DIR=$gmp_package
  86             if test ! -d "$GMP_DIR"; then
  87                 AC_ERROR(Directory given for GMP Distribution is not a directory)
  88             fi
  89             CPPFLAGS="-I$GMP_DIR/include $CPPFLAGS"
  90             LDFLAGS="-L$GMP_DIR/lib $LDFLAGS"
  91         fi
  92         poly_cv_gmpfatal="no"
  93         AC_CHECK_HEADER(gmp.h,
  94                 [AC_CHECK_LIB(gmp,main,
  95                     [],
  96                     [poly_cv_gmpfatal="yes"])],
  97                 [poly_cv_gmpfatal="yes"])
  98         if test "$poly_cv_gmpfatal" = "yes"; then
  99                 AC_MSG_ERROR([GMP not found])
 100         fi
 101 fi
 102 AC_CHECK_DECL(mpz_divisible_p,[],[AC_LIBOBJ(mpz_divisible_p)],[#include <gmp.h>])
 103
 104 # BV_SUBMODULE(SUBMODULE)
 105 AC_DEFUN([BV_SUBMODULE],[
 106         case "$with_$1" in
 107         no)
 108                 AC_MSG_ERROR(Need $1)
 109                 ;;
 110         bundled|system)
 111                 ;;
 112         *)
 113                 if test -d $srcdir/.git -a \
 114                         ! -d $srcdir/$1/.git; then
 115                         AC_MSG_WARN(
 116 [git repo detected, but submodule $1 not initialized])
 117                         AC_MSG_WARN([You may want to run])
 118                         AC_MSG_WARN([   git submodule init])
 119                         AC_MSG_WARN([   git submodule update])
 120                         AC_MSG_WARN([   sh autogen.sh])
 121                 fi
 122                 if test -f $srcdir/$1/configure; then
 123                         with_$1="bundled"
 124                 else
 125                         with_$1="system"
 126                 fi
 127                 ;;
 128         esac
 129 ])
 130
 131 AC_ARG_WITH(polylib,
 132         [AS_HELP_STRING([--with-polylib=bundled|system],[Which PolyLib to use])])
 133 AC_ARG_WITH(polylib_prefix,
 134         [AS_HELP_STRING([--with-polylib-prefix=DIR],[Location of system PolyLib])])
 135
 136 if test "x$with_polylib_prefix" != "x"; then
 137         with_polylib="system"
 138 fi
 139 BV_SUBMODULE(polylib)
 140 AC_MSG_CHECKING([which PolyLib to use])
 141 AC_MSG_RESULT($with_polylib)
 142
 143 AC_SUBST(POLYLIB_CPPFLAGS)
 144 AC_SUBST(POLYLIB_LDFLAGS)
 145 AC_SUBST(POLYLIB_LIBS)
 146 if test "$with_polylib" = "bundled"; then
 147         bv_configure_args="$bv_configure_args --with-polylib-builddir=../polylib"
 148         POLYLIB_CPPFLAGS="-Ipolylib/include -I$srcdir/polylib/include"
 149 else
 150         POLYLIB_LIBS="-lpolylibgmp"
 151         if test "x$with_polylib_prefix" != "x"; then
 152                 POLYLIB_CPPFLAGS="-I$with_polylib_prefix/include"
 153                 POLYLIB_LDFLAGS="-L$with_polylib_prefix/lib"
 154         fi
 155         SAVE_CPPFLAGS="$CPPFLAGS"
 156         CPPFLAGS="$POLYLIB_CPPFLAGS $CPPFLAGS"
 157         AC_CHECK_HEADERS([polylib/polylibgmp.h], [], [
 158                 AC_MSG_ERROR(Need PolyLib)
 159         ])
 160         CPPFLAGS="$SAVE_CPPFLAGS"
 161 fi
 162
 163 AM_CONDITIONAL(BUNDLED_POLYLIB, test $with_polylib = bundled)
 164
 165 AC_ARG_WITH(piplib,
 166         [AS_HELP_STRING([--with-piplib=bundled|system],[Which piplib to use])])
 167 AC_ARG_WITH(piplib_prefix,
 168         [AS_HELP_STRING([--with-piplib-prefix=DIR],[Location of system piplib])])
 169
 170 if test "x$with_piplib_prefix" != "x"; then
 171         with_piplib="system"
 172 fi
 173 BV_SUBMODULE(piplib)
 174 AC_MSG_CHECKING([which piplib to use])
 175 AC_MSG_RESULT($with_piplib)
 176
 177 AC_SUBST(PIPLIB_CPPFLAGS)
 178 AC_SUBST(PIPLIB_LDFLAGS)
 179 AC_SUBST(PIPLIB_LIBS)
 180 if test "$with_piplib" = "bundled"; then
 181         bv_configure_args="$bv_configure_args --with-piplib-builddir=../piplib"
 182         bv_configure_args="$bv_configure_args --enable-mp-version"
 183         PIPLIB_CPPFLAGS="-I$srcdir/piplib/include"
 184 else
 185         PIPLIB_LIBS="-lpiplibMP"
 186         if test "x$with_piplib_prefix" != "x"; then
 187                 PIPLIB_CPPFLAGS="-I$with_piplib_prefix/include"
 188                 PIPLIB_LDFLAGS="-L$with_piplib_prefix/lib"
 189         fi
 190         SAVE_CPPFLAGS="$CPPFLAGS"
 191         SAVE_LDFLAGS="$LDFLAGS"
 192         CPPFLAGS="$PIPLIB_CPPFLAGS $CPPFLAGS"
 193         LDFLAGS="$PIPLIB_LDFLAGS $LDFLAGS"
 194         AC_CHECK_LIB(piplibMP, pip_solve,[
 195             AC_CHECK_MEMBER(PipOptions.Urs_parms, [], [
 196                 AC_MSG_ERROR([Piplib too old; please install version 1.3.6 or newer])
 197             ],[#include <stdio.h>
 198                #include <piplib/piplibMP.h>])
 199         ],[
 200             AC_MSG_ERROR([Piplib not found])
 201         ])
 202         CPPFLAGS="$SAVE_CPPFLAGS"
 203         LDFLAGS="$SAVE_LDFLAGS"
 204 fi
 205 AM_CONDITIONAL(BUNDLED_PIPLIB, test $with_piplib = bundled)
 206
 207 AC_MSG_CHECKING(if the fractional representation should be used)
 208 AC_ARG_ENABLE(fractional, [AS_HELP_STRING([--disable-fractional],
 209                                           [Don't use fractional representation])],
 210             [bv_cv_fractional=$enableval], [bv_cv_fractional="yes"])
 211 AC_ARG_ENABLE(modulo, [AS_HELP_STRING([--disable-modulo],
 212                                       [Don't use fractional representation])],
 213             [bv_cv_modulo=$enableval], [bv_cv_modulo="$bv_cv_fractional"])
 214 AC_MSG_RESULT($bv_cv_modulo)
 215 if test "x$bv_cv_modulo" != "xno" ; then
 216         AC_DEFINE(USE_MODULO,[], [Use fractional representation])
 217 fi
 218
 219 AC_MSG_CHECKING(whether to use incremental algorithm)
 220 AC_ARG_ENABLE(incremental,
 221         [AS_HELP_STRING([--enable-incremental@<:@=bf|df@:>@],
 222                         [Enable incremental algorithm [bf]])],
 223         [bv_cv_incremental=$enableval], [bv_cv_incremental="no"])
 224 AC_MSG_RESULT($bv_cv_incremental)
 225 case $bv_cv_incremental in
 226         yes | bf)
 227                 AC_DEFINE(USE_INCREMENTAL_BF,[],
 228                           [Use breadth-first incremental algorithm])
 229         ;;
 230         df)
 231                 AC_DEFINE(USE_INCREMENTAL_DF,[],
 232                           [Use depth-first incremental algorithm])
 233         ;;
 234 esac
 235
 236 AC_ARG_WITH(ntl,
 237             [  --with-ntl=DIR          DIR Location of NTL],
 238             [ echo "Package ntl : $withval" && ntl_package=$withval],
 239             [ ntl_package=yes ])
 240
 241 if test "$ntl_package" = "no"; then
 242     AC_MSG_ERROR(Need ntl)
 243 fi
 244
 245 if test "$ntl_package" != "yes"; then
 246     CPPFLAGS="-I$ntl_package/include $CPPFLAGS"
 247     LDFLAGS="-L$ntl_package/lib $LDFLAGS"
 248 fi
 249
 250 AC_EGREP_CPP(yes, [
 251     #include <NTL/ZZ.h>
 252     #ifdef NTL_GMP_LIP
 253     yes
 254     #endif
 255     ],:,AC_MSG_ERROR(ntl not compiled with gmp support))
 256
 257 AC_CHECK_LIB(ntl, main,[],[
 258     AC_MSG_ERROR(Need ntl)
 259 ])
 260
 261 AC_MSG_CHECKING(whether to compile bernstein)
 262 AC_ARG_WITH(bernstein,
 263             [AS_HELP_STRING([--without-bernstein],[do not compile bernstein])],
 264             [ with_bernstein=$withval],  [ with_bernstein=yes ])
 265 AC_MSG_RESULT($with_bernstein)
 266
 267 AC_SUBST(bv_barvinok_maximize)
 268 have_ginac=false
 269 if test "$with_bernstein" != "no"; then
 270         AC_LANG_PUSH(C++)
 271         AM_PATH_GINAC(1.3.3, [
 272                 have_ginac=true
 273                 AC_DEFINE(HAVE_GINAC,[],[use GiNaC])
 274                 EXTRA_PACKAGE_LIBS="-lbernstein $EXTRA_PACKAGE_LIBS"
 275                 bv_barvinok_maximize="barvinok_maximize\$(EXEEXT)"
 276         ])
 277         AC_LANG_POP
 278 fi
 279 AM_CONDITIONAL(HAVE_GINAC, test x$have_ginac = xtrue)
 280
 281 AC_MSG_CHECKING(whether to use Omega)
 282 AC_ARG_WITH(omega, [AS_HELP_STRING([--with-omega=DIR],[DIR Location of Omega])],
 283             [ omega_package=$withval],  [ omega_package=yes ])
 284 AC_MSG_RESULT($omega_package)
 285
 286 AC_SUBST(OMEGA_CPPFLAGS)
 287 AC_SUBST(OMEGA_LDFLAGS)
 288 AC_SUBST(OMEGA_LIBS)
 289 AC_SUBST(bv_omega_programs)
 290 have_omega=false
 291 if test "$omega_package" != "no"; then
 292     if test "x$omega_package" != "xyes"; then
 293         OMEGA_CPPFLAGS="-I$omega_package/include/omega"
 294         OMEGA_LDFLAGS="-L$omega_package/lib"
 295     else
 296         for i in /usr/include /usr/local/include; do
 297             if test -f $i/omega/omega.h; then
 298                 OMEGA_CPPFLAGS="-I$i/omega"
 299             fi
 300         done
 301     fi
 302
 303     AC_LANG_PUSH(C++)
 304     SAVE_CPPFLAGS="$CPPFLAGS"
 305     CPPFLAGS="$OMEGA_CPPFLAGS $CPPFLAGS"
 306     AC_CHECK_HEADERS([omega.h],[
 307         if test x$have_ginac = xtrue; then
 308             bv_omega_programs="occ $bv_omega_programs"
 309         fi
 310         AC_DEFINE(HAVE_OMEGA,[],[use omega])
 311         OMEGA_LIBS="-lcode_gen -lomega"
 312         have_omega=true
 313     ],[AC_MSG_WARN(Omega not found)])
 314     CPPFLAGS="$SAVE_CPPFLAGS"
 315     AC_LANG_POP
 316 fi
 317 AM_CONDITIONAL(HAVE_OMEGA, test x$have_omega = xtrue)
 318
 319
 320 AC_MSG_CHECKING(whether to use cddlib)
 321 AC_ARG_WITH(cddlib, [AS_HELP_STRING([--with-cddlib=DIR],[DIR Location of cddlib])],
 322             [ cddlib_package=$withval],  [ cddlib_package=yes ])
 323 AC_MSG_RESULT($cddlib_package)
 324
 325 have_cddlib=false
 326 if test "$cddlib_package" != "no"; then
 327     if test "x$cddlib_package" != "xyes"; then
 328         CPPFLAGS="-I$cddlib_package/include $CPPFLAGS"
 329         LDFLAGS="-L$cddlib_package/lib $LDFLAGS"
 330     fi
 331     AC_TRY_LINK([
 332 #define GMPRATIONAL
 333 #include <setoper.h>
 334 #include <cddmp.h>
 335 ], [
 336     mytype a;
 337     dd_init(a); ], [
 338         have_cddlib=true
 339         AC_CHECK_LIB(cddgmp, main,[],[have_cddlib=false])
 340     ])
 341 fi
 342 AM_CONDITIONAL(HAVE_CDDLIB, test x$have_cddlib = xtrue)
 343
 344
 345
 346 AC_MSG_CHECKING(whether to use GLPK)
 347 AC_ARG_WITH(glpk, [AS_HELP_STRING([--with-glpk=DIR],[DIR Location of GLPK])],
 348             [ glpk_package=$withval],  [ glpk_package=yes ])
 349 AC_MSG_RESULT($glpk_package)
 350
 351 have_glpk=false
 352 if test "$glpk_package" != "no"; then
 353     if test "x$glpk_package" != "xyes"; then
 354         CPPFLAGS="-I$glpk_package/include $CPPFLAGS"
 355         LDFLAGS="-L$glpk_package/lib $LDFLAGS"
 356     fi
 357     AC_CHECK_HEADERS([glpk.h],[
 358         have_glpk=true
 359         AC_CHECK_LIB(glpk, main,[],[have_glpk=false])
 360     ])
 361 fi
 362 AM_CONDITIONAL(HAVE_GLPK, test x$have_glpk = xtrue)
 363
 364 AC_SUBST(GIT_HEAD_ID)
 365 AC_SUBST(GIT_HEAD)
 366 AC_SUBST(GIT_HEAD_VERSION)
 367 if test -f $srcdir/.git/HEAD; then
 368     GIT_HEAD="$srcdir/.git/index"
 369     GIT_REPO="$srcdir/.git"
 370     GIT_HEAD_ID=`GIT_DIR=$GIT_REPO git describe`
 371 elif test -f $srcdir/GIT_HEAD_ID; then
 372     GIT_HEAD_ID=`cat $srcdir/GIT_HEAD_ID`
 373 else
 374     mysrcdir=`(cd $srcdir; pwd)`
 375     head=`basename $mysrcdir | sed -e 's/.*-//'`
 376     head2=`echo $head | sed -e 's/[^0-9a-f]//'`
 377     head3=`echo $head2 | sed -e 's/........................................//'`
 378     base=`basename $mysrcdir | sed -e 's/-.*//'`
 379     if test "x$head3" = "x" -a "x$head" = "x$head2"; then
 380         GIT_HEAD_ID="barvinok-$VERSION-$head
 381     elif test "x$base" = "xbarvinok-$VERSION" -a "x$head" != "x"; then
 382         GIT_HEAD_ID="barvinok-$VERSION-$head
 383     else
 384         GIT_HEAD_ID="UNKNOWN"
 385     fi
 386 fi
 387 if test -z "$GIT_REPO" ; then
 388     GIT_HEAD_VERSION="$GIT_HEAD_ID"
 389 else
 390     GIT_HEAD_VERSION="\`GIT_DIR=$GIT_REPO git describe\`"
 391 fi
 392 echo '#define GIT_HEAD_ID "'$GIT_HEAD_ID'"' > version.h
 393
 394 AC_LANG_PUSH(C++)
 395 AC_TRY_COMPILE([
 396                 #include <set>
 397                 void negate();
 398         ], [negate()],
 399         suffix="normal", suffix="broken")
 400 AC_CONFIG_COMMANDS([barvinok/set.h],
 401                    [cp $srcdir/barvinok/set.h.$suffix barvinok/set.h],
 402                    [suffix="$suffix"])
 403 AC_CONFIG_COMMANDS([barvinok/NTL.h],
 404                    [cp $srcdir/barvinok/NTL.h.$suffix barvinok/NTL.h],
 405                    [suffix="$suffix"])
 406 use_fdstream=false
 407 SAVE_CPPFLAGS="$CPPFLAGS"
 408 CPPFLAGS="-I$srcdir $CPPFLAGS"
 409 AC_TRY_COMPILE([#include "fdstream.h"],[],
 410         [AC_DEFINE(USE_FDSTREAM,[],[use fdstream])
 411         use_fdstream=true])
 412 CPPFLAGS="$SAVE_CPPFLAGS"
 413 AC_LANG_POP
 414 AM_CONDITIONAL(USE_FDSTREAM, [test "$use_fdstream" = true])
 415
 416 PACKAGE_LIBS="-lbarvinok $EXTRA_PACKAGE_LIBS -lpolylibgmp -lpiplibMP"
 417 AX_CREATE_PKGCONFIG_INFO
 418
 419 AC_CONFIG_HEADERS(config.h)
 420 AC_CONFIG_FILES(Makefile lib/Makefile doc/Makefile omega/Makefile)
 421 if test $with_polylib = bundled; then
 422         AC_CONFIG_SUBDIRS(polylib)
 423 fi
 424 if test $with_piplib = bundled; then
 425         AC_CONFIG_SUBDIRS(piplib)
 426 fi
 427 if test x$have_ginac = xtrue; then
 428     AC_CONFIG_SUBDIRS(bernstein)
 429 fi
 430 AC_CONFIG_COMMANDS_POST([
 431         dnl pass on arguments to subdir configures, but don't
 432         dnl add them to config.status
 433         ac_configure_args="$ac_configure_args $bv_configure_args"
 434 ])
 435 AC_OUTPUT