configure.in

   1 AC_INIT
   2 AM_INIT_AUTOMAKE(barvinok, 0.19)
   3 AC_PROG_CXX
   4 AM_PROG_LEX
   5 AC_PROG_YACC
   6 AC_SUBST(versioninfo)
   7 versioninfo=10:1:0
   8
   9 AC_CANONICAL_HOST
  10 AC_LIBTOOL_WIN32_DLL
  11 AC_SUBST(BV_LDFLAGS)
  12 case $host in
  13         *-*-cygwin* | *-*-mingw* | *-*-pw32* | *-*-os2*)
  14         if test "$enable_shared" = yes; then
  15                 BV_LDFLAGS="-no-undefined"
  16         fi
  17         ;;
  18 esac
  19
  20 AC_PROG_LIBTOOL
  21
  22 AC_CHECK_HEADERS(getopt.h)
  23 AC_CHECK_HEADERS(sys/times.h)
  24
  25 dnl Check for GMP library
  26 AC_MSG_CHECKING(whether to use GMP)
  27 AC_ARG_WITH(libgmp,
  28         [  --with-libgmp           DIR Location of the GMP Distribution],
  29         gmp_package=$withval, gmp_package=yes)
  30 if test "x$gmp_package" = "xno"; then
  31         AC_MSG_RESULT(no)
  32         AC_MSG_ERROR(Need gmp)
  33 else
  34         AC_MSG_RESULT(yes)
  35         if test "x$gmp_package" != "xyes"; then
  36             GMP_DIR=$gmp_package
  37             if test ! -d "$GMP_DIR"; then
  38                 AC_ERROR(Directory given for GMP Distribution is not a directory)
  39             fi
  40             CPPFLAGS="-I$GMP_DIR/include $CPPFLAGS"
  41             LDFLAGS="-L$GMP_DIR/lib $LDFLAGS"
  42         fi
  43         poly_cv_gmpfatal="no"
  44         AC_CHECK_HEADER(gmp.h,
  45                 [AC_CHECK_LIB(gmp,main,
  46                     [],
  47                     [poly_cv_gmpfatal="yes"])],
  48                 [poly_cv_gmpfatal="yes"])
  49         if test "$poly_cv_gmpfatal" = "yes"; then
  50                 AC_MSG_ERROR([GMP not found])
  51         fi
  52 fi
  53 AC_CHECK_DECL(mpz_divisible_p,[],[AC_LIBOBJ(mpz_divisible_p)],[#include <gmp.h>])
  54
  55 AC_ARG_WITH(polylib,
  56             [  --with-polylib=DIR      DIR Location of PolyLib],
  57             [ echo "Package polylib : $withval" && polylib_package=$withval],
  58             [ polylib_package=yes ])
  59
  60 if test "$polylib_package" = "no"; then
  61     AC_MSG_ERROR(Need polylib)
  62 fi
  63
  64 if test "$polylib_package" != "yes"; then
  65     CPPFLAGS="-I$polylib_package/include $CPPFLAGS"
  66     LDFLAGS="-L$polylib_package/lib $LDFLAGS"
  67     LD_LIBRARY_PATH="$polylib_package/lib:$LD_LIBRARY_PATH"
  68     export LD_LIBRARY_PATH
  69 fi
  70
  71 AC_CHECK_LIB(polylibgmp, PolyhedronTSort,[],[
  72     AC_MSG_ERROR(Need polylib)
  73 ])
  74 AC_CHECK_FUNCS(Enumeration_Free)
  75 AC_SUBST(bv_extra_programs)
  76 AC_CHECK_FUNCS(LexSmaller,[
  77         bv_extra_programs="verify_lexsmaller $bv_extra_programs"
  78     ])
  79 AC_REPLACE_FUNCS(DomainConstraintSimplify)
  80 AC_TRY_RUN([
  81 #include <polylib/polylibgmp.h>
  82
  83 int main()
  84 {
  85     int i, j;
  86     Polyhedron *P;
  87     Matrix *M = Matrix_Alloc(6,5);
  88     for (i = 0; i < 6; ++i) {
  89         value_set_si(M->p[i][0], 1);
  90         for (j = 1; j < 4; ++j)
  91             value_set_si(M->p[i][j], (j-1 == i/2) * (1-2*(i%2)));
  92         value_set_si(M->p[i][4], i%2);
  93     }
  94     P = Constraints2Polyhedron(M, 6);
  95     return !(P->NbRays == 8);
  96 }
  97 ],
  98 [AC_DEFINE(HAVE_GROWING_CHERNIKOVA,[],
  99           [PolyLib automatically grows the Chernikova table space])],
 100 AC_MSG_WARN([This version of PolyLib does not automatically])
 101 AC_MSG_WARN([enlarge the Chernikova table space]),
 102 AC_MSG_WARN([Unable to determine whether PolyLib automatically])
 103 AC_MSG_WARN([grows the Chernikova table space]))
 104
 105 AC_TRY_RUN([
 106 #include <polylib/polylibgmp.h>
 107
 108 int main()
 109 {
 110     enode *en = new_enode(polynomial, 1, 1);
 111     return !(en->arr[0].x.p == NULL);
 112 }
 113 ],,
 114 AC_MSG_WARN([This version of polylib leaks]),[true])
 115
 116 AC_TRY_RUN([
 117 #include <stdio.h>
 118 #include <polylib/polylibgmp.h>
 119
 120 int main()
 121 {
 122     Matrix *M;
 123     Polyhedron *P, *C;
 124     Param_Polyhedron *PP;
 125     int i;
 126     Param_Vertices *V;
 127
 128     freopen("$srcdir/tests/ehrhart/t12.in", "r", stdin);
 129     M = Matrix_Read();
 130     P = Constraints2Polyhedron(M, 1024);
 131     M = Matrix_Read();
 132     C = Constraints2Polyhedron(M, 1024);
 133     PP = Polyhedron2Param_SimplifiedDomain(&P, C, 1024, NULL, NULL);
 134     for (i = 0, V = PP->V; V; ++i, V = V->next)
 135         ;
 136     return !(i == 10);
 137 }
 138 ],
 139 [AC_DEFINE(HAVE_CORRECT_VERTICES,[],
 140           [PolyLib computes correct vertices])],
 141 AC_MSG_WARN([This version of polylib produces incorrect vertices.]),
 142 AC_MSG_WARN([Unable to determine whether PolyLib computes correct vertices]))
 143
 144 AC_MSG_CHECKING([number of arguments of Polyhedron_Enumerate])
 145 AC_TRY_COMPILE([#include <polylib/polylibgmp.h>],
 146                [Polyhedron_Enumerate(NULL,NULL,0,NULL)],
 147                [AC_MSG_RESULT(4)
 148                 AC_DEFINE(HAVE_ENUMERATE4,[],
 149                           [Polyhedron_Enumerate takes four arguments])],
 150                [AC_MSG_RESULT(3)])
 151
 152 AC_MSG_CHECKING([number of arguments of count_points])
 153 AC_TRY_COMPILE([#include <polylib/polylibgmp.h>],
 154                [count_points(0,NULL,NULL,NULL)],
 155                [AC_MSG_RESULT(4)
 156                 AC_DEFINE(HAVE_COUNT_POINTS4,[],
 157                           [count_points takes four arguments])],
 158                [AC_MSG_RESULT(3)])
 159
 160 AC_MSG_CHECKING([for value_subtract macro])
 161 AC_EGREP_CPP(yes, [
 162     #include <polylib/polylibgmp.h>
 163     #ifdef value_subtract
 164     yes
 165     #endif
 166     ],[AC_MSG_RESULT(yes)],
 167     [AC_MSG_RESULT(no)
 168      AC_DEFINE(value_subtract,value_substract,
 169                 [define to value_substract if missing from PolyLib])])
 170
 171 AC_ARG_WITH(piplib,
 172             [  --with-piplib=DIR       DIR Location of PIP],
 173             [ echo "Package piplib : $withval" && piplib_package=$withval],
 174             [ piplib_package=yes ])
 175
 176 if test "$piplib_package" != "no"; then
 177     if test "$piplib_package" != "yes"; then
 178         CPPFLAGS="-I$piplib_package/include $CPPFLAGS"
 179         LDFLAGS="-L$piplib_package/lib $LDFLAGS"
 180     fi
 181
 182     AC_CHECK_LIB(piplibMP, pip_solve,[
 183         AC_DEFINE(HAVE_PIPLIB,[],[use piplib])
 184         LIBS="-lpiplibMP $LIBS"
 185         AC_LIBOBJ(piputil)
 186         bv_extra_programs="piptest $bv_extra_programs"
 187     ],[
 188         AC_MSG_WARN([Piplib not found])
 189     ])
 190 fi
 191
 192 AC_MSG_CHECKING(whether to use Omega)
 193 AC_ARG_WITH(omega, [AS_HELP_STRING([--with-omega=DIR],[DIR Location of Omega])],
 194             [ omega_package=$withval],  [ omega_package=yes ])
 195 AC_MSG_RESULT($omega_package)
 196
 197 AC_SUBST(OMEGA_CPPFLAGS)
 198 AC_SUBST(OMEGA_LDFLAGS)
 199 AC_SUBST(bv_omega_programs)
 200 if test "$omega_package" != "no"; then
 201     if test "x$omega_package" != "xyes"; then
 202         OMEGA_CPPFLAGS="-I$omega_package/include/omega $CPPFLAGS"
 203         OMEGA_LDFLAGS="-L$omega_package/lib $LDFLAGS"
 204     else
 205         for i in /usr/include /usr/local/include; do
 206             if test -f $i/omega/omega.h; then
 207                 OMEGA_CPPFLAGS="-I$i/omega $CPPFLAGS"
 208             fi
 209         done
 210     fi
 211
 212     AC_LANG_PUSH(C++)
 213     SAVE_CPPFLAGS="$CPPFLAGS"
 214     CPPFLAGS="$OMEGA_CPPFLAGS"
 215     AC_CHECK_HEADERS([omega.h],[
 216         bv_omega_programs="occ $bv_omega_programs"
 217     ],[AC_MSG_WARN(Omega not found)])
 218     CPPFLAGS="$SAVE_CPPFLAGS"
 219     AC_LANG_POP
 220 fi
 221
 222 AC_MSG_CHECKING(if --enable-fractional option specified)
 223 AC_ARG_ENABLE(fractional,
 224             [  --enable-fractional     Use fractional representation],
 225             [bv_cv_fractional=$enableval], [bv_cv_fractional="no"])
 226 AC_MSG_RESULT($bv_cv_fractional)
 227 AC_MSG_CHECKING(if --enable-modulo option specified)
 228 AC_ARG_ENABLE(modulo,
 229             [  --enable-modulo         Use fractional representation],
 230             [bv_cv_modulo=$enableval], [bv_cv_modulo="no"])
 231 AC_MSG_RESULT($bv_cv_modulo)
 232 if test "x$bv_cv_modulo" != "xno" -o "x$bv_cv_fractional" != "xno"; then
 233         AC_DEFINE(USE_MODULO,[], [Use fractional representation])
 234 fi
 235
 236 AC_MSG_CHECKING(whether to use incremental algorithm)
 237 AC_ARG_ENABLE(incremental,
 238         [AS_HELP_STRING([--enable-incremental@<:@=bf|df@:>@],
 239                         [Enable incremental algorithm [bf]])],
 240         [bv_cv_incremental=$enableval], [bv_cv_incremental="no"])
 241 AC_MSG_RESULT($bv_cv_incremental)
 242 case $bv_cv_incremental in
 243         yes | bf)
 244                 AC_DEFINE(USE_INCREMENTAL_BF,[],
 245                           [Use breadth-first incremental algorithm])
 246         ;;
 247         df)
 248                 AC_DEFINE(USE_INCREMENTAL_DF,[],
 249                           [Use depth-first incremental algorithm])
 250         ;;
 251 esac
 252
 253 AC_ARG_WITH(ntl,
 254             [  --with-ntl=DIR          DIR Location of NTL],
 255             [ echo "Package ntl : $withval" && ntl_package=$withval],
 256             [ ntl_package=yes ])
 257
 258 if test "$ntl_package" = "no"; then
 259     AC_MSG_ERROR(Need ntl)
 260 fi
 261
 262 if test "$ntl_package" != "yes"; then
 263     CPPFLAGS="-I$ntl_package/include $CPPFLAGS"
 264     LDFLAGS="-L$ntl_package/lib $LDFLAGS"
 265 fi
 266
 267 AC_EGREP_CPP(yes, [
 268     #include <NTL/ZZ.h>
 269     #ifdef NTL_GMP_LIP
 270     yes
 271     #endif
 272     ],:,AC_MSG_ERROR(ntl not compiled with gmp support))
 273
 274 AC_CHECK_LIB(ntl, main,[],[
 275     AC_MSG_ERROR(Need ntl)
 276 ])
 277
 278 AC_SUBST(GIT_HEAD_ID)
 279 AC_SUBST(GIT_HEAD)
 280 AC_SUBST(GIT_HEAD_VERSION)
 281 if test -f $srcdir/.git/HEAD; then
 282     GIT_HEAD="$srcdir/.git/HEAD"
 283     GIT_HEAD_ID=`cat $srcdir/.git/HEAD`
 284 elif test -f $srcdir/GIT_HEAD_ID; then
 285     GIT_HEAD_ID=`cat $srcdir/GIT_HEAD_ID`
 286 else
 287     mysrcdir=`(cd $srcdir; pwd)`
 288     head=`basename $mysrcdir | sed -e 's/.*-//'`
 289     head2=`echo $head | sed -e 's/[^0-9a-f]//'`
 290     head3=`echo $head2 | sed -e 's/........................................//'`
 291     if test "x$head3" = "x" -a "x$head" = "x$head2"; then
 292         GIT_HEAD_ID="$head"
 293     else
 294         GIT_HEAD_ID="UNKNOWN"
 295     fi
 296 fi
 297 if test -z "$GIT_HEAD" ; then
 298     GIT_HEAD_VERSION="$GIT_HEAD_ID"
 299 else
 300     GIT_HEAD_VERSION='`cat $<`'
 301 fi
 302 echo '#define GIT_HEAD_ID "'$GIT_HEAD_ID'"' > version.h
 303
 304 AX_CREATE_PKGCONFIG_INFO
 305
 306 AC_CONFIG_HEADERS(config.h)
 307 AC_OUTPUT(Makefile omega/Makefile)