configure.ac

   1 AC_INIT([barvinok], [0.38], [isl-development@googlegroups.com])
   2 AC_CONFIG_MACRO_DIR([m4])
   3 AM_INIT_AUTOMAKE([foreign])
   4 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   5 AC_PROG_CC
   6
   7 AC_PROG_CXX
   8 AM_PROG_LEX
   9 AC_PROG_YACC
  10 AC_SUBST(versioninfo)
  11 versioninfo=23:3:0
  12
  13 AC_CANONICAL_HOST
  14 AC_LIBTOOL_WIN32_DLL
  15 AC_SUBST(BV_LDFLAGS)
  16 case $host in
  17         *-*-cygwin* | *-*-mingw* | *-*-pw32* | *-*-os2*)
  18         if test "$enable_shared" = yes; then
  19                 BV_LDFLAGS="-no-undefined"
  20         fi
  21         ;;
  22 esac
  23
  24 AC_PROG_LIBTOOL
  25
  26 PKG_PROG_PKG_CONFIG
  27
  28 AC_CHECK_HEADERS(getopt.h)
  29 AC_CHECK_HEADERS(sys/times.h)
  30 AC_CHECK_FUNCS(sigaction)
  31
  32 AC_MSG_CHECKING(whether to build shared libbarvinok)
  33 AC_ARG_ENABLE(shared_barvinok,
  34         AS_HELP_STRING([--enable-shared-barvinok],
  35                        [build shared barvinok library]),
  36         [bv_cv_shared_barvinok=$enableval], [bv_cv_shared_barvinok="no"])
  37 AC_MSG_RESULT($bv_cv_shared_barvinok)
  38 if test "x$bv_cv_shared_barvinok" != "xyes" ; then
  39         BV_LDFLAGS="$BV_LDFLAGS -static"
  40 fi
  41
  42 AC_CXX_GNUCXX_HASHMAP
  43
  44 AC_ARG_WITH(default-prefix,
  45         AS_HELP_STRING([--with-default-prefix=DIR],
  46             [Default installation prefix of optional packages]))
  47 if test "${with_default_prefix+set}" = set; then
  48         if test "${with_libgmp+set}" != set -a \
  49            -f "$with_default_prefix/include/gmp.h"; then
  50                 with_gmp_prefix=$with_default_prefix
  51         fi
  52         if test "${with_ntl+set}" != set -a \
  53            "${with_ntl_prefix+set}" != set -a \
  54            -f "$with_default_prefix/include/NTL/ZZ.h"; then
  55                 with_ntl_prefix=$with_default_prefix
  56         fi
  57         if test "${with_cddlib+set}" != set -a \
  58            -f "$with_default_prefix/include/cddmp.h"; then
  59                 with_cddlib=$with_default_prefix
  60         fi
  61         if test "${with_glpk+set}" != set -a \
  62            -f "$with_default_prefix/include/glpk.h"; then
  63                 with_glpk=$with_default_prefix
  64         fi
  65         if test "${with_topcom+set}" != set -a \
  66            -f "$with_default_prefix/bin/points2triangs"; then
  67                 with_topcom=$with_default_prefix
  68         fi
  69 fi
  70
  71 AX_SUBMODULE(gmp,system|build,system)
  72
  73 case "$with_gmp" in
  74 build)
  75         with_gmp_builddir=`echo @abs_builddir@ | \
  76                            $with_gmp_builddir/config.status --file=-`
  77         CPPFLAGS="-I$with_gmp_builddir $CPPFLAGS"
  78         LDFLAGS="-L$with_gmp_builddir/$lt_cv_objdir $LDFLAGS"
  79         bv_extra="--with-gmp --with-gmp-builddir=$with_gmp_builddir"
  80         bv_configure_args="$bv_configure_args $bv_extra"
  81         ;;
  82 system)
  83         if test "x$with_gmp_prefix" != "x"; then
  84                 bv_extra="--with-libgmp=$with_gmp_prefix"
  85                 bv_configure_args="$bv_configure_args $bv_extra"
  86                 CPPFLAGS="-I$with_gmp_prefix/include $CPPFLAGS"
  87                 LDFLAGS="-L$with_gmp_prefix/lib $LDFLAGS"
  88         else
  89                 bv_configure_args="$bv_configure_args --with-libgmp --with-gmp"
  90         fi
  91         ;;
  92 esac
  93
  94 poly_cv_gmpfatal="no"
  95 AC_CHECK_HEADER(gmp.h,
  96         [AC_CHECK_LIB(gmp,main,
  97             [],
  98             [poly_cv_gmpfatal="yes"])],
  99         [poly_cv_gmpfatal="yes"])
 100 if test "$poly_cv_gmpfatal" = "yes"; then
 101         AC_MSG_ERROR([GMP not found])
 102 fi
 103 AC_CHECK_DECL(mpz_divisible_p,[],[AC_LIBOBJ(mpz_divisible_p)],[#include <gmp.h>])
 104
 105 AX_SUBMODULE(polylib,build|bundled|system,bundled)
 106
 107 AC_SUBST(POLYLIB_CPPFLAGS)
 108 AC_SUBST(POLYLIB_LDFLAGS)
 109 AC_SUBST(POLYLIB_LIBS)
 110 case "$with_polylib" in
 111 bundled)
 112         bv_configure_args="$bv_configure_args --with-polylib-builddir=../polylib"
 113         POLYLIB_CPPFLAGS="-I\$(top_builddir)/polylib/include -I\$(top_srcdir)/polylib/include"
 114         ;;
 115 build)
 116         with_polylib_builddir=`echo @abs_builddir@ | $with_polylib_builddir/config.status --file=-`
 117         POLYLIB_CPPFLAGS="-I$polylib_srcdir/include -I$with_polylib_builddir/include"
 118         POLYLIB_LIBS="$with_polylib_builddir/libpolylibgmp.la"
 119         ;;
 120 system)
 121         POLYLIB_LIBS="-lpolylibgmp"
 122         if test "x$with_polylib_prefix" != "x"; then
 123                 POLYLIB_CPPFLAGS="-I$with_polylib_prefix/include"
 124                 POLYLIB_LDFLAGS="-L$with_polylib_prefix/lib"
 125         fi
 126         SAVE_CPPFLAGS="$CPPFLAGS"
 127         CPPFLAGS="$POLYLIB_CPPFLAGS $CPPFLAGS"
 128         AC_CHECK_HEADERS([polylib/polylibgmp.h], [], [
 129                 AC_MSG_ERROR(Need PolyLib)
 130         ])
 131         CPPFLAGS="$SAVE_CPPFLAGS"
 132 esac
 133
 134 AM_CONDITIONAL(BUNDLED_POLYLIB, test $with_polylib = bundled)
 135
 136 AX_SUBMODULE(isl,build|bundled|system,bundled)
 137
 138 AC_SUBST(ISL_CFLAGS)
 139 AC_SUBST(ISL_LIBS)
 140 AC_SUBST(ISL_BUILDDIR)
 141 case "$with_isl" in
 142 bundled)
 143         ISL_BUILDDIR=isl
 144         ISL_CFLAGS="-I\$(top_srcdir)/isl/include -I\$(top_builddir)/isl/include"
 145         bv_configure_args="$bv_configure_args --with-isl-builddir=../isl"
 146         PACKAGE_CFLAGS_ISL='-I${prefix}/include'
 147         ;;
 148 build)
 149         ISL_BUILDDIR=`echo @abs_builddir@ | $with_isl_builddir/config.status --file=-`
 150         bv_configure_args="$bv_configure_args --with-isl-builddir=$ISL_BUILDDIR"
 151         ISL_CFLAGS="-I$isl_srcdir/include -I$ISL_BUILDDIR/include"
 152         PACKAGE_CFLAGS_ISL='-I${prefix}/include'
 153         ;;
 154 system)
 155         PKG_CHECK_MODULES([ISL], [isl])
 156         PACKAGE_CFLAGS_ISL="$ISL_CFLAGS"
 157 esac
 158 AM_CONDITIONAL(BUNDLED_ISL, test $with_isl = bundled)
 159 AM_CONDITIONAL(BUILD_ISL, test $with_isl = build)
 160
 161 AX_SUBMODULE(pet,bundled|build|system|no,no)
 162 AC_SUBST(PET_CFLAGS)
 163 AC_SUBST(PET_LIBS)
 164 AC_SUBST(PET_BUILDDIR)
 165 case "$with_pet" in
 166 bundled)
 167         PET_CFLAGS="-I\$(top_srcdir)/pet/include"
 168         AC_DEFINE(HAVE_PET,[],[use Pet])
 169         ;;
 170 build)
 171         PET_BUILDDIR=`echo @abs_builddir@ | $with_pet_builddir/config.status --file=-`
 172         PET_CFLAGS="-I$pet_srcdir/include"
 173         AC_DEFINE(HAVE_PET,[],[use Pet])
 174         ;;
 175 system)
 176         PKG_CHECK_MODULES([PET], [pet])
 177         AC_DEFINE(HAVE_PET,[],[use Pet])
 178 esac
 179 AM_CONDITIONAL(BUNDLED_PET, test $with_pet = bundled)
 180 AM_CONDITIONAL(BUILD_PET, test $with_pet = build)
 181
 182 AC_MSG_CHECKING(if the fractional representation should be used)
 183 AC_ARG_ENABLE(fractional, [AS_HELP_STRING([--disable-fractional],
 184                                           [Don't use fractional representation])],
 185             [bv_cv_fractional=$enableval], [bv_cv_fractional="yes"])
 186 AC_ARG_ENABLE(modulo, [AS_HELP_STRING([--disable-modulo],
 187                                       [Don't use fractional representation])],
 188             [bv_cv_modulo=$enableval], [bv_cv_modulo="$bv_cv_fractional"])
 189 AC_MSG_RESULT($bv_cv_modulo)
 190 if test "x$bv_cv_modulo" != "xno" ; then
 191         AC_DEFINE(USE_MODULO,[], [Use fractional representation])
 192 fi
 193
 194 AC_MSG_CHECKING(whether to use incremental algorithm)
 195 AC_ARG_ENABLE(incremental,
 196         [AS_HELP_STRING([--enable-incremental@<:@=bf|df@:>@],
 197                         [Enable incremental algorithm [bf]])],
 198         [bv_cv_incremental=$enableval], [bv_cv_incremental="no"])
 199 AC_MSG_RESULT($bv_cv_incremental)
 200 case $bv_cv_incremental in
 201         yes | bf)
 202                 AC_DEFINE(USE_INCREMENTAL_BF,[],
 203                           [Use breadth-first incremental algorithm])
 204         ;;
 205         df)
 206                 AC_DEFINE(USE_INCREMENTAL_DF,[],
 207                           [Use depth-first incremental algorithm])
 208         ;;
 209 esac
 210
 211 AC_ARG_WITH(ntl,
 212             [AC_HELP_STRING([--with-ntl=system|build],
 213                             [Which NTL to use [default=system]])])
 214
 215 AC_ARG_WITH(ntl-prefix,
 216             [AC_HELP_STRING([--with-ntl-prefix=DIR],
 217                             [Prefix of NTL installation])])
 218
 219 AC_ARG_WITH(ntl-builddir,
 220             [AC_HELP_STRING([--with-ntl-builddir=DIR],
 221                             [Prefix of NTL root build directory
 222                              containing include and src subdirectories])])
 223
 224 if test "x$with_ntl_builddir" != "x"; then
 225         if test "x$with_ntl" != "xbuild" -a "x$with_ntl" != "x"; then
 226                 AC_MSG_ERROR(m4_normalize([Setting --with-ntl-builddir implies
 227                                            use of build NTL]))
 228         fi
 229         with_ntl="build"
 230 fi
 231
 232 if test "x$with_ntl_prefix" != "x"; then
 233         if test "x$with_ntl" != "xsystem" -a "x$with_ntl" != "x"; then
 234                 AC_MSG_ERROR(m4_normalize([Setting --with-ntl-prefix implies
 235                                            use of system NTL]))
 236         fi
 237         with-ntl="system"
 238 fi
 239
 240 case "$with_ntl" in
 241 build|system)
 242         ;;
 243 *)
 244         with_ntl="system"
 245         ;;
 246 esac
 247 AC_MSG_CHECKING([which NTL to use])
 248 AC_MSG_RESULT($with_ntl)
 249
 250 AC_SUBST(NTL_CPPFLAGS)
 251 AC_SUBST(NTL_LDFLAGS)
 252 case "$with_ntl" in
 253 build)
 254         NTL_CPPFLAGS="-I$with_ntl_builddir/include"
 255         NTL_LDFLAGS="-L$with_ntl_builddir/src/$lt_cv_objdir"
 256         ntl_builddir_found=false
 257         AC_CHECK_FILE(["$with_ntl_builddir/src/ZZ.c"],
 258                       [ntl_builddir_found=true],[])
 259         if test "x$ntl_builddir_found" != "xtrue"; then
 260                 if test -f "$with_ntl_builddir/ZZ.c"; then
 261                         ntl_builddir=`dirname $with_ntl_builddir`
 262                         AC_MSG_ERROR(m4_normalize(
 263                               [NTL source directory src/ specified as builddir.
 264                                Use root directory instead as
 265                                --with-ntl-builddir=$ntl_builddir]))
 266                 else
 267                         AC_MSG_ERROR([Could not find NTL in the builddir])
 268                 fi
 269         fi
 270         ;;
 271 system)
 272         if test "x$with_ntl_prefix" != "x"; then
 273                 NTL_CPPFLAGS="-I$with_ntl_prefix/include"
 274                 NTL_LDFLAGS="-L$with_ntl_prefix/lib"
 275         fi
 276         ;;
 277 esac
 278
 279 AX_CHECK_NTL
 280
 281 AC_SUBST(bv_cone_hilbert_basis)
 282 AC_MSG_CHECKING(whether to compile zsolve)
 283 AC_ARG_WITH(zsolve,
 284             [AS_HELP_STRING([--without-zsolve],[do not compile zsolve])],
 285             [ with_zsolve=$withval],  [ with_zsolve=yes ])
 286 AC_MSG_RESULT($with_zsolve)
 287
 288 use_zsolve=false
 289 if test "$with_zsolve" != "no"; then
 290         if test "$GCC" = "yes"; then
 291                 $CC --version |
 292                 sed -e 's/.* \(@<:@0-9@:>@@<:@0-9@:>@*\)\.\(@<:@0-9@:>@@<:@0-9@:>@*\).*/\1 \2/' |
 293                 (read major minor
 294                         if test $major -gt 3; then
 295                                 exit 0
 296                         fi
 297                         if test $major -eq 3 -a $minor -ge 4; then
 298                                 exit 0
 299                         fi
 300                         exit 1
 301                 ) && use_zsolve=true
 302         fi
 303         if test "$use_zsolve" = false; then
 304                 AC_MSG_WARN(gcc 3.4 required to compile zsolve)
 305         else
 306                 AC_DEFINE(USE_ZSOLVE,[],[use zsolve])
 307                 bv_cone_hilbert_basis="cone_hilbert_basis\$(EXEEXT)"
 308         fi
 309 fi
 310 AM_CONDITIONAL(USE_ZSOLVE, test x$use_zsolve = xtrue)
 311
 312 AX_SUBMODULE(omega,no|system,no)
 313
 314 AC_SUBST(OMEGA_CPPFLAGS)
 315 AC_SUBST(OMEGA_LDFLAGS)
 316 AC_SUBST(OMEGA_LIBS)
 317 AC_SUBST(OMEGA_CODEGEN_LIBS)
 318 have_omega=false
 319 have_codegen=false
 320 case "$with_omega" in
 321 system)
 322     if test "x$with_omega_prefix" != "xyes"; then
 323         OMEGA_CPPFLAGS="-I$with_omega_prefix/include/omega"
 324         OMEGA_LDFLAGS="-L$with_omega_prefix/lib"
 325     else
 326         for i in /usr/include /usr/local/include; do
 327             if test -f $i/omega/omega.h; then
 328                 OMEGA_CPPFLAGS="-I$i/omega"
 329             fi
 330         done
 331     fi
 332
 333     AC_LANG_PUSH(C++)
 334     SAVE_CPPFLAGS="$CPPFLAGS"
 335     SAVE_LDFLAGS="$LDFLAGS"
 336     CPPFLAGS="$OMEGA_CPPFLAGS $CPPFLAGS"
 337     LDFLAGS="$OMEGA_LDFLAGS $LDFLAGS"
 338     AC_CHECK_HEADERS([omega.h],[
 339         OMEGA_LIBS="-lomega"
 340         AC_CHECK_LIB(code_gen,main,[
 341                 OMEGA_CODEGEN_LIBS="-lcode_gen -lomega"
 342                 have_codegen=true
 343         ])
 344         have_omega=true
 345     ],[AC_MSG_WARN(Omega not found)])
 346     CPPFLAGS="$SAVE_CPPFLAGS"
 347     LDFLAGS="$SAVE_LDFLAGS"
 348     AC_LANG_POP
 349     ;;
 350 esac
 351 if test "$have_omega" = true; then
 352         AC_DEFINE(HAVE_OMEGA,[],[use omega])
 353 fi
 354 AM_CONDITIONAL(HAVE_OMEGA, test x$have_omega = xtrue)
 355
 356 use_parker=false
 357 AC_MSG_CHECKING(whether to compile parker)
 358 AC_ARG_WITH(parker,
 359             [AS_HELP_STRING([--without-zsolve],[do not compile zsolve])],
 360             [ with_parker=$withval],  [ with_parker=yes ])
 361 AC_MSG_RESULT($with_parker)
 362
 363 if test "$with_parker" != "no"; then
 364         AC_MSG_CHECKING(for mona)
 365         AC_ARG_WITH(mona,
 366                 [AS_HELP_STRING([--with-mona=DIR],[mona *source* directory])],
 367                                 [], [AC_MSG_RESULT(not specified)])
 368
 369         if test "x$with_mona" != "x"; then
 370                 AC_SUBST(MONAPATH)
 371                 MONAPATH=$with_mona
 372                 AC_MSG_RESULT($MONAPATH)
 373                 use_parker=true
 374                 AC_DEFINE(USE_PARKER,[],[use parker])
 375         fi
 376
 377         if test "x$with_mona" = "x"; then
 378                 AC_MSG_WARN(mona source directory required to compile parker)
 379                 AC_MSG_WARN(http://www.brics.dk/mona/download)
 380         fi
 381 fi
 382 AM_CONDITIONAL(USE_PARKER, test x$use_parker = xtrue)
 383
 384 AC_MSG_CHECKING(whether to use cddlib)
 385 AC_ARG_WITH(cddlib, [AS_HELP_STRING([--with-cddlib=DIR],[DIR Location of cddlib])],
 386             [ cddlib_package=$withval],  [ cddlib_package=yes ])
 387 AC_MSG_RESULT($cddlib_package)
 388
 389 have_cddlib=false
 390 if test "$cddlib_package" != "no"; then
 391     if test "x$cddlib_package" != "xyes"; then
 392         CPPFLAGS="-I$cddlib_package/include $CPPFLAGS"
 393         LDFLAGS="-L$cddlib_package/lib $LDFLAGS"
 394     fi
 395     AC_TRY_LINK([
 396 #define GMPRATIONAL
 397 #include <setoper.h>
 398 #include <cddmp.h>
 399 ], [
 400     mytype a;
 401     dd_init(a); ], [
 402         have_cddlib=true
 403         AC_CHECK_LIB(cddgmp, main,[
 404                 SAVE_LIBS="$LIBS"
 405                 LIBS="-lcddgmp $LIBS"
 406                 AC_DEFINE_UNQUOTED([SRCDIR], ["$srcdir"], [srcdir])
 407                 AC_LANG_PUSH(C++)
 408                 AC_RUN_IFELSE([AC_LANG_PROGRAM([[#define GMPRATIONAL
 409 #include <setoper.h>
 410 #include <cdd.h>]],
 411                 [[
 412         const char *filename = SRCDIR"/cdd94e-test";
 413         FILE *f;
 414         dd_MatrixPtr M;
 415         dd_LPType *lp;
 416         dd_ErrorType err = dd_NoError;
 417
 418         dd_set_global_constants();
 419
 420         f = fopen(filename, "r");
 421         M = dd_PolyFile2Matrix(f, &err);
 422         lp = dd_Matrix2LP(M, &err);
 423         dd_LPSolve(lp, dd_DualSimplex, &err);
 424         return lp->LPS == dd_Inconsistent;
 425                 ]])],[
 426                         AC_DEFINE(HAVE_LIBCDDGMP, [], [Define to 1 if you have the `cddgmp' library (-lcddgmp).])
 427                 ],[
 428                         AC_MSG_WARN(please upgrade cddlib to 0.94e or later)
 429                         LIBS="$SAVE_LIBS"
 430                         have_cddlib=false
 431                 ])
 432                 AC_LANG_POP
 433         ],[have_cddlib=false])
 434     ])
 435 fi
 436 AM_CONDITIONAL(HAVE_CDDLIB, test x$have_cddlib = xtrue)
 437
 438
 439
 440 AC_MSG_CHECKING(whether to use GLPK)
 441 AC_ARG_WITH(glpk, [AS_HELP_STRING([--with-glpk=DIR],[DIR Location of GLPK])],
 442             [ glpk_package=$withval],  [ glpk_package=yes ])
 443 AC_MSG_RESULT($glpk_package)
 444
 445 have_glpk=false
 446 if test "$glpk_package" != "no"; then
 447     if test "x$glpk_package" != "xyes"; then
 448         CPPFLAGS="-I$glpk_package/include $CPPFLAGS"
 449         LDFLAGS="-L$glpk_package/lib $LDFLAGS"
 450     fi
 451     AC_CHECK_HEADERS([glpk.h],[
 452         have_glpk=true
 453         AC_CHECK_LIB(glpk, [glp_simplex],[],[have_glpk=false])
 454     ])
 455 fi
 456 AM_CONDITIONAL(HAVE_GLPK, test x$have_glpk = xtrue)
 457
 458 AC_MSG_CHECKING(location of TOPCOM)
 459 AC_ARG_WITH(topcom, [AS_HELP_STRING([--with-topcom=DIR],[Location of TOPCOM])],
 460             [topcom_package=$withval], [topcom_package=unspecified])
 461 AC_MSG_RESULT($topcom_package)
 462 have_topcom=false
 463 if test "$topcom_package" != no; then
 464         topcom_path="$PATH"
 465         if test "$topcom_package" != unspecified; then
 466                 topcom_path="$topcom_package/bin"
 467         fi
 468         AC_PATH_PROG([POINTS2TRIANGS], [points2triangs], [], [$topcom_path])
 469         if test -n "$POINTS2TRIANGS"; then
 470                 have_topcom=true
 471                 AC_DEFINE_UNQUOTED(POINTS2TRIANGS_PATH, ["$POINTS2TRIANGS"],
 472                                     [Path of points2triangs])
 473         fi
 474 fi
 475 AM_CONDITIONAL(HAVE_TOPCOM, test x$have_topcom = xtrue)
 476
 477 AX_DETECT_GIT_HEAD
 478 echo '#define GIT_HEAD_ID "'$GIT_HEAD_ID'"' > version.h
 479
 480 AC_LANG_PUSH(C++)
 481 AC_TRY_COMPILE([
 482                 #include <set>
 483                 void negate();
 484         ], [negate()],
 485         suffix="normal", suffix="broken")
 486 AC_CONFIG_COMMANDS([barvinok/set.h],
 487                    [cp $srcdir/barvinok/set.h.$suffix barvinok/set.h],
 488                    [suffix="$suffix"])
 489 AC_CONFIG_COMMANDS([barvinok/NTL.h],
 490                    [cp $srcdir/barvinok/NTL.h.$suffix barvinok/NTL.h],
 491                    [suffix="$suffix"])
 492 use_fdstream=false
 493 SAVE_CPPFLAGS="$CPPFLAGS"
 494 CPPFLAGS="-I$srcdir $CPPFLAGS"
 495 AC_TRY_COMPILE([#include "fdstream.h"],[],
 496         [AC_DEFINE(USE_FDSTREAM,[],[use fdstream])
 497         use_fdstream=true])
 498 CPPFLAGS="$SAVE_CPPFLAGS"
 499 AC_LANG_POP
 500 AM_CONDITIONAL(USE_FDSTREAM, [test "$use_fdstream" = true])
 501
 502 PACKAGE_CFLAGS="$PACKAGE_CFLAGS_ISL"
 503 PACKAGE_LIBS="-lbarvinok $EXTRA_PACKAGE_LIBS -lpolylibgmp -lisl"
 504 AX_CREATE_PKGCONFIG_INFO
 505
 506 AC_CONFIG_HEADERS(config.h)
 507 AC_CONFIG_FILES(Makefile zsolve/Makefile doc/Makefile)
 508 AC_CONFIG_FILES(parker/Makefile)
 509 if test $with_polylib = bundled; then
 510         AC_CONFIG_SUBDIRS(polylib)
 511 fi
 512 if test $with_isl = bundled; then
 513         AC_CONFIG_SUBDIRS(isl)
 514 fi
 515 if test $with_pet = bundled; then
 516         AC_CONFIG_SUBDIRS(pet)
 517 fi
 518 AC_CONFIG_COMMANDS_POST([
 519         dnl pass on arguments to subdir configures, but don't
 520         dnl add them to config.status
 521         ac_configure_args="$ac_configure_args $bv_configure_args"
 522 ])
 523 AC_OUTPUT