configure.in

   1 AC_INIT
   2 AM_INIT_AUTOMAKE(barvinok, 0.27)
   3 AC_PROG_CC
   4 gl_EARLY
   5
   6 AC_PROG_CXX
   7 AM_PROG_LEX
   8 AC_PROG_YACC
   9 AC_SUBST(versioninfo)
  10 versioninfo=17:0:0
  11
  12 AC_CANONICAL_HOST
  13 AC_LIBTOOL_WIN32_DLL
  14 AC_SUBST(BV_LDFLAGS)
  15 case $host in
  16         *-*-cygwin* | *-*-mingw* | *-*-pw32* | *-*-os2*)
  17         if test "$enable_shared" = yes; then
  18                 BV_LDFLAGS="-no-undefined"
  19         fi
  20         ;;
  21 esac
  22
  23 AC_PROG_LIBTOOL
  24
  25 gl_MODULES(argp progname)
  26 gl_INIT
  27
  28 PKG_PROG_PKG_CONFIG
  29
  30 AC_CHECK_HEADERS(getopt.h)
  31 AC_CHECK_HEADERS(sys/times.h)
  32
  33 AC_MSG_CHECKING(whether to build shared libbarvinok)
  34 AC_ARG_ENABLE(shared_barvinok,
  35         AS_HELP_STRING([--enable-shared-barvinok],
  36                        [build shared barvinok library]),
  37         [bv_cv_shared_barvinok=$enableval], [bv_cv_shared_barvinok="no"])
  38 AC_MSG_RESULT($bv_cv_shared_barvinok)
  39 if test "x$bv_cv_shared_barvinok" != "xyes" ; then
  40         BV_LDFLAGS="$BV_LDFLAGS -static"
  41 fi
  42
  43 AC_CXX_GNUCXX_HASHMAP
  44
  45 AC_ARG_WITH(default-prefix,
  46         AS_HELP_STRING([--with-default-prefix=DIR],
  47             [Default installation prefix of optional packages]))
  48 if test "${with_default_prefix+set}" = set; then
  49         if test "${with_ginac_prefix+set}" != set -a \
  50            -f "$with_default_prefix/lib/pkgconfig/ginac.pc"; then
  51                 with_ginac_prefix=$with_default_prefix
  52         fi
  53         if test "${with_libgmp+set}" != set -a \
  54            -f "$with_default_prefix/include/gmp.h"; then
  55                 with_libgmp=$with_default_prefix
  56         fi
  57         if test "${with_ntl+set}" != set -a \
  58            -f "$with_default_prefix/include/NTL/ZZ.h"; then
  59                 with_ntl=$with_default_prefix
  60         fi
  61         if test "${with_omega+set}" != set -a \
  62            -f "$with_default_prefix/include/omega/omega.h"; then
  63                 with_omega=$with_default_prefix
  64         fi
  65         if test "${with_cddlib+set}" != set -a \
  66            -f "$with_default_prefix/include/cddmp.h"; then
  67                 with_cddlib=$with_default_prefix
  68         fi
  69         if test "${with_glpk+set}" != set -a \
  70            -f "$with_default_prefix/include/glpk.h"; then
  71                 with_glpk=$with_default_prefix
  72         fi
  73         if test "${with_topcom+set}" != set -a \
  74            -f "$with_default_prefix/bin/points2triangs"; then
  75                 with_topcom=$with_default_prefix
  76         fi
  77 fi
  78
  79 dnl Check for GMP library
  80 AC_MSG_CHECKING(whether to use GMP)
  81 AC_ARG_WITH(libgmp,
  82         [  --with-libgmp           DIR Location of the GMP Distribution],
  83         gmp_package=$withval, gmp_package=yes)
  84 if test "x$gmp_package" = "xno"; then
  85         AC_MSG_RESULT(no)
  86         AC_MSG_ERROR(Need gmp)
  87 else
  88         AC_MSG_RESULT(yes)
  89         if test "x$gmp_package" = "xyes"; then
  90                 bv_configure_args="$bv_configure_args --with-libgmp --with-gmp"
  91         else
  92             bv_configure_args="$bv_configure_args --with-libgmp=$gmp_package"
  93             bv_configure_args="$bv_configure_args --with-gmp=$gmp_package"
  94             GMP_DIR=$gmp_package
  95             if test ! -d "$GMP_DIR"; then
  96                 AC_ERROR(Directory given for GMP Distribution is not a directory)
  97             fi
  98             CPPFLAGS="-I$GMP_DIR/include $CPPFLAGS"
  99             LDFLAGS="-L$GMP_DIR/lib $LDFLAGS"
 100         fi
 101         poly_cv_gmpfatal="no"
 102         AC_CHECK_HEADER(gmp.h,
 103                 [AC_CHECK_LIB(gmp,main,
 104                     [],
 105                     [poly_cv_gmpfatal="yes"])],
 106                 [poly_cv_gmpfatal="yes"])
 107         if test "$poly_cv_gmpfatal" = "yes"; then
 108                 AC_MSG_ERROR([GMP not found])
 109         fi
 110 fi
 111 AC_CHECK_DECL(mpz_divisible_p,[],[AC_LIBOBJ(mpz_divisible_p)],[#include <gmp.h>])
 112
 113 # BV_SUBMODULE(SUBMODULE)
 114 AC_DEFUN([BV_SUBMODULE],[
 115         case "$with_$1" in
 116         no)
 117                 AC_MSG_ERROR(Need $1)
 118                 ;;
 119         bundled|system)
 120                 ;;
 121         *)
 122                 if test -d $srcdir/.git -a \
 123                         ! -d $srcdir/$1/.git; then
 124                         AC_MSG_WARN(
 125 [git repo detected, but submodule $1 not initialized])
 126                         AC_MSG_WARN([You may want to run])
 127                         AC_MSG_WARN([   git submodule init])
 128                         AC_MSG_WARN([   git submodule update])
 129                         AC_MSG_WARN([   sh autogen.sh])
 130                 fi
 131                 if test -f $srcdir/$1/configure; then
 132                         with_$1="bundled"
 133                 else
 134                         with_$1="system"
 135                 fi
 136                 ;;
 137         esac
 138 ])
 139
 140 AC_ARG_WITH(polylib,
 141         [AS_HELP_STRING([--with-polylib=bundled|system],[Which PolyLib to use])])
 142 AC_ARG_WITH(polylib_prefix,
 143         [AS_HELP_STRING([--with-polylib-prefix=DIR],[Location of system PolyLib])])
 144
 145 if test "x$with_polylib_prefix" != "x"; then
 146         with_polylib="system"
 147 fi
 148 BV_SUBMODULE(polylib)
 149 AC_MSG_CHECKING([which PolyLib to use])
 150 AC_MSG_RESULT($with_polylib)
 151
 152 AC_SUBST(POLYLIB_CPPFLAGS)
 153 AC_SUBST(POLYLIB_LDFLAGS)
 154 AC_SUBST(POLYLIB_LIBS)
 155 if test "$with_polylib" = "bundled"; then
 156         bv_configure_args="$bv_configure_args --with-polylib-builddir=../polylib"
 157         POLYLIB_CPPFLAGS="-I\$(top_builddir)/polylib/include -I\$(top_srcdir)/polylib/include"
 158 else
 159         POLYLIB_LIBS="-lpolylibgmp"
 160         if test "x$with_polylib_prefix" != "x"; then
 161                 POLYLIB_CPPFLAGS="-I$with_polylib_prefix/include"
 162                 POLYLIB_LDFLAGS="-L$with_polylib_prefix/lib"
 163         fi
 164         SAVE_CPPFLAGS="$CPPFLAGS"
 165         CPPFLAGS="$POLYLIB_CPPFLAGS $CPPFLAGS"
 166         AC_CHECK_HEADERS([polylib/polylibgmp.h], [], [
 167                 AC_MSG_ERROR(Need PolyLib)
 168         ])
 169         CPPFLAGS="$SAVE_CPPFLAGS"
 170 fi
 171
 172 AM_CONDITIONAL(BUNDLED_POLYLIB, test $with_polylib = bundled)
 173
 174 AC_ARG_WITH(piplib,
 175         [AS_HELP_STRING([--with-piplib=bundled|system],[Which piplib to use])])
 176 AC_ARG_WITH(piplib_prefix,
 177         [AS_HELP_STRING([--with-piplib-prefix=DIR],[Location of system piplib])])
 178
 179 if test "x$with_piplib_prefix" != "x"; then
 180         with_piplib="system"
 181 fi
 182 BV_SUBMODULE(piplib)
 183 AC_MSG_CHECKING([which piplib to use])
 184 AC_MSG_RESULT($with_piplib)
 185
 186 AC_SUBST(PIPLIB_CPPFLAGS)
 187 AC_SUBST(PIPLIB_LDFLAGS)
 188 AC_SUBST(PIPLIB_LIBS)
 189 if test "$with_piplib" = "bundled"; then
 190         bv_configure_args="$bv_configure_args --with-piplib-builddir=../piplib"
 191         bv_configure_args="$bv_configure_args --enable-mp-version"
 192         PIPLIB_CPPFLAGS="-I$srcdir/piplib/include"
 193 else
 194         PIPLIB_LIBS="-lpiplibMP"
 195         if test "x$with_piplib_prefix" != "x"; then
 196                 PIPLIB_CPPFLAGS="-I$with_piplib_prefix/include"
 197                 PIPLIB_LDFLAGS="-L$with_piplib_prefix/lib"
 198         fi
 199         SAVE_CPPFLAGS="$CPPFLAGS"
 200         SAVE_LDFLAGS="$LDFLAGS"
 201         CPPFLAGS="$PIPLIB_CPPFLAGS $CPPFLAGS"
 202         LDFLAGS="$PIPLIB_LDFLAGS $LDFLAGS"
 203         AC_CHECK_LIB(piplibMP, pip_solve,[
 204             AC_CHECK_MEMBER(PipOptions.Urs_parms, [], [
 205                 AC_MSG_ERROR([Piplib too old; please install version 1.3.6 or newer])
 206             ],[#include <stdio.h>
 207                #include <piplib/piplibMP.h>])
 208         ],[
 209             AC_MSG_ERROR([Piplib not found])
 210         ])
 211         CPPFLAGS="$SAVE_CPPFLAGS"
 212         LDFLAGS="$SAVE_LDFLAGS"
 213 fi
 214 AM_CONDITIONAL(BUNDLED_PIPLIB, test $with_piplib = bundled)
 215
 216 AC_MSG_CHECKING(if the fractional representation should be used)
 217 AC_ARG_ENABLE(fractional, [AS_HELP_STRING([--disable-fractional],
 218                                           [Don't use fractional representation])],
 219             [bv_cv_fractional=$enableval], [bv_cv_fractional="yes"])
 220 AC_ARG_ENABLE(modulo, [AS_HELP_STRING([--disable-modulo],
 221                                       [Don't use fractional representation])],
 222             [bv_cv_modulo=$enableval], [bv_cv_modulo="$bv_cv_fractional"])
 223 AC_MSG_RESULT($bv_cv_modulo)
 224 if test "x$bv_cv_modulo" != "xno" ; then
 225         AC_DEFINE(USE_MODULO,[], [Use fractional representation])
 226 fi
 227
 228 AC_MSG_CHECKING(whether to use incremental algorithm)
 229 AC_ARG_ENABLE(incremental,
 230         [AS_HELP_STRING([--enable-incremental@<:@=bf|df@:>@],
 231                         [Enable incremental algorithm [bf]])],
 232         [bv_cv_incremental=$enableval], [bv_cv_incremental="no"])
 233 AC_MSG_RESULT($bv_cv_incremental)
 234 case $bv_cv_incremental in
 235         yes | bf)
 236                 AC_DEFINE(USE_INCREMENTAL_BF,[],
 237                           [Use breadth-first incremental algorithm])
 238         ;;
 239         df)
 240                 AC_DEFINE(USE_INCREMENTAL_DF,[],
 241                           [Use depth-first incremental algorithm])
 242         ;;
 243 esac
 244
 245 AC_ARG_WITH(ntl,
 246             [  --with-ntl=DIR          DIR Location of NTL],
 247             [ echo "Package ntl : $withval" && ntl_package=$withval],
 248             [ ntl_package=yes ])
 249
 250 if test "$ntl_package" = "no"; then
 251     AC_MSG_ERROR(Need ntl)
 252 fi
 253
 254 AC_SUBST(NTL_CPPFLAGS)
 255 AC_SUBST(NTL_LDFLAGS)
 256 if test "$ntl_package" != "yes"; then
 257     NTL_CPPFLAGS="-I$ntl_package/include"
 258     NTL_LDFLAGS="-L$ntl_package/lib"
 259 fi
 260
 261 SAVE_CPPFLAGS="$CPPFLAGS"
 262 SAVE_LDFLAGS="$LDFLAGS"
 263 CPPFLAGS="$NTL_CPPFLAGS $CPPFLAGS"
 264 LDFLAGS="$NTL_LDFLAGS $LDFLAGS"
 265 AC_EGREP_CPP(yes, [
 266     #include <NTL/ZZ.h>
 267     #ifdef NTL_GMP_LIP
 268     yes
 269     #endif
 270     ],:,AC_MSG_ERROR(ntl not compiled with gmp support))
 271
 272 AC_CHECK_LIB(ntl, main,[],[
 273     AC_MSG_ERROR(Need ntl)
 274 ])
 275 CPPFLAGS="$SAVE_CPPFLAGS"
 276 LDFLAGS="$SAVE_LDFLAGS"
 277
 278 AC_SUBST(bv_cone_hilbert_basis)
 279 AC_MSG_CHECKING(whether to compile zsolve)
 280 AC_ARG_WITH(bernstein,
 281             [AS_HELP_STRING([--without-zsolve],[do not compile zsolve])],
 282             [ with_zsolve=$withval],  [ with_zsolve=yes ])
 283 AC_MSG_RESULT($with_zsolve)
 284
 285 use_zsolve=false
 286 if test "$with_zsolve" != "no"; then
 287         if test "$GCC" = "yes"; then
 288                 $CC --version |
 289                 sed -e 's/.* \(@<:@0-9@:>@@<:@0-9@:>@*\)\.\(@<:@0-9@:>@@<:@0-9@:>@*\).*/\1 \2/' |
 290                 (read major minor
 291                         if test $major -gt 3; then
 292                                 exit 0
 293                         fi
 294                         if test $major -eq 3 -a $minor -ge 4; then
 295                                 exit 0
 296                         fi
 297                         exit 1
 298                 ) && use_zsolve=true
 299         fi
 300         if test "$use_zsolve" = false; then
 301                 AC_MSG_WARN(gcc 3.4 required to compile zsolve)
 302         else
 303                 AC_DEFINE(USE_ZSOLVE,[],[use zsolve])
 304                 bv_cone_hilbert_basis="cone_hilbert_basis\$(EXEEXT)"
 305         fi
 306 fi
 307 AM_CONDITIONAL(USE_ZSOLVE, test x$use_zsolve = xtrue)
 308
 309 AC_MSG_CHECKING(whether to compile bernstein)
 310 AC_ARG_WITH(bernstein,
 311             [AS_HELP_STRING([--without-bernstein],[do not compile bernstein])],
 312             [ with_bernstein=$withval],  [ with_bernstein=yes ])
 313 AC_MSG_RESULT($with_bernstein)
 314
 315 AC_ARG_WITH(ginac_prefix,
 316         [AS_HELP_STRING([--with-ginac-prefix=DIR],[Installation prefix of GiNaC])])
 317 if test "x$with_ginac_prefix" != "x"; then
 318         export PKG_CONFIG_PATH=$with_ginac_prefix/lib/pkgconfig:$PKG_CONFIG_PATH
 319 fi
 320
 321 AC_SUBST(bv_barvinok_bound)
 322 have_ginac=false
 323 if test "$with_bernstein" != "no"; then
 324         PKG_CHECK_EXISTS([ginac], [
 325                 PKG_CHECK_MODULES(ginac, ginac)
 326                 have_ginac=true
 327                 AC_DEFINE(HAVE_GINAC,[],[use GiNaC])
 328                 EXTRA_PACKAGE_LIBS="-lbernstein $EXTRA_PACKAGE_LIBS"
 329                 bv_barvinok_bound="barvinok_bound\$(EXEEXT) test_bound\$(EXEEXT)"
 330         ])
 331 fi
 332 AM_CONDITIONAL(HAVE_GINAC, test x$have_ginac = xtrue)
 333
 334 AC_MSG_CHECKING(whether to use Omega)
 335 AC_ARG_WITH(omega, [AS_HELP_STRING([--with-omega=DIR],[DIR Location of Omega])],
 336             [ omega_package=$withval],  [ omega_package=yes ])
 337 AC_MSG_RESULT($omega_package)
 338
 339 AC_SUBST(OMEGA_CPPFLAGS)
 340 AC_SUBST(OMEGA_LDFLAGS)
 341 AC_SUBST(OMEGA_LIBS)
 342 AC_SUBST(bv_omega_programs)
 343 have_omega=false
 344 if test "$omega_package" != "no"; then
 345     if test "x$omega_package" != "xyes"; then
 346         OMEGA_CPPFLAGS="-I$omega_package/include/omega"
 347         OMEGA_LDFLAGS="-L$omega_package/lib"
 348     else
 349         for i in /usr/include /usr/local/include; do
 350             if test -f $i/omega/omega.h; then
 351                 OMEGA_CPPFLAGS="-I$i/omega"
 352             fi
 353         done
 354     fi
 355
 356     AC_LANG_PUSH(C++)
 357     SAVE_CPPFLAGS="$CPPFLAGS"
 358     SAVE_LDFLAGS="$LDFLAGS"
 359     CPPFLAGS="$OMEGA_CPPFLAGS $CPPFLAGS"
 360     LDFLAGS="$OMEGA_LDFLAGS $LDFLAGS"
 361     AC_CHECK_HEADERS([omega.h],[
 362         if test x$have_ginac = xtrue; then
 363                 AC_CHECK_LIB(code_gen,main,[
 364                         bv_omega_programs="occ $bv_omega_programs"
 365                 ])
 366         fi
 367         AC_DEFINE(HAVE_OMEGA,[],[use omega])
 368         OMEGA_LIBS="-lomega"
 369         have_omega=true
 370     ],[AC_MSG_WARN(Omega not found)])
 371     CPPFLAGS="$SAVE_CPPFLAGS"
 372     LDFLAGS="$SAVE_LDFLAGS"
 373     AC_LANG_POP
 374 fi
 375 AM_CONDITIONAL(HAVE_OMEGA, test x$have_omega = xtrue)
 376
 377 use_parker=false
 378 AC_MSG_CHECKING(whether to compile parker)
 379 AC_ARG_WITH(parker,
 380             [AS_HELP_STRING([--without-zsolve],[do not compile zsolve])],
 381             [ with_parker=$withval],  [ with_parker=yes ])
 382 AC_MSG_RESULT($with_parker)
 383
 384 if test "$with_parker" != "no"; then
 385         AC_MSG_CHECKING(for mona)
 386         AC_ARG_WITH(mona,
 387                 [AS_HELP_STRING([--with-mona=DIR],[mona *source* directory])],
 388                                 [], [AC_MSG_RESULT(not specified)])
 389
 390         if test "x$with_mona" != "x"; then
 391                 AC_SUBST(MONAPATH)
 392                 MONAPATH=$with_mona
 393                 AC_MSG_RESULT($MONAPATH)
 394                 use_parker=true
 395                 AC_DEFINE(USE_PARKER,[],[use parker])
 396         fi
 397
 398         if test "x$with_mona" = "x"; then
 399                 AC_MSG_WARN(mona source directory required to compile parker)
 400                 AC_MSG_WARN(http://www.brics.dk/mona/download)
 401         fi
 402 fi
 403 AM_CONDITIONAL(USE_PARKER, test x$use_parker = xtrue)
 404
 405 AC_MSG_CHECKING(whether to use cddlib)
 406 AC_ARG_WITH(cddlib, [AS_HELP_STRING([--with-cddlib=DIR],[DIR Location of cddlib])],
 407             [ cddlib_package=$withval],  [ cddlib_package=yes ])
 408 AC_MSG_RESULT($cddlib_package)
 409
 410 have_cddlib=false
 411 if test "$cddlib_package" != "no"; then
 412     if test "x$cddlib_package" != "xyes"; then
 413         CPPFLAGS="-I$cddlib_package/include $CPPFLAGS"
 414         LDFLAGS="-L$cddlib_package/lib $LDFLAGS"
 415     fi
 416     AC_TRY_LINK([
 417 #define GMPRATIONAL
 418 #include <setoper.h>
 419 #include <cddmp.h>
 420 ], [
 421     mytype a;
 422     dd_init(a); ], [
 423         have_cddlib=true
 424         AC_CHECK_LIB(cddgmp, main,[
 425                 SAVE_LIBS="$LIBS"
 426                 LIBS="-lcddgmp $LIBS"
 427                 AC_DEFINE_UNQUOTED([SRCDIR], ["$srcdir"], [srcdir])
 428                 AC_LANG_PUSH(C++)
 429                 AC_RUN_IFELSE(AC_LANG_PROGRAM([[#define GMPRATIONAL
 430 #include <setoper.h>
 431 #include <cdd.h>]],
 432                 [[
 433         const char *filename = SRCDIR"/cdd94e-test";
 434         FILE *f;
 435         dd_MatrixPtr M;
 436         dd_LPType *lp;
 437         dd_ErrorType err = dd_NoError;
 438
 439         dd_set_global_constants();
 440
 441         f = fopen(filename, "r");
 442         M = dd_PolyFile2Matrix(f, &err);
 443         lp = dd_Matrix2LP(M, &err);
 444         dd_LPSolve(lp, dd_DualSimplex, &err);
 445         return lp->LPS == dd_Inconsistent;
 446                 ]]),[
 447                         AC_DEFINE(HAVE_LIBCDDGMP, [], [Define to 1 if you have the `cddgmp' library (-lcddgmp).])
 448                 ],[
 449                         AC_MSG_WARN(please upgrade cddlib to 0.94e or later)
 450                         LIBS="$SAVE_LIBS"
 451                         have_cddlib=false
 452                 ])
 453                 AC_LANG_POP
 454         ],[have_cddlib=false])
 455     ])
 456 fi
 457 AM_CONDITIONAL(HAVE_CDDLIB, test x$have_cddlib = xtrue)
 458
 459
 460
 461 AC_MSG_CHECKING(whether to use GLPK)
 462 AC_ARG_WITH(glpk, [AS_HELP_STRING([--with-glpk=DIR],[DIR Location of GLPK])],
 463             [ glpk_package=$withval],  [ glpk_package=yes ])
 464 AC_MSG_RESULT($glpk_package)
 465
 466 have_glpk=false
 467 if test "$glpk_package" != "no"; then
 468     if test "x$glpk_package" != "xyes"; then
 469         CPPFLAGS="-I$glpk_package/include $CPPFLAGS"
 470         LDFLAGS="-L$glpk_package/lib $LDFLAGS"
 471     fi
 472     AC_CHECK_HEADERS([glpk.h],[
 473         have_glpk=true
 474         AC_CHECK_LIB(glpk, main,[],[have_glpk=false])
 475     ])
 476 fi
 477 AM_CONDITIONAL(HAVE_GLPK, test x$have_glpk = xtrue)
 478
 479 AC_MSG_CHECKING(location of TOPCOM)
 480 AC_ARG_WITH(topcom, [AS_HELP_STRING([--with-topcom=DIR],[Location of TOPCOM])],
 481             [topcom_package=$withval], [topcom_package=unspecified])
 482 AC_MSG_RESULT($topcom_package)
 483 have_topcom=false
 484 if test "$topcom_package" != no; then
 485         topcom_path="$PATH"
 486         if test "$topcom_package" != unspecified; then
 487                 topcom_path="$topcom_package/bin"
 488         fi
 489         AC_PATH_PROG([POINTS2TRIANGS], [points2triangs], [], [$topcom_path])
 490         if test -n "$POINTS2TRIANGS"; then
 491                 have_topcom=true
 492                 AC_DEFINE_UNQUOTED(POINTS2TRIANGS_PATH, ["$POINTS2TRIANGS"],
 493                                     [Path of points2triangs])
 494         fi
 495 fi
 496 AM_CONDITIONAL(HAVE_TOPCOM, test x$have_topcom = xtrue)
 497
 498 AC_SUBST(GIT_HEAD_ID)
 499 AC_SUBST(GIT_HEAD)
 500 AC_SUBST(GIT_HEAD_VERSION)
 501 if test -f $srcdir/.git/HEAD; then
 502     GIT_HEAD="$srcdir/.git/index"
 503     GIT_REPO="$srcdir/.git"
 504     GIT_HEAD_ID=`GIT_DIR=$GIT_REPO git describe`
 505 elif test -f $srcdir/GIT_HEAD_ID; then
 506     GIT_HEAD_ID=`cat $srcdir/GIT_HEAD_ID`
 507 else
 508     mysrcdir=`(cd $srcdir; pwd)`
 509     head=`basename $mysrcdir | sed -e 's/.*-//'`
 510     head2=`echo $head | sed -e 's/[^0-9a-f]//'`
 511     head3=`echo $head2 | sed -e 's/........................................//'`
 512     base=`basename $mysrcdir | sed -e 's/-.*//'`
 513     if test "x$head3" = "x" -a "x$head" = "x$head2"; then
 514         GIT_HEAD_ID="barvinok-$VERSION-$head
 515     elif test "x$base" = "xbarvinok-$VERSION" -a "x$head" != "x"; then
 516         GIT_HEAD_ID="barvinok-$VERSION-$head
 517     else
 518         GIT_HEAD_ID="UNKNOWN"
 519     fi
 520 fi
 521 if test -z "$GIT_REPO" ; then
 522     GIT_HEAD_VERSION="$GIT_HEAD_ID"
 523 else
 524     GIT_HEAD_VERSION="\`GIT_DIR=$GIT_REPO git describe\`"
 525 fi
 526 echo '#define GIT_HEAD_ID "'$GIT_HEAD_ID'"' > version.h
 527
 528 AC_LANG_PUSH(C++)
 529 AC_TRY_COMPILE([
 530                 #include <set>
 531                 void negate();
 532         ], [negate()],
 533         suffix="normal", suffix="broken")
 534 AC_CONFIG_COMMANDS([barvinok/set.h],
 535                    [cp $srcdir/barvinok/set.h.$suffix barvinok/set.h],
 536                    [suffix="$suffix"])
 537 AC_CONFIG_COMMANDS([barvinok/NTL.h],
 538                    [cp $srcdir/barvinok/NTL.h.$suffix barvinok/NTL.h],
 539                    [suffix="$suffix"])
 540 use_fdstream=false
 541 SAVE_CPPFLAGS="$CPPFLAGS"
 542 CPPFLAGS="-I$srcdir $CPPFLAGS"
 543 AC_TRY_COMPILE([#include "fdstream.h"],[],
 544         [AC_DEFINE(USE_FDSTREAM,[],[use fdstream])
 545         use_fdstream=true])
 546 CPPFLAGS="$SAVE_CPPFLAGS"
 547 AC_LANG_POP
 548 AM_CONDITIONAL(USE_FDSTREAM, [test "$use_fdstream" = true])
 549
 550 PACKAGE_LIBS="-lbarvinok -lbarvinok-core $EXTRA_PACKAGE_LIBS -lpolylibgmp -lpiplibMP"
 551 AX_CREATE_PKGCONFIG_INFO
 552
 553 AC_CONFIG_HEADERS(config.h)
 554 AC_CONFIG_FILES(Makefile lib/Makefile zsolve/Makefile doc/Makefile omega/Makefile)
 555 AC_CONFIG_FILES(parker/Makefile)
 556 if test $with_polylib = bundled; then
 557         AC_CONFIG_SUBDIRS(polylib)
 558 fi
 559 if test $with_piplib = bundled; then
 560         AC_CONFIG_SUBDIRS(piplib)
 561 fi
 562 if test x$have_ginac = xtrue; then
 563     AC_CONFIG_SUBDIRS(bernstein)
 564 fi
 565 AC_CONFIG_COMMANDS_POST([
 566         dnl pass on arguments to subdir configures, but don't
 567         dnl add them to config.status
 568         ac_configure_args="$ac_configure_args $bv_configure_args"
 569 ])
 570 AC_OUTPUT