awesomeConfig.cmake

   1 set(PROJECT_AWE_NAME awesome)
   2
   3 # If ${SOURCE_DIR} is a git repository VERSION is set to
   4 # `git describe` later.
   5 set(VERSION devel)
   6
   7 set(CODENAME "Ruby Tuesday")
   8
   9 project(${PROJECT_AWE_NAME} C)
  10
  11 set(CMAKE_BUILD_TYPE RELEASE)
  12
  13 option(WITH_DBUS "build with D-BUS" ON)
  14 option(GENERATE_MANPAGES "generate manpages" ON)
  15 option(COMPRESS_MANPAGES "compress manpages" ON)
  16 option(GENERATE_DOC "generate API documentation" ON)
  17
  18 # {{{ CFLAGS
  19 add_definitions(-O1 -std=gnu99 -ggdb3 -rdynamic -fno-strict-aliasing -Wall -Wextra
  20     -Wchar-subscripts -Wundef -Wshadow -Wcast-align -Wwrite-strings
  21     -Wsign-compare -Wunused -Wno-unused-parameter -Wuninitialized -Winit-self
  22     -Wpointer-arith -Wformat-nonliteral
  23     -Wno-format-zero-length -Wmissing-format-attribute -Wmissing-prototypes
  24     -Wstrict-prototypes)
  25 # }}}
  26
  27 # {{{ Endianness
  28 include(TestBigEndian)
  29 TEST_BIG_ENDIAN(AWESOME_IS_BIG_ENDIAN)
  30 # }}}
  31
  32 # {{{ Find external utilities
  33 macro(a_find_program var prg req)
  34     set(required ${req})
  35     find_program(${var} ${prg})
  36     if(NOT ${var})
  37         message(STATUS "${prg} not found.")
  38         if(required)
  39             message(FATAL_ERROR "${prg} is required to build awesome")
  40         endif()
  41     else()
  42         message(STATUS "${prg} -> ${${var}}")
  43     endif()
  44 endmacro()
  45
  46 a_find_program(CAT_EXECUTABLE cat TRUE)
  47 a_find_program(LN_EXECUTABLE ln TRUE)
  48 a_find_program(GREP_EXECUTABLE grep TRUE)
  49 a_find_program(GIT_EXECUTABLE git FALSE)
  50 a_find_program(HOSTNAME_EXECUTABLE hostname FALSE)
  51 # programs needed for man pages
  52 a_find_program(ASCIIDOC_EXECUTABLE asciidoc FALSE)
  53 a_find_program(XMLTO_EXECUTABLE xmlto FALSE)
  54 a_find_program(GZIP_EXECUTABLE gzip FALSE)
  55 # lua documentation
  56 a_find_program(LUA_EXECUTABLE lua FALSE)
  57 a_find_program(LDOC_EXECUTABLE ldoc.lua FALSE)
  58 # theme graphics
  59 a_find_program(CONVERT_EXECUTABLE convert TRUE)
  60 # doxygen
  61 include(FindDoxygen)
  62 # pkg-config
  63 include(FindPkgConfig)
  64 # lua 5.1
  65 include(FindLua51)
  66 # }}}
  67
  68 # {{{ Check if documentation can be build
  69 if(GENERATE_MANPAGES)
  70     if(NOT ASCIIDOC_EXECUTABLE OR NOT XMLTO_EXECUTABLE OR (COMPRESS_MANPAGES AND NOT GZIP_EXECUTABLE))
  71         if(NOT ASCIIDOC_EXECUTABLE)
  72             SET(missing "asciidoc")
  73         endif()
  74         if(NOT XMLTO_EXECUTABLE)
  75             SET(missing ${missing} " xmlto")
  76         endif()
  77         if(COMPRESS_MANPAGES AND NOT GZIP_EXECUTABLE)
  78             SET(missing ${missing} " gzip")
  79         endif()
  80
  81         message(STATUS "Not generating manpages. Missing: " ${missing})
  82         set(GENERATE_MANPAGES OFF)
  83     endif()
  84 endif()
  85
  86 if(GENERATE_DOC)
  87     if(NOT LDOC_EXECUTABLE)
  88         message(STATUS "Not generating API documentation. Missing: ldoc")
  89         set(GENERATE_DOC OFF)
  90     endif()
  91 endif()
  92 # }}}
  93
  94 # {{{ Version stamp
  95 if(EXISTS ${SOURCE_DIR}/.git/HEAD AND GIT_EXECUTABLE)
  96     # get current version
  97     execute_process(
  98         COMMAND ${GIT_EXECUTABLE} describe
  99         WORKING_DIRECTORY ${SOURCE_DIR}
 100         OUTPUT_VARIABLE VERSION
 101         OUTPUT_STRIP_TRAILING_WHITESPACE)
 102     # file the git-version-stamp.sh script will look into
 103     set(VERSION_STAMP_FILE ${BUILD_DIR}/.version_stamp)
 104     file(WRITE ${VERSION_STAMP_FILE} ${VERSION})
 105     # create a version_stamp target later
 106     set(BUILD_FROM_GIT TRUE)
 107 elseif( EXISTS ${SOURCE_DIR}/.version_stamp )
 108     # get version from version stamp
 109     file(READ ${SOURCE_DIR}/.version_stamp VERSION)
 110 endif()
 111 # }}}
 112
 113 # {{{ Get hostname
 114 execute_process(
 115     COMMAND ${HOSTNAME_EXECUTABLE}
 116     WORKING_DIRECTORY ${SOURCE_DIR}
 117     OUTPUT_VARIABLE BUILDHOSTNAME
 118     OUTPUT_STRIP_TRAILING_WHITESPACE)
 119 # }}}
 120
 121 # {{{ Required libraries
 122 #
 123 # this sets up:
 124 # AWESOME_REQUIRED_LDFLAGS
 125 # AWESOME_REQUIRED_INCLUDE_DIRS
 126
 127 # Use pkgconfig to get most of the libraries
 128 pkg_check_modules(AWESOME_COMMON_REQUIRED REQUIRED
 129     xcb>=1.6)
 130
 131 pkg_check_modules(AWESOME_REQUIRED REQUIRED
 132     glib-2.0
 133     gdk-pixbuf-2.0
 134     cairo
 135     x11
 136     xcb-cursor
 137     xcb-randr
 138     xcb-xtest
 139     xcb-xinerama
 140     xcb-shape
 141     xcb-util>=0.3.8
 142     xcb-keysyms>=0.3.4
 143     xcb-icccm>=0.3.8
 144     cairo-xcb
 145     libstartup-notification-1.0>=0.10
 146     xproto>=7.0.15
 147     libxdg-basedir>=1.0.0)
 148
 149 if(NOT AWESOME_REQUIRED_FOUND OR NOT AWESOME_COMMON_REQUIRED_FOUND)
 150     message(FATAL_ERROR)
 151 endif()
 152
 153 macro(a_find_library variable library)
 154     find_library(${variable} ${library})
 155     if(NOT ${variable})
 156         message(FATAL_ERROR ${library} " library not found.")
 157     endif()
 158 endmacro()
 159
 160 # Check for backtrace_symbols()
 161 include(CheckFunctionExists)
 162 check_function_exists(backtrace_symbols HAS_EXECINFO)
 163 if(NOT HAS_EXECINFO)
 164     find_library(LIB_EXECINFO execinfo)
 165     if(LIB_EXECINFO)
 166         set(HAS_EXECINFO 1)
 167         set(AWESOME_REQUIRED_LDFLAGS
 168             ${AWESOME_REQUIRED_LDFLAGS}
 169             ${LIB_EXECINFO})
 170     endif()
 171 endif()
 172 if(HAS_EXECINFO)
 173     message(STATUS "checking for execinfo -- found")
 174 else()
 175     message(STATUS "checking for execinfo -- not found")
 176 endif()
 177
 178 # __builtin_clz is available since gcc 3.4
 179 try_compile(HAS___BUILTIN_CLZ
 180     ${CMAKE_BINARY_DIR}
 181     ${CMAKE_SOURCE_DIR}/build-tests/__builtin_clz.c)
 182 if(HAS___BUILTIN_CLZ)
 183     message(STATUS "checking for __builtin_clz -- yes")
 184 else()
 185     message(STATUS "checking for __builtin_clz -- no")
 186 endif()
 187
 188 # Error check
 189 if(NOT LUA51_FOUND AND NOT LUA50_FOUND) # This is a workaround to a cmake bug
 190     message(FATAL_ERROR "lua library not found")
 191 endif()
 192
 193 set(AWESOME_REQUIRED_LDFLAGS
 194     ${AWESOME_COMMON_REQUIRED_LDFLAGS}
 195     ${AWESOME_REQUIRED_LDFLAGS}
 196     ${LUA_LIBRARIES})
 197
 198 set(AWESOME_REQUIRED_INCLUDE_DIRS
 199     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
 200     ${AWESOME_REQUIRED_INCLUDE_DIRS}
 201     ${LUA_INCLUDE_DIR})
 202 # }}}
 203
 204 # {{{ Optional libraries
 205 #
 206 # this sets up:
 207 # AWESOME_OPTIONAL_LDFLAGS
 208 # AWESOME_OPTIONAL_INCLUDE_DIRS
 209
 210 if(WITH_DBUS)
 211     pkg_check_modules(DBUS dbus-1)
 212     if(DBUS_FOUND)
 213         set(AWESOME_OPTIONAL_LDFLAGS ${AWESOME_OPTIONAL_LDFLAGS} ${DBUS_LDFLAGS})
 214         set(AWESOME_OPTIONAL_INCLUDE_DIRS ${AWESOME_OPTIONAL_INCLUDE_DIRS} ${DBUS_INCLUDE_DIRS})
 215     else()
 216         set(WITH_DBUS OFF)
 217         message(STATUS "DBUS not found. Disabled.")
 218     endif()
 219 endif()
 220 # }}}
 221
 222 # {{{ Install path and configuration variables
 223 #If a sysconfdir is specified, use it instead
 224 #of the default configuration dir.
 225 if(DEFINED SYSCONFDIR)
 226     set(SYSCONFDIR ${SYSCONFDIR} CACHE PATH "config directory")
 227 else()
 228     set(SYSCONFDIR ${CMAKE_INSTALL_PREFIX}/etc CACHE PATH "config directory")
 229 endif()
 230
 231 #If an XDG Config Dir is specificed, use it instead
 232 #of the default XDG configuration dir.
 233 if(DEFINED XDG_CONFIG_DIR)
 234     set(XDG_CONFIG_DIR ${XDG_CONFIG_DIR} CACHE PATH "xdg config directory")
 235 else()
 236     set(XDG_CONFIG_DIR ${SYSCONFDIR}/xdg CACHE PATH "xdg config directory")
 237 endif()
 238
 239 # setting AWESOME_DOC_PATH
 240 if(DEFINED AWESOME_DOC_PATH)
 241     set(AWESOME_DOC_PATH ${AWESOME_DOC_PATH} CACHE PATH "awesome docs directory")
 242 else()
 243     set(AWESOME_DOC_PATH ${CMAKE_INSTALL_PREFIX}/share/doc/${PROJECT_AWE_NAME} CACHE PATH "awesome docs directory")
 244 endif()
 245
 246 # setting AWESOME_XSESSION_PATH
 247 if(DEFINED AWESOME_XSESSION_PATH)
 248     set(AWESOME_XSESSION_PATH ${AWESOME_XSESSION_PATH} CACHE PATH "awesome xsessions directory")
 249 else()
 250     set(AWESOME_XSESSION_PATH ${CMAKE_INSTALL_PREFIX}/share/xsessions CACHE PATH "awesome xsessions directory")
 251 endif()
 252
 253 # set man path
 254 if(DEFINED AWESOME_MAN_PATH)
 255    set(AWESOME_MAN_PATH ${AWESOME_MAN_PATH} CACHE PATH "awesome manpage directory")
 256 else()
 257    set(AWESOME_MAN_PATH ${CMAKE_INSTALL_PREFIX}/share/man CACHE PATH "awesome manpage directory")
 258 endif()
 259
 260 # Hide to avoid confusion
 261 mark_as_advanced(CMAKE_INSTALL_CMAKE_INSTALL_PREFIX)
 262
 263 set(AWESOME_VERSION          ${VERSION})
 264 set(AWESOME_COMPILE_MACHINE  ${CMAKE_SYSTEM_PROCESSOR})
 265 set(AWESOME_COMPILE_HOSTNAME ${BUILDHOSTNAME})
 266 set(AWESOME_COMPILE_BY       $ENV{USER})
 267 set(AWESOME_RELEASE          ${CODENAME})
 268 set(AWESOME_SYSCONFDIR       ${XDG_CONFIG_DIR}/${PROJECT_AWE_NAME})
 269 set(AWESOME_DATA_PATH        ${CMAKE_INSTALL_PREFIX}/share/${PROJECT_AWE_NAME})
 270 set(AWESOME_LUA_LIB_PATH     ${AWESOME_DATA_PATH}/lib)
 271 set(AWESOME_ICON_PATH        ${AWESOME_DATA_PATH}/icons)
 272 set(AWESOME_THEMES_PATH      ${AWESOME_DATA_PATH}/themes)
 273 # }}}
 274
 275 # {{{ Configure files
 276 file(GLOB_RECURSE awesome_lua_configure_files RELATIVE ${SOURCE_DIR} ${SOURCE_DIR}/lib/*.lua.in ${SOURCE_DIR}/themes/*/*.lua.in)
 277 set(AWESOME_CONFIGURE_FILES
 278     ${awesome_lua_configure_files}
 279     config.h.in
 280     config.ld.in
 281     awesomerc.lua.in
 282     awesome-version-internal.h.in
 283     awesome.doxygen.in)
 284
 285 macro(a_configure_file file)
 286     string(REGEX REPLACE ".in\$" "" outfile ${file})
 287     message(STATUS "Configuring ${outfile}")
 288     configure_file(${SOURCE_DIR}/${file}
 289                    ${BUILD_DIR}/${outfile}
 290                    ESCAPE_QUOTE
 291                    @ONLY)
 292 endmacro()
 293
 294 foreach(file ${AWESOME_CONFIGURE_FILES})
 295     a_configure_file(${file})
 296 endforeach()
 297 #}}}
 298
 299 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:textwidth=80