awesomeConfig.cmake

   1 set(PROJECT_AWE_NAME awesome)
   2
   3 # If ${SOURCE_DIR} is a git repository VERSION is set to
   4 # `git describe` later.
   5 set(VERSION devel)
   6
   7 set(CODENAME "The Fox")
   8
   9 project(${PROJECT_AWE_NAME} C)
  10
  11 set(CMAKE_BUILD_TYPE RELEASE)
  12
  13 option(WITH_DBUS "build with D-BUS" ON)
  14 option(GENERATE_MANPAGES "generate manpages" ON)
  15 option(COMPRESS_MANPAGES "compress manpages" ON)
  16 option(GENERATE_DOC "generate API documentation" ON)
  17
  18 # {{{ CFLAGS
  19 add_definitions(-O1 -std=gnu99 -ggdb3 -rdynamic -fno-strict-aliasing -Wall -Wextra
  20     -Wchar-subscripts -Wundef -Wshadow -Wcast-align -Wwrite-strings
  21     -Wsign-compare -Wunused -Wno-unused-parameter -Wuninitialized -Winit-self
  22     -Wpointer-arith -Wformat-nonliteral
  23     -Wno-format-zero-length -Wmissing-format-attribute -Wmissing-prototypes
  24     -Wstrict-prototypes)
  25 # }}}
  26
  27 # {{{ Endianness
  28 include(TestBigEndian)
  29 TEST_BIG_ENDIAN(AWESOME_IS_BIG_ENDIAN)
  30 # }}}
  31
  32 # {{{ Find external utilities
  33 macro(a_find_program var prg req)
  34     set(required ${req})
  35     find_program(${var} ${prg})
  36     if(NOT ${var})
  37         message(STATUS "${prg} not found.")
  38         if(required)
  39             message(FATAL_ERROR "${prg} is required to build awesome")
  40         endif()
  41     else()
  42         message(STATUS "${prg} -> ${${var}}")
  43     endif()
  44 endmacro()
  45
  46 a_find_program(CAT_EXECUTABLE cat TRUE)
  47 a_find_program(LN_EXECUTABLE ln TRUE)
  48 a_find_program(GREP_EXECUTABLE grep TRUE)
  49 a_find_program(GIT_EXECUTABLE git FALSE)
  50 a_find_program(HOSTNAME_EXECUTABLE hostname FALSE)
  51 # programs needed for man pages
  52 a_find_program(ASCIIDOC_EXECUTABLE asciidoc FALSE)
  53 a_find_program(XMLTO_EXECUTABLE xmlto FALSE)
  54 a_find_program(GZIP_EXECUTABLE gzip FALSE)
  55 # lua documentation
  56 a_find_program(LUA_EXECUTABLE lua FALSE)
  57 a_find_program(LDOC_EXECUTABLE ldoc FALSE)
  58 if(NOT LDOC_EXECUTABLE)
  59     a_find_program(LDOC_EXECUTABLE ldoc.lua FALSE)
  60 endif()
  61 # theme graphics
  62 a_find_program(CONVERT_EXECUTABLE convert TRUE)
  63 # doxygen
  64 include(FindDoxygen)
  65 # pkg-config
  66 include(FindPkgConfig)
  67 # lua 5.1
  68 include(FindLua51)
  69 # }}}
  70
  71 # {{{ Check if documentation can be build
  72 if(GENERATE_MANPAGES)
  73     if(NOT ASCIIDOC_EXECUTABLE OR NOT XMLTO_EXECUTABLE OR (COMPRESS_MANPAGES AND NOT GZIP_EXECUTABLE))
  74         if(NOT ASCIIDOC_EXECUTABLE)
  75             SET(missing "asciidoc")
  76         endif()
  77         if(NOT XMLTO_EXECUTABLE)
  78             SET(missing ${missing} " xmlto")
  79         endif()
  80         if(COMPRESS_MANPAGES AND NOT GZIP_EXECUTABLE)
  81             SET(missing ${missing} " gzip")
  82         endif()
  83
  84         message(STATUS "Not generating manpages. Missing: " ${missing})
  85         set(GENERATE_MANPAGES OFF)
  86     endif()
  87 endif()
  88
  89 if(GENERATE_DOC)
  90     if(NOT LDOC_EXECUTABLE)
  91         message(STATUS "Not generating API documentation. Missing: ldoc")
  92         set(GENERATE_DOC OFF)
  93     endif()
  94 endif()
  95 # }}}
  96
  97 # {{{ Version stamp
  98 if(EXISTS ${SOURCE_DIR}/.git/HEAD AND GIT_EXECUTABLE)
  99     # get current version
 100     execute_process(
 101         COMMAND ${GIT_EXECUTABLE} describe
 102         WORKING_DIRECTORY ${SOURCE_DIR}
 103         OUTPUT_VARIABLE VERSION
 104         OUTPUT_STRIP_TRAILING_WHITESPACE)
 105     # file the git-version-stamp.sh script will look into
 106     set(VERSION_STAMP_FILE ${BUILD_DIR}/.version_stamp)
 107     file(WRITE ${VERSION_STAMP_FILE} ${VERSION})
 108     # create a version_stamp target later
 109     set(BUILD_FROM_GIT TRUE)
 110 elseif( EXISTS ${SOURCE_DIR}/.version_stamp )
 111     # get version from version stamp
 112     file(READ ${SOURCE_DIR}/.version_stamp VERSION)
 113 endif()
 114 # }}}
 115
 116 # {{{ Get hostname
 117 execute_process(
 118     COMMAND ${HOSTNAME_EXECUTABLE}
 119     WORKING_DIRECTORY ${SOURCE_DIR}
 120     OUTPUT_VARIABLE BUILDHOSTNAME
 121     OUTPUT_STRIP_TRAILING_WHITESPACE)
 122 # }}}
 123
 124 # {{{ Required libraries
 125 #
 126 # this sets up:
 127 # AWESOME_REQUIRED_LDFLAGS
 128 # AWESOME_REQUIRED_INCLUDE_DIRS
 129
 130 # Use pkgconfig to get most of the libraries
 131 pkg_check_modules(AWESOME_COMMON_REQUIRED REQUIRED
 132     xcb>=1.6)
 133
 134 pkg_check_modules(AWESOME_REQUIRED REQUIRED
 135     glib-2.0
 136     gdk-pixbuf-2.0
 137     cairo
 138     x11
 139     xcb-cursor
 140     xcb-randr
 141     xcb-xtest
 142     xcb-xinerama
 143     xcb-shape
 144     xcb-util>=0.3.8
 145     xcb-keysyms>=0.3.4
 146     xcb-icccm>=0.3.8
 147     cairo-xcb
 148     libstartup-notification-1.0>=0.10
 149     xproto>=7.0.15
 150     libxdg-basedir>=1.0.0)
 151
 152 if(NOT AWESOME_REQUIRED_FOUND OR NOT AWESOME_COMMON_REQUIRED_FOUND)
 153     message(FATAL_ERROR)
 154 endif()
 155
 156 macro(a_find_library variable library)
 157     find_library(${variable} ${library})
 158     if(NOT ${variable})
 159         message(FATAL_ERROR ${library} " library not found.")
 160     endif()
 161 endmacro()
 162
 163 # Check for backtrace_symbols()
 164 include(CheckFunctionExists)
 165 check_function_exists(backtrace_symbols HAS_EXECINFO)
 166 if(NOT HAS_EXECINFO)
 167     find_library(LIB_EXECINFO execinfo)
 168     if(LIB_EXECINFO)
 169         set(HAS_EXECINFO 1)
 170         set(AWESOME_REQUIRED_LDFLAGS
 171             ${AWESOME_REQUIRED_LDFLAGS}
 172             ${LIB_EXECINFO})
 173     endif()
 174 endif()
 175 if(HAS_EXECINFO)
 176     message(STATUS "checking for execinfo -- found")
 177 else()
 178     message(STATUS "checking for execinfo -- not found")
 179 endif()
 180
 181 # __builtin_clz is available since gcc 3.4
 182 try_compile(HAS___BUILTIN_CLZ
 183     ${CMAKE_BINARY_DIR}
 184     ${CMAKE_SOURCE_DIR}/build-tests/__builtin_clz.c)
 185 if(HAS___BUILTIN_CLZ)
 186     message(STATUS "checking for __builtin_clz -- yes")
 187 else()
 188     message(STATUS "checking for __builtin_clz -- no")
 189 endif()
 190
 191 # Error check
 192 if(NOT LUA51_FOUND AND NOT LUA50_FOUND) # This is a workaround to a cmake bug
 193     message(FATAL_ERROR "lua library not found")
 194 endif()
 195
 196 set(AWESOME_REQUIRED_LDFLAGS
 197     ${AWESOME_COMMON_REQUIRED_LDFLAGS}
 198     ${AWESOME_REQUIRED_LDFLAGS}
 199     ${LUA_LIBRARIES})
 200
 201 set(AWESOME_REQUIRED_INCLUDE_DIRS
 202     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
 203     ${AWESOME_REQUIRED_INCLUDE_DIRS}
 204     ${LUA_INCLUDE_DIR})
 205 # }}}
 206
 207 # {{{ Optional libraries
 208 #
 209 # this sets up:
 210 # AWESOME_OPTIONAL_LDFLAGS
 211 # AWESOME_OPTIONAL_INCLUDE_DIRS
 212
 213 if(WITH_DBUS)
 214     pkg_check_modules(DBUS dbus-1)
 215     if(DBUS_FOUND)
 216         set(AWESOME_OPTIONAL_LDFLAGS ${AWESOME_OPTIONAL_LDFLAGS} ${DBUS_LDFLAGS})
 217         set(AWESOME_OPTIONAL_INCLUDE_DIRS ${AWESOME_OPTIONAL_INCLUDE_DIRS} ${DBUS_INCLUDE_DIRS})
 218     else()
 219         set(WITH_DBUS OFF)
 220         message(STATUS "DBUS not found. Disabled.")
 221     endif()
 222 endif()
 223 # }}}
 224
 225 # {{{ Install path and configuration variables
 226 #If a sysconfdir is specified, use it instead
 227 #of the default configuration dir.
 228 if(DEFINED SYSCONFDIR)
 229     set(SYSCONFDIR ${SYSCONFDIR} CACHE PATH "config directory")
 230 else()
 231     set(SYSCONFDIR ${CMAKE_INSTALL_PREFIX}/etc CACHE PATH "config directory")
 232 endif()
 233
 234 #If an XDG Config Dir is specificed, use it instead
 235 #of the default XDG configuration dir.
 236 if(DEFINED XDG_CONFIG_DIR)
 237     set(XDG_CONFIG_DIR ${XDG_CONFIG_DIR} CACHE PATH "xdg config directory")
 238 else()
 239     set(XDG_CONFIG_DIR ${SYSCONFDIR}/xdg CACHE PATH "xdg config directory")
 240 endif()
 241
 242 # setting AWESOME_DOC_PATH
 243 if(DEFINED AWESOME_DOC_PATH)
 244     set(AWESOME_DOC_PATH ${AWESOME_DOC_PATH} CACHE PATH "awesome docs directory")
 245 else()
 246     set(AWESOME_DOC_PATH ${CMAKE_INSTALL_PREFIX}/share/doc/${PROJECT_AWE_NAME} CACHE PATH "awesome docs directory")
 247 endif()
 248
 249 # setting AWESOME_XSESSION_PATH
 250 if(DEFINED AWESOME_XSESSION_PATH)
 251     set(AWESOME_XSESSION_PATH ${AWESOME_XSESSION_PATH} CACHE PATH "awesome xsessions directory")
 252 else()
 253     set(AWESOME_XSESSION_PATH ${CMAKE_INSTALL_PREFIX}/share/xsessions CACHE PATH "awesome xsessions directory")
 254 endif()
 255
 256 # set man path
 257 if(DEFINED AWESOME_MAN_PATH)
 258    set(AWESOME_MAN_PATH ${AWESOME_MAN_PATH} CACHE PATH "awesome manpage directory")
 259 else()
 260    set(AWESOME_MAN_PATH ${CMAKE_INSTALL_PREFIX}/share/man CACHE PATH "awesome manpage directory")
 261 endif()
 262
 263 # Hide to avoid confusion
 264 mark_as_advanced(CMAKE_INSTALL_CMAKE_INSTALL_PREFIX)
 265
 266 set(AWESOME_VERSION          ${VERSION})
 267 set(AWESOME_COMPILE_MACHINE  ${CMAKE_SYSTEM_PROCESSOR})
 268 set(AWESOME_COMPILE_HOSTNAME ${BUILDHOSTNAME})
 269 set(AWESOME_COMPILE_BY       $ENV{USER})
 270 set(AWESOME_RELEASE          ${CODENAME})
 271 set(AWESOME_SYSCONFDIR       ${XDG_CONFIG_DIR}/${PROJECT_AWE_NAME})
 272 set(AWESOME_DATA_PATH        ${CMAKE_INSTALL_PREFIX}/share/${PROJECT_AWE_NAME})
 273 set(AWESOME_LUA_LIB_PATH     ${AWESOME_DATA_PATH}/lib)
 274 set(AWESOME_ICON_PATH        ${AWESOME_DATA_PATH}/icons)
 275 set(AWESOME_THEMES_PATH      ${AWESOME_DATA_PATH}/themes)
 276 # }}}
 277
 278 # {{{ Configure files
 279 file(GLOB_RECURSE awesome_lua_configure_files RELATIVE ${SOURCE_DIR} ${SOURCE_DIR}/lib/*.lua.in ${SOURCE_DIR}/themes/*/*.lua.in)
 280 set(AWESOME_CONFIGURE_FILES
 281     ${awesome_lua_configure_files}
 282     config.h.in
 283     config.ld.in
 284     awesomerc.lua.in
 285     awesome-version-internal.h.in
 286     awesome.doxygen.in)
 287
 288 macro(a_configure_file file)
 289     string(REGEX REPLACE ".in\$" "" outfile ${file})
 290     message(STATUS "Configuring ${outfile}")
 291     configure_file(${SOURCE_DIR}/${file}
 292                    ${BUILD_DIR}/${outfile}
 293                    ESCAPE_QUOTE
 294                    @ONLY)
 295 endmacro()
 296
 297 foreach(file ${AWESOME_CONFIGURE_FILES})
 298     a_configure_file(${file})
 299 endforeach()
 300 #}}}
 301
 302 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:textwidth=80