awesomeConfig.cmake

   1 set(PROJECT_AWE_NAME awesome)
   2
   3 # If ${SOURCE_DIR} is a git repository VERSION is set to
   4 # `git describe` later.
   5 set(VERSION devel)
   6
   7 set(CODENAME "White Christmas")
   8
   9 project(${PROJECT_AWE_NAME} C)
  10
  11 set(CMAKE_BUILD_TYPE RELEASE)
  12
  13 option(WITH_DBUS "build with D-BUS" ON)
  14 option(GENERATE_MANPAGES "generate manpages" ON)
  15 option(COMPRESS_MANPAGES "compress manpages" ON)
  16 option(GENERATE_LUADOC "generate luadoc" ON)
  17
  18 # {{{ CFLAGS
  19 add_definitions(-std=gnu99 -ggdb3 -fno-strict-aliasing -Wall -Wextra
  20     -Wchar-subscripts -Wundef -Wshadow -Wcast-align -Wwrite-strings
  21     -Wsign-compare -Wunused -Wno-unused-parameter -Wuninitialized -Winit-self
  22     -Wpointer-arith -Wredundant-decls -Wformat-nonliteral
  23     -Wno-format-zero-length -Wmissing-format-attribute -Wmissing-prototypes
  24     -Wstrict-prototypes)
  25 # }}}
  26
  27 # {{{ Endianness
  28 include(TestBigEndian)
  29 TEST_BIG_ENDIAN(AWESOME_IS_BIG_ENDIAN)
  30 # }}}
  31
  32 # {{{ Find external utilities
  33 macro(a_find_program var prg req)
  34     set(required ${req})
  35     find_program(${var} ${prg})
  36     if(NOT ${var})
  37         message(STATUS "${prg} not found.")
  38         if(required)
  39             message(FATAL_ERROR "${prg} is required to build awesome")
  40         endif()
  41     else()
  42         message(STATUS "${prg} -> ${${var}}")
  43     endif()
  44 endmacro()
  45
  46 a_find_program(CAT_EXECUTABLE cat TRUE)
  47 a_find_program(LN_EXECUTABLE ln TRUE)
  48 a_find_program(GREP_EXECUTABLE grep TRUE)
  49 a_find_program(GIT_EXECUTABLE git FALSE)
  50 a_find_program(HOSTNAME_EXECUTABLE hostname FALSE)
  51 a_find_program(GPERF_EXECUTABLE gperf TRUE)
  52 # programs needed for man pages
  53 a_find_program(ASCIIDOC_EXECUTABLE asciidoc FALSE)
  54 a_find_program(XMLTO_EXECUTABLE xmlto FALSE)
  55 a_find_program(GZIP_EXECUTABLE gzip FALSE)
  56 # lua documentation
  57 a_find_program(LUA_EXECUTABLE lua FALSE)
  58 a_find_program(LUADOC_EXECUTABLE luadoc FALSE)
  59 # theme graphics
  60 a_find_program(CONVERT_EXECUTABLE convert TRUE)
  61 # doxygen
  62 include(FindDoxygen)
  63 # pkg-config
  64 include(FindPkgConfig)
  65 # lua 5.1
  66 include(FindLua51)
  67 # }}}
  68
  69 # {{{ Check if documentation can be build
  70 if(GENERATE_MANPAGES)
  71     if(NOT ASCIIDOC_EXECUTABLE OR NOT XMLTO_EXECUTABLE OR (COMPRESS_MANPAGES AND NOT GZIP_EXECUTABLE))
  72         if(NOT ASCIIDOC_EXECUTABLE)
  73             SET(missing "asciidoc")
  74         endif()
  75         if(NOT XMLTO_EXECUTABLE)
  76             SET(missing ${missing} " xmlto")
  77         endif()
  78         if(COMPRESS_MANPAGES AND NOT GZIP_EXECUTABLE)
  79             SET(missing ${missing} " gzip")
  80         endif()
  81
  82         message(STATUS "Not generating manpages. Missing: " ${missing})
  83         set(GENERATE_MANPAGES OFF)
  84     endif()
  85 endif()
  86
  87 if(GENERATE_LUADOC)
  88     if(NOT LUADOC_EXECUTABLE)
  89         message(STATUS "Not generating luadoc. Missing: luadoc")
  90         set(GENERATE_LUADOC OFF)
  91     endif()
  92 endif()
  93 # }}}
  94
  95 # {{{ Version stamp
  96 if(EXISTS ${SOURCE_DIR}/.git/HEAD AND GIT_EXECUTABLE)
  97     # get current version
  98     execute_process(
  99         COMMAND ${GIT_EXECUTABLE} describe
 100         WORKING_DIRECTORY ${SOURCE_DIR}
 101         OUTPUT_VARIABLE VERSION
 102         OUTPUT_STRIP_TRAILING_WHITESPACE)
 103     # file the git-version-stamp.sh script will look into
 104     set(VERSION_STAMP_FILE ${BUILD_DIR}/.version_stamp)
 105     file(WRITE ${VERSION_STAMP_FILE} ${VERSION})
 106     # create a version_stamp target later
 107     set(BUILD_FROM_GIT TRUE)
 108 elseif( EXISTS ${SOURCE_DIR}/.version_stamp )
 109     # get version from version stamp
 110     file(READ ${SOURCE_DIR}/.version_stamp VERSION)
 111 endif()
 112 # }}}
 113
 114 # {{{ Get hostname
 115 execute_process(
 116     COMMAND ${HOSTNAME_EXECUTABLE}
 117     WORKING_DIRECTORY ${SOURCE_DIR}
 118     OUTPUT_VARIABLE BUILDHOSTNAME
 119     OUTPUT_STRIP_TRAILING_WHITESPACE)
 120 # }}}
 121
 122 # {{{ Required libraries
 123 #
 124 # this sets up:
 125 # AWESOME_REQUIRED_LDFLAGS
 126 # AWESOME_REQUIRED_INCLUDE_DIRS
 127
 128 # Use pkgconfig to get most of the libraries
 129 pkg_check_modules(AWESOME_COMMON_REQUIRED REQUIRED
 130     xcb>=1.6)
 131
 132 pkg_check_modules(AWESOME_REQUIRED REQUIRED
 133     glib-2.0
 134     cairo
 135     x11
 136     x11-xcb
 137     xcursor
 138     pango>=1.19.3
 139     pangocairo>=1.19.3
 140     xcb-randr
 141     xcb-xtest
 142     xcb-xinerama
 143     xcb-shape
 144     xcb-util>=0.3.8
 145     xcb-keysyms>=0.3.4
 146     xcb-icccm>=0.3.8
 147     xcb-image>=0.3.0
 148     cairo-xcb
 149     libstartup-notification-1.0>=0.10
 150     xproto>=7.0.15
 151     imlib2
 152     libxdg-basedir>=1.0.0)
 153
 154 if(NOT AWESOME_REQUIRED_FOUND OR NOT AWESOME_COMMON_REQUIRED_FOUND)
 155     message(FATAL_ERROR)
 156 endif()
 157
 158 macro(a_find_library variable library)
 159     find_library(${variable} ${library})
 160     if(NOT ${variable})
 161         message(FATAL_ERROR ${library} " library not found.")
 162     endif()
 163 endmacro()
 164
 165 # Check for libev
 166 a_find_library(LIB_EV ev)
 167
 168 # Check for backtrace_symbols()
 169 include(CheckFunctionExists)
 170 check_function_exists(backtrace_symbols HAS_EXECINFO)
 171 if(NOT HAS_EXECINFO)
 172     find_library(LIB_EXECINFO execinfo)
 173     if(LIB_EXECINFO)
 174         set(HAS_EXECINFO 1)
 175         set(AWESOME_REQUIRED_LDFLAGS
 176             ${AWESOME_REQUIRED_LDFLAGS}
 177             ${LIB_EXECINFO})
 178     endif()
 179 endif()
 180 if(HAS_EXECINFO)
 181     message(STATUS "checking for execinfo -- found")
 182 else()
 183     message(STATUS "checking for execinfo -- not found")
 184 endif()
 185
 186 # __builtin_clz is available since gcc 3.4
 187 try_compile(HAS___BUILTIN_CLZ
 188     ${CMAKE_BINARY_DIR}
 189     ${CMAKE_SOURCE_DIR}/build-tests/__builtin_clz.c)
 190 if(HAS___BUILTIN_CLZ)
 191     message(STATUS "checking for __builtin_clz -- yes")
 192 else()
 193     message(STATUS "checking for __builtin_clz -- no")
 194 endif()
 195
 196 # Error check
 197 if(NOT LUA51_FOUND AND NOT LUA50_FOUND) # This is a workaround to a cmake bug
 198     message(FATAL_ERROR "lua library not found")
 199 endif()
 200
 201 set(AWESOME_REQUIRED_LDFLAGS
 202     ${AWESOME_COMMON_REQUIRED_LDFLAGS}
 203     ${AWESOME_REQUIRED_LDFLAGS}
 204     ${LIB_EV}
 205     ${LUA_LIBRARIES})
 206
 207 set(AWESOME_REQUIRED_INCLUDE_DIRS
 208     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
 209     ${AWESOME_REQUIRED_INCLUDE_DIRS}
 210     ${LUA_INCLUDE_DIR})
 211 # }}}
 212
 213 # {{{ Optional libraries
 214 #
 215 # this sets up:
 216 # AWESOME_OPTIONAL_LDFLAGS
 217 # AWESOME_OPTIONAL_INCLUDE_DIRS
 218
 219 if(WITH_DBUS)
 220     pkg_check_modules(DBUS dbus-1)
 221     if(DBUS_FOUND)
 222         set(AWESOME_OPTIONAL_LDFLAGS ${AWESOME_OPTIONAL_LDFLAGS} ${DBUS_LDFLAGS})
 223         set(AWESOME_OPTIONAL_INCLUDE_DIRS ${AWESOME_OPTIONAL_INCLUDE_DIRS} ${DBUS_INCLUDE_DIRS})
 224     else()
 225         set(WITH_DBUS OFF)
 226         message(STATUS "DBUS not found. Disabled.")
 227     endif()
 228 endif()
 229 # }}}
 230
 231 # {{{ Install path and configuration variables
 232 #If a sysconfdir is specified, use it instead
 233 #of the default configuration dir.
 234 if(DEFINED SYSCONFDIR)
 235     set(SYSCONFDIR ${SYSCONFDIR} CACHE PATH "config directory")
 236 else()
 237     set(SYSCONFDIR ${CMAKE_INSTALL_PREFIX}/etc CACHE PATH "config directory")
 238 endif()
 239
 240 #If an XDG Config Dir is specificed, use it instead
 241 #of the default XDG configuration dir.
 242 if(DEFINED XDG_CONFIG_DIR)
 243     set(XDG_CONFIG_DIR ${XDG_CONFIG_DIR} CACHE PATH "xdg config directory")
 244 else()
 245     set(XDG_CONFIG_DIR ${SYSCONFDIR}/xdg CACHE PATH "xdg config directory")
 246 endif()
 247
 248 # setting AWESOME_DOC_PATH
 249 if(DEFINED AWESOME_DOC_PATH)
 250     set(AWESOME_DOC_PATH ${AWESOME_DOC_PATH} CACHE PATH "awesome docs directory")
 251 else()
 252     set(AWESOME_DOC_PATH ${CMAKE_INSTALL_PREFIX}/share/doc/${PROJECT_AWE_NAME} CACHE PATH "awesome docs directory")
 253 endif()
 254
 255 # setting AWESOME_XSESSION_PATH
 256 if(DEFINED AWESOME_XSESSION_PATH)
 257     set(AWESOME_XSESSION_PATH ${AWESOME_XSESSION_PATH} CACHE PATH "awesome xsessions directory")
 258 else()
 259     set(AWESOME_XSESSION_PATH ${CMAKE_INSTALL_PREFIX}/share/xsessions CACHE PATH "awesome xsessions directory")
 260 endif()
 261
 262 # set man path
 263 if(DEFINED AWESOME_MAN_PATH)
 264    set(AWESOME_MAN_PATH ${AWESOME_MAN_PATH} CACHE PATH "awesome manpage directory")
 265 else()
 266    set(AWESOME_MAN_PATH ${CMAKE_INSTALL_PREFIX}/share/man CACHE PATH "awesome manpage directory")
 267 endif()
 268
 269 # Hide to avoid confusion
 270 mark_as_advanced(CMAKE_INSTALL_CMAKE_INSTALL_PREFIX)
 271
 272 set(AWESOME_VERSION          ${VERSION})
 273 set(AWESOME_COMPILE_MACHINE  ${CMAKE_SYSTEM_PROCESSOR})
 274 set(AWESOME_COMPILE_HOSTNAME ${BUILDHOSTNAME})
 275 set(AWESOME_COMPILE_BY       $ENV{USER})
 276 set(AWESOME_RELEASE          ${CODENAME})
 277 set(AWESOME_SYSCONFDIR       ${XDG_CONFIG_DIR}/${PROJECT_AWE_NAME})
 278 set(AWESOME_DATA_PATH        ${CMAKE_INSTALL_PREFIX}/share/${PROJECT_AWE_NAME})
 279 set(AWESOME_LUA_LIB_PATH     ${AWESOME_DATA_PATH}/lib)
 280 set(AWESOME_ICON_PATH        ${AWESOME_DATA_PATH}/icons)
 281 set(AWESOME_THEMES_PATH      ${AWESOME_DATA_PATH}/themes)
 282 # }}}
 283
 284 # {{{ Configure files
 285 file(GLOB_RECURSE awesome_lua_configure_files RELATIVE ${SOURCE_DIR} ${SOURCE_DIR}/lib/*.lua.in ${SOURCE_DIR}/themes/*/*.lua.in)
 286 set(AWESOME_CONFIGURE_FILES
 287     ${awesome_lua_configure_files}
 288     config.h.in
 289     awesomerc.lua.in
 290     awesome-version-internal.h.in
 291     awesome.doxygen.in)
 292
 293 macro(a_configure_file file)
 294     string(REGEX REPLACE ".in\$" "" outfile ${file})
 295     message(STATUS "Configuring ${outfile}")
 296     configure_file(${SOURCE_DIR}/${file}
 297                    ${BUILD_DIR}/${outfile}
 298                    ESCAPE_QUOTE
 299                    @ONLY)
 300 endmacro()
 301
 302 foreach(file ${AWESOME_CONFIGURE_FILES})
 303     a_configure_file(${file})
 304 endforeach()
 305 #}}}
 306
 307 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:textwidth=80