awesomeConfig.cmake

   1 set(PROJECT_AWE_NAME awesome)
   2
   3 # If ${SOURCE_DIR} is a git repository VERSION is set to
   4 # `git describe` later.
   5 set(VERSION devel)
   6
   7 set(CODENAME "Closing In")
   8
   9 project(${PROJECT_AWE_NAME} C)
  10
  11 set(CMAKE_BUILD_TYPE RELEASE)
  12
  13 option(WITH_DBUS "build with D-BUS" ON)
  14 option(GENERATE_MANPAGES "generate manpages" ON)
  15 option(COMPRESS_MANPAGES "compress manpages" ON)
  16 option(GENERATE_LUADOC "generate luadoc" ON)
  17
  18 # {{{ CFLAGS
  19 add_definitions(-std=gnu99 -ggdb3 -rdynamic -fno-strict-aliasing -Wall -Wextra
  20     -Wchar-subscripts -Wundef -Wshadow -Wcast-align -Wwrite-strings
  21     -Wsign-compare -Wunused -Wno-unused-parameter -Wuninitialized -Winit-self
  22     -Wpointer-arith -Wredundant-decls -Wformat-nonliteral
  23     -Wno-format-zero-length -Wmissing-format-attribute -Wmissing-prototypes
  24     -Wstrict-prototypes)
  25 # }}}
  26
  27 # {{{ Endianness
  28 include(TestBigEndian)
  29 TEST_BIG_ENDIAN(AWESOME_IS_BIG_ENDIAN)
  30 # }}}
  31
  32 # {{{ Find external utilities
  33 macro(a_find_program var prg req)
  34     set(required ${req})
  35     find_program(${var} ${prg})
  36     if(NOT ${var})
  37         message(STATUS "${prg} not found.")
  38         if(required)
  39             message(FATAL_ERROR "${prg} is required to build awesome")
  40         endif()
  41     else()
  42         message(STATUS "${prg} -> ${${var}}")
  43     endif()
  44 endmacro()
  45
  46 a_find_program(CAT_EXECUTABLE cat TRUE)
  47 a_find_program(LN_EXECUTABLE ln TRUE)
  48 a_find_program(GREP_EXECUTABLE grep TRUE)
  49 a_find_program(GIT_EXECUTABLE git FALSE)
  50 a_find_program(HOSTNAME_EXECUTABLE hostname FALSE)
  51 # programs needed for man pages
  52 a_find_program(ASCIIDOC_EXECUTABLE asciidoc FALSE)
  53 a_find_program(XMLTO_EXECUTABLE xmlto FALSE)
  54 a_find_program(GZIP_EXECUTABLE gzip FALSE)
  55 # lua documentation
  56 a_find_program(LUA_EXECUTABLE lua FALSE)
  57 a_find_program(LUADOC_EXECUTABLE luadoc FALSE)
  58 # theme graphics
  59 a_find_program(CONVERT_EXECUTABLE convert TRUE)
  60 # doxygen
  61 include(FindDoxygen)
  62 # pkg-config
  63 include(FindPkgConfig)
  64 # lua 5.1
  65 include(FindLua51)
  66 # }}}
  67
  68 # {{{ Check if documentation can be build
  69 if(GENERATE_MANPAGES)
  70     if(NOT ASCIIDOC_EXECUTABLE OR NOT XMLTO_EXECUTABLE OR (COMPRESS_MANPAGES AND NOT GZIP_EXECUTABLE))
  71         if(NOT ASCIIDOC_EXECUTABLE)
  72             SET(missing "asciidoc")
  73         endif()
  74         if(NOT XMLTO_EXECUTABLE)
  75             SET(missing ${missing} " xmlto")
  76         endif()
  77         if(COMPRESS_MANPAGES AND NOT GZIP_EXECUTABLE)
  78             SET(missing ${missing} " gzip")
  79         endif()
  80
  81         message(STATUS "Not generating manpages. Missing: " ${missing})
  82         set(GENERATE_MANPAGES OFF)
  83     endif()
  84 endif()
  85
  86 if(GENERATE_LUADOC)
  87     if(NOT LUADOC_EXECUTABLE)
  88         message(STATUS "Not generating luadoc. Missing: luadoc")
  89         set(GENERATE_LUADOC OFF)
  90     endif()
  91 endif()
  92 # }}}
  93
  94 # {{{ Version stamp
  95 if(EXISTS ${SOURCE_DIR}/.git/HEAD AND GIT_EXECUTABLE)
  96     # get current version
  97     execute_process(
  98         COMMAND ${GIT_EXECUTABLE} describe
  99         WORKING_DIRECTORY ${SOURCE_DIR}
 100         OUTPUT_VARIABLE VERSION
 101         OUTPUT_STRIP_TRAILING_WHITESPACE)
 102     # file the git-version-stamp.sh script will look into
 103     set(VERSION_STAMP_FILE ${BUILD_DIR}/.version_stamp)
 104     file(WRITE ${VERSION_STAMP_FILE} ${VERSION})
 105     # create a version_stamp target later
 106     set(BUILD_FROM_GIT TRUE)
 107 elseif( EXISTS ${SOURCE_DIR}/.version_stamp )
 108     # get version from version stamp
 109     file(READ ${SOURCE_DIR}/.version_stamp VERSION)
 110 endif()
 111 # }}}
 112
 113 # {{{ Get hostname
 114 execute_process(
 115     COMMAND ${HOSTNAME_EXECUTABLE}
 116     WORKING_DIRECTORY ${SOURCE_DIR}
 117     OUTPUT_VARIABLE BUILDHOSTNAME
 118     OUTPUT_STRIP_TRAILING_WHITESPACE)
 119 # }}}
 120
 121 # {{{ Required libraries
 122 #
 123 # this sets up:
 124 # AWESOME_REQUIRED_LDFLAGS
 125 # AWESOME_REQUIRED_INCLUDE_DIRS
 126
 127 # Use pkgconfig to get most of the libraries
 128 pkg_check_modules(AWESOME_COMMON_REQUIRED REQUIRED
 129     xcb>=1.6)
 130
 131 pkg_check_modules(AWESOME_REQUIRED REQUIRED
 132     glib-2.0
 133     gdk-pixbuf-2.0
 134     cairo
 135     x11
 136     x11-xcb
 137     xcursor
 138     xcb-randr
 139     xcb-xtest
 140     xcb-xinerama
 141     xcb-shape
 142     xcb-util>=0.3.8
 143     xcb-keysyms>=0.3.4
 144     xcb-icccm>=0.3.8
 145     xcb-image>=0.3.0
 146     cairo-xcb
 147     libstartup-notification-1.0>=0.10
 148     xproto>=7.0.15
 149     libxdg-basedir>=1.0.0)
 150
 151 if(NOT AWESOME_REQUIRED_FOUND OR NOT AWESOME_COMMON_REQUIRED_FOUND)
 152     message(FATAL_ERROR)
 153 endif()
 154
 155 macro(a_find_library variable library)
 156     find_library(${variable} ${library})
 157     if(NOT ${variable})
 158         message(FATAL_ERROR ${library} " library not found.")
 159     endif()
 160 endmacro()
 161
 162 # Check for libev
 163 a_find_library(LIB_EV ev)
 164
 165 # Check for backtrace_symbols()
 166 include(CheckFunctionExists)
 167 check_function_exists(backtrace_symbols HAS_EXECINFO)
 168 if(NOT HAS_EXECINFO)
 169     find_library(LIB_EXECINFO execinfo)
 170     if(LIB_EXECINFO)
 171         set(HAS_EXECINFO 1)
 172         set(AWESOME_REQUIRED_LDFLAGS
 173             ${AWESOME_REQUIRED_LDFLAGS}
 174             ${LIB_EXECINFO})
 175     endif()
 176 endif()
 177 if(HAS_EXECINFO)
 178     message(STATUS "checking for execinfo -- found")
 179 else()
 180     message(STATUS "checking for execinfo -- not found")
 181 endif()
 182
 183 # __builtin_clz is available since gcc 3.4
 184 try_compile(HAS___BUILTIN_CLZ
 185     ${CMAKE_BINARY_DIR}
 186     ${CMAKE_SOURCE_DIR}/build-tests/__builtin_clz.c)
 187 if(HAS___BUILTIN_CLZ)
 188     message(STATUS "checking for __builtin_clz -- yes")
 189 else()
 190     message(STATUS "checking for __builtin_clz -- no")
 191 endif()
 192
 193 # Error check
 194 if(NOT LUA51_FOUND AND NOT LUA50_FOUND) # This is a workaround to a cmake bug
 195     message(FATAL_ERROR "lua library not found")
 196 endif()
 197
 198 set(AWESOME_REQUIRED_LDFLAGS
 199     ${AWESOME_COMMON_REQUIRED_LDFLAGS}
 200     ${AWESOME_REQUIRED_LDFLAGS}
 201     ${LIB_EV}
 202     ${LUA_LIBRARIES})
 203
 204 set(AWESOME_REQUIRED_INCLUDE_DIRS
 205     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
 206     ${AWESOME_REQUIRED_INCLUDE_DIRS}
 207     ${LUA_INCLUDE_DIR})
 208 # }}}
 209
 210 # {{{ Optional libraries
 211 #
 212 # this sets up:
 213 # AWESOME_OPTIONAL_LDFLAGS
 214 # AWESOME_OPTIONAL_INCLUDE_DIRS
 215
 216 if(WITH_DBUS)
 217     pkg_check_modules(DBUS dbus-1)
 218     if(DBUS_FOUND)
 219         set(AWESOME_OPTIONAL_LDFLAGS ${AWESOME_OPTIONAL_LDFLAGS} ${DBUS_LDFLAGS})
 220         set(AWESOME_OPTIONAL_INCLUDE_DIRS ${AWESOME_OPTIONAL_INCLUDE_DIRS} ${DBUS_INCLUDE_DIRS})
 221     else()
 222         set(WITH_DBUS OFF)
 223         message(STATUS "DBUS not found. Disabled.")
 224     endif()
 225 endif()
 226 # }}}
 227
 228 # {{{ Install path and configuration variables
 229 #If a sysconfdir is specified, use it instead
 230 #of the default configuration dir.
 231 if(DEFINED SYSCONFDIR)
 232     set(SYSCONFDIR ${SYSCONFDIR} CACHE PATH "config directory")
 233 else()
 234     set(SYSCONFDIR ${CMAKE_INSTALL_PREFIX}/etc CACHE PATH "config directory")
 235 endif()
 236
 237 #If an XDG Config Dir is specificed, use it instead
 238 #of the default XDG configuration dir.
 239 if(DEFINED XDG_CONFIG_DIR)
 240     set(XDG_CONFIG_DIR ${XDG_CONFIG_DIR} CACHE PATH "xdg config directory")
 241 else()
 242     set(XDG_CONFIG_DIR ${SYSCONFDIR}/xdg CACHE PATH "xdg config directory")
 243 endif()
 244
 245 # setting AWESOME_DOC_PATH
 246 if(DEFINED AWESOME_DOC_PATH)
 247     set(AWESOME_DOC_PATH ${AWESOME_DOC_PATH} CACHE PATH "awesome docs directory")
 248 else()
 249     set(AWESOME_DOC_PATH ${CMAKE_INSTALL_PREFIX}/share/doc/${PROJECT_AWE_NAME} CACHE PATH "awesome docs directory")
 250 endif()
 251
 252 # setting AWESOME_XSESSION_PATH
 253 if(DEFINED AWESOME_XSESSION_PATH)
 254     set(AWESOME_XSESSION_PATH ${AWESOME_XSESSION_PATH} CACHE PATH "awesome xsessions directory")
 255 else()
 256     set(AWESOME_XSESSION_PATH ${CMAKE_INSTALL_PREFIX}/share/xsessions CACHE PATH "awesome xsessions directory")
 257 endif()
 258
 259 # set man path
 260 if(DEFINED AWESOME_MAN_PATH)
 261    set(AWESOME_MAN_PATH ${AWESOME_MAN_PATH} CACHE PATH "awesome manpage directory")
 262 else()
 263    set(AWESOME_MAN_PATH ${CMAKE_INSTALL_PREFIX}/share/man CACHE PATH "awesome manpage directory")
 264 endif()
 265
 266 # Hide to avoid confusion
 267 mark_as_advanced(CMAKE_INSTALL_CMAKE_INSTALL_PREFIX)
 268
 269 set(AWESOME_VERSION          ${VERSION})
 270 set(AWESOME_COMPILE_MACHINE  ${CMAKE_SYSTEM_PROCESSOR})
 271 set(AWESOME_COMPILE_HOSTNAME ${BUILDHOSTNAME})
 272 set(AWESOME_COMPILE_BY       $ENV{USER})
 273 set(AWESOME_RELEASE          ${CODENAME})
 274 set(AWESOME_SYSCONFDIR       ${XDG_CONFIG_DIR}/${PROJECT_AWE_NAME})
 275 set(AWESOME_DATA_PATH        ${CMAKE_INSTALL_PREFIX}/share/${PROJECT_AWE_NAME})
 276 set(AWESOME_LUA_LIB_PATH     ${AWESOME_DATA_PATH}/lib)
 277 set(AWESOME_ICON_PATH        ${AWESOME_DATA_PATH}/icons)
 278 set(AWESOME_THEMES_PATH      ${AWESOME_DATA_PATH}/themes)
 279 # }}}
 280
 281 # {{{ Configure files
 282 file(GLOB_RECURSE awesome_lua_configure_files RELATIVE ${SOURCE_DIR} ${SOURCE_DIR}/lib/*.lua.in ${SOURCE_DIR}/themes/*/*.lua.in)
 283 set(AWESOME_CONFIGURE_FILES
 284     ${awesome_lua_configure_files}
 285     config.h.in
 286     awesomerc.lua.in
 287     awesome-version-internal.h.in
 288     awesome.doxygen.in)
 289
 290 macro(a_configure_file file)
 291     string(REGEX REPLACE ".in\$" "" outfile ${file})
 292     message(STATUS "Configuring ${outfile}")
 293     configure_file(${SOURCE_DIR}/${file}
 294                    ${BUILD_DIR}/${outfile}
 295                    ESCAPE_QUOTE
 296                    @ONLY)
 297 endmacro()
 298
 299 foreach(file ${AWESOME_CONFIGURE_FILES})
 300     a_configure_file(${file})
 301 endforeach()
 302 #}}}
 303
 304 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:textwidth=80