build-aux/autotroll.m4

   1 # Build Qt apps with the autotools (Autoconf/Automake).
   2 # M4 macros.
   3 # This file is part of AutoTroll.
   4 # Copyright (C) 2006  Benoit Sigoure <benoit.sigoure@lrde.epita.fr>
   5 #
   6 # AutoTroll is free software; you can redistribute it and/or
   7 # modify it under the terms of the GNU General Public License
   8 # as published by the Free Software Foundation; either version 2
   9 # of the License, or (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301,
  19 # USA.
  20 #
  21 # In addition, as a special exception, the copyright holders of AutoTroll
  22 # give you unlimited permission to copy, distribute and modify the configure
  23 # scripts that are the output of Autoconf when processing the macros of
  24 # AutoTroll.  You need not follow the terms of the GNU General Public License
  25 # when using or distributing such scripts, even though portions of the text of
  26 # AutoTroll appear in them. The GNU General Public License (GPL) does govern
  27 # all other use of the material that constitutes AutoTroll.
  28 #
  29 # This special exception to the GPL applies to versions of AutoTroll
  30 # released by the copyright holders of AutoTroll.  Note that people who make
  31 # modified versions of AutoTroll are not obligated to grant this special
  32 # exception for their modified versions; it is their choice whether to do so.
  33 # The GNU General Public License gives permission to release a modified version
  34 # without this exception; this exception also makes it possible to release a
  35 # modified version which carries forward this exception.
  36
  37  # ------------- #
  38  # DOCUMENTATION #
  39  # ------------- #
  40
  41 # Disclaimer: Never tested with anything else than Qt 4.2! Feedback welcome.
  42 # Simply invoke AT_WITH_QT in your configure.ac. AT_WITH_QT can take
  43 # arguments which are documented in depth below. The default arguments are
  44 # equivalent to the default .pro file generated by qmake.
  45 #
  46 # Invoking AT_WITH_QT will do the following:
  47 #  - Add a --with-qt option to your configure
  48 #  - Find qmake, moc and uic and save them in the make variables $(QMAKE),
  49 #    $(MOC), $(UIC).
  50 #  - Save the path to Qt in $(QT_PATH)
  51 #  - Find the flags to use Qt, that is:
  52 #     * $(QT_DEFINES): -D's defined by qmake.
  53 #     * $(QT_CFLAGS): CFLAGS as defined by qmake (C?!)
  54 #     * $(QT_CXXFLAGS): CXXFLAGS as defined by qmake.
  55 #     * $(QT_INCPATH): -I's defined by qmake.
  56 #     * $(QT_CPPFLAGS): Same as $(QT_DEFINES) + $(QT_INCPATH)
  57 #     * $(QT_LFLAGS): LFLAGS defined by qmake.
  58 #     * $(QT_LDFLAGS): Same thing as $(QT_LFLAGS).
  59 #     * $(QT_LIBS): LIBS defined by qmake.
  60 #
  61 # You *MUST* invoke $(MOC) and/or $(UIC) where necessary. AutoTroll provides
  62 # you with Makerules to ease this, here is a sample Makefile.am to use with
  63 # AutoTroll which builds the code given in the chapter 7 of the Qt Tutorial:
  64 # http://doc.trolltech.com/4.2/tutorial-t7.html
  65 #
  66 # -------------------------------------------------------------------------
  67 # include $(top_srcdir)/build-aux/autotroll.mk
  68 #
  69 # ACLOCAL_AMFLAGS = -I build-aux
  70 #
  71 # bin_PROGRAMS = lcdrange
  72 # lcdrange_SOURCES =  $(BUILT_SOURCES) lcdrange.cpp lcdrange.h main.cpp
  73 # lcdrange_CXXFLAGS = $(QT_CXXFLAGS) $(AM_CXXFLAGS)
  74 # lcdrange_CPPFLAGS = $(QT_CPPFLAGS) $(AM_CPPFLAGS)
  75 # lcdrange_LDFLAGS  = $(QT_LDFLAGS) $(LDFLAGS)
  76 # lcdrange_LDADD    = $(QT_LIBS) $(LDADD)
  77 #
  78 # BUILT_SOURCES = lcdrange.moc.cpp
  79 # -------------------------------------------------------------------------
  80 #
  81 # Note that your MOC, UIC and QRC files *MUST* be listed manually in
  82 # BUILT_SOURCES. If you name them properly (eg: .moc.cc, .qrc.cc, .ui.cc -- of
  83 # course you can use .cpp or .cxx or .C rather than .cc) AutoTroll will build
  84 # them automagically for you (using implicit rules defined in autotroll.mk).
  85
  86 m4_define([_AUTOTROLL_SERIAL], [m4_translit([
  87 # serial 3
  88 ], [#
  89 ], [])])
  90
  91
  92 m4_ifdef([AX_INSTEAD_IF], [],
  93 [AC_DEFUN([AX_INSTEAD_IF],
  94   [m4_ifval([$1],
  95     [AC_MSG_WARN([$2]); [$1]],
  96     [AC_MSG_ERROR([$2])])])])
  97
  98 m4_pattern_forbid([^AT_])dnl
  99 m4_pattern_forbid([^_AT_])dnl
 100
 101 # AT_WITH_QT([QT_modules], [QT_config], [QT_misc], [RUN-IF-FAILED], [RUN-IF-OK])
 102 # ------------------------------------------------------------------------------
 103 # Enable Qt support and add an option --with-qt to the configure script.
 104 #
 105 # The QT_modules argument is optional and defines extra modules to enable or
 106 # disable (it's equivalent to the QT variable in .pro files). Modules can be
 107 # specified as follows:
 108 #
 109 # AT_WITH_QT   => No argument -> No QT value.
 110 #                                Qmake sets it to "core gui" by default.
 111 # AT_WITH_QT([xml])   => QT += xml
 112 # AT_WITH_QT([+xml])  => QT += xml
 113 # AT_WITH_QT([-gui])  => QT -= gui
 114 # AT_WITH_QT([xml -gui +sql svg])  => QT += xml sql svg
 115 #                                     QT -= gui
 116 #
 117 # The QT_config argument is also optional and follows the same convention as
 118 # QT_modules. Instead of changing the QT variable, it changes the CONFIG
 119 # variable, which is used to tweak configuration and compiler options.
 120 #
 121 # The last argument, QT_misc (also optional) will be copied as-is the .pro
 122 # file used to guess how to compile Qt apps. You may use it to further tweak
 123 # the build process of Qt apps if tweaking the QT or CONFIG variables isn't
 124 # enough for you.
 125 #
 126 # RUN-IF-FAILED is arbitrary code to execute if Qt cannot be found or if any
 127 # problem happens.  If this argument is omitted, then AC_MSG_ERROR will be
 128 # called.  RUN-IF-OK is arbitrary code to execute if Qt was successfully found.
 129 AC_DEFUN([AT_WITH_QT],
 130 [AC_REQUIRE([AC_CANONICAL_HOST])dnl
 131 AC_REQUIRE([AC_CANONICAL_BUILD])dnl
 132 AC_REQUIRE([AC_PROG_CXX])dnl
 133 echo "$as_me: this is autotroll.m4[]_AUTOTROLL_SERIAL" >&AS_MESSAGE_LOG_FD
 134
 135   test x"$TROLL" != x && echo 'ViM rox emacs.'
 136
 137 dnl Memo: AC_ARG_WITH(package, help-string, [if-given], [if-not-given])
 138   AC_ARG_WITH([qt],
 139               [AS_HELP_STRING([--with-qt],
 140                  [Path to Qt @<:@Look in PATH and /usr/local/Trolltech@:>@])],
 141               [QT_PATH=$withval])
 142
 143   # this is a hack to get decent flow control with 'break'
 144   for _qt_ignored in once; do
 145
 146   # Find Qt.
 147   AC_ARG_VAR([QT_PATH], [Path to the Qt installation])
 148   if test -d /usr/local/Trolltech; then
 149     # Try to find the latest version.
 150     tmp_qt_paths=`echo /usr/local/Trolltech/*/bin | tr ' ' '\n' | sort -nr \
 151                                               | xargs | sed 's/  */:/g'`
 152   fi
 153
 154   # Find qmake.
 155   AC_ARG_VAR([QMAKE], [Qt Makefile generator command])
 156   AC_PATH_PROGS([QMAKE], [qmake qmake-qt4 qmake-qt3], [missing],
 157                 [$QT_DIR:$QT_PATH:$PATH:$tmp_qt_paths])
 158   if test x"$QMAKE" = xmissing; then
 159     AX_INSTEAD_IF([$4], [Cannot find qmake in your PATH. Try using --with-qt.])
 160     break
 161   fi
 162
 163   # Find moc (Meta Object Compiler).
 164   AC_ARG_VAR([MOC], [Qt Meta Object Compiler command])
 165   AC_PATH_PROGS([MOC], [moc moc-qt4 moc-qt3], [missing],
 166                 [$QT_PATH:$PATH:$tmp_qt_paths])
 167   if test x"$MOC" = xmissing; then
 168     AX_INSTEAD_IF([$4],
 169    [Cannot find moc (Meta Object Compiler) in your PATH. Try using --with-qt.])
 170     break
 171   fi
 172
 173   # Find uic (User Interface Compiler).
 174   AC_ARG_VAR([UIC], [Qt User Interface Compiler command])
 175   AC_PATH_PROGS([UIC], [uic uic-qt4 uic-qt3 uic3], [missing],
 176                 [$QT_PATH:$PATH:$tmp_qt_paths])
 177   if test x"$UIC" = xmissing; then
 178     AX_INSTEAD_IF([$4],
 179 [Cannot find uic (User Interface Compiler) in your PATH. Try using --with-qt.])
 180     break
 181   fi
 182
 183   # Find rcc (Qt Resource Compiler).
 184   AC_ARG_VAR([RCC], [Qt Resource Compiler command])
 185   AC_PATH_PROGS([RCC], [rcc], [false], [$QT_PATH:$PATH:$tmp_qt_paths])
 186   if test x"$UIC" = xfalse; then
 187     AC_MSG_WARN([Cannot find rcc (Qt Resource Compiler) in your PATH.\
 188   Try using --with-qt.])
 189   fi
 190
 191   # If we don't know the path to Qt, guess it from the path to qmake.
 192   if test x"$QT_PATH" = x; then
 193     QT_PATH=`dirname "$QMAKE"`
 194   fi
 195   if test x"$QT_PATH" = x; then
 196     AX_INSTEAD_IF([$4],
 197                   [Cannot find the path to your Qt install. Use --with-qt.])
 198     break
 199   fi
 200   AC_SUBST([QT_PATH])
 201
 202   # Get ready to build a test-app with Qt.
 203   if mkdir conftest.dir && cd conftest.dir; then :; else
 204     AX_INSTEAD_IF([$4], [Cannot mkdir conftest.dir or cd to that directory.])
 205     break
 206   fi
 207
 208   cat >conftest.h <<_ASEOF
 209 #include <QObject>
 210
 211 class Foo: public QObject
 212 {
 213   Q_OBJECT;
 214 public:
 215   Foo();
 216   ~Foo() {}
 217 public slots:
 218   void setValue(int value);
 219 signals:
 220   void valueChanged(int newValue);
 221 private:
 222   int value_;
 223 };
 224 _ASEOF
 225
 226   cat >conftest.cpp <<_ASEOF
 227 #include "conftest.h"
 228 Foo::Foo()
 229   : value_ (42)
 230 {
 231   connect(this, SIGNAL(valueChanged(int)), this, SLOT(setValue(int)));
 232 }
 233
 234 void Foo::setValue(int value)
 235 {
 236   value_ = value;
 237 }
 238
 239 int main()
 240 {
 241   Foo f;
 242 }
 243 _ASEOF
 244   if $QMAKE -project; then :; else
 245     AX_INSTEAD_IF([$4], [Calling $QMAKE -project failed.])
 246     break
 247   fi
 248
 249   # Find the .pro file generated by qmake.
 250   pro_file='conftest.dir.pro'
 251   test -f $pro_file || pro_file=`echo *.pro`
 252   if test -f "$pro_file"; then :; else
 253     AX_INSTEAD_IF([$4], [Can't find the .pro file generated by Qmake.])
 254     break
 255   fi
 256
 257 dnl Tweak the value of QT in the .pro if have been the 1st arg.
 258 m4_ifval([$1], [_AT_TWEAK_PRO_FILE([QT], [$1])])
 259
 260 dnl Tweak the value of CONFIG in the .pro if have been given a 2nd arg.
 261 m4_ifval([$2], [_AT_TWEAK_PRO_FILE([CONFIG], [$2])])
 262
 263 m4_ifval([$3],
 264 [ # Add the extra-settings the user wants to set in the .pro
 265   echo "$3" >>"$pro_file"
 266 ])
 267
 268   echo "$as_me:$LINENO: Invoking $QMAKE on $pro_file" >&AS_MESSAGE_LOG_FD
 269   sed 's/^/| /' "$pro_file" >&AS_MESSAGE_LOG_FD
 270
 271   if $QMAKE; then :; else
 272     AX_INSTEAD_IF([$4], [Calling $QMAKE failed.])
 273     break
 274   fi
 275
 276   # QMake has a very annoying misfeature: sometimes it generates Makefiles
 277   # where all the references to the files from the Qt installation are
 278   # relative.  We can't use them as-is because if we take, say, a
 279   # -I../../usr/include/Qt from that Makefile, the flag is invalid as soon
 280   # as we use it in another (sub) directory.  So what this perl pass does is
 281   # that it rewrite all relative paths to absolute paths.  Another problem
 282   # when building on Cygwin is that QMake mixes paths with blackslashes and
 283   # forward slashes and paths must be handled with extra care because of the
 284   # stupid Windows drive letters.
 285   echo "$as_me:$LINENO: fixing the Makefiles:" Makefile* >&AS_MESSAGE_LOG_FD
 286   cat >fixmk.pl <<\EOF
 287 [use strict;
 288 use Cwd qw(cwd abs_path);
 289 # This variable is useful on Cygwin for the following reason: Say that you are
 290 # in `/' (that is, in fact you are in C:/cygwin, or something like that) if you
 291 # `cd ..' then obviously you remain in `/' (that is in C:/cygwin).  QMake
 292 # generates paths that are relative to C:/ (or another driver letter, whatever)
 293 # so the trick to get the `..' resolved properly is to prepend the absolute
 294 # path of the current working directory in a Windows-style.  C:/cygwin/../ will
 295 # properly become C:/.
 296 my $d = "";
 297 my $r2a = 0;
 298 my $b2f = 0;
 299
 300 my $cygwin = 0;
 301 if ($^O eq "cygwin") {
 302   $cygwin = 1;
 303   $d = cwd();
 304   $d = `cygpath --mixed '$d'`;
 305   chomp($d);
 306   $d .= "/";
 307 }
 308
 309 sub rel2abs($)
 310 {
 311   my $p = $d . shift;
 312   # print "r2a p=$p";
 313   -e $p || return $p;
 314   if ($cygwin) {
 315     $p = `cygpath --mixed '$p'`;
 316     chomp($p);
 317   }
 318   else {
 319     # Do not use abs_path on Cygwin: it incorrectly resolves the paths that are
 320     # relative to C:/ rather than `/'.
 321     $p = abs_path($p);
 322   }
 323   # print " -> $p\n";
 324   ++$r2a;
 325   return $p;
 326 }
 327
 328 # Only useful on Cygwin.
 329 sub back2forward($)
 330 {
 331   my $p = shift;
 332   # print "b2f p=$p";
 333   -e $p || return $p;
 334   $p = `cygpath --mixed '$p'`;
 335   chomp($p);
 336   # print " -> $p\n";
 337   ++$b2f;
 338   return $p;
 339 }
 340
 341 foreach my $mk (@ARGV)
 342 {
 343   next if $mk =~ /~$/;
 344   open(MK, $mk) or die("open $mk: $!");
 345   # print "mk=$mk\n";
 346   my $file = join("", <MK>);
 347   close(MK) or die("close $mk: $!");
 348   rename $mk, $mk . "~" or die("rename $mk: $!");
 349   $file =~ s{(?:\.\.[\\/])+(?:[^"'\s:]+)}{rel2abs($&)}gse;
 350   $file =~ s{(?:[a-zA-Z]:[\\/])?(?:[^"\s]+\\[^"\s:]+)+}
 351             {back2forward($&)}gse if $cygwin;
 352   open(MK, ">", $mk) or die("open >$mk: $!");
 353   print MK $file;
 354   close(MK) or die("close >$mk: $!");
 355   print "$mk: updated $r2a relative paths and $b2f backslash-style paths\n";
 356   $r2a = 0;
 357   $b2f = 0;
 358 }]
 359 EOF
 360
 361   perl >&AS_MESSAGE_LOG_FD -w fixmk.pl Makefile* ||
 362   AC_MSG_WARN([failed to fix the Makefiles generated by $QMAKE])
 363   rm -f fixmk.pl
 364
 365   # Try to compile a simple Qt app.
 366   AC_CACHE_CHECK([whether we can build a simple Qt app], [at_cv_qt_build],
 367   [at_cv_qt_build=ko
 368   : ${MAKE=make}
 369
 370   if $MAKE >&AS_MESSAGE_LOG_FD 2>&1; then
 371     at_cv_qt_build='ok, looks like Qt 4'
 372   else
 373     echo "$as_me:$LINENO: Build failed, trying to #include <qobject.h> \
 374 instead" >&AS_MESSAGE_LOG_FD
 375     sed 's/<QObject>/<qobject.h>/' conftest.h > tmp.h && mv tmp.h conftest.h
 376     if $MAKE >&AS_MESSAGE_LOG_FD 2>&1; then
 377       at_cv_qt_build='ok, looks like Qt 3'
 378     else
 379       # Sometimes (such as on Debian) build will fail because Qt hasn't been
 380       # installed in debug mode and qmake tries (by default) to build apps in
 381       # debug mode => Try again in release mode.
 382       echo "$as_me:$LINENO: Build failed, trying to enforce release mode" \
 383             >&AS_MESSAGE_LOG_FD
 384
 385       _AT_TWEAK_PRO_FILE([CONFIG], [+release])
 386
 387       sed 's/<qobject.h>/<QObject>/' conftest.h > tmp.h && mv tmp.h conftest.h
 388       if $MAKE >&AS_MESSAGE_LOG_FD 2>&1; then
 389         at_cv_qt_build='ok, looks like Qt 4, release mode forced'
 390       else
 391         echo "$as_me:$LINENO: Build failed, trying to #include <qobject.h> \
 392 instead" >&AS_MESSAGE_LOG_FD
 393         sed 's/<QObject>/<qobject.h>/' conftest.h >tmp.h && mv tmp.h conftest.h
 394         if $MAKE >&AS_MESSAGE_LOG_FD 2>&1; then
 395           at_cv_qt_build='ok, looks like Qt 3, release mode forced'
 396         else
 397           at_cv_qt_build=ko
 398           echo "$as_me:$LINENO: failed program was:" >&AS_MESSAGE_LOG_FD
 399           sed 's/^/| /' conftest.h >&AS_MESSAGE_LOG_FD
 400           echo "$as_me:$LINENO: failed program was:" >&AS_MESSAGE_LOG_FD
 401           sed 's/^/| /' conftest.cpp >&AS_MESSAGE_LOG_FD
 402         fi # if make with Qt3-style #include and release mode forced.
 403       fi # if make with Qt4-style #include and release mode forced.
 404     fi # if make with Qt3-style #include.
 405   fi # if make with Qt4-style #include.
 406   ])dnl end: AC_CACHE_CHECK(at_cv_qt_build)
 407
 408   if test x"$at_cv_qt_build" = xko; then
 409     AX_INSTEAD_IF([$4], [Cannot build a test Qt program])
 410     break
 411   fi
 412   QT_VERSION_MAJOR=`echo "$at_cv_qt_build" | sed 's/[[^0-9]]*//g'`
 413   AC_SUBST([QT_VERSION_MAJOR])
 414
 415   # This sed filter is applied after an expression of the form: /^FOO.*=/!d;
 416   # It starts by removing the beginning of the line, removing references to
 417   # SUBLIBS, removing unnecessary whitespaces at the beginning, and prefixes
 418   # all variable uses by QT_.
 419   qt_sed_filter='s///;
 420                  s/$(SUBLIBS)//g;
 421                  s/^ *//;
 422                  s/\$(\(@<:@A-Z_@:>@@<:@A-Z_@:>@*\))/$(QT_\1)/g'
 423
 424   # Find the Makefile (qmake happens to generate a fake Makefile which invokes
 425   # a Makefile.Debug or Makefile.Release). We we have both, we'll pick the
 426   # Makefile.Release. The reason is that the main difference is that release
 427   # uses -Os and debug -g. We can override -Os by passing another -O but we
 428   # usually don't override -g.
 429   if test -f Makefile.Release; then
 430     at_mfile='Makefile.Release'
 431   else
 432     at_mfile='Makefile'
 433   fi
 434   if test -f $at_mfile; then :; else
 435     AX_INSTEAD_IF([$4], [Cannot find the Makefile generated by qmake.])
 436     break
 437   fi
 438
 439   # Find the DEFINES of Qt (should have been named CPPFLAGS).
 440   AC_CACHE_CHECK([for the DEFINES to use with Qt], [at_cv_env_QT_DEFINES],
 441   [at_cv_env_QT_DEFINES=`sed "/^DEFINES@<:@^A-Z=@:>@*=/!d;$qt_sed_filter" $at_mfile`])
 442   AC_SUBST([QT_DEFINES], [$at_cv_env_QT_DEFINES])
 443
 444   # Find the CFLAGS of Qt (We can use Qt in C?!)
 445   AC_CACHE_CHECK([for the CFLAGS to use with Qt], [at_cv_env_QT_CFLAGS],
 446   [at_cv_env_QT_CFLAGS=`sed "/^CFLAGS@<:@^A-Z=@:>@*=/!d;$qt_sed_filter" $at_mfile`])
 447   AC_SUBST([QT_CFLAGS], [$at_cv_env_QT_CFLAGS])
 448
 449   # Find the CXXFLAGS of Qt.
 450   AC_CACHE_CHECK([for the CXXFLAGS to use with Qt], [at_cv_env_QT_CXXFLAGS],
 451   [at_cv_env_QT_CXXFLAGS=`sed "/^CXXFLAGS@<:@^A-Z=@:>@*=/!d;$qt_sed_filter" $at_mfile`])
 452   AC_SUBST([QT_CXXFLAGS], [$at_cv_env_QT_CXXFLAGS])
 453
 454   # Find the INCPATH of Qt.
 455   AC_CACHE_CHECK([for the INCPATH to use with Qt], [at_cv_env_QT_INCPATH],
 456   [at_cv_env_QT_INCPATH=`sed "/^INCPATH@<:@^A-Z=@:>@*=/!d;$qt_sed_filter" $at_mfile`])
 457   AC_SUBST([QT_INCPATH], [$at_cv_env_QT_INCPATH])
 458
 459   AC_SUBST([QT_CPPFLAGS], ["$at_cv_env_QT_DEFINES $at_cv_env_QT_INCPATH"])
 460
 461   # Find the LFLAGS of Qt (Should have been named LDFLAGS)
 462   AC_CACHE_CHECK([for the LDFLAGS to use with Qt], [at_cv_env_QT_LDFLAGS],
 463   [at_cv_env_QT_LDFLAGS=`sed "/^LFLAGS@<:@^A-Z=@:>@*=/!d;$qt_sed_filter" $at_mfile`])
 464   AC_SUBST([QT_LFLAGS], [$at_cv_env_QT_LDFLAGS])
 465   AC_SUBST([QT_LDFLAGS], [$at_cv_env_QT_LDFLAGS])
 466
 467   AC_MSG_CHECKING([whether host operating system is Darwin])
 468   at_darwin="no"
 469   case $host_os in
 470     darwin*)
 471       at_darwin="yes"
 472       ;;
 473   esac
 474   AC_MSG_RESULT([$at_darwin])
 475
 476   # Find the LIBS of Qt.
 477   AC_CACHE_CHECK([for the LIBS to use with Qt], [at_cv_env_QT_LIBS],
 478   [at_cv_env_QT_LIBS=`sed "/^LIBS@<:@^A-Z@:>@*=/!d;$qt_sed_filter" $at_mfile`
 479    if test x$at_darwin = xyes; then
 480      # Fix QT_LIBS: as of today Libtool (GNU Libtool 1.5.23a) doesn't handle
 481      # -F properly. The "bug" has been fixed on 22 October 2006
 482      # by Peter O'Gorman but we provide backward compatibility here.
 483      at_cv_env_QT_LIBS=`echo "$at_cv_env_QT_LIBS" \
 484                              | sed 's/^-F/-Wl,-F/;s/ -F/ -Wl,-F/g'`
 485    fi
 486   ])
 487   AC_SUBST([QT_LIBS], [$at_cv_env_QT_LIBS])
 488
 489   cd .. && rm -rf conftest.dir
 490
 491   # Run the user code
 492   $5
 493
 494   done  # end hack (useless for to be able to use break)
 495 ])
 496
 497 # AT_REQUIRE_QT_VERSION(QT_version, RUN-IF-FAILED, RUN-IF-OK)
 498 # -----------------------------------------------------------
 499 # Check (using qmake) that Qt's version "matches" QT_version.
 500 # Must be run AFTER AT_WITH_QT. Requires autoconf 2.60.
 501 #
 502 # RUN-IF-FAILED is arbitrary code to execute if Qt cannot be found or if any
 503 # problem happens.  If this argument is omitted, then AC_MSG_ERROR will be
 504 # called.  RUN-IF-OK is arbitrary code to execute if Qt was successfully found.
 505 AC_DEFUN([AT_REQUIRE_QT_VERSION],
 506 [ AC_PREREQ([2.60])
 507   # this is a hack to get decent flow control with 'break'
 508   for _qt_ignored in once; do
 509
 510   if test x"$QMAKE" = x; then
 511     AX_INSTEAD_IF([$2],
 512                   [\$QMAKE is empty.\
 513   Did you invoke AT@&t@_WITH_QT before AT@&t@_REQUIRE_QT_VERSION?])
 514     break
 515   fi
 516   AC_CACHE_CHECK([for Qt's version], [at_cv_QT_VERSION],
 517   [echo "$as_me:$LINENO: Running $QMAKE --version:" >&AS_MESSAGE_LOG_FD
 518   $QMAKE --version >&AS_MESSAGE_LOG_FD 2>&1
 519   qmake_version_sed=['/^.*\([0-9]\.[0-9]\.[0-9]\).*$/!d;s//\1/']
 520   at_cv_QT_VERSION=`$QMAKE --version 2>&1 | sed "$qmake_version_sed"`])
 521   if test x"$at_cv_QT_VERSION" = x; then
 522     AX_INSTEAD_IF([$2], [Cannot detect Qt's version.])
 523     break
 524   fi
 525   AC_SUBST([QT_VERSION], [$at_cv_QT_VERSION])
 526   AS_VERSION_COMPARE([$QT_VERSION], [$1],
 527     [AX_INSTEAD_IF([$2], [This package requires Qt $1 or above.])],
 528     [$2], [$2])
 529
 530   # Run the user code
 531   $3
 532
 533   done  # end hack (useless for to be able to use break)
 534 ])
 535
 536 # _AT_TWEAK_PRO_FILE(QT_VAR, VALUE)
 537 # ---------------------------
 538 # @internal. Tweak the variable QT_VAR in the .pro.
 539 # VALUE is an IFS-separated list of value and each value is rewritten
 540 # as follows:
 541 #   +value  => QT_VAR += value
 542 #   -value  => QT_VAR -= value
 543 #    value  => QT_VAR += value
 544 AC_DEFUN([_AT_TWEAK_PRO_FILE],
 545 [ # Tweak the value of $1 in the .pro file for $2.
 546
 547   qt_conf=''
 548   for at_mod in $2; do
 549     at_mod=`echo "$at_mod" | sed 's/^-//; tough
 550                                   s/^+//; beef
 551                                   :ough
 552                                   s/^/$1 -= /;n
 553                                   :eef
 554                                   s/^/$1 += /'`
 555     qt_conf="$qt_conf
 556 $at_mod"
 557   done
 558   echo "$qt_conf" | sed 1d >>"$pro_file"
 559 ])