build-aux/autotroll.m4

   1 # Build Qt apps with the autotools (Autoconf/Automake).
   2 # M4 macros.
   3 # This file is part of AutoTroll.
   4 # Copyright (C) 2006  Benoit Sigoure <benoit.sigoure@lrde.epita.fr>
   5 #
   6 # AutoTroll is free software; you can redistribute it and/or
   7 # modify it under the terms of the GNU General Public License
   8 # as published by the Free Software Foundation; either version 2
   9 # of the License, or (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301,
  19 # USA.
  20 #
  21 # In addition, as a special exception, the copyright holders of AutoTroll
  22 # give you unlimited permission to copy, distribute and modify the configure
  23 # scripts that are the output of Autoconf when processing the macros of
  24 # AutoTroll.  You need not follow the terms of the GNU General Public License
  25 # when using or distributing such scripts, even though portions of the text of
  26 # AutoTroll appear in them. The GNU General Public License (GPL) does govern
  27 # all other use of the material that constitutes AutoTroll.
  28 #
  29 # This special exception to the GPL applies to versions of AutoTroll
  30 # released by the copyright holders of AutoTroll.  Note that people who make
  31 # modified versions of AutoTroll are not obligated to grant this special
  32 # exception for their modified versions; it is their choice whether to do so.
  33 # The GNU General Public License gives permission to release a modified version
  34 # without this exception; this exception also makes it possible to release a
  35 # modified version which carries forward this exception.
  36
  37  # ------------- #
  38  # DOCUMENTATION #
  39  # ------------- #
  40
  41 # Disclaimer: Never tested with anything else than Qt 4.2! Feedback welcome.
  42 # Simply invoke AT_WITH_QT in your configure.ac. AT_WITH_QT can take
  43 # arguments which are documented in depth below. The default arguments are
  44 # equivalent to the default .pro file generated by qmake.
  45 #
  46 # Invoking AT_WITH_QT will do the following:
  47 #  - Add a --with-qt option to your configure
  48 #  - Find qmake, moc and uic and save them in the make variables $(QMAKE),
  49 #    $(MOC), $(UIC).
  50 #  - Save the path to Qt in $(QT_PATH)
  51 #  - Find the flags to use Qt, that is:
  52 #     * $(QT_DEFINES): -D's defined by qmake.
  53 #     * $(QT_CFLAGS): CFLAGS as defined by qmake (C?!)
  54 #     * $(QT_CXXFLAGS): CXXFLAGS as defined by qmake.
  55 #     * $(QT_INCPATH): -I's defined by qmake.
  56 #     * $(QT_CPPFLAGS): Same as $(QT_DEFINES) + $(QT_INCPATH)
  57 #     * $(QT_LFLAGS): LFLAGS defined by qmake.
  58 #     * $(QT_LDFLAGS): Same thing as $(QT_LFLAGS).
  59 #     * $(QT_LIBS): LIBS defined by qmake.
  60 #
  61 # You *MUST* invoke $(MOC) and/or $(UIC) where necessary. AutoTroll provides
  62 # you with Makerules to ease this, here is a sample Makefile.am to use with
  63 # AutoTroll which builds the code given in the chapter 7 of the Qt Tutorial:
  64 # http://doc.trolltech.com/4.2/tutorial-t7.html
  65 #
  66 # -------------------------------------------------------------------------
  67 # include $(top_srcdir)/build-aux/autotroll.mk
  68 #
  69 # ACLOCAL_AMFLAGS = -I build-aux
  70 #
  71 # bin_PROGRAMS = lcdrange
  72 # lcdrange_SOURCES =  $(BUILT_SOURCES) lcdrange.cpp lcdrange.h main.cpp
  73 # lcdrange_CXXFLAGS = $(QT_CXXFLAGS) $(AM_CXXFLAGS)
  74 # lcdrange_CPPFLAGS = $(QT_CPPFLAGS) $(AM_CPPFLAGS)
  75 # lcdrange_LDFLAGS  = $(QT_LDFLAGS) $(LDFLAGS)
  76 # lcdrange_LDADD    = $(QT_LIBS) $(LDADD)
  77 #
  78 # BUILT_SOURCES = lcdrange.moc.cpp
  79 # -------------------------------------------------------------------------
  80 #
  81 # Note that your MOC, UIC and QRC files *MUST* be listed manually in
  82 # BUILT_SOURCES. If you name them properly (eg: .moc.cc, .qrc.cc, .ui.cc -- of
  83 # course you can use .cpp or .cxx or .C rather than .cc) AutoTroll will build
  84 # them automagically for you (using implicit rules defined in autotroll.mk).
  85
  86 m4_define([_AUTOTROLL_SERIAL], [m4_translit([
  87 # serial 4
  88 ], [#
  89 ], [])])
  90
  91
  92 m4_ifdef([AX_INSTEAD_IF], [],
  93 [AC_DEFUN([AX_INSTEAD_IF],
  94   [m4_ifval([$1],
  95     [AC_MSG_WARN([$2]); [$1]],
  96     [AC_MSG_ERROR([$2])])])])
  97
  98 m4_pattern_forbid([^AT_])dnl
  99 m4_pattern_forbid([^_AT_])dnl
 100
 101 # AT_WITH_QT([QT_modules], [QT_config], [QT_misc], [RUN-IF-FAILED], [RUN-IF-OK])
 102 # ------------------------------------------------------------------------------
 103 # Enable Qt support and add an option --with-qt to the configure script.
 104 #
 105 # The QT_modules argument is optional and defines extra modules to enable or
 106 # disable (it's equivalent to the QT variable in .pro files). Modules can be
 107 # specified as follows:
 108 #
 109 # AT_WITH_QT   => No argument -> No QT value.
 110 #                                Qmake sets it to "core gui" by default.
 111 # AT_WITH_QT([xml])   => QT += xml
 112 # AT_WITH_QT([+xml])  => QT += xml
 113 # AT_WITH_QT([-gui])  => QT -= gui
 114 # AT_WITH_QT([xml -gui +sql svg])  => QT += xml sql svg
 115 #                                     QT -= gui
 116 #
 117 # The QT_config argument is also optional and follows the same convention as
 118 # QT_modules. Instead of changing the QT variable, it changes the CONFIG
 119 # variable, which is used to tweak configuration and compiler options.
 120 #
 121 # The last argument, QT_misc (also optional) will be copied as-is the .pro
 122 # file used to guess how to compile Qt apps. You may use it to further tweak
 123 # the build process of Qt apps if tweaking the QT or CONFIG variables isn't
 124 # enough for you.
 125 #
 126 # RUN-IF-FAILED is arbitrary code to execute if Qt cannot be found or if any
 127 # problem happens.  If this argument is omitted, then AC_MSG_ERROR will be
 128 # called.  RUN-IF-OK is arbitrary code to execute if Qt was successfully found.
 129 AC_DEFUN([AT_WITH_QT],
 130 [AC_REQUIRE([AC_CANONICAL_HOST])dnl
 131 AC_REQUIRE([AC_CANONICAL_BUILD])dnl
 132 AC_REQUIRE([AC_PROG_CXX])dnl
 133 echo "$as_me: this is autotroll.m4[]_AUTOTROLL_SERIAL" >&AS_MESSAGE_LOG_FD
 134
 135   test x"$TROLL" != x && echo 'ViM rox emacs.'
 136
 137 dnl Memo: AC_ARG_WITH(package, help-string, [if-given], [if-not-given])
 138   AC_ARG_WITH([qt],
 139               [AS_HELP_STRING([--with-qt],
 140                  [Path to Qt @<:@Look in PATH and /usr/local/Trolltech@:>@])],
 141               [QT_PATH=$withval])
 142
 143   # this is a hack to get decent flow control with 'break'
 144   for _qt_ignored in once; do
 145
 146   # Find Qt.
 147   AC_ARG_VAR([QT_PATH], [Path to the Qt installation])
 148   if test -d /usr/local/Trolltech; then
 149     # Try to find the latest version.
 150     tmp_qt_paths=`echo /usr/local/Trolltech/*/bin | tr ' ' '\n' | sort -nr \
 151                                               | xargs | sed 's/  */:/g'`
 152   fi
 153   # Path to which recent MacPorts (~v1.7) install Qt4.
 154   test -d /opt/local/libexec/qt4-mac/bin \
 155     && tmp_qt_paths="$tmp_qt_paths:/opt/local/libexec/qt4-mac/bin"
 156
 157   # Find qmake.
 158   AC_ARG_VAR([QMAKE], [Qt Makefile generator command])
 159   AC_PATH_PROGS([QMAKE], [qmake qmake-qt4 qmake-qt3], [missing],
 160                 [$QT_DIR:$QT_PATH:$PATH:$tmp_qt_paths])
 161   if test x"$QMAKE" = xmissing; then
 162     AX_INSTEAD_IF([$4], [Cannot find qmake in your PATH. Try using --with-qt.])
 163     break
 164   fi
 165
 166   # Find moc (Meta Object Compiler).
 167   AC_ARG_VAR([MOC], [Qt Meta Object Compiler command])
 168   AC_PATH_PROGS([MOC], [moc moc-qt4 moc-qt3], [missing],
 169                 [$QT_PATH:$PATH:$tmp_qt_paths])
 170   if test x"$MOC" = xmissing; then
 171     AX_INSTEAD_IF([$4],
 172    [Cannot find moc (Meta Object Compiler) in your PATH. Try using --with-qt.])
 173     break
 174   fi
 175
 176   # Find uic (User Interface Compiler).
 177   AC_ARG_VAR([UIC], [Qt User Interface Compiler command])
 178   AC_PATH_PROGS([UIC], [uic uic-qt4 uic-qt3 uic3], [missing],
 179                 [$QT_PATH:$PATH:$tmp_qt_paths])
 180   if test x"$UIC" = xmissing; then
 181     AX_INSTEAD_IF([$4],
 182 [Cannot find uic (User Interface Compiler) in your PATH. Try using --with-qt.])
 183     break
 184   fi
 185
 186   # Find rcc (Qt Resource Compiler).
 187   AC_ARG_VAR([RCC], [Qt Resource Compiler command])
 188   AC_PATH_PROGS([RCC], [rcc], [false], [$QT_PATH:$PATH:$tmp_qt_paths])
 189   if test x"$UIC" = xfalse; then
 190     AC_MSG_WARN([Cannot find rcc (Qt Resource Compiler) in your PATH.\
 191   Try using --with-qt.])
 192   fi
 193
 194   # If we don't know the path to Qt, guess it from the path to qmake.
 195   if test x"$QT_PATH" = x; then
 196     QT_PATH=`dirname "$QMAKE"`
 197   fi
 198   if test x"$QT_PATH" = x; then
 199     AX_INSTEAD_IF([$4],
 200                   [Cannot find the path to your Qt install. Use --with-qt.])
 201     break
 202   fi
 203   AC_SUBST([QT_PATH])
 204
 205   # Get ready to build a test-app with Qt.
 206   if mkdir conftest.dir && cd conftest.dir; then :; else
 207     AX_INSTEAD_IF([$4], [Cannot mkdir conftest.dir or cd to that directory.])
 208     break
 209   fi
 210
 211   cat >conftest.h <<_ASEOF
 212 #include <QObject>
 213
 214 class Foo: public QObject
 215 {
 216   Q_OBJECT;
 217 public:
 218   Foo();
 219   ~Foo() {}
 220 public slots:
 221   void setValue(int value);
 222 signals:
 223   void valueChanged(int newValue);
 224 private:
 225   int value_;
 226 };
 227 _ASEOF
 228
 229   cat >conftest.cpp <<_ASEOF
 230 #include "conftest.h"
 231 Foo::Foo()
 232   : value_ (42)
 233 {
 234   connect(this, SIGNAL(valueChanged(int)), this, SLOT(setValue(int)));
 235 }
 236
 237 void Foo::setValue(int value)
 238 {
 239   value_ = value;
 240 }
 241
 242 int main()
 243 {
 244   Foo f;
 245 }
 246 _ASEOF
 247   if $QMAKE -project; then :; else
 248     AX_INSTEAD_IF([$4], [Calling $QMAKE -project failed.])
 249     break
 250   fi
 251
 252   # Find the .pro file generated by qmake.
 253   pro_file='conftest.dir.pro'
 254   test -f $pro_file || pro_file=`echo *.pro`
 255   if test -f "$pro_file"; then :; else
 256     AX_INSTEAD_IF([$4], [Can't find the .pro file generated by Qmake.])
 257     break
 258   fi
 259
 260 dnl Tweak the value of QT in the .pro if have been the 1st arg.
 261 m4_ifval([$1], [_AT_TWEAK_PRO_FILE([QT], [$1])])
 262
 263 dnl Tweak the value of CONFIG in the .pro if have been given a 2nd arg.
 264 m4_ifval([$2], [_AT_TWEAK_PRO_FILE([CONFIG], [$2])])
 265
 266 m4_ifval([$3],
 267 [ # Add the extra-settings the user wants to set in the .pro
 268   echo "$3" >>"$pro_file"
 269 ])
 270
 271   echo "$as_me:$LINENO: Invoking $QMAKE on $pro_file" >&AS_MESSAGE_LOG_FD
 272   sed 's/^/| /' "$pro_file" >&AS_MESSAGE_LOG_FD
 273
 274   if $QMAKE; then :; else
 275     AX_INSTEAD_IF([$4], [Calling $QMAKE failed.])
 276     break
 277   fi
 278
 279   # QMake has a very annoying misfeature: sometimes it generates Makefiles
 280   # where all the references to the files from the Qt installation are
 281   # relative.  We can't use them as-is because if we take, say, a
 282   # -I../../usr/include/Qt from that Makefile, the flag is invalid as soon
 283   # as we use it in another (sub) directory.  So what this perl pass does is
 284   # that it rewrite all relative paths to absolute paths.  Another problem
 285   # when building on Cygwin is that QMake mixes paths with blackslashes and
 286   # forward slashes and paths must be handled with extra care because of the
 287   # stupid Windows drive letters.
 288   echo "$as_me:$LINENO: fixing the Makefiles:" Makefile* >&AS_MESSAGE_LOG_FD
 289   cat >fixmk.pl <<\EOF
 290 [use strict;
 291 use Cwd qw(cwd abs_path);
 292 # This variable is useful on Cygwin for the following reason: Say that you are
 293 # in `/' (that is, in fact you are in C:/cygwin, or something like that) if you
 294 # `cd ..' then obviously you remain in `/' (that is in C:/cygwin).  QMake
 295 # generates paths that are relative to C:/ (or another driver letter, whatever)
 296 # so the trick to get the `..' resolved properly is to prepend the absolute
 297 # path of the current working directory in a Windows-style.  C:/cygwin/../ will
 298 # properly become C:/.
 299 my $d = "";
 300 my $r2a = 0;
 301 my $b2f = 0;
 302
 303 my $cygwin = 0;
 304 if ($^O eq "cygwin") {
 305   $cygwin = 1;
 306   $d = cwd();
 307   $d = `cygpath --mixed '$d'`;
 308   chomp($d);
 309   $d .= "/";
 310 }
 311
 312 sub rel2abs($)
 313 {
 314   my $p = $d . shift;
 315   # print "r2a p=$p";
 316   -e $p || return $p;
 317   if ($cygwin) {
 318     $p = `cygpath --mixed '$p'`;
 319     chomp($p);
 320   }
 321   else {
 322     # Do not use abs_path on Cygwin: it incorrectly resolves the paths that are
 323     # relative to C:/ rather than `/'.
 324     $p = abs_path($p);
 325   }
 326   # print " -> $p\n";
 327   ++$r2a;
 328   return $p;
 329 }
 330
 331 # Only useful on Cygwin.
 332 sub back2forward($)
 333 {
 334   my $p = shift;
 335   # print "b2f p=$p";
 336   -e $p || return $p;
 337   $p = `cygpath --mixed '$p'`;
 338   chomp($p);
 339   # print " -> $p\n";
 340   ++$b2f;
 341   return $p;
 342 }
 343
 344 foreach my $mk (@ARGV)
 345 {
 346   next if $mk =~ /~$/;
 347   open(MK, $mk) or die("open $mk: $!");
 348   # print "mk=$mk\n";
 349   my $file = join("", <MK>);
 350   close(MK) or die("close $mk: $!");
 351   rename $mk, $mk . "~" or die("rename $mk: $!");
 352   $file =~ s{(?:\.\.[\\/])+(?:[^"'\s:]+)}{rel2abs($&)}gse;
 353   $file =~ s{(?:[a-zA-Z]:[\\/])?(?:[^"\s]+\\[^"\s:]+)+}
 354             {back2forward($&)}gse if $cygwin;
 355   open(MK, ">", $mk) or die("open >$mk: $!");
 356   print MK $file;
 357   close(MK) or die("close >$mk: $!");
 358   print "$mk: updated $r2a relative paths and $b2f backslash-style paths\n";
 359   $r2a = 0;
 360   $b2f = 0;
 361 }]
 362 EOF
 363
 364   perl >&AS_MESSAGE_LOG_FD -w fixmk.pl Makefile* ||
 365   AC_MSG_WARN([failed to fix the Makefiles generated by $QMAKE])
 366   rm -f fixmk.pl
 367
 368   # Try to compile a simple Qt app.
 369   AC_CACHE_CHECK([whether we can build a simple Qt app], [at_cv_qt_build],
 370   [at_cv_qt_build=ko
 371   : ${MAKE=make}
 372
 373   if $MAKE >&AS_MESSAGE_LOG_FD 2>&1; then
 374     at_cv_qt_build='ok, looks like Qt 4'
 375   else
 376     echo "$as_me:$LINENO: Build failed, trying to #include <qobject.h> \
 377 instead" >&AS_MESSAGE_LOG_FD
 378     sed 's/<QObject>/<qobject.h>/' conftest.h > tmp.h && mv tmp.h conftest.h
 379     if $MAKE >&AS_MESSAGE_LOG_FD 2>&1; then
 380       at_cv_qt_build='ok, looks like Qt 3'
 381     else
 382       # Sometimes (such as on Debian) build will fail because Qt hasn't been
 383       # installed in debug mode and qmake tries (by default) to build apps in
 384       # debug mode => Try again in release mode.
 385       echo "$as_me:$LINENO: Build failed, trying to enforce release mode" \
 386             >&AS_MESSAGE_LOG_FD
 387
 388       _AT_TWEAK_PRO_FILE([CONFIG], [+release])
 389
 390       sed 's/<qobject.h>/<QObject>/' conftest.h > tmp.h && mv tmp.h conftest.h
 391       if $MAKE >&AS_MESSAGE_LOG_FD 2>&1; then
 392         at_cv_qt_build='ok, looks like Qt 4, release mode forced'
 393       else
 394         echo "$as_me:$LINENO: Build failed, trying to #include <qobject.h> \
 395 instead" >&AS_MESSAGE_LOG_FD
 396         sed 's/<QObject>/<qobject.h>/' conftest.h >tmp.h && mv tmp.h conftest.h
 397         if $MAKE >&AS_MESSAGE_LOG_FD 2>&1; then
 398           at_cv_qt_build='ok, looks like Qt 3, release mode forced'
 399         else
 400           at_cv_qt_build=ko
 401           echo "$as_me:$LINENO: failed program was:" >&AS_MESSAGE_LOG_FD
 402           sed 's/^/| /' conftest.h >&AS_MESSAGE_LOG_FD
 403           echo "$as_me:$LINENO: failed program was:" >&AS_MESSAGE_LOG_FD
 404           sed 's/^/| /' conftest.cpp >&AS_MESSAGE_LOG_FD
 405         fi # if make with Qt3-style #include and release mode forced.
 406       fi # if make with Qt4-style #include and release mode forced.
 407     fi # if make with Qt3-style #include.
 408   fi # if make with Qt4-style #include.
 409   ])dnl end: AC_CACHE_CHECK(at_cv_qt_build)
 410
 411   if test x"$at_cv_qt_build" = xko; then
 412     AX_INSTEAD_IF([$4], [Cannot build a test Qt program])
 413     break
 414   fi
 415   QT_VERSION_MAJOR=`echo "$at_cv_qt_build" | sed 's/[[^0-9]]*//g'`
 416   AC_SUBST([QT_VERSION_MAJOR])
 417
 418   # This sed filter is applied after an expression of the form: /^FOO.*=/!d;
 419   # It starts by removing the beginning of the line, removing references to
 420   # SUBLIBS, removing unnecessary whitespaces at the beginning, and prefixes
 421   # all variable uses by QT_.
 422   qt_sed_filter='s///;
 423                  s/$(SUBLIBS)//g;
 424                  s/^ *//;
 425                  s/\$(\(@<:@A-Z_@:>@@<:@A-Z_@:>@*\))/$(QT_\1)/g'
 426
 427   # Find the Makefile (qmake happens to generate a fake Makefile which invokes
 428   # a Makefile.Debug or Makefile.Release). We we have both, we'll pick the
 429   # Makefile.Release. The reason is that the main difference is that release
 430   # uses -Os and debug -g. We can override -Os by passing another -O but we
 431   # usually don't override -g.
 432   if test -f Makefile.Release; then
 433     at_mfile='Makefile.Release'
 434   else
 435     at_mfile='Makefile'
 436   fi
 437   if test -f $at_mfile; then :; else
 438     AX_INSTEAD_IF([$4], [Cannot find the Makefile generated by qmake.])
 439     break
 440   fi
 441
 442   # Find the DEFINES of Qt (should have been named CPPFLAGS).
 443   AC_CACHE_CHECK([for the DEFINES to use with Qt], [at_cv_env_QT_DEFINES],
 444   [at_cv_env_QT_DEFINES=`sed "/^DEFINES@<:@^A-Z=@:>@*=/!d;$qt_sed_filter" $at_mfile`])
 445   AC_SUBST([QT_DEFINES], [$at_cv_env_QT_DEFINES])
 446
 447   # Find the CFLAGS of Qt (We can use Qt in C?!)
 448   AC_CACHE_CHECK([for the CFLAGS to use with Qt], [at_cv_env_QT_CFLAGS],
 449   [at_cv_env_QT_CFLAGS=`sed "/^CFLAGS@<:@^A-Z=@:>@*=/!d;$qt_sed_filter" $at_mfile`])
 450   AC_SUBST([QT_CFLAGS], [$at_cv_env_QT_CFLAGS])
 451
 452   # Find the CXXFLAGS of Qt.
 453   AC_CACHE_CHECK([for the CXXFLAGS to use with Qt], [at_cv_env_QT_CXXFLAGS],
 454   [at_cv_env_QT_CXXFLAGS=`sed "/^CXXFLAGS@<:@^A-Z=@:>@*=/!d;$qt_sed_filter" $at_mfile`])
 455   AC_SUBST([QT_CXXFLAGS], [$at_cv_env_QT_CXXFLAGS])
 456
 457   # Find the INCPATH of Qt.
 458   AC_CACHE_CHECK([for the INCPATH to use with Qt], [at_cv_env_QT_INCPATH],
 459   [at_cv_env_QT_INCPATH=`sed "/^INCPATH@<:@^A-Z=@:>@*=/!d;$qt_sed_filter" $at_mfile`])
 460   AC_SUBST([QT_INCPATH], [$at_cv_env_QT_INCPATH])
 461
 462   AC_SUBST([QT_CPPFLAGS], ["$at_cv_env_QT_DEFINES $at_cv_env_QT_INCPATH"])
 463
 464   # Find the LFLAGS of Qt (Should have been named LDFLAGS)
 465   AC_CACHE_CHECK([for the LDFLAGS to use with Qt], [at_cv_env_QT_LDFLAGS],
 466   [at_cv_env_QT_LDFLAGS=`sed "/^LFLAGS@<:@^A-Z=@:>@*=/!d;$qt_sed_filter" $at_mfile`])
 467   AC_SUBST([QT_LFLAGS], [$at_cv_env_QT_LDFLAGS])
 468   AC_SUBST([QT_LDFLAGS], [$at_cv_env_QT_LDFLAGS])
 469
 470   AC_MSG_CHECKING([whether host operating system is Darwin])
 471   at_darwin="no"
 472   case $host_os in
 473     darwin*)
 474       at_darwin="yes"
 475       ;;
 476   esac
 477   AC_MSG_RESULT([$at_darwin])
 478
 479   # Find the LIBS of Qt.
 480   AC_CACHE_CHECK([for the LIBS to use with Qt], [at_cv_env_QT_LIBS],
 481   [at_cv_env_QT_LIBS=`sed "/^LIBS@<:@^A-Z@:>@*=/!d;$qt_sed_filter" $at_mfile`
 482    if test x$at_darwin = xyes; then
 483      # Fix QT_LIBS: as of today Libtool (GNU Libtool 1.5.23a) doesn't handle
 484      # -F properly. The "bug" has been fixed on 22 October 2006
 485      # by Peter O'Gorman but we provide backward compatibility here.
 486      at_cv_env_QT_LIBS=`echo "$at_cv_env_QT_LIBS" \
 487                              | sed 's/^-F/-Wl,-F/;s/ -F/ -Wl,-F/g'`
 488    fi
 489   ])
 490   AC_SUBST([QT_LIBS], [$at_cv_env_QT_LIBS])
 491
 492   cd .. && rm -rf conftest.dir
 493
 494   # Run the user code
 495   $5
 496
 497   done  # end hack (useless for to be able to use break)
 498 ])
 499
 500 # AT_REQUIRE_QT_VERSION(QT_version, RUN-IF-FAILED, RUN-IF-OK)
 501 # -----------------------------------------------------------
 502 # Check (using qmake) that Qt's version "matches" QT_version.
 503 # Must be run AFTER AT_WITH_QT. Requires autoconf 2.60.
 504 #
 505 # RUN-IF-FAILED is arbitrary code to execute if Qt cannot be found or if any
 506 # problem happens.  If this argument is omitted, then AC_MSG_ERROR will be
 507 # called.  RUN-IF-OK is arbitrary code to execute if Qt was successfully found.
 508 AC_DEFUN([AT_REQUIRE_QT_VERSION],
 509 [ AC_PREREQ([2.60])
 510   # this is a hack to get decent flow control with 'break'
 511   for _qt_ignored in once; do
 512
 513   if test x"$QMAKE" = x; then
 514     AX_INSTEAD_IF([$2],
 515                   [\$QMAKE is empty.\
 516   Did you invoke AT@&t@_WITH_QT before AT@&t@_REQUIRE_QT_VERSION?])
 517     break
 518   fi
 519   AC_CACHE_CHECK([for Qt's version], [at_cv_QT_VERSION],
 520   [echo "$as_me:$LINENO: Running $QMAKE --version:" >&AS_MESSAGE_LOG_FD
 521   $QMAKE --version >&AS_MESSAGE_LOG_FD 2>&1
 522   qmake_version_sed=['/^.*\([0-9]\.[0-9]\.[0-9]\).*$/!d;s//\1/']
 523   at_cv_QT_VERSION=`$QMAKE --version 2>&1 | sed "$qmake_version_sed"`])
 524   if test x"$at_cv_QT_VERSION" = x; then
 525     AX_INSTEAD_IF([$2], [Cannot detect Qt's version.])
 526     break
 527   fi
 528   AC_SUBST([QT_VERSION], [$at_cv_QT_VERSION])
 529   AS_VERSION_COMPARE([$QT_VERSION], [$1],
 530     [AX_INSTEAD_IF([$2], [This package requires Qt $1 or above.])],
 531     [$2], [$2])
 532
 533   # Run the user code
 534   $3
 535
 536   done  # end hack (useless for to be able to use break)
 537 ])
 538
 539 # _AT_TWEAK_PRO_FILE(QT_VAR, VALUE)
 540 # ---------------------------
 541 # @internal. Tweak the variable QT_VAR in the .pro.
 542 # VALUE is an IFS-separated list of value and each value is rewritten
 543 # as follows:
 544 #   +value  => QT_VAR += value
 545 #   -value  => QT_VAR -= value
 546 #    value  => QT_VAR += value
 547 AC_DEFUN([_AT_TWEAK_PRO_FILE],
 548 [ # Tweak the value of $1 in the .pro file for $2.
 549
 550   qt_conf=''
 551   for at_mod in $2; do
 552     at_mod=`echo "$at_mod" | sed 's/^-//; tough
 553                                   s/^+//; beef
 554                                   :ough
 555                                   s/^/$1 -= /;n
 556                                   :eef
 557                                   s/^/$1 += /'`
 558     qt_conf="$qt_conf
 559 $at_mod"
 560   done
 561   echo "$qt_conf" | sed 1d >>"$pro_file"
 562 ])