gen-testsuite-part

   1 #! /usr/bin/env perl
   2 # Automatically compute some dependencies for the hand-written tests
   3 # of the Automake testsuite.  Also, automatically generate some more
   4 # tests from them (for particular cases/setups only).
   5
   6 # Copyright (C) 2011-2012 Free Software Foundation, Inc.
   7
   8 # This program is free software; you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 2, or (at your option)
  11 # any later version.
  12
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 #--------------------------------------------------------------------------
  22
  23 use warnings FATAL => "all";
  24 use strict;
  25 use File::Basename ();
  26 use constant TRUE => 1;
  27 use constant FALSE => 0;
  28
  29 my $me = File::Basename::basename $0;
  30
  31 # For use in VPATH builds.
  32 my $srcdir = ".";
  33
  34 # The testsuite subdirectory, relative to the top-lever source directory.
  35 my $testdir = "t";
  36
  37 # Where testsuite-related helper scripts, data files and shell libraries
  38 # are placed.  Relative to the top-lever source directory.
  39 my $testauxdir = "$testdir/ax";
  40
  41 #--------------------------------------------------------------------------
  42
  43 sub unindent ($)
  44 {
  45   my $text = shift;
  46   $text =~ /^(\s*)/;
  47   my $indentation = $1;
  48   $text =~ s/^$indentation//gm;
  49   return $text;
  50 }
  51
  52 sub atomic_write ($$;$)
  53 {
  54   my ($outfile, $func) = (shift, shift);
  55   my $perms = @_ > 0 ? shift : 0777;
  56   my $tmpfile = "$outfile-t";
  57   foreach my $f ($outfile, $tmpfile)
  58     {
  59       unlink $f or die "$me: cannot unlink '$f': $!\n"
  60         if -e $f;
  61     }
  62   open (my $fh, ">$tmpfile")
  63     or die "$me: can't write to '$tmpfile': $!\n";
  64   $func->($fh);
  65   close $fh
  66     or die "$me: closing '$tmpfile': $!\n";
  67   chmod ($perms & ~umask, $tmpfile)
  68     or die "$me: cannot change perms for '$tmpfile': $!\n";
  69   rename ($tmpfile, $outfile)
  70     or die "$me: renaming '$tmpfile' -> '$outfile: $!\n'";
  71 }
  72
  73 sub line_match ($$)
  74 {
  75   my ($re, $file) = (shift, shift);
  76   # Try both builddir and srcdir, with builddir first, to play nice
  77   # with VPATH builds.
  78   open (FH, "<$file") or open (FH, "<$srcdir/$file")
  79     or die "$me: cannot open file '$file': $!\n";
  80   my $ret = 0;
  81   while (defined (my $line = <FH>))
  82     {
  83       if ($line =~ $re)
  84         {
  85           $ret = 1;
  86           last;
  87         }
  88     }
  89   close FH or die "$me: cannot close file '$file': $!\n";
  90   return $ret;
  91 }
  92
  93 sub write_wrapper_script ($$$)
  94 {
  95   my ($file_handle, $wrapped_test, $shell_setup_code, $creator_name) = @_;
  96   print $file_handle unindent <<EOF;
  97     #! /bin/sh
  98     # This file has been automatically generated.  DO NOT EDIT BY HAND!
  99     . test-lib.sh
 100     $shell_setup_code
 101     # In the spirit of VPATH, we prefer a test in the build tree
 102     # over one in the source tree.
 103     for dir in . "\$am_top_srcdir"; do
 104       if test -f "\$dir/$wrapped_test"; then
 105         echo "\$0: will source \$dir/$wrapped_test"
 106         . "\$dir/$wrapped_test"; exit \$?
 107       fi
 108     done
 109     echo "\$0: cannot find wrapped test '$wrapped_test'" >&2
 110     exit 99
 111 EOF
 112 }
 113
 114 sub get_list_of_tests ()
 115 {
 116   my $make = defined $ENV{MAKE} ? $ENV{MAKE} : "make";
 117   # Unset MAKEFLAGS, for when we are called from make itself.
 118   my $cmd = "MAKEFLAGS= && unset MAKEFLAGS && cd '$srcdir' && "
 119             . "$make -s -f $testdir/list-of-tests.mk print-list-of-tests";
 120   my @tests_list = split /\s+/, `$cmd`;
 121   die "$me: cannot get list of tests\n" unless $? == 0 && @tests_list;
 122   my $ok = 1;
 123   foreach my $test (@tests_list)
 124     {
 125       # Respect VPATH builds.
 126       next if -f $test || -f "$srcdir/$test";
 127       warn "$me: test '$test' not found\n";
 128       $ok = 0;
 129     }
 130   die "$me: some test scripts not found\n" if !$ok;
 131   return @tests_list;
 132 }
 133
 134 sub parse_options (@)
 135 {
 136   use Getopt::Long qw/GetOptions/;
 137   local @ARGV = @_;
 138   GetOptions ('srcdir=s' => \$srcdir) or die "$me: usage error\n";
 139   die "$me: too many arguments\n" if @ARGV > 0;
 140   die "$me: srcdir '$srcdir': not a directory\n" unless -d $srcdir;
 141 }
 142
 143 #--------------------------------------------------------------------------
 144
 145 my %deps_extractor =
 146   (
 147     libtool_macros =>
 148       {
 149         line_matcher => qr/^\s*required=.*\blibtool/,
 150         nodist_prereqs => "$testdir/libtool-macros.log",
 151       },
 152     gettext_macros =>
 153       {
 154         line_matcher => qr/^\s*required=.*\bgettext/,
 155         nodist_prereqs => "$testdir/gettext-macros.log",
 156       },
 157     use_trivial_test_driver =>
 158       {
 159         line_matcher => qr/\btrivial-test-driver\b/,
 160         dist_prereqs => "$testauxdir/trivial-test-driver",
 161       },
 162     check_testsuite_summary =>
 163       {
 164         line_matcher => qr/\btestsuite-summary-checks\.sh\b/,
 165         dist_prereqs => "$testauxdir/testsuite-summary-checks.sh",
 166       },
 167     extract_testsuite_summary =>
 168       {
 169         line_matcher => qr/\bextract-testsuite-summary\.pl\b/,
 170         dist_prereqs => "$testauxdir/extract-testsuite-summary.pl",
 171       },
 172     check_tap_testsuite_summary =>
 173       {
 174         line_matcher => qr/\btap-summary-aux\.sh\b/,
 175         dist_prereqs => "$testauxdir/tap-summary-aux.sh",
 176       },
 177     on_tap_with_common_setup =>
 178       {
 179         line_matcher => qr/\btap-setup\.sh\b/,
 180         dist_prereqs => "$testauxdir/tap-setup.sh",
 181         nodist_prereqs => "$testdir/tap-common-setup.log",
 182       },
 183     depcomp =>
 184       {
 185         line_matcher => qr/\bdepcomp\.sh\b/,
 186         dist_prereqs => "$testauxdir/depcomp.sh",
 187       },
 188   );
 189
 190 #--------------------------------------------------------------------------
 191
 192 my %test_generators =
 193   (
 194     #
 195     # Any test script in the Automake testsuite that checks features of
 196     # the Automake-provided parallel testsuite harness might want to
 197     # define a sibling test that does similar checks, but for the old
 198     # serial testsuite harness instead.
 199     #
 200     # Individual tests can request the creation of such a sibling by
 201     # making the string "try-with-serial-tests" appear any line of the
 202     # test itself.
 203     #
 204     serial_testsuite_harness =>
 205       {
 206         line_matcher     => qr/\btry-with-serial-tests\b/,
 207         shell_setup_code => 'am_serial_tests=yes',
 208       },
 209     #
 210     # For each test script in the Automake testsuite that tests features
 211     # of one or more automake-provided shell script from the 'lib/'
 212     # subdirectory by running those scripts directly (i.e., not thought
 213     # make calls and automake-generated makefiles), define a sibling test
 214     # that does likewise, but running the said script with the configure
 215     # time $SHELL instead of the default system shell /bin/sh.
 216     #
 217     # A test is considered a candidate for sibling-generation if it calls
 218     # the 'get_shell_script' function anywhere.
 219     #
 220     # Individual tests can prevent the creation of such a sibling by
 221     # explicitly setting the '$am_test_prefer_config_shell' variable
 222     # to either "yes" or "no".
 223     # The rationale for this is that if the variable is set to "yes",
 224     # the test already uses $SHELL, so that a sibling would be just a
 225     # duplicate; while if the variable is set to "no", the test doesn't
 226     # support, or is not meant to use, $SHELL to run the script under
 227     # testing, and forcing it to do so in the sibling would likely
 228     # cause a spurious failure.
 229     #
 230     prefer_config_shell =>
 231       {
 232         line_matcher =>
 233           qr/(^|\s)get_shell_script\s/,
 234         line_rejecter =>
 235           qr/\bam_test_prefer_config_shell=/,
 236         shell_setup_code =>
 237           'am_test_prefer_config_shell=yes',
 238       },
 239     #
 240     # Tests on tap support should be run with both the perl and awk
 241     # implementations of the TAP driver (they run with the awk one
 242     # by default).
 243     #
 244     perl_tap_driver =>
 245       {
 246         line_matcher =>
 247           qr<(?:\bfetch_tap_driver\b|[\s/]tap-setup\.sh\b)>,
 248         line_rejecter =>
 249           qr/\bam_tap_implementation=/,
 250         shell_setup_code =>
 251           'am_tap_implementation=perl',
 252       },
 253   );
 254
 255 #--------------------------------------------------------------------------
 256
 257 parse_options @ARGV;
 258
 259 my @all_tests = get_list_of_tests;
 260 my @generated_tests = (); # Will be updated later.
 261
 262 print "## -*- Makefile -*-\n";
 263 print "## Generated by $me.  DO NOT EDIT BY HAND!\n\n";
 264
 265 print <<EOF;
 266
 267 ## --------------------------------------------- ##
 268 ##  Autogenerated tests and their dependencies.  ##
 269 ## --------------------------------------------- ##
 270
 271 EOF
 272
 273 # A test script '$test' can possibly match more than one condition, so
 274 # for each tests we need to keep a list of generated wrapper tests.
 275 # Since what defines these wrapper scripts is the set of initializations
 276 # that are issued before sourcing the original, wrapped tests, these
 277 # initializations is what we put in our list entries.
 278 # The list will be saved in the hash entry '$wrapper_setups{$test}'.
 279 my %wrapper_setups = ();
 280 foreach my $test (@all_tests)
 281   {
 282     my @setups = ('');
 283     foreach my $x (values %test_generators)
 284     {
 285       next
 286         if not line_match $x->{line_matcher}, $test;
 287       next
 288         if $x->{line_rejecter} and line_match $x->{line_rejecter}, $test;
 289       @setups = map { ($_, "$_\n$x->{shell_setup_code}") } @setups;
 290     }
 291     @setups = grep { $_ ne '' } @setups;
 292     $wrapper_setups{$test} = \@setups if @setups;
 293   }
 294 # And now create all the wrapper tests.
 295 while (my ($wrapped_test, $setup_list) = each %wrapper_setups)
 296   {
 297     (my $base = $wrapped_test) =~ s/\.([^.]*)$//;
 298     my $suf = $1 or die "$me: test '$wrapped_test' lacks a suffix\n";
 299     my $count = 0;
 300     foreach my $setup (@$setup_list)
 301       {
 302         $count++;
 303         my $wbase = "$base-w" . ($count > 1 ? $count : '');
 304         my $wrapper_test =  "$wbase.$suf";
 305         # Register wrapper test as "autogenerated".
 306         push @generated_tests, $wrapper_test;
 307         # Create wrapper test.
 308         atomic_write $wrapper_test,
 309                      sub { write_wrapper_script $_[0], $wrapped_test,
 310                                                 $setup },
 311                      0555;
 312         # The generated test works by sourcing the original test, so that
 313         # it has to be re-run every time that changes ...
 314         print "$wbase.log: $wrapped_test\n";
 315         # ... but also every time the prerequisites of the wrapped test
 316         # changes.  The simpler (although suboptimal) way to do so is to
 317         # ensure that the wrapped tests runs before the wrapper one (in
 318         # case it needs to be re-run *at all*).
 319         # FIXME: we could maybe refactor the script to find a more
 320         # granular way to express such implicit dependencies.
 321         print "$wbase.log: $base.log\n";
 322       }
 323   }
 324
 325 print <<EOF;
 326
 327 ## ---------------------------------------------------- ##
 328 ##  Ad-hoc autogenerated tests and their dependencies.  ##
 329 ## ---------------------------------------------------- ##
 330
 331 EOF
 332
 333 print "## Tests on automatic dependency tracking (see 'depcomp.sh').\n";
 334
 335 # Key: depmode, value: list of required programs.
 336 my %depmodes =
 337   (
 338     auto         => ["cc"],
 339     disabled     => ["cc"],
 340     makedepend   => ["cc", "makedepend"],
 341     dashmstdout  => ["gcc"],
 342     cpp          => ["gcc"],
 343 # This was for older (pre-3.x) GCC versions (newer versions
 344 # have depmode "gcc3").  But other compilers use this depmode
 345 # as well (for example, the IMB xlc/xlC compilers, and the HP
 346 # C compiler, see 'lib/depcomp' for more info), so it's not
 347 # obsolete, and it's worth giving it some coverage.
 348     gcc          => ["gcc"],
 349 # This is for older (pre-7) msvc versions.  Newer versions
 350 # have depmodes "msvc7" and "msvc7msys".
 351     msvisualcpp  => ["cl", "cygpath"],
 352     msvcmsys     => ["cl", "mingw"],
 353   );
 354
 355 foreach my $lt (TRUE, FALSE)
 356   {
 357     foreach my $m (keys %depmodes)
 358       {
 359         my $planned = ($lt && $m eq "auto") ? 84 : 28;
 360         my @required =
 361           (
 362             @{$depmodes{$m}},
 363             $lt ? ("libtoolize",) : (),
 364           );
 365         my @vars_init =
 366           (
 367             "am_create_testdir=empty",
 368             "depmode=$m",
 369             "depcomp_with_libtool=" . ($lt ? "yes" : "no"),
 370           );
 371         my $test = "$testdir/depcomp" . ($lt ? "-lt-" : "-") . "$m.tap";
 372         # Register wrapper test as "autogenerated" ...
 373         push @generated_tests, $test;
 374         # ... and create it.
 375         atomic_write ($test, sub
 376           {
 377             my $file_handle = shift;
 378             print $file_handle unindent <<EOF;
 379               #! /bin/sh
 380               # Automatically generated test.  DO NOT EDIT BY HAND!
 381               @vars_init
 382               required="@required"
 383               . ./defs || exit 1
 384               plan_ $planned
 385               . depcomp.sh
 386               exit \$?
 387 EOF
 388           },
 389           0555);
 390       }
 391    }
 392
 393 # Update generated makefile fragment to account for all the generated tests.
 394 print "generated_TESTS =\n";
 395 map { print "generated_TESTS += $_\n" } @generated_tests;
 396
 397 # The test scripts are scanned for automatic dependency generation *after*
 398 # the generated tests have been created, so they too can be scanned.  To
 399 # do so correctly, we need to update the list in '@all_tests' to make it
 400 # comprise also the freshly-generated tests.
 401
 402 push @all_tests, @generated_tests;
 403
 404 print <<EOF;
 405
 406 ## ----------------------------- ##
 407 ##  Autogenerated dependencies.  ##
 408 ## ----------------------------- ##
 409
 410 EOF
 411
 412 while (my ($k, $x) = each %deps_extractor)
 413   {
 414     my $dist_prereqs = $x->{dist_prereqs} || "";
 415     my $nodist_prereqs = $x->{nodist_prereqs} || "";
 416     my @tests = grep { line_match $x->{line_matcher}, $_ } @all_tests;
 417     map { s/\.[^.]*$//; s/$/\.log/; } (my @logs = @tests);
 418     print "## Added by deps-extracting key '$k'.\n";
 419     ## The list of all tests which have a dependency detected by the
 420     ## current key.
 421     print join(" \\\n  ", "${k}_TESTS =", @tests) . "\n";
 422     print "EXTRA_DIST += $dist_prereqs\n";
 423     map { print "$_: $dist_prereqs $nodist_prereqs\n" } @logs;
 424     print "\n";
 425   }
 426
 427 __END__