Merge branch 'minor'
[automake.git] / configure.ac
blob1aee6af278edc254e31ae24267b3057332fa42d8
1 # Process this file with autoconf to produce a configure script.
3 # Copyright (C) 1995-2017 Free Software Foundation, Inc.
5 # This program is free software; you can redistribute it and/or modify
6 # it under the terms of the GNU General Public License as published by
7 # the Free Software Foundation; either version 2, or (at your option)
8 # any later version.
10 # This program is distributed in the hope that it will be useful,
11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
13 # GNU General Public License for more details.
15 # You should have received a copy of the GNU General Public License
16 # along with this program.  If not, see <https://www.gnu.org/licenses/>.
18 AC_PREREQ([2.69])
19 AC_INIT([GNU Automake], [1.99a], [bug-automake@gnu.org])
21 AC_CONFIG_SRCDIR([bin/automake.in])
22 AC_CONFIG_AUX_DIR([lib])
24 AM_SILENT_RULES([yes])
26 AC_CANONICAL_HOST
27 AC_CANONICAL_BUILD
29 # Save the AUTOCONF setting before AM_INIT_AUTOMAKE overrides it; this
30 # way we can run Autoconf tests from configure (or from the test
31 # suite) without being bothered by 'missing'.  Likewise for autom4te,
32 # autoreconf, autoheader, and autoupdate.
33 AC_SUBST([am_AUTOCONF], ["${AUTOCONF-autoconf}"])
34 AC_SUBST([am_AUTOM4TE], ["${AUTOM4TE-autom4te}"])
35 AC_SUBST([am_AUTORECONF], ["${AUTORECONF-autoreconf}"])
36 AC_SUBST([am_AUTOHEADER], ["${AUTOHEADER-autoheader}"])
37 AC_SUBST([am_AUTOUPDATE], ["${AUTOUPDATE-autoupdate}"])
39 dnl We call AC_PROG_CC in an unusual way, and only for use in our
40 dnl testsuite, so also use 'no-dependencies' and 'no-define' among
41 dnl the automake options to avoid bloating and potential problems.
42 AM_INIT_AUTOMAKE([-Wall -Werror dist-xz filename-length-max=99
43                   no-define no-dependencies])
45 # Keep this on a line of its own, since it must be found and processed
46 # by the 'update-copyright' rule in our Makefile.
47 RELEASE_YEAR=2017
48 AC_SUBST([RELEASE_YEAR])
50 # The API version is the base version.  We must guarantee
51 # compatibility for all releases with the same API version.
52 APIVERSION=1.99a
53 AC_SUBST([APIVERSION])
55 AC_SUBST([pkgvdatadir], ["\${datadir}/$PACKAGE-$APIVERSION"])
56 AC_SUBST([scriptdir], ["\${pkgvdatadir}"])
57 AC_SUBST([amdir], ["\${pkgvdatadir}/am"])
58 AC_SUBST([automake_acdir], ["\${datadir}/aclocal-$APIVERSION"])
59 AC_SUBST([system_acdir], ["\${datadir}/aclocal"])
61 # Our build system is bootstrapped with the bleeding-edge versions of
62 # aclocal and automake, hence the remake rules must use those versions
63 # as well.  The extra quoting is to cater to cases when the build
64 # directory contains whitespace or shell metacharacters.
65 ACLOCAL="\"`pwd`/pre-inst-env\" aclocal-$APIVERSION"
66 AUTOMAKE="\"`pwd`/pre-inst-env\" automake-$APIVERSION"
68 AC_PROG_LN_S
70 AC_PATH_PROG([PERL], [perl])
71 if test -z "$PERL"; then
72    AC_MSG_ERROR([perl not found])
74 # Save details about the selected perl interpreter in config.log.
75 AM_RUN_LOG([$PERL --version])
76 $PERL -e 'require 5.006;' || {
77    AC_MSG_ERROR(
78 [perl 5.6 or better is required; perl 5.8.2 or better
79 is recommended.  If you have several perl versions
80 installed, select the one Automake should use using
81   ./configure PERL=/path/to/perl])
84 # The test suite will skip some tests if tex is absent.
85 AC_CHECK_PROG([TEX], [tex], [tex])
86 # Save details about the selected TeX program in config.log.
87 # Redirect input from /dev/null, as TeX might otherwise hang waiting
88 # for input from the terminal.
89 AM_RUN_LOG([$TEX --version </dev/null])
91 # The test suite will skip some tests if no lex or yacc program is
92 # available.
93 # We don't use AC_PROG_LEX nor AC_PROG_YACC here because:
94 #  1. we don't want flex (resp. bison) to be preferred to system lex
95 #     (resp. system yacc);
96 #  2. we don't want $LEX (resp. $YACC) to be defined to ':' (resp. 'yacc')
97 #     by default;
98 #  3. we prefer not to have the variables YFLAGS, LEX_OUTPUT_ROOT and
99 #     LEXLIB to be calculated and/or AC_SUBST'd;
100 #  4. we prefer that the YACC and LEX variables are not reported in the
101 #     configure help screen.
102 AC_CHECK_PROGS([YACC], [yacc byacc 'bison -y'], [false])
103 AC_CHECK_PROGS([LEX], [lex flex], [false])
105 # Test for Autoconf.  We run Autoconf in a subdirectory to ease
106 # deletion of any files created (such as those added to
107 # autom4te.cache).  We used to perform only the last of the three
108 # following tests, but some users were unable to figure out that their
109 # installation was broken since --version appeared to work.
111 AC_SUBST([required_autoconf_version], [2.65])
112 AC_CACHE_CHECK([whether autoconf is installed], [am_cv_autoconf_installed],
113 [if AM_RUN_LOG([$am_AUTOCONF --version]);
114 then
115   am_cv_autoconf_installed=yes
116 else
117   am_cv_autoconf_installed=no
118 fi])
119 if test "$am_cv_autoconf_installed" = no; then
120   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.
121     Please make sure it is installed and in your PATH.])
124 AC_CACHE_CHECK([whether autoconf works], [am_cv_autoconf_works],
125 [mkdir conftest
126 echo 'AC''_INIT' > conftest/conftest.ac
127 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
128 then
129   am_cv_autoconf_works=yes
130 else
131   am_cv_autoconf_works=no
133 rm -rf conftest])
134 if test "$am_cv_autoconf_works" = no; then
135   AC_MSG_ERROR([The installed version of autoconf does not work.
136     Please check config.log for error messages before this one.])
139 AC_CACHE_CHECK([whether autoconf is recent enough], [am_cv_autoconf_version],
140 [mkdir conftest
141 dnl Creative quoting required to avoid spurious expansion of AC_PREREQ macro
142 echo 'AC'"_PREREQ([[$required_autoconf_version]])" > conftest/conftest.ac
143 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
144 then
145   am_cv_autoconf_version=yes
146 else
147   am_cv_autoconf_version=no
149 rm -rf conftest])
150 if test "$am_cv_autoconf_version" = no; then
151   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.])
154 # Test for ln.  We need use it to install the versioned binaries.
155 AC_MSG_CHECKING([whether ln works])
156 AC_CACHE_VAL([am_cv_prog_ln], [
157 rm -f conftest conftest.file
158 : >conftest.file
159 if ln conftest.file conftest 2>/dev/null; then
160   am_cv_prog_ln=ln
161 else
162   am_cv_prog_ln='cp -p'
164 rm -f conftest conftest.file])
165 AC_SUBST([LN], [$am_cv_prog_ln])
166 result=no
167 test "x$am_cv_prog_ln" = xln && result=yes
168 AC_MSG_RESULT([$result])
170 # The amount we should wait after modifying files.
171 # FIXME: for file systems with sub-second timestamp resolutions, this
172 # FIXME: might be just one second (or even less if 'sleep' supports
173 # FIXME: non-integer arguments); is it worth pursuing that road?
174 AC_SUBST([MODIFICATION_DELAY], [2])
176 ## ------------------------------------------- ##
177 ##  Test for things needed by the test suite.  ##
178 ## ------------------------------------------- ##
180 AC_PROG_EGREP
181 AC_PROG_FGREP
183 dnl FIXME: could we extract this in a simpler way through autoconf
184 dnl FIXME: idioms or internals?
185 AC_DEFUN(
186   [_AM_INIT_BOURNE_COMPATIBLE_VAR],
187   [am_bourne_compatible="AS_ESCAPE(_m4_expand([AS_BOURNE_COMPATIBLE]))"])
190 dnl Arguments to this macro:
192 dnl   $1 - shell to test
193 dnl   $2 - description of the tested feature
194 dnl   $3 - shell code used to check the feature; to indicate success,
195 dnl        it can either exit with status 77, or have the last command
196 dnl        returning with exit status of zero
197 dnl   $4 - shell code to execute if the check on the shell is successful
198 dnl        (defaults to nothing)
199 dnl   $5 - shell code to execute if the check on the shell is not
200 dnl        successful (defaults to nothing)
202 AC_DEFUN([_AM_CHECK_SHELL_FEATURE],
203   [AC_REQUIRE([_AM_INIT_BOURNE_COMPATIBLE_VAR])
204   AC_MSG_CHECKING([whether $1 $2])
205   if { $1 -c "$am_bourne_compatible
206 AS_ESCAPE([$3])
207 test \$? -eq 0 || exit 1
208 # Use 77 to indicate success (rather than 0), in case some shell
209 # acts like Solaris 10's /bin/sh, exiting successfully on some
210 # syntax errors.
211 exit 77" >&AS_MESSAGE_LOG_FD 2>&1; test $? -eq 77; }
212   then
213     AC_MSG_RESULT([yes])
214     $4
215   else
216     AC_MSG_RESULT([no])
217     $5
218   fi])
220 # AM_CHECK_CANDIDATE_TEST_SHELL(SHELL-PATH)
221 # -----------------------------------------
223 # Check if the given shell is good enough to run our test scripts.
224 # Inspired to gnulib's 'tests/init.sh'.
226 # We require POSIX and XSI features (e.g., '$(...)' for command
227 # substitutions, '$((...))' for shell arithmetic, and support for
228 # '${var#...}' and '${var%...}' parameter expansions).
230 # We require that the shell can correctly trap EXIT when 'set -e' is in
231 # effect (OSF1/Tru64 sh failed to do so, see commit v1.10b-52-g9fe8259).
233 # We want to able to define shell aliases with the same name of shell
234 # builtins.
236 # We also prefer shells that, when 'set -x' is in effect, do not also
237 # redirect traces upon stderr redirections.  For example,
238 #  $ set -x; echo x 2>file
239 # would emit "+ echo x" into file with older zsh versions.  Similarly,
240 #   $ set -x; P=1 true 2>file
241 # would emit "P=1" into file with /usr/xpg4/bin/sh from Solaris 10 and
242 # /bin/sh from SunOS 5.11 and OpenBSD 4.7.
244 # Use '$am_score' to indicate the degree of acceptability of the shell.
245 # A score of "10" means that the shell is good enough for our needs;
246 # a score of "9" means that the shell has some minor bugs or limitation,
247 # but is still (barely) acceptable for our uses.  Any other score means
248 # that the shell is broken or unfit.
250 AC_DEFUN([_AM_CHECK_CANDIDATE_SHELL],
251   [am_score=10
252   while :; do
254     _AM_CHECK_SHELL_FEATURE([$1],
255       [supports \$(cmd)],
256       [test "$(echo x)" = x],
257       [], [am_score=1; break])
259     _AM_CHECK_SHELL_FEATURE([$1],
260       [supports \$((expr))],
261       [test $((1 + 2 * 3)) = 7],
262       [], [am_score=1; break])
264     _AM_CHECK_SHELL_FEATURE([$1],
265       [supports \${@%:@var}],
266       [zero='' one='x' twelve=' foobar baz!' \
267         && test ${@%:@zero} -eq 0 \
268         && test ${@%:@one} -eq 1 \
269         && test ${@%:@twelve} -eq 12],
270       [], [am_score=1; break])
272     _AM_CHECK_SHELL_FEATURE([$1],
273       [supports \${var@%:@glob} and \${var%glob}],
274       [v=a/b/c \
275         && test ${v@%:@*/} = b/c \
276         && test ${v@%:@@%:@*/} = c \
277         && test ${v%/*} = a/b \
278         && test ${v%%/*} = a],
279       [], [am_score=1; break])
281     _AM_CHECK_SHELL_FEATURE([$1],
282       [preserves exit traps with "set -e"],
283       [set -e; trap 'exit $?' 0; (exit 77); exit 77],
284       [], [am_score=1; break])
286     _AM_CHECK_SHELL_FEATURE([$1],
287       [can define exit traps in a shell function],
288       [fail=0 && foo() { trap 'fail=1' 0; } && foo && test $fail = 0],
289       [], [am_score=1; break])
291     _AM_CHECK_SHELL_FEATURE([$1],
292       [corrupts stderr with "set -x"],
293       [(set -x; P=1 true 2>&3) 3>&1 2>/dev/null | grep P=1],
294       [am_score=9], [])
296     echo 'return 34' > conftest-return.sh
297     echo 'ok=no' >> conftest-return.sh
298     _AM_CHECK_SHELL_FEATURE([$1],
299       [can return early from "dot-sourced" files],
300       [ok=yes; . ./conftest-return.sh; test $? -eq 34 && test $ok = yes],
301       [rm -f conftest-return.sh],
302       [rm -f conftest-return.sh; am_score=1; break])
304     echo 'alias false=echo' > conftest-alias.sh
305     echo 'false && test "$(false 97)" = 97' >> conftest-alias.sh
306     _AM_CHECK_SHELL_FEATURE([$1],
307       [supports alias named like shell builtins],
308       [. ./conftest-alias.sh],
309       [rm -f conftest-alias.sh],
310       [rm -f conftest-alias.sh; am_score=1; break])
312     _AM_CHECK_SHELL_FEATURE([$1],
313       [supports "test -e"],
314       [test -e config.log && test -e . && test ! -e nonesuch],
315       [], [am_score=1; break])
317     break
318   done])
320 # These messages only goes to the config.log file.
321 AC_MSG_NOTICE([will now look for a sturdy POSIX shell, for our testsuite])
323 AC_CACHE_VAL(
324   [ac_cv_AM_TEST_RUNNER_SHELL],
325   [if test "$AM_TEST_RUNNER_SHELL"; then
326     # Let the user override it.
327     ac_cv_AM_TEST_RUNNER_SHELL=$AM_TEST_RUNNER_SHELL
328   else
329     ac_cv_AM_TEST_RUNNER_SHELL=no
330     am_candidate_shells=${CONFIG_SHELL-}
331     # For the benefit of Solaris.
332     am_PATH=$PATH$PATH_SEPARATOR/usr/xpg6/bin$PATH_SEPARATOR/usr/xpg4/bin
333     for am_sh in sh sh5 dash ash bash zsh ksh pdksh; do
334       AC_PATH_PROG([am_candidate_sh], [$am_sh], [], [$am_PATH])
335       if test -n "$am_candidate_sh"; then
336         am_candidate_shells="$am_candidate_shells $am_candidate_sh"
337       fi
338       AM_SUBST_NOTMAKE([am_candidate_sh])
339       # Must nullify these in order not to interfere with the checks in
340       # the next loop.
341       AS_UNSET([am_candidate_sh])
342       AS_UNSET([ac_cv_path_am_candidate_sh])
343     done
344     AS_UNSET([am_PATH]) # Not required anymore
345     for am_sh in $am_candidate_shells; do
346       am_score=0
347       _AM_CHECK_CANDIDATE_SHELL([$am_sh])
348       if test $am_score -eq 9; then
349         # The shell is barely acceptable for our needs.  We might
350         # still find one that is even better, so continue looking.
351         AC_MSG_NOTICE([shell $am_sh is acceptable, but we might do better])
352         ac_cv_AM_TEST_RUNNER_SHELL=$am_sh
353       elif test $am_score -eq 10; then
354         AC_MSG_NOTICE([shell $am_sh is good enough, stop looking])
355         ac_cv_AM_TEST_RUNNER_SHELL=$am_sh
356         break
357       fi
358     done
359   fi
360   AM_TEST_RUNNER_SHELL=$ac_cv_AM_TEST_RUNNER_SHELL])
362 if test $AM_TEST_RUNNER_SHELL = no; then
363   AC_MSG_FAILURE([m4_normalize([no POSIX shell found that is good
364                                 enough to be used in our testsuite])])
365 else
366   AC_MSG_NOTICE([will use $AM_TEST_RUNNER_SHELL as the testsuite shell])
369 AC_ARG_VAR([AM_TEST_RUNNER_SHELL],
370            [a sturdy POSIX shell for our testsuite])
373 ###########################################################################
375 # Look for C, C++ and fortran compilers to be used in the testsuite.
377 dnl We don't want to abort our configuration script if no C compiler is
378 dnl available, as such a compiler is only required to run part of the
379 dnl testsuite, not to build or install Automake.  Ditto for C++, Fortran
380 dnl and Fortran 77 compilers.  Unfortunately, autoconf does not offer an
381 dnl easy way to obtain this behaviour, so we'll need a few hacks.
383 dnl We want the body of this macro to expand as a single shell statement,
384 dnl thus we wrap it into { ... } brackets.
385 AC_DEFUN([_AM_WRAP_MSG_ERROR], [ {
386   AC_MSG_WARN([$1])
387   am__failed=yes
388   break
389 } ])
391 AC_DEFUN([_AM_COMPILER_CAN_FAIL], [
392   m4_pushdef([AC_MSG_FAILURE], m4_defn([_AM_WRAP_MSG_ERROR]))
393   m4_pushdef([AC_MSG_ERROR],   m4_defn([_AM_WRAP_MSG_ERROR]))
394   am__failed=no
395   while :; do
396      $1
397      break
398   done
399   AS_IF([test $am__failed = yes], [$2])
400   # We have to clear these cache variables, so that future checks on
401   # compilers for different languages won't be confused.
402   unset ac_cv_objext ac_cv_exeext
403   # We also need to meddle with the autoconf internals to ensure that
404   # checks to find object and executable extensions will be run anew.
405   # FIXME: In the long run, the better thing to do would be to fix
406   # FIXME: autoconf instead ...
407   m4_undefine([m4_provide(_AC_COMPILER_OBJEXT)])
408   m4_undefine([m4_provide(_AC_COMPILER_EXEEXT)])
409   m4_popdef([AC_MSG_FAILURE])
410   m4_popdef([AC_MSG_ERROR])
413 AC_DEFUN([_AM_SKIP_COMP_TESTS],
414   [AC_MSG_NOTICE([tests requiring the $1 compiler will be skipped])])
416 # Prefer generic compilers to GNU ones when possible.  This will ensure
417 # more testsuite coverage "in the wild".
418 # Note that we don't look for the MSVC C/C++ compiler here.  This is
419 # deliberate; for more discussion and rationale, see:
420 # <https://lists.gnu.org/archive/html/automake-patches/2012-01/msg00130.html>
422 AC_MSG_NOTICE([will now look for generic compilers])
424 # C compiler.
425 _AM_COMPILER_CAN_FAIL(dnl
426   [AC_PROG_CC([cc gcc])],
427   [CC=false; _AM_SKIP_COMP_TESTS([C])])
429 AS_IF([test x"$GCC" = x"yes"], [am_CC_is_GNU=yes], [am_CC_is_GNU=no])
431 # On case-insensitive file systems (seen e.g. on Cygwin and Mac OS X)
432 # we must avoid looking for 'CC', because that would be the same as
433 # 'cc', and could cause $CXX to point to the C compiler, instead of
434 # to a C++ compiler as expected (see automake bugs #11893 and #10766).
435 # Similarly, we must avoid looking for 'RCC', as that can point to the
436 # Qt4 "Resource Compiler": <http://doc.qt.digia.com/4.2/rcc.html>
437 if test -f /bIn/rMdIr || test -f /uSr/bIn/rMdIr; then
438   # Case-insensitive file system, don't look for CC.
439   am_CC= am_RCC=
440 else
441   am_CC=CC am_RCC=RCC
444 # The list of C++ compilers here has been copied, pasted and edited
445 # from 'lib/autoconf/c.m4:AC_PROG_CXX' in the Autoconf distribution.
446 # Keep it in sync, or better again, find out a way to avoid this code
447 # duplication.
448 _AM_COMPILER_CAN_FAIL([AC_PROG_CXX(dnl
449   [aCC $am_CC FCC KCC $am_RCC xlC_r xlC c++ cxx cc++ gpp g++])],
450   [CXX=false; _AM_SKIP_COMP_TESTS([C++])])
452 AS_IF([test x"$GXX" = x"yes"], [am_CXX_is_GNU=yes], [am_CXX_is_GNU=no])
454 # The lists of Fortran compilers here has been copied, pasted and edited
455 # from file 'lib/autoconf/fortran.m4' in the Autoconf distribution.
456 # Keep it in sync, or better again, find out a way to avoid this code
457 # duplication.
459 _AM_COMPILER_CAN_FAIL([AC_PROG_FC(dnl
460   [xlf95 f95 fort ifort ifc efc pgfortran pgf95 lf95 ftn nagfor] dnl
461   [xlf90 f90 pgf90 pghpf epcf90 g95 gfortran])],
462   [FC=false; _AM_SKIP_COMP_TESTS([Fortran])])
464 AS_IF([test x"$GFC" = x"yes"], [am_FC_is_GNU=yes], [am_FC_is_GNU=no])
466 _AM_COMPILER_CAN_FAIL([AC_PROG_F77(dnl
467   [xlf f77 frt pgf77 cf77 fort77 fl32 af77 g77 gfortran])],
468   [F77=false; _AM_SKIP_COMP_TESTS([Fortran 77])])
470 AS_IF([test x"$G77" = x"yes"], [am_F77_is_GNU=yes], [am_F77_is_GNU=no])
472 # Some tests will need the GNU compilers.  Searching for them here would
473 # be overkill, since our testsuite already handles their search and setup
474 # pretty well.  But in case the compilers already found are the GNU ones,
475 # we want to use them in the testsuite where GNU compilers are required.
476 # Also, in case the compilers detected above (at configure time) are not
477 # the GNU ones, we cannot use the values of CFLAGS, CXXFLAGS, FCFLAGS and
478 # FFLAGS detected for them with the GNU compilers too, since it's likely
479 # they won't be compatible.  So we allow the user to define variants of
480 # these variables for the GNU compilers separately.
482 AC_MSG_NOTICE([will now look for GNU compilers])
484 # GNU C compiler.
485 AC_ARG_VAR([GNU_CC],     [GNU C compiler])
486 AC_ARG_VAR([GNU_CFLAGS], [GNU C compiler flags])
487 if test $am_CC_is_GNU = yes; then
488   AC_MSG_NOTICE([$CC is already a GNU C compiler])
489   GNU_CC=$CC GNU_CFLAGS=${GNU_CFLAGS-$CFLAGS}
490 else
491   AC_CHECK_TOOLS([GNU_CC], [gcc], [false])
493 if test "$GNU_CC" != false; then
494   AS_IF([AM_RUN_LOG([$GNU_CC --version && $GNU_CC -v])], [],
495         [AC_MSG_WARN([botched installation for GNU C compiler])
496          _AM_SKIP_COMP_TESTS([GNU C])])
499 # GNU C++ compiler.
500 AC_ARG_VAR([GNU_CXX],      [GNU C++ compiler])
501 AC_ARG_VAR([GNU_CXXFLAGS], [GNU C++ compiler flags])
502 if test $am_CXX_is_GNU = yes; then
503   AC_MSG_NOTICE([$CXX is already a GNU C++ compiler])
504   GNU_CXX=$CXX
505   GNU_CXXFLAGS=${GNU_CXXFLAGS-$CXXFLAGS}
506 else
507   AC_CHECK_TOOLS([GNU_CXX], [g++ gpp], [false])
509 if test "$GNU_CXX" != false; then
510   AS_IF([AM_RUN_LOG([$GNU_CXX --version && $GNU_CXX -v])], [],
511         [AC_MSG_WARN([botched installation for GNU C++ compiler])
512          _AM_SKIP_COMP_TESTS([GNU C++])])
515 # GNU Fortran compiler.
516 AC_ARG_VAR([GNU_FC],      [GNU Fortran compiler])
517 AC_ARG_VAR([GNU_FCFLAGS], [GNU Fortran compiler flags])
518 if test $am_FC_is_GNU = yes; then
519   AC_MSG_NOTICE([$FC is already a GNU Fortran compiler])
520   GNU_FC=$FC
521   GNU_FCFLAGS=${GNU_FCFLAGS-$FCFLAGS}
522 else
523   AC_CHECK_TOOLS([GNU_FC], [gfortran], [false])
525 if test "$GNU_FC" != false; then
526   AS_IF([AM_RUN_LOG([$GNU_FC --version && $GNU_FC -v])], [],
527         [AC_MSG_WARN([botched installation for GNU Fortran compiler])
528          _AM_SKIP_COMP_TESTS([GNU Fortran])])
531 # GNU Fortran 77 compiler.
532 AC_ARG_VAR([GNU_F77],    [GNU Fortran 77 compiler])
533 AC_ARG_VAR([GNU_FFLAGS], [GNU Fortran 77 compiler flags])
534 if test $am_F77_is_GNU = yes; then
535   AC_MSG_NOTICE([$F77 is already a GNU Fortran 77 compiler])
536   GNU_F77=$F77
537   GNU_FFLAGS=${GNU_FFLAGS-$FFLAGS}
538 else
539   AC_CHECK_TOOLS([GNU_F77], [g77 gfortran], [false])
541 if test "$GNU_F77" != false; then
542   AS_IF([AM_RUN_LOG([$GNU_F77 --version && $GNU_F77 -v])], [],
543         [AC_MSG_WARN([botched installation for GNU Fortran 77 compiler])
544         _AM_SKIP_COMP_TESTS([GNU Fortran 77])])
547 # GNU Java compiler.
548 AC_ARG_VAR([GNU_GCJ], [GNU Java compiler])
549 AC_ARG_VAR([GNU_GCJFLAGS], [GNU Java compiler flags])
550 AC_CHECK_TOOLS([GNU_GCJ], [gcj], [false])
551 if test "$GNU_GCJ" != false; then
552   AS_IF([AM_RUN_LOG([$GNU_GCJ --version && $GNU_GCJ -v])], [],
553         [AC_MSG_WARN([botched installation for GNU Java compiler])
554         _AM_SKIP_COMP_TESTS([GNU Java])])
557 # If we have been able to find at least a working compiler above, we
558 # know what the object and executable extensions for this platform are.
559 OBJEXT=${ac_cv_objext-UNKNOWN}
560 EXEEXT=${ac_cv_exeext-UNKNOWN}
561 AC_SUBST([OBJEXT])
562 AC_SUBST([EXEEXT])
564 ###########################################################################
566 ## ---------------------- ##
567 ##  Create output files.  ##
568 ## ---------------------- ##
570 AC_CONFIG_FILES([Makefile])
571 AC_CONFIG_LINKS([GNUmakefile:GNUmakefile])
572 AC_CONFIG_FILES([pre-inst-env], [chmod +x pre-inst-env])
573 AC_OUTPUT
575 # Inform the user if this version of automake is a beta release or
576 # a development snapshot.
577 # According to HACKING, the version of a development snapshot should
578 # end with an "odd" letter (a, c, ...), the version of a test release
579 # should end wit an "even" letter (b, d, ...).
581 am_stable_version_rx='[[1-9]\.[0-9]+(\.[0-9]+)?]'
582 am_beta_version_rx="[$am_stable_version_rx[bdfhjlnprtvxz]]"
584 am_release_type=`AS_ECHO(["$PACKAGE_VERSION"]) | LC_ALL=C awk ["
585   /^$am_stable_version_rx$/ { print \"stable\"; exit(0); }
586   /^$am_beta_version_rx$/ { print \"beta version\"; exit(0); }
587   { print \"development snapshot\"; }"]`
589 # '$silent' is set to yes if configure is passed the '--quiet' option.
590 test "$am_release_type" = stable || test "$silent" = yes || cat <<EOF
592 WARNING: You are about to use a $am_release_type of automake.
593 WARNING: It might easily suffer from new bugs or regressions.
594 WARNING: You are strongly advised not to use it in production code.
596 Please report bugs, problems and feedback to <AC_PACKAGE_BUGREPORT>.
599 AS_EXIT([0])