lib/autoconf/autotest.m4

   1 # This file is part of Autoconf.                       -*- Autoconf -*-
   2 # Interface with Autotest.
   3 # Copyright (C) 1992-1996, 1998-2005, 2009-2017 Free Software
   4 # Foundation, Inc.
   5
   6 # This file is part of Autoconf.  This program is free
   7 # software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the
   9 # Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # Under Section 7 of GPL version 3, you are granted additional
  18 # permissions described in the Autoconf Configure Script Exception,
  19 # version 3.0, as published by the Free Software Foundation.
  20 #
  21 # You should have received a copy of the GNU General Public License
  22 # and a copy of the Autoconf Configure Script Exception along with
  23 # this program; see the files COPYINGv3 and COPYING.EXCEPTION
  24 # respectively.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 # Written by David MacKenzie, with help from
  27 # Franc,ois Pinard, Karl Berry, Richard Pixley, Ian Lance Taylor,
  28 # Roland McGrath, Noah Friedman, david d zuhn, and many others.
  29
  30
  31 # AC_CONFIG_TESTDIR(TEST-DIRECTORY, [AUTOTEST-PATH = TEST-DIRECTORY])
  32 # -------------------------------------------------------------------
  33 # Configure an Autotest test suite directory.  Invoke it once per dir,
  34 # even if there are several test suites in there.
  35 #
  36 # AUTOTEST-PATH must help the test suite to find the executables.
  37 # It is relative to the top level of the package, and is expanded
  38 # into all the build dirs of AUTOTEST-PATH, then all the src dirs.
  39 #
  40 # Do not use _ACEOF as we are being dumped into config.status via
  41 # an _ACEOF-heredoc.
  42 AC_DEFUN([AC_CONFIG_TESTDIR],
  43 [AC_CONFIG_COMMANDS([$1/atconfig],
  44 [cat >$1/atconfig <<ATEOF
  45 @%:@ Configurable variable values for building test suites.
  46 @%:@ Generated by $[0].
  47 @%:@ Copyright (C) m4_PACKAGE_YEAR Free Software Foundation, Inc.
  48
  49 # The test suite will define top_srcdir=$at_top_srcdir/../.. etc.
  50 at_testdir='$1'
  51 abs_builddir='$ac_abs_builddir'
  52 at_srcdir='$ac_srcdir'
  53 abs_srcdir='$ac_abs_srcdir'
  54 at_top_srcdir='$ac_top_srcdir'
  55 abs_top_srcdir='$ac_abs_top_srcdir'
  56 at_top_build_prefix='$ac_top_build_prefix'
  57 abs_top_builddir='$ac_abs_top_builddir'
  58
  59 # Backward compatibility with Autotest <= 2.59b:
  60 at_top_builddir=\$at_top_build_prefix
  61
  62 m4_provide_if([_AC_COMPILER_EXEEXT], [
  63 EXEEXT='$ac_cv_exeext'
  64 ])dnl
  65 AUTOTEST_PATH='m4_default([$2], [$1])'
  66
  67 SHELL=\${CONFIG_SHELL-'$SHELL'}
  68 m4_provide_if([AC_ERLANG_PATH_ERL], [
  69 ERL='$ERL'
  70 ])dnl
  71 m4_provide_if([AC_ERLANG_PATH_ERLC], [
  72 ERLC='$ERLC'
  73 ERLCFLAGS='$ERLCFLAGS'
  74 ])dnl
  75 ATEOF
  76 ],
  77 [m4_provide_if([_AC_COMPILER_EXEEXT], [ac_cv_exeext="$ac_cv_exeext"
  78 ])m4_provide_if([AC_ERLANG_PATH_ERL], [ERL="$ERL"
  79 ])m4_provide_if([AC_ERLANG_PATH_ERLC], [ERLC="$ERLC"
  80 ERLCFLAGS="$ERLCFLAGS"
  81 ])])])# AC_CONFIG_TESTDIR