acidrip/PKGBUILD

   1 # Contributor:
   2 # Contributor: Aaron Griffin <aaron@archlinux.org>
   3
   4 pkgname=acidrip
   5 pkgver=0.14
   6 pkgrel=10
   7 pkgdesc="A Gtk2::Perl application for ripping and encoding DVD's"
   8 arch=('any')
   9 url="http://sourceforge.net/projects/acidrip/"
  10 license=('GPL')
  11 depends=('mplayer' 'lsdvd' 'lame' 'libdvdcss' 'gtk2-perl' 'perl' 'mencoder')
  12 source=(http://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.gz
  13         'acidrip.desktop' 'acidrip.png'
  14         'crop-fixes.patch' 'xvidencopts.patch')
  15 md5sums=('c1c27bbf658e5c30f43e067a8ae283de'
  16          'f6896612df224a325d66c5f8fa8553e7'
  17          '7498602e2a3838cf35b94af85d9954d3'
  18          '1a8470702e2e0eda8ecbc473141aa08f'
  19          '8cdf13f4bf0fd7b8c3c6adfd22480706')
  20 options=('!emptydirs')
  21
  22 build() {
  23   cd ${srcdir}/${pkgname}-${pkgver}
  24   patch -Np1 -i ${srcdir}/crop-fixes.patch
  25   patch -Np1 -i ${srcdir}/xvidencopts.patch
  26
  27   # install module in vendor directories.
  28   perl Makefile.PL INSTALLDIRS=vendor INSTALLVENDORSCRIPT=/usr/bin
  29   make
  30 }
  31
  32 package() {
  33   cd ${srcdir}/${pkgname}-${pkgver}
  34   make install DESTDIR=${pkgdir}
  35
  36   install -Dm644 ${srcdir}/acidrip.png \
  37       ${pkgdir}/usr/share/pixmaps/acidrip.png
  38   install -Dm644 ${srcdir}/acidrip.desktop \
  39       ${pkgdir}/usr/share/applications/acidrip.desktop
  40 }