lib/Audio/MPD/Common/Item/Song.pm

   1 use strict;
   2 use warnings;
   3
   4 package Audio::MPD::Common::Item::Song;
   5 # ABSTRACT: a song object with some audio tags
   6
   7 use Moose;
   8 use Readonly;
   9
  10 use base qw{ Audio::MPD::Common::Item };
  11 use overload '""' => \&as_string;
  12
  13 Readonly my $SEP => ' = ';
  14
  15
  16 # -- attributes
  17
  18 =attr $song->album;
  19
  20 Album of the song.
  21
  22 =attr $song->artist;
  23
  24 Artist of the song.
  25
  26 =attr $song->date;
  27
  28 Last modification date of the song.
  29
  30 =attr $song->file;
  31
  32 Path to the song. Only attribute which will always be defined.
  33
  34 =attr $song->genre;
  35
  36 Genre of the song.
  37
  38 =attr $song->id;
  39
  40 Id of the song in MPD's database.
  41
  42 =attr $song->pos;
  43
  44 Position of the song in the playlist.
  45
  46 =attr $song->title;
  47
  48 Title of the song.
  49
  50 =attr $song->track;
  51
  52 Track number of the song.
  53
  54 =attr $song->time;
  55
  56 Length of the song in seconds.
  57
  58 =cut
  59
  60 has album  => ( is=>'ro', isa=>'Str' );
  61 has artist => ( is=>'ro', isa=>'Str' );
  62 has date   => ( is=>'ro', isa=>'Int' );
  63 has file   => ( is=>'ro', isa=>'Str', required=>1 );
  64 has genre  => ( is=>'ro', isa=>'Str' );
  65 has id     => ( is=>'ro', isa=>'Int' );
  66 has pos    => ( is=>'ro', isa=>'Int' );
  67 has title  => ( is=>'ro', isa=>'Str' );
  68 has track  => ( is=>'ro', isa=>'Int' );
  69 has time   => ( is=>'ro', isa=>'Int' );
  70
  71
  72 # -- public methods
  73
  74 =method my $str = $song->as_string;
  75
  76 Return a string representing $song. This string will be:
  77
  78 =over 4
  79
  80 =item either "album = track = artist = title"
  81
  82 =item or "artist = title"
  83
  84 =item or "title"
  85
  86 =item or "file"
  87
  88 =back
  89
  90 (in this order), depending on the existing tags of the song. The last
  91 possibility always exist of course, since it's a path.
  92
  93 This method is also used to automatically stringify the C<$song>.
  94
  95 =cut
  96
  97 sub as_string {
  98     my ($self) = @_;
  99
 100     return $self->file unless defined $self->title;
 101     my $str = $self->title;
 102     return $str unless defined $self->artist;
 103     $str = $self->artist . $SEP . $str;
 104     return $str unless defined $self->album && defined $self->track;
 105     return join $SEP,
 106         $self->album,
 107         $self->track,
 108         $str;
 109 }
 110
 111 1;
 112 __END__
 113
 114 =head1 DESCRIPTION
 115
 116 L<Audio::MPD::Common::Item::Song> is more a placeholder with some
 117 attributes. Those attributes are taken from the song tags, so some of
 118 them can be empty depending on the file.
 119
 120 The constructor should only be called by L<Audio::MPD::Common::Item>'s
 121 constructor.