m4/ac_define_dir.m4

   1 dnl @synopsis AC_DEFINE_DIR(VARNAME, DIR [, DESCRIPTION])
   2 dnl
   3 dnl This macro _AC_DEFINEs VARNAME to the expansion of the DIR
   4 dnl variable, taking care of fixing up ${prefix} and such.
   5 dnl
   6 dnl VARNAME is offered as both a C preprocessor symbol, and an output
   7 dnl variable.
   8 dnl
   9 dnl Note that the 3 argument form is only supported with autoconf 2.13 and
  10 dnl later (i.e. only where _AC_DEFINE supports 3 arguments).
  11 dnl
  12 dnl Examples:
  13 dnl
  14 dnl    AC_DEFINE_DIR(DATADIR, datadir)
  15 dnl    AC_DEFINE_DIR(PROG_PATH, bindir, [Location of installed binaries])
  16 dnl
  17 dnl @version $Id: ac_define_dir.m4,v 1.2 2003/10/28 23:36:47 guidod Exp $
  18 dnl @author Guido Draheim <guidod@gmx.de>, original by Alexandre Oliva
  19
  20 AC_DEFUN([AC_DEFINE_DIR], [
  21   test "x$prefix" = xNONE && prefix="$ac_default_prefix"
  22   test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  23   ac_define_dir=`eval echo [$]$2`
  24   ac_define_dir=`eval echo [$]ac_define_dir`
  25   $1="$ac_define_dir"
  26   AC_SUBST($1)
  27   ifelse($3, ,
  28     AC_DEFINE_UNQUOTED($1, "$ac_define_dir"),
  29     AC_DEFINE_UNQUOTED($1, "$ac_define_dir", $3))
  30 ])