rofimoji/trunk/PKGBUILD

   1 # Maintainer: Daniel M. Capella <polyzen@archlinux.org>
   2
   3 pkgname=rofimoji
   4 pkgver=6.1.0
   5 pkgrel=2
   6 pkgdesc='Character picker for rofi'
   7 arch=('any')
   8 url=https://github.com/fdw/rofimoji
   9 license=('MIT')
  10 depends=('python-configargparse')
  11 makedepends=('python-build' 'python-installer' 'python-poetry-core')
  12 optdepends=('emoji-font: for the emojis character file'
  13             'nerd-fonts: for the nerd_font character file'
  14             'rofi: for the X.Org selector'
  15             'xclip: for one of the X.Org clipboarders'
  16             'xsel: for one of the X.Org clipboarders'
  17             'xdotool: for the X.Org typer'
  18             'wofi: for a Wayland selector'
  19             'fuzzel: for a Wayland selector'
  20             'wl-clipboard: for the Wayland clipboarder'
  21             'wtype: for the Wayland typer')
  22 install=$pkgname.install
  23 source=("https://files.pythonhosted.org/packages/source/${pkgname::1}/$pkgname/$pkgname-$pkgver.tar.gz")
  24 sha256sums=('5af61a78905d7c66d7043b9f802cd40bd6e2f265bfaf43c54156405914cfa112')
  25 b2sums=('7dd3aaa55d76d656571b31855f2d67fbcfc0e66e9fa6454a7ef3e02b8f2880b6f08fe3598a87c3fa00918994be88cc76b5b231b1abbd45aa1dbbfc8ff0076f3a')
  26
  27 prepare() {
  28   cd $pkgname-$pkgver
  29   # Remove include list https://github.com/pypa/wheel/issues/92
  30   sed -i '/^include =/,/]/d' pyproject.toml
  31 }
  32
  33 build() {
  34   cd $pkgname-$pkgver
  35   python -m build --wheel --skip-dependency-check --no-isolation
  36 }
  37
  38 package() {
  39   cd $pkgname-$pkgver
  40   python -m installer --destdir="$pkgdir" dist/*.whl
  41   install -Dm644 -t "$pkgdir"/usr/share/man/man1 src/picker/docs/$pkgname.1
  42
  43   # Symlink license file
  44   local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
  45   install -d "$pkgdir"/usr/share/licenses/$pkgname
  46   ln -s "$site_packages"/$pkgname-$pkgver.dist-info/LICENSE \
  47     "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  48 }