python-smbprotocol/trunk/PKGBUILD

   1 # Maintainer: Bruno Pagani <archange@archlinux.org>
   2
   3 _pkg=smbprotocol
   4 pkgname=python-${_pkg}
   5 pkgver=1.10.1
   6 pkgrel=2
   7 pkgdesc="SMBv2 and v3 client"
   8 arch=(any)
   9 url="https://github.com/jborean93/smbprotocol"
  10 license=(MIT)
  11 depends=(python-cryptography python-pyspnego python-six)
  12 makedepends=(git python-setuptools)
  13 checkdepends=(python-pytest python-pytest-mock python-gssapi)
  14 optdepends=('python-gssapi: Kerberos support')
  15 # tags are not signed, commits only
  16 _commit=1ea33abd58f2e3886220a10888608052bf3608c1 # git rev-parse v${pkgver}
  17 #source=(git+${url}.git#commit=${_commit}?signed)
  18 # 1.9.0 was signed using GitHub key
  19 source=(git+${url}.git#commit=${_commit})
  20 sha256sums=('SKIP')
  21 validpgpkeys=(A03A0E13C2EFFD384B1EC39A2AAC89085FBBDAB5) # Jordan Borean <jborean93@gmail.com>
  22
  23 build() {
  24   cd ${_pkg}
  25   python setup.py build
  26 }
  27
  28 check() {
  29   cd ${_pkg}
  30   PYTHONPATH="${PWD}"/src pytest -vv --color=yes
  31 }
  32
  33 package() {
  34   cd ${_pkg}
  35   python setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=1
  36   install -Dm644 LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}
  37 }