configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.65)
   4
   5 m4_define(anjuta_major_version,  3)
   6 m4_define(anjuta_minor_version, 5)
   7 m4_define(anjuta_micro_version, 0)
   8 m4_define(anjuta_version, anjuta_major_version.anjuta_minor_version.anjuta_micro_version)
   9 m4_define(bugzilla_version, anjuta_major_version.anjuta_minor_version.anjuta_micro_version)
  10
  11 AC_INIT([Anjuta],[anjuta_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=anjuta],[anjuta],[http://www.anjuta.org/])
  12
  13 AC_CONFIG_HEADERS([config.h])
  14 AC_CONFIG_SRCDIR([src/main.c])
  15 AC_CONFIG_MACRO_DIR([m4])
  16
  17
  18 AC_DEFINE(ANJUTA_MAJOR_VERSION, anjuta_major_version, [Anjuta major version])
  19 AC_SUBST(ANJUTA_MAJOR_VERSION, anjuta_major_version)
  20 AC_DEFINE(ANJUTA_MINOR_VERSION, anjuta_minor_version, [Anjuta minor version])
  21 AC_SUBST(ANJUTA_MINOR_VERSION, anjuta_minor_version)
  22 AC_DEFINE(ANJUTA_MICRO_VERSION, anjuta_micro_version, [Anjuta micro version])
  23 AC_SUBST(ANJUTA_MICRO_VERSION, anjuta_micro_version)
  24 AC_DEFINE(ANJUTA_VERSION, anjuta_version, [Anjuta version])
  25 AC_SUBST(ANJUTA_VERSION)
  26
  27 ANJUTA_VERSION=anjuta_version
  28 AC_SUBST(ANJUTA_VERSION)
  29
  30 BUGZILLA_VERSION=bugzilla_version
  31 AC_SUBST(BUGZILLA_VERSION)
  32
  33 dnl Anjuta core
  34 GLIB_REQUIRED=2.28.0
  35 GLIB_NEW_REQUIRED=2.29.2
  36 GTK_REQUIRED=3.0.0
  37 GTHREAD_REQUIRED=2.22.0
  38 GDK_PIXBUF_REQUIRED=2.0.0
  39 GDA4_REQUIRED=4.2.0
  40 GDA5_REQUIRED=4.99.0
  41 VTE_REQUIRED=0.27.6
  42 LIBXML_REQUIRED=2.4.23
  43 GDL_REQUIRED=2.91.4
  44 LIBWNCK_REQUIRED=2.12
  45
  46 dnl GtkSourceView
  47 GTKSOURCEVIEW_REQUIRED=2.91.8
  48
  49 dnl Devhelp
  50 LIBDEVHELP_REQUIRED=3.0.0
  51
  52 dnl Glade
  53 GLADEUI_REQUIRED=3.11.0
  54
  55 dnl Vala
  56 VALA14_REQUIRED=0.13.3
  57
  58 dnl Introspection
  59 GI_REQUIRED=0.9.5
  60
  61 dnl Various
  62 LIBGRAPHVIZ_REQUIRED=1.0
  63
  64 dnl Subversion plugin
  65 NEON_REQUIRED=0.28.2
  66 SVN_MAJOR=1
  67 SVN_MINOR=5
  68 SVN_PATCH=0
  69 SUBVERSION_REQUIRED=$SVN_MAJOR.$SVN_MINOR.$SVN_PATCH
  70
  71 AM_INIT_AUTOMAKE([1.10 dist-xz no-dist-gzip])
  72 AM_MAINTAINER_MODE([enable])
  73
  74 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  75
  76 dnl Check for C Compiler
  77 AC_PROG_CC
  78 AC_PROG_CPP
  79 AC_PROG_LEX
  80 if test "$LEX" != "flex"; then
  81         AC_MSG_ERROR(flex is required)
  82 fi
  83 AC_PROG_YACC
  84 if test "$YACC" != "bison -y"; then
  85         AC_MSG_ERROR(bison is required)
  86 fi
  87 AC_LANG([C])
  88 AC_LANG([C++])
  89 AC_PROG_CXX
  90 AM_PROG_CC_C_O
  91
  92 GNOME_COMPILE_WARNINGS([maximum])
  93 AM_CFLAGS="$AM_CFLAGS $WARN_CFLAGS"
  94 AM_CXXFLAGS="$AM_CXXFLAGS $WARN_CXXFLAGS"
  95
  96 dnl Enable debugging mode
  97 AC_ARG_ENABLE(debug,
  98   AS_HELP_STRING([--enable-debug],[Enable debug messages]),
  99   [if test "x$enableval" = "xyes"; then
 100       AM_CFLAGS="$AM_CFLAGS -DDEBUG"
 101   fi]
 102   AM_CXXFLAGS="$AM_CXXFLAGS -DDEBUG")
 103 AC_SUBST(AM_CFLAGS)
 104 AC_SUBST(AM_CXXFLAGS)
 105
 106 ANJUTA_LDFLAGS="-no-undefined"
 107 ANJUTA_PLUGIN_LDFLAGS="-module -avoid-version -no-undefined"
 108 AC_SUBST(ANJUTA_LDFLAGS)
 109 AC_SUBST(ANJUTA_PLUGIN_LDFLAGS)
 110
 111 dnl GSettings
 112 GLIB_GSETTINGS
 113
 114 dnl Disable deprecated APIs
 115 dnl if test x$MAINT = x; then
 116 dnl     DEPRECATED_FLAGS="-DGDK_DISABLE_DEPRECATED -DGTK_DISABLE_DEPRECATED"
 117 dnl     AC_SUBST(DEPRECATED_FLAGS)
 118 dnl fi
 119
 120 dnl Check for pkg-config
 121 PKG_PROG_PKG_CONFIG([0.22])
 122
 123 dnl Enable versioned user preferences directory
 124 AC_ARG_WITH(pref-suffix,
 125   AS_HELP_STRING([--with-pref-suffix=VALUE],[Suffix to add to user preferences dir.]),
 126   PREF_SUFFIX="$withval")
 127
 128 AC_SUBST(PREF_SUFFIX)
 129 AC_DEFINE_UNQUOTED(PREF_SUFFIX,
 130       "${PREF_SUFFIX}",
 131           [Suffix to add to preferences directory])
 132
 133 # Initialize libtool
 134 LT_PREREQ([2.2])
 135 LT_INIT([disable-static])
 136
 137 dnl ***************************************************************************
 138 dnl Check for GObject-Introspection
 139 dnl ***************************************************************************
 140 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [GOBJECT_INTROSPECTION_CHECK([0.6.7])],
 141 [AM_CONDITIONAL(HAVE_INTROSPECTION, false)])
 142
 143 dnl ***************************************************************************
 144 dnl Set gjsdir
 145 dnl ***************************************************************************
 146 gjsdir=`pkg-config --variable=jsdir gjs-1.0`
 147 AC_SUBST(gjsdir)
 148
 149 dnl Check base modules
 150
 151 PKG_CHECK_MODULES([ANJUTA],
 152    [gthread-2.0 >= $GTHREAD_REQUIRED
 153         glib-2.0 >= $GLIB_REQUIRED
 154         gio-2.0 >= $GLIB_REQUIRED
 155         gmodule-2.0 >= $GLIB_REQUIRED
 156         gtk+-3.0 >= $GTK_REQUIRED
 157         gdk-pixbuf-2.0 >= $GDK_PIXBUF_REQUIRED])
 158
 159 PKG_CHECK_MODULES([XML],
 160    [libxml-2.0 >= $LIBXML_REQUIRED])
 161
 162 PKG_CHECK_MODULES([GDL],
 163    [gdl-3.0 >= $GDL_REQUIRED])
 164
 165 PKG_CHECK_MODULES([GDA],
 166    [libgda-5.0 >= $GDA5_REQUIRED],,
 167    [PKG_CHECK_MODULES([GDA],
 168       [libgda-4.0 >= $GDA4_REQUIRED])])
 169
 170 PKG_CHECK_MODULES([VTE],
 171    [vte-2.90 >= $VTE_REQUIRED])
 172
 173 dnl Check for better module
 174
 175 PKG_CHECK_MODULES([GLIB_NEW],
 176    [glib-2.0 >= $GLIB_NEW_REQUIRED],
 177    HAVE_GLIB_2_29_2=1,
 178    HAVE_GLIB_2_29_2=0)
 179 AC_SUBST(HAVE_GLIB_2_29_2)
 180 AC_DEFINE_UNQUOTED([GLIB_2_29_2], $HAVE_GLIB_2_29_2, [Define to 1 if glib is version 2.29.2 or greater])
 181
 182 dnl Check for autogen
 183 dnl -----------------
 184 AC_PATH_PROG(AUTOGEN_PATH, autogen,no)
 185 if test x$AUTOGEN_PATH = xno; then
 186    AC_MSG_WARN([Couldn't find autogen. You will be able to build anjuta without autogen \
 187                 but several things won't work. You can get it from http://autogen.sourceforge.net/])
 188 fi
 189
 190 dnl Check for Devhelp
 191 dnl -----------------
 192
 193 AC_ARG_ENABLE(plugin-devhelp,
 194   AS_HELP_STRING([--disable-plugin-devhelp],[Disable devhelp plugin support in Anjuta.]),
 195   [ if test "$enableval" = "no"; then
 196        user_disabled_devhelp=1
 197     fi ],
 198   [ user_disabled_devhelp=0 ] )
 199
 200 AC_MSG_CHECKING(if devhelp plugin is disabled)
 201 if test "$user_disabled_devhelp" = 1; then
 202         AC_MSG_RESULT(yes)
 203         devhelp_enabled="no"
 204 else
 205         AC_MSG_RESULT(no)
 206         PKG_CHECK_MODULES(PLUGIN_DEVHELP,
 207                                 [libdevhelp-3.0 >= $LIBDEVHELP_REQUIRED],
 208                                 [
 209                                     devhelp_enabled=yes
 210                                 ], [
 211                                     devhelp_enabled=no
 212                                 ])
 213 fi
 214
 215 AM_CONDITIONAL(HAVE_PLUGIN_DEVHELP, [test x$devhelp_enabled = xyes])
 216
 217 dnl Check for Glade3
 218 dnl ---------------------
 219
 220 AC_ARG_ENABLE(plugin-glade,
 221   AS_HELP_STRING([--disable-plugin-glade],[Disable glade plugin support in Anjuta.]),
 222   [ if test "$enableval" = "no"; then
 223        user_disabled_glade=1
 224     fi ],
 225   [ user_disabled_glade=0 ] )
 226
 227 AC_MSG_CHECKING(if glade plugin is disabled)
 228 if test "$user_disabled_glade" = 1; then
 229         AC_MSG_RESULT(yes)
 230         gladeui_found="no"
 231 else
 232         AC_MSG_RESULT(no)
 233         gladeui_version=0
 234         PKG_CHECK_MODULES(PLUGIN_GLADE, gladeui-2.0 >= $GLADEUI_REQUIRED,
 235             [
 236                 gladeui_found=yes
 237             ], [
 238                 gladeui_found=no
 239             ])
 240 fi
 241
 242 AM_CONDITIONAL(HAVE_PLUGIN_GLADE, [test x$gladeui_found = xyes])
 243
 244 dnl Check for gtksourceview
 245 dnl -------------------------------------------------------------
 246 PKG_CHECK_MODULES(SOURCEVIEW,
 247                 [gtksourceview-3.0 >= $GTKSOURCEVIEW_REQUIRED])
 248
 249 dnl Check for vala
 250 dnl -------------------------------------------------------------
 251
 252 AC_ARG_ENABLE(vala,
 253         AS_HELP_STRING([--disable-vala],[Disable vala support]),
 254         [ if test "$enableval" = "no"; then
 255                 user_disabled_vala=1
 256           fi ],
 257         [ user_disabled_vala=0 ])
 258
 259 AC_MSG_CHECKING(if vala support is disabled)
 260 if test "$user_disabled_vala" = 1; then
 261         AC_MSG_RESULT(yes)
 262         enable_vala="no"
 263 else
 264         AC_MSG_RESULT(no)
 265         AC_MSG_CHECKING(if libvala is available)
 266         PKG_CHECK_EXISTS([ libvala-0.16 ],
 267                          [ valaver="-0.16" ],
 268                          [ PKG_CHECK_EXISTS([ libvala-0.14 >= $VALA14_REQUIRED ],
 269                                             [ valaver="-0.14" ],
 270                                             [ valaver="" ])
 271                          ])
 272         if test "x$valaver" != "x"; then
 273                 AC_MSG_RESULT(yes)
 274                 enable_vala="yes"
 275                 LIBVALA="libvala${valaver}"
 276                 PKG_CHECK_MODULES([VALA], ${LIBVALA})
 277         else
 278                 AC_MSG_RESULT(no)
 279                 enable_vala="no"
 280                 VALA_REQUIRED=$VALA14_REQUIRED
 281         fi
 282         AC_SUBST(LIBVALA)
 283 fi
 284
 285 if test x$enable_vala = xyes; then
 286         AC_PATH_PROGS(VALAC, [valac${valaver} valac], valac)
 287         AC_SUBST(VALAC)
 288 fi
 289
 290 AM_CONDITIONAL(ENABLE_VALA, [test x$enable_vala = xyes])
 291
 292 dnl Check for Python
 293 dnl -------------------------------------------------------------
 294
 295 AM_PATH_PYTHON([],
 296         [have_python="yes"],
 297         [have_python="no"])
 298
 299 if test x$have_python = xyes; then
 300         if test -x $PYTHON-config; then
 301                 PYTHON_CFLAGS=`$PYTHON-config --cflags`
 302                 PYTHON_LIBS=`$PYTHON-config --libs`
 303                 AC_SUBST(PYTHON_CFLAGS)
 304                 AC_SUBST(PYTHON_LIBS)
 305         else
 306                 have_python="no"
 307         fi
 308 fi
 309
 310 AM_CONDITIONAL(HAVE_PYTHON, [test x$have_python = xyes])
 311
 312 PKG_CHECK_MODULES([PLUGIN_SYMBOL_DB],
 313      [libgda-5.0 >= $GDA5_REQUIRED],,
 314      [PKG_CHECK_MODULES([PLUGIN_SYMBOL_DB],
 315          [libgda-4.0 >= $GDA4_REQUIRED])])
 316
 317 dnl Disable packagekit support
 318 dnl -----------------------------------
 319 AC_ARG_ENABLE(packagekit,
 320   [AC_HELP_STRING([--disable-packagekit],[build without PackageKit support])],,
 321   [enable_packagekit=yes])
 322 if test "x$enable_packagekit" != "xno"; then
 323   AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable PackageKit installer])
 324 fi
 325
 326 dnl Setup Anjuta Library flags
 327 dnl --------------------------
 328 LIBANJUTA_CFLAGS='$(ANJUTA_CFLAGS) $(GDL_CFLAGS) $(DEPRECATED_FLAGS) -I$(top_srcdir) -I$(top_builddir)/libanjuta -DPACKAGE_PIXMAPS_DIR=\""$(datadir)/pixmaps/$(PACKAGE)"\" -DPACKAGE_LIB_DIR=\""$(pkglibdir)"\" -DPACKAGE_DATA_DIR=\""$(datadir)/$(PACKAGE)"\"'
 329 LIBANJUTA_LIBS='$(top_builddir)/libanjuta/libanjuta-3.la'
 330 AC_SUBST(LIBANJUTA_CFLAGS)
 331 AC_SUBST(LIBANJUTA_LIBS)
 332
 333 dnl Setup FooCanvas Library flags
 334 dnl --------------------------
 335 LIBFOOCANVAS_CFLAGS='-I$(top_srcdir)'
 336 LIBFOOCANVAS_LIBS='$(top_builddir)/libfoocanvas/libanjuta-foocanvas.la'
 337 AC_SUBST(LIBFOOCANVAS_CFLAGS)
 338 AC_SUBST(LIBFOOCANVAS_LIBS)
 339
 340 dnl Checks for Xft/XRender for foocanvas
 341 dnl
 342 AC_CHECK_LIB(Xrender, XRenderFindFormat,
 343         [AC_SUBST(RENDER_LIBS, "-lXrender -lXext")
 344          AC_DEFINE(HAVE_RENDER, 1, [Define if libXrender is available.])],
 345         [AC_SUBST(RENDER_LIBS, "")],
 346         [-lXext])
 347
 348 dnl Setup Plugin directories
 349 dnl ------------------------
 350 anjuta_plugin_dir='$(libdir)/anjuta'
 351 anjuta_data_dir='$(datadir)/anjuta'
 352 anjuta_ui_dir='$(datadir)/anjuta/ui'
 353 anjuta_glade_dir='$(datadir)/anjuta/glade'
 354 anjuta_image_dir='$(datadir)/pixmaps/anjuta'
 355 AC_SUBST(anjuta_plugin_dir)
 356 AC_SUBST(anjuta_data_dir)
 357 AC_SUBST(anjuta_ui_dir)
 358 AC_SUBST(anjuta_glade_dir)
 359 AC_SUBST(anjuta_image_dir)
 360
 361 dnl ***************************************************************************
 362 dnl Check for marshal and enum generators
 363 dnl ***************************************************************************
 364 GLIB_GENMARSHAL="`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`"
 365 AC_SUBST(GLIB_GENMARSHAL)
 366 GLIB_MKENUMS="`$PKG_CONFIG --variable=glib_mkenums glib-2.0`"
 367 AC_SUBST(GLIB_MKENUMS)
 368
 369 dnl Set up Glade 3 catlog information
 370 dnl ---------------------
 371 GLADE_PLUGINS_PATH="`$PKG_CONFIG --variable=moduledir gladeui-1.0`"
 372 AC_SUBST(GLADE_PLUGINS_PATH)
 373 GLADE_CATALOG_PATH="`$PKG_CONFIG --variable=catalogdir gladeui-1.0`"
 374 AC_SUBST(GLADE_CATALOG_PATH)
 375
 376 dnl ***************************************************************************
 377 dnl Internatinalization
 378 dnl ***************************************************************************
 379 IT_PROG_INTLTOOL([0.40.1])
 380
 381 AM_GNU_GETTEXT([external])
 382 AM_GNU_GETTEXT_VERSION([0.17])
 383
 384 GETTEXT_PACKAGE=anjuta
 385 AC_SUBST(GETTEXT_PACKAGE)
 386 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [GETTEXT package name])
 387
 388 BISON_I18N
 389
 390 dnl ***************************************************************************
 391 dnl Check for gtk-doc.
 392 dnl ***************************************************************************
 393 GTK_DOC_CHECK([1.4])
 394
 395 dnl ***************************************************************************
 396 dnl User manual
 397 dnl ***************************************************************************
 398 GNOME_DOC_INIT([0.18])
 399
 400 dnl Define convenience macros
 401 dnl -------------------------
 402 dnl CHECK_HEADER_DEFINE(LABEL, HEADER [,ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND ] ])
 403 AC_DEFUN([CHECK_HEADER_DEFINE],
 404 [
 405         AC_MSG_CHECKING("if $1 is defined in $2")
 406         AC_EGREP_CPP(yes,
 407 [#include <$2>
 408 #ifdef $1
 409   yes
 410 #endif
 411 ], [
 412         AC_MSG_RESULT(yes)
 413         $3
 414 ], [
 415         AC_MSG_RESULT(no)
 416         $4
 417 ]) ])
 418
 419 dnl Checks for header files.
 420 AC_CHECK_HEADERS(dirent.h fcntl.h fnmatch.h stat.h stdlib.h string.h stdint.h)
 421 AC_CHECK_HEADERS(time.h types.h unistd.h)
 422 AC_CHECK_HEADERS(sys/dir.h sys/stat.h sys/times.h sys/types.h)
 423
 424 dnl Checks for typedefs, structures, and compiler characteristics.
 425
 426 AC_CANONICAL_HOST
 427 CYGWIN=no
 428 MINGW32=no
 429 case $host_os in
 430   *cygwin* ) CYGWIN=yes;;
 431   *mingw32* ) MINGW32=yes;;
 432 esac
 433
 434
 435 dnl Check for bind in libsocket (needed on Solaris)
 436 AC_CHECK_LIB(socket, bind)
 437
 438 dnl Check for function forkpty and related headers
 439 AC_SEARCH_LIBS(forkpty, util, , AC_DEFINE(EMULATE_FORKPTY, [], [Need  to implement our own forkpty()]))
 440 AC_CHECK_HEADERS(libutil.h util.h pty.h)
 441
 442 dnl Checks for library functions.
 443 AC_CHECK_FUNCS(fnmatch)
 444 AC_CHECK_FUNCS(strstr)
 445 AC_CHECK_FUNCS(stricmp)
 446 AC_CHECK_FUNCS(strnicmp)
 447 AC_CHECK_FUNCS(getline)
 448
 449 dnl for libegg/egg-recent-model.c
 450 AC_CHECK_DECLS([lockf])
 451 AC_CHECK_FUNCS([lockf])
 452
 453 AC_CHECK_FUNCS(fgetpos, have_fgetpos=yes)
 454
 455 dnl SEEK_SET should be in stdio.h, but may be in unistd.h on SunOS 4.1.x
 456 if test "$have_fgetpos" != yes ; then
 457     CHECK_HEADER_DEFINE(SEEK_SET, stdio.h,,
 458         CHECK_HEADER_DEFINE(SEEK_SET, unistd.h,,
 459             AC_DEFINE(SEEK_SET, 0, [Seek set 0])))
 460 fi
 461
 462 AC_CHECK_FUNCS(mkstemp, have_mkstemp=yes)
 463 if test "$have_mkstemp" != yes ; then
 464     AC_CHECK_FUNCS(chmod)
 465     if test "$tmpdir_specified" = yes ; then
 466         AC_MSG_RESULT(use of tmpnam overrides temporary directory selection)
 467     fi
 468 else
 469     AC_MSG_CHECKING(directory to use for temporary files)
 470     if test -z "$enable_tmpdir" -o "$enable_tmpdir" = no -o "$enable_tmpdir" = yes ;
 471         then tmpdir=/tmp
 472         else tmpdir="$enable_tmpdir"
 473     fi
 474     if test -d $tmpdir ; then
 475         AC_MSG_RESULT($tmpdir)
 476         AC_DEFINE_UNQUOTED(TMPDIR, "$tmpdir", [Directory for temporary files])
 477     else
 478         AC_MSG_WARN($tmpdir does not exist)
 479     fi
 480 fi
 481
 482 dnl -----------------------------
 483 dnl Checks for FreeBSD Build
 484 dnl -----------------------------
 485 AC_MSG_CHECKING(if building on FreeBSD)
 486
 487 if test `uname -s` = "FreeBSD" ; then
 488         AC_MSG_RESULT(yes)
 489         FREEBSD_BUILD=-DFREEBSD
 490         AC_SUBST(FREEBSD_BUILD)
 491         AC_PATH_PROG(GMAKE, gmake, no)
 492         if test "x$GMAKE" = "xno"; then
 493                 AC_MSG_ERROR(You need gmake installed to build Anjuta!)
 494         fi
 495 else
 496         AC_MSG_RESULT(no)
 497         GMAKE="make"
 498 fi
 499
 500 AC_SUBST(GMAKE)
 501
 502 dnl Checks for missing prototypes
 503 dnl -----------------------------
 504 AC_MSG_NOTICE([checking for missing prototypes...])
 505
 506 AC_DEFUN([CHECK_PROTO], [AC_EGREP_HEADER([[^A-Za-z0-9_]$1([   ]+[A-Za-z0-9_]*)?\(], $2,, AC_DEFINE(patsubst([NEED_PROTO_NAME], [NAME], translit($1, [a-z], [A-Z])),,[Do not know]) AC_MSG_RESULT(adding prototype for $1))])
 507
 508 if test "$have_remove" = yes ; then
 509     CHECK_PROTO(remove, stdio.h)
 510 else
 511     CHECK_PROTO(unlink, unistd.h)
 512 fi
 513 CHECK_PROTO(malloc, stdlib.h)
 514 CHECK_PROTO(getenv, stdlib.h)
 515 CHECK_PROTO(stat,   sys/stat.h)
 516 CHECK_PROTO(lstat,  sys/stat.h)
 517 if test "$have_fgetpos" = yes ; then
 518     CHECK_PROTO(fgetpos, stdio.h)
 519 fi
 520 if test "$have_truncate" = yes ; then
 521     CHECK_PROTO(truncate, unistd.h)
 522 fi
 523 if test "$have_ftruncate" = yes ; then
 524     CHECK_PROTO(ftruncate, unistd.h)
 525 fi
 526
 527 dnl  **********************************************************
 528 dnl  check if we have svn libraries to build subversion plugin
 529 dnl  (stolen from kdevelop ;-)
 530 dnl  **********************************************************
 531
 532 AC_MSG_CHECKING(for Subversion svn-config)
 533 AC_ARG_WITH(subversion-dir,
 534                 AS_HELP_STRING([--with-subversion-dir=DIR],[Where Subversion is installed ]),
 535                 [
 536                                 SVNCONFIG="$withval/bin/svn-config"
 537                 ])
 538
 539 if test -z "$SVNCONFIG"; then
 540                 _SVNCONFIG="`svn-config --prefix 2> /dev/null`"
 541                 if test -n "$_SVNCONFIG"; then
 542                                 SVNCONFIG="$_SVNCONFIG/bin/svn-config"
 543                 fi
 544 fi
 545
 546 AC_SUBST(SVNCONFIG)
 547 if test -x "$SVNCONFIG"; then
 548                 SVNLD="`$SVNCONFIG --ldflags 2> /dev/null`"
 549                 SVN_LIB="`$SVNCONFIG --libs --cflags 2> /dev/null` -lsvn_client-1 -lsvn_subr-1"
 550                 dnl ugly hack for subversion svn-config problems in 0.14.x, to be removed when svn-config is fixed
 551                 SVN_INCLUDE="`$SVNCONFIG --includes 2> /dev/null` -I$_SVNCONFIG/include/subversion-1/"
 552                 AC_MSG_RESULT(yes)
 553 else
 554                 AC_MSG_RESULT(not found)
 555
 556                 dnl just a fallback to debian's config so that it works for me :)
 557                 AC_ARG_WITH(svn-include,
 558                                                                 [[  --with-svn-include=DIR   Use the given path to the subversion headers.]],
 559                                                                 [
 560                                                                 if test "$withval" != "yes" -a "$withval" != ""; then
 561                                                                                 SVN_INCLUDES=$withval
 562                                                                 fi
 563                                                                 ])
 564                 if test -z "$SVN_INCLUDES"; then
 565                         SVN_INCLUDES="/usr/local/include /usr/include"
 566                 fi
 567                 AC_MSG_CHECKING([for Subversion headers])
 568                 SVN_INCLUDE=""
 569                 for VALUE in $SVN_INCLUDES ; do
 570                                 if test -f $VALUE/subversion-1/svn_types.h ; then
 571                                                 SVN_INCLUDE=$VALUE/subversion-1
 572                                                 break
 573                                 fi
 574                                 if test -f $VALUE/svn_types.h ; then
 575                                                 SVN_INCLUDE=$VALUE
 576                                                 break
 577                                 fi
 578                 done
 579                 if test $SVN_INCLUDE ; then
 580                                 AC_MSG_RESULT([found])
 581                 else
 582                                 AC_MSG_RESULT([not found])
 583                 fi
 584                 SVN_LIBS="/usr/local/lib64 /usr/local/lib /usr/lib64 /usr/lib"
 585                 AC_ARG_WITH(svn-lib,
 586                                                 [[  --with-svn-lib=DIR  Use the given path to the subversion libraries.]],
 587                                                 [
 588                                                         if test "$withval" != "yes" -a "$withval" != ""; then
 589                                                                 SVN_LIBS=$withval
 590                                                         fi
 591                                                 ])
 592                 AC_MSG_CHECKING([for Subversion libraries])
 593                 SVN_LIB=""
 594                 for VALUE in $SVN_LIBS ; do
 595                                 if ls $VALUE/libsvn_client-1.* 1>/dev/null 2>&1; then
 596                                                 SVN_LIB=$VALUE
 597                                                 break
 598                                 fi
 599                 done
 600                 if test $SVN_LIB ; then
 601                                 AC_MSG_RESULT([found])
 602                 else
 603                                 AC_MSG_RESULT([not found])
 604                 fi
 605 fi
 606
 607 dnl ******************************************************************
 608 dnl Check for extra libs required by subversion.
 609 dnl FIXME: This should actually be done by subversion and not by us.
 610 dnl ******************************************************************
 611
 612 AC_ARG_ENABLE(plugin-subversion,
 613   AS_HELP_STRING([--disable-plugin-subversion],[Disable subversion support in Anjuta.]),
 614   [ if test "$enableval" = "no"; then
 615         user_disabled_subversion=1
 616     fi ],
 617   [ user_disabled_subversion=0 ] )
 618
 619 AC_MSG_CHECKING(if subversion support is disabled)
 620 if test "$user_disabled_subversion" = 1; then
 621         AC_MSG_RESULT(yes)
 622         SVN_INCLUDE=""
 623         SVN_LIB=""
 624 else
 625         AC_MSG_RESULT(no)
 626 fi
 627
 628 if test -n "$SVN_INCLUDE" ; then
 629         dnl ------------------------------------
 630         dnl APR. Required by subversion (devel)
 631         dnl ------------------------------------
 632         have_atr=no
 633         PKG_CHECK_MODULES(APR,                            \
 634                 apr-1, have_apr=yes, have_apr=no)
 635         if test x"$have_apr" = "xno"; then
 636                 SVN_INCLUDE=""
 637         fi
 638
 639         dnl -----------------------------------------
 640         dnl APR util. Required by subversion (devel)
 641         dnl------------------------------------------
 642         have_atr_util=no
 643         PKG_CHECK_MODULES(APR_UTILS,                            \
 644                 apr-util-1, have_apr_util=yes, have_apr_util=no)
 645         if test x"$have_apr_util" = "xno"; then
 646                 SVN_INCLUDE=""
 647         fi
 648
 649         dnl -----------------------------------------
 650         dnl NEON. Required by subversion (devel)
 651         dnl------------------------------------------
 652         have_neon=no
 653         PKG_CHECK_MODULES(NEON,                            \
 654                 neon, have_neon=yes, have_neon=no)
 655         if test x"$have_neon" = "xno"; then
 656                 SVN_INCLUDE=""
 657         fi
 658
 659         dnl Make sure our SVN version is high enough
 660         dnl Eww, eww, eww, this is dirty
 661         AC_MSG_CHECKING([for subversion >= $SUBVERSION_REQUIRED])
 662         AC_LANG([C])
 663         dnl Temporarily set CFLAGS so that include dirs are found
 664         CFLAGS_TMP=$CFLAGS
 665         CFLAGS="-I$SVN_INCLUDE $APR_CFLAGS"
 666         AC_COMPILE_IFELSE(
 667                 [AC_LANG_PROGRAM([[#include <svn_version.h>]],
 668                         [[
 669                                 #if (SVN_VER_MAJOR < $SVN_MAJOR) || (SVN_VER_MINOR < $SVN_MINOR) || (SVN_VER_PATCH < $SVN_PATCH)
 670                                 #       error "Version too low"
 671                                 #endif
 672                         ]])], AC_MSG_RESULT(yes), have_svn_version=no)
 673         if test x"$have_svn_version" = "xno"; then
 674                 AC_MSG_RESULT(no)
 675                 SVN_INCLUDE=""
 676         fi
 677         CFLAGS=$CFLAGS_TMP
 678 fi
 679
 680 dnl ------------------------------------------
 681 dnl Finally prepare subversion build flags
 682 dnl ------------------------------------------
 683
 684 if test -n "$SVN_INCLUDE" ; then
 685         SVN_INCLUDE="-I$SVN_INCLUDE"
 686         if test x != "x$SVN_LIB" ; then
 687             SVN_LIB="-L$SVN_LIB $APR_LIBS $APR_UTILS_LIBS $NEON_LIBS -lsvn_client-1 -lsvn_subr-1"
 688         else
 689             SVN_LIB="$APR_LIBS $APR_UTILS_LIBS $NEON_LIBS -lsvn_client-1 -lsvn_subr-1"
 690         fi
 691         SVN_CFLAGS="$APR_CFLAGS $APR_UTILS_CFLAGS $NEON_CFLAGS"
 692 fi
 693
 694 AM_CONDITIONAL(BUILD_SVN, [test -n "$SVN_INCLUDE"])
 695 AC_SUBST(SVN_INCLUDE)
 696 AC_SUBST(SVN_LIB)
 697 AC_SUBST(SVN_CFLAGS)
 698
 699 dnl ------------------------------------------
 700 dnl Symbol-db shared memory checks
 701 dnl ------------------------------------------
 702
 703 SYMBOL_DB_SHM="/dev/shm"
 704 user_specified_shm=0
 705 AC_MSG_CHECKING(for symbol-db shared memory)
 706 AC_ARG_WITH(symbol-db-shm,
 707                 AS_HELP_STRING([--with-symbol-db-shm=DIR],[Where shared memory is placed ]),
 708                 [
 709                                 user_specified_shm=1
 710                                 SYMBOL_DB_SHM="$withval"
 711                 ])
 712 if test "$user_specified_shm" = 1; then
 713         AC_MSG_RESULT(yes)
 714 else
 715         AC_MSG_RESULT(no)
 716 fi
 717
 718 AC_SUBST(SYMBOL_DB_SHM)
 719
 720
 721 dnl Check for graphviz (class inheritance and profiler plugins)
 722 AC_ARG_ENABLE(graphviz,
 723         AS_HELP_STRING([--disable-graphviz],[Disable GraphViz support in Anjuta]),
 724         [ if test "$enableval" = "no"; then
 725                 user_disabled_graphviz=1
 726           fi ],
 727         [ user_disabled_graphviz=0 ])
 728
 729 AC_MSG_CHECKING(if GraphViz support is disabled)
 730 if test "$user_disabled_graphviz" = 1; then
 731         AC_MSG_RESULT(yes)
 732         libgraphviz_found="no"
 733 else
 734         AC_MSG_RESULT(no)
 735         PKG_CHECK_MODULES(GRAPHVIZ,
 736                 [libgvc >= $LIBGRAPHVIZ_REQUIRED libgraph >= $LIBGRAPHVIZ_REQUIRED],
 737                 [libgraphviz_found="yes"],
 738                 [libgraphviz_found="no"])
 739 fi
 740
 741 AM_CONDITIONAL(HAVE_GRAPHVIZ, [test x$libgraphviz_found = xyes])
 742
 743 dnl Test using autotest
 744 dnl -----------------------------
 745 AC_CONFIG_TESTDIR(plugins/am-project/tests)
 746 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 747
 748 AC_CONFIG_FILES([
 749 Makefile
 750 po/Makefile.in
 751 libanjuta/Makefile
 752 libanjuta/tests/Makefile
 753 libanjuta/interfaces/Makefile
 754 libanjuta/libanjuta-3.0.pc
 755 libanjuta/anjuta-version.h
 756 src/Makefile
 757 pixmaps/Makefile
 758 pixmaps/16x16/Makefile
 759 pixmaps/22x22/Makefile
 760 pixmaps/24x24/Makefile
 761 pixmaps/32x32/Makefile
 762 pixmaps/48x48/Makefile
 763 pixmaps/scalable/Makefile
 764 data/Makefile
 765 data/welcome.txt
 766 doc/anjuta.1
 767 doc/anjuta-launcher.1
 768 doc/Makefile
 769 scripts/Makefile
 770 launcher/Makefile
 771 plugins/Makefile
 772 plugins/class-gen/Makefile
 773 plugins/class-gen/templates/Makefile
 774 plugins/code-analyzer/Makefile
 775 plugins/patch/Makefile
 776 plugins/document-manager/Makefile
 777 plugins/document-manager/images/Makefile
 778 plugins/message-view/Makefile
 779 plugins/gdb/Makefile
 780 plugins/gdb/images/Makefile
 781 plugins/debug-manager/Makefile
 782 plugins/debug-manager/images/Makefile
 783 plugins/devhelp/Makefile
 784 plugins/devhelp/images/Makefile
 785 plugins/glade/Makefile
 786 plugins/glade/images/Makefile
 787 plugins/js-debugger/Makefile
 788 plugins/file-manager/Makefile
 789 plugins/file-loader/Makefile
 790 plugins/file-wizard/Makefile
 791 plugins/build-basic-autotools/Makefile
 792 plugins/project-manager/Makefile
 793 plugins/symbol-db/benchmark/Makefile
 794 plugins/symbol-db/benchmark/symbol-db/Makefile
 795 plugins/symbol-db/benchmark/libgda/Makefile
 796 plugins/symbol-db/benchmark/sqlite/Makefile
 797 plugins/symbol-db/images/Makefile
 798 plugins/symbol-db/Makefile
 799 plugins/symbol-db/anjuta-tags/Makefile
 800 plugins/project-wizard/Makefile
 801 plugins/snippets-manager/Makefile
 802 plugins/cvs-plugin/Makefile
 803 plugins/subversion/Makefile
 804 plugins/git/Makefile
 805 plugins/git/images/Makefile
 806 plugins/sourceview/Makefile
 807 plugins/terminal/Makefile
 808 plugins/tools/Makefile
 809 plugins/tools/scripts/Makefile
 810 plugins/language-manager/Makefile
 811 plugins/project-import/Makefile
 812 plugins/project-wizard/templates/Makefile
 813 plugins/project-wizard/templates/mkfile/Makefile
 814 plugins/project-wizard/templates/mkfile/src/Makefile
 815 plugins/project-wizard/templates/mkfile/po/Makefile
 816 plugins/project-wizard/templates/minimal/Makefile
 817 plugins/project-wizard/templates/js_minimal/Makefile
 818 plugins/project-wizard/templates/js_minimal/src/Makefile
 819 plugins/project-wizard/templates/terminal/Makefile
 820 plugins/project-wizard/templates/terminal/src/Makefile
 821 plugins/project-wizard/templates/terminal/po/Makefile
 822 plugins/project-wizard/templates/cpp/Makefile
 823 plugins/project-wizard/templates/cpp/src/Makefile
 824 plugins/project-wizard/templates/cpp/po/Makefile
 825 plugins/project-wizard/templates/gtk/Makefile
 826 plugins/project-wizard/templates/gtk/src/Makefile
 827 plugins/project-wizard/templates/gtk/po/Makefile
 828 plugins/project-wizard/templates/gtkapplication/Makefile
 829 plugins/project-wizard/templates/gtkapplication/src/Makefile
 830 plugins/project-wizard/templates/gtkapplication/po/Makefile
 831 plugins/project-wizard/templates/anjuta-plugin/Makefile
 832 plugins/project-wizard/templates/anjuta-plugin/src/Makefile
 833 plugins/project-wizard/templates/anjuta-plugin/po/Makefile
 834 plugins/project-wizard/templates/gtkmm/Makefile
 835 plugins/project-wizard/templates/gtkmm/src/Makefile
 836 plugins/project-wizard/templates/gtkmm/po/Makefile
 837 plugins/project-wizard/templates/gcj/Makefile
 838 plugins/project-wizard/templates/gcj/src/Makefile
 839 plugins/project-wizard/templates/java/Makefile
 840 plugins/project-wizard/templates/java/src/Makefile
 841 plugins/project-wizard/templates/java/po/Makefile
 842 plugins/project-wizard/templates/python/Makefile
 843 plugins/project-wizard/templates/python/src/Makefile
 844 plugins/project-wizard/templates/python/po/Makefile
 845 plugins/project-wizard/templates/pygtk/Makefile
 846 plugins/project-wizard/templates/pygtk/src/Makefile
 847 plugins/project-wizard/templates/pygtk/po/Makefile
 848 plugins/project-wizard/templates/vala-gtk/Makefile
 849 plugins/project-wizard/templates/vala-gtk/src/Makefile
 850 plugins/project-wizard/templates/wxwin/Makefile
 851 plugins/project-wizard/templates/wxwin/src/Makefile
 852 plugins/project-wizard/templates/wxwin/po/Makefile
 853 plugins/project-wizard/templates/xlib/Makefile
 854 plugins/project-wizard/templates/xlib/src/Makefile
 855 plugins/project-wizard/templates/xlib/po/Makefile
 856 plugins/project-wizard/templates/xlib-dock/Makefile
 857 plugins/project-wizard/templates/xlib-dock/src/Makefile
 858 plugins/project-wizard/templates/xlib-dock/po/Makefile
 859 plugins/project-wizard/templates/sdl/Makefile
 860 plugins/project-wizard/templates/sdl/src/Makefile
 861 plugins/project-wizard/templates/sdl/po/Makefile
 862 plugins/project-wizard/templates/licenses/Makefile
 863 plugins/project-wizard/templates/library/Makefile
 864 plugins/project-wizard/templates/library/src/Makefile
 865 plugins/project-wizard/templates/library/po/Makefile
 866 plugins/project-wizard/templates/directory/Makefile
 867 plugins/project-wizard/templates/m4/Makefile
 868 plugins/project-wizard/templates/gnome-shell-extension/Makefile
 869 plugins/project-wizard/templates/gnome-shell-extension/src/Makefile
 870 plugins/am-project/Makefile
 871 plugins/am-project/tests/atlocal
 872 plugins/am-project/tests/Makefile
 873 plugins/mk-project/Makefile
 874 plugins/dir-project/Makefile
 875 plugins/language-support-cpp-java/Makefile
 876 plugins/language-support-cpp-java/cxxparser/Makefile
 877 plugins/run-program/Makefile
 878 plugins/starter/Makefile
 879 plugins/language-support-js/Makefile
 880 plugins/language-support-vala/Makefile
 881 plugins/language-support-python/Makefile
 882 plugins/python-loader/Makefile
 883 anjuta.desktop.in
 884 manuals/Makefile
 885 manuals/reference/Makefile
 886 manuals/reference/libanjuta/Makefile
 887 manuals/reference/libanjuta/version.xml
 888 manuals/anjuta-manual/Makefile
 889 manuals/anjuta-faqs/Makefile
 890 manuals/anjuta-build-tutorial/Makefile
 891 mime/Makefile
 892 ])
 893 AC_OUTPUT
 894 echo " "
 895 echo "-------------------------------------------------------------------"
 896 echo "Conditionally built plugins:"
 897 echo "-------------------------------------------------------------------"
 898 if [ test -n "$SVN_INCLUDE" ]; then
 899         echo "Building subversion plugin: ............................YES"
 900 else
 901         echo "Building subversion plugin: ............................NO"
 902                 echo "        Requires apr (>= 0.9.4); http://subversion.org"
 903                 echo "        Requires apr-util (>= 0.9.4); http://subversion.org"
 904                 echo "        Requires neon (>= 0.28.2); http://subversion.org"
 905                 echo "        Requires subversion (>= 1.5); http://subversion.org"
 906 fi
 907
 908 if [ test x$gladeui_found = xyes ]; then
 909        echo "Building glade plugin: .................................YES"
 910 else
 911        echo "Building glade plugin: .................................NO"
 912        echo "        Requires glade-3 (>= $GLADEUI_REQUIRED)"
 913 fi
 914
 915 if [ test x$devhelp_enabled = xyes ]; then
 916        echo "Building devhelp plugin: ...............................YES"
 917 else
 918        echo "Building devhelp plugin: ...............................NO"
 919        echo "        Requires libdevhelp-3.0 (>= $LIBDEVHELP_REQUIRED)"
 920 fi
 921 if [ test x$enable_vala = xyes ]; then
 922         echo "Building Vala support: .................................YES"
 923 else
 924         echo "Building Vala support: .................................NO"
 925         echo "        Requires libvala (>= $VALA_REQUIRED)"
 926 fi
 927 if [ test x$libgraphviz_found = xyes ]; then
 928         echo "Building class inheritance plugin: .....................YES"
 929 else
 930         echo "Building class inheritance plugin: .....................NO"
 931         echo "        Requires graphviz (>= 2.6.0); http://graphviz.org"
 932 fi
 933 echo "-------------------------------------------------------------------"
 934 echo "AM_CFLAGS = $AM_CFLAGS"
 935 echo "AM_CXXFLAGS = $AM_CXXFLAGS"