?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
Merge branch 'cc/bisect'
[alt-git.git] / git-svn.perl
blob0e61897b9ecc255d3d22d016b46c90d3a30e9f38
1 #!/usr/bin/env perl
2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
3 # License: GPL v2 or later
4 use warnings;
5 use strict;
6 use vars qw/ $AUTHOR $VERSION
7 $sha1 $sha1_short $_revision
8 $_q $_authors %users/;
9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
10 $VERSION = '@@GIT_VERSION@@';
11
12 # From which subdir have we been invoked?
13 my $cmd_dir_prefix = eval {
14 command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
15 } || '';
16
17 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
18 $ENV{GIT_DIR} ||= '.git';
19 $Git::SVN::default_repo_id = 'svn';
20 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
21 $Git::SVN::Ra::_log_window_size = 100;
22
23 $Git::SVN::Log::TZ = $ENV{TZ};
24 $ENV{TZ} = 'UTC';
25 $| = 1; # unbuffer STDOUT
26
27 sub fatal (@) { print STDERR "@_\n"; exit 1 }
28 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
29 require SVN::Ra;
30 require SVN::Delta;
31 if ($SVN::Core::VERSION lt '1.1.0') {
32 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
33 }
34 push @Git::SVN::Ra::ISA, 'SVN::Ra';
35 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
36 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
37 use Carp qw/croak/;
38 use Digest::MD5;
39 use IO::File qw//;
40 use File::Basename qw/dirname basename/;
41 use File::Path qw/mkpath/;
42 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
43 use IPC::Open3;
44 use Git;
45
46 BEGIN {
47 # import functions from Git into our packages, en masse
48 no strict 'refs';
49 foreach (qw/command command_oneline command_noisy command_output_pipe
50 command_input_pipe command_close_pipe/) {
51 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
52 Git::SVN::Migration Git::SVN::Log Git::SVN),
53 __PACKAGE__) {
54 *{"${package}::$_"} = \&{"Git::$_"};
55 }
56 }
57 }
58
59 my ($SVN);
60
61 $sha1 = qr/[a-f\d]{40}/;
62 $sha1_short = qr/[a-f\d]{4,40}/;
63 my ($_stdin, $_help, $_edit,
64 $_message, $_file,
65 $_template, $_shared,
66 $_version, $_fetch_all, $_no_rebase,
67 $_merge, $_strategy, $_dry_run, $_local,
68 $_prefix, $_no_checkout, $_url, $_verbose,
69 $_git_format);
70 $Git::SVN::_follow_parent = 1;
71 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
72 'config-dir=s' => \$Git::SVN::Ra::config_dir,
73 'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
74 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
75 'authors-file|A=s' => \$_authors,
76 'repack:i' => \$Git::SVN::_repack,
77 'noMetadata' => \$Git::SVN::_no_metadata,
78 'useSvmProps' => \$Git::SVN::_use_svm_props,
79 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
80 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
81 'no-checkout' => \$_no_checkout,
82 'quiet|q' => \$_q,
83 'repack-flags|repack-args|repack-opts=s' =>
84 \$Git::SVN::_repack_flags,
85 'use-log-author' => \$Git::SVN::_use_log_author,
86 'add-author-from' => \$Git::SVN::_add_author_from,
87 %remote_opts );
88
89 my ($_trunk, $_tags, $_branches, $_stdlayout);
90 my %icv;
91 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
92 'trunk|T=s' => \$_trunk, 'tags|t=s' => \$_tags,
93 'branches|b=s' => \$_branches, 'prefix=s' => \$_prefix,
94 'stdlayout|s' => \$_stdlayout,
95 'minimize-url|m' => \$Git::SVN::_minimize_url,
96 'no-metadata' => sub { $icv{noMetadata} = 1 },
97 'use-svm-props' => sub { $icv{useSvmProps} = 1 },
98 'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
99 'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
100 %remote_opts );
101 my %cmt_opts = ( 'edit|e' => \$_edit,
102 'rmdir' => \$SVN::Git::Editor::_rmdir,
103 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
104 'l=i' => \$SVN::Git::Editor::_rename_limit,
105 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
106 );
107
108 my %cmd = (
109 fetch => [ \&cmd_fetch, "Download new revisions from SVN",
110 { 'revision|r=s' => \$_revision,
111 'fetch-all|all' => \$_fetch_all,
112 %fc_opts } ],
113 clone => [ \&cmd_clone, "Initialize and fetch revisions",
114 { 'revision|r=s' => \$_revision,
115 %fc_opts, %init_opts } ],
116 init => [ \&cmd_init, "Initialize a repo for tracking" .
117 " (requires URL argument)",
118 \%init_opts ],
119 'multi-init' => [ \&cmd_multi_init,
120 "Deprecated alias for ".
121 "'$0 init -T<trunk> -b<branches> -t<tags>'",
122 \%init_opts ],
123 dcommit => [ \&cmd_dcommit,
124 'Commit several diffs to merge with upstream',
125 { 'merge|m|M' => \$_merge,
126 'strategy|s=s' => \$_strategy,
127 'verbose|v' => \$_verbose,
128 'dry-run|n' => \$_dry_run,
129 'fetch-all|all' => \$_fetch_all,
130 'no-rebase' => \$_no_rebase,
131 %cmt_opts, %fc_opts } ],
132 'set-tree' => [ \&cmd_set_tree,
133 "Set an SVN repository to a git tree-ish",
134 { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
135 'create-ignore' => [ \&cmd_create_ignore,
136 'Create a .gitignore per svn:ignore',
137 { 'revision|r=i' => \$_revision
138 } ],
139 'propget' => [ \&cmd_propget,
140 'Print the value of a property on a file or directory',
141 { 'revision|r=i' => \$_revision } ],
142 'proplist' => [ \&cmd_proplist,
143 'List all properties of a file or directory',
144 { 'revision|r=i' => \$_revision } ],
145 'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
146 { 'revision|r=i' => \$_revision
147 } ],
148 'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
149 { 'revision|r=i' => \$_revision
150 } ],
151 'multi-fetch' => [ \&cmd_multi_fetch,
152 "Deprecated alias for $0 fetch --all",
153 { 'revision|r=s' => \$_revision, %fc_opts } ],
154 'migrate' => [ sub { },
155 # no-op, we automatically run this anyways,
156 'Migrate configuration/metadata/layout from
157 previous versions of git-svn',
158 { 'minimize' => \$Git::SVN::Migration::_minimize,
159 %remote_opts } ],
160 'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
161 { 'limit=i' => \$Git::SVN::Log::limit,
162 'revision|r=s' => \$_revision,
163 'verbose|v' => \$Git::SVN::Log::verbose,
164 'incremental' => \$Git::SVN::Log::incremental,
165 'oneline' => \$Git::SVN::Log::oneline,
166 'show-commit' => \$Git::SVN::Log::show_commit,
167 'non-recursive' => \$Git::SVN::Log::non_recursive,
168 'authors-file|A=s' => \$_authors,
169 'color' => \$Git::SVN::Log::color,
170 'pager=s' => \$Git::SVN::Log::pager
171 } ],
172 'find-rev' => [ \&cmd_find_rev, "Translate between SVN revision numbers and tree-ish",
173 {} ],
174 'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
175 { 'merge|m|M' => \$_merge,
176 'verbose|v' => \$_verbose,
177 'strategy|s=s' => \$_strategy,
178 'local|l' => \$_local,
179 'fetch-all|all' => \$_fetch_all,
180 %fc_opts } ],
181 'commit-diff' => [ \&cmd_commit_diff,
182 'Commit a diff between two trees',
183 { 'message|m=s' => \$_message,
184 'file|F=s' => \$_file,
185 'revision|r=s' => \$_revision,
186 %cmt_opts } ],
187 'info' => [ \&cmd_info,
188 "Show info about the latest SVN revision
189 on the current branch",
190 { 'url' => \$_url, } ],
191 'blame' => [ \&Git::SVN::Log::cmd_blame,
192 "Show what revision and author last modified each line of a file",
193 { 'git-format' => \$_git_format } ],
194 );
195
196 my $cmd;
197 for (my $i = 0; $i < @ARGV; $i++) {
198 if (defined $cmd{$ARGV[$i]}) {
199 $cmd = $ARGV[$i];
200 splice @ARGV, $i, 1;
201 last;
202 }
203 };
204
205 # make sure we're always running at the top-level working directory
206 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
207 unless (-d $ENV{GIT_DIR}) {
208 if ($git_dir_user_set) {
209 die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
210 "but it is not a directory\n";
211 }
212 my $git_dir = delete $ENV{GIT_DIR};
213 chomp(my $cdup = command_oneline(qw/rev-parse --show-cdup/));
214 unless (length $cdup) {
215 die "Already at toplevel, but $git_dir ",
216 "not found '$cdup'\n";
217 }
218 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
219 unless (-d $git_dir) {
220 die "$git_dir still not found after going to ",
221 "'$cdup'\n";
222 }
223 $ENV{GIT_DIR} = $git_dir;
224 }
225 }
226
227 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
228
229 read_repo_config(\%opts);
230 Getopt::Long::Configure('pass_through') if ($cmd && ($cmd eq 'log' || $cmd eq 'blame'));
231 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
232 'minimize-connections' => \$Git::SVN::Migration::_minimize,
233 'id|i=s' => \$Git::SVN::default_ref_id,
234 'svn-remote|remote|R=s' => sub {
235 $Git::SVN::no_reuse_existing = 1;
236 $Git::SVN::default_repo_id = $_[1] });
237 exit 1 if (!$rv && $cmd && $cmd ne 'log');
238
239 usage(0) if $_help;
240 version() if $_version;
241 usage(1) unless defined $cmd;
242 load_authors() if $_authors;
243
244 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
245 Git::SVN::Migration::migration_check();
246 }
247 Git::SVN::init_vars();
248 eval {
249 Git::SVN::verify_remotes_sanity();
250 $cmd{$cmd}->[0]->(@ARGV);
251 };
252 fatal $@ if $@;
253 post_fetch_checkout();
254 exit 0;
255
256 ####################### primary functions ######################
257 sub usage {
258 my $exit = shift || 0;
259 my $fd = $exit ? \*STDERR : \*STDOUT;
260 print $fd <<"";
261 git-svn - bidirectional operations between a single Subversion tree and git
262 Usage: $0 <command> [options] [arguments]\n
263
264 print $fd "Available commands:\n" unless $cmd;
265
266 foreach (sort keys %cmd) {
267 next if $cmd && $cmd ne $_;
268 next if /^multi-/; # don't show deprecated commands
269 print $fd ' ',pack('A17',$_),$cmd{$_}->[1],"\n";
270 foreach (sort keys %{$cmd{$_}->[2]}) {
271 # mixed-case options are for .git/config only
272 next if /[A-Z]/ && /^[a-z]+$/i;
273 # prints out arguments as they should be passed:
274 my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
275 print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
276 "--$_" : "-$_" }
277 split /\|/,$_)," $x\n";
278 }
279 }
280 print $fd <<"";
281 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
282 arbitrary identifier if you're tracking multiple SVN branches/repositories in
283 one git repository and want to keep them separate. See git-svn(1) for more
284 information.
285
286 exit $exit;
287 }
288
289 sub version {
290 print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
291 exit 0;
292 }
293
294 sub do_git_init_db {
295 unless (-d $ENV{GIT_DIR}) {
296 my @init_db = ('init');
297 push @init_db, "--template=$_template" if defined $_template;
298 if (defined $_shared) {
299 if ($_shared =~ /[a-z]/) {
300 push @init_db, "--shared=$_shared";
301 } else {
302 push @init_db, "--shared";
303 }
304 }
305 command_noisy(@init_db);
306 }
307 my $set;
308 my $pfx = "svn-remote.$Git::SVN::default_repo_id";
309 foreach my $i (keys %icv) {
310 die "'$set' and '$i' cannot both be set\n" if $set;
311 next unless defined $icv{$i};
312 command_noisy('config', "$pfx.$i", $icv{$i});
313 $set = $i;
314 }
315 }
316
317 sub init_subdir {
318 my $repo_path = shift or return;
319 mkpath([$repo_path]) unless -d $repo_path;
320 chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
321 $ENV{GIT_DIR} = '.git';
322 }
323
324 sub cmd_clone {
325 my ($url, $path) = @_;
326 if (!defined $path &&
327 (defined $_trunk || defined $_branches || defined $_tags ||
328 defined $_stdlayout) &&
329 $url !~ m#^[a-z\+]+://#) {
330 $path = $url;
331 }
332 $path = basename($url) if !defined $path || !length $path;
333 cmd_init($url, $path);
334 Git::SVN::fetch_all($Git::SVN::default_repo_id);
335 }
336
337 sub cmd_init {
338 if (defined $_stdlayout) {
339 $_trunk = 'trunk' if (!defined $_trunk);
340 $_tags = 'tags' if (!defined $_tags);
341 $_branches = 'branches' if (!defined $_branches);
342 }
343 if (defined $_trunk || defined $_branches || defined $_tags) {
344 return cmd_multi_init(@_);
345 }
346 my $url = shift or die "SVN repository location required ",
347 "as a command-line argument\n";
348 init_subdir(@_);
349 do_git_init_db();
350
351 Git::SVN->init($url);
352 }
353
354 sub cmd_fetch {
355 if (grep /^\d+=./, @_) {
356 die "'<rev>=<commit>' fetch arguments are ",
357 "no longer supported.\n";
358 }
359 my ($remote) = @_;
360 if (@_ > 1) {
361 die "Usage: $0 fetch [--all] [svn-remote]\n";
362 }
363 $remote ||= $Git::SVN::default_repo_id;
364 if ($_fetch_all) {
365 cmd_multi_fetch();
366 } else {
367 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
368 }
369 }
370
371 sub cmd_set_tree {
372 my (@commits) = @_;
373 if ($_stdin || !@commits) {
374 print "Reading from stdin...\n";
375 @commits = ();
376 while (<STDIN>) {
377 if (/\b($sha1_short)\b/o) {
378 unshift @commits, $1;
379 }
380 }
381 }
382 my @revs;
383 foreach my $c (@commits) {
384 my @tmp = command('rev-parse',$c);
385 if (scalar @tmp == 1) {
386 push @revs, $tmp[0];
387 } elsif (scalar @tmp > 1) {
388 push @revs, reverse(command('rev-list',@tmp));
389 } else {
390 fatal "Failed to rev-parse $c";
391 }
392 }
393 my $gs = Git::SVN->new;
394 my ($r_last, $cmt_last) = $gs->last_rev_commit;
395 $gs->fetch;
396 if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
397 fatal "There are new revisions that were fetched ",
398 "and need to be merged (or acknowledged) ",
399 "before committing.\nlast rev: $r_last\n",
400 " current: $gs->{last_rev}";
401 }
402 $gs->set_tree($_) foreach @revs;
403 print "Done committing ",scalar @revs," revisions to SVN\n";
404 unlink $gs->{index};
405 }
406
407 sub cmd_dcommit {
408 my $head = shift;
409 git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
410 'Cannot dcommit with a dirty index. Commit your changes first, '
411 . "or stash them with `git stash'.\n";
412 $head ||= 'HEAD';
413 my @refs;
414 my ($url, $rev, $uuid, $gs) = working_head_info($head, \@refs);
415 if ($url) {
416 print "Committing to $url ...\n";
417 }
418 unless ($gs) {
419 die "Unable to determine upstream SVN information from ",
420 "$head history.\nPerhaps the repository is empty.";
421 }
422 my $last_rev;
423 my ($linear_refs, $parents) = linearize_history($gs, \@refs);
424 if ($_no_rebase && scalar(@$linear_refs) > 1) {
425 warn "Attempting to commit more than one change while ",
426 "--no-rebase is enabled.\n",
427 "If these changes depend on each other, re-running ",
428 "without --no-rebase may be required."
429 }
430 while (1) {
431 my $d = shift @$linear_refs or last;
432 unless (defined $last_rev) {
433 (undef, $last_rev, undef) = cmt_metadata("$d~1");
434 unless (defined $last_rev) {
435 fatal "Unable to extract revision information ",
436 "from commit $d~1";
437 }
438 }
439 if ($_dry_run) {
440 print "diff-tree $d~1 $d\n";
441 } else {
442 my $cmt_rev;
443 my %ed_opts = ( r => $last_rev,
444 log => get_commit_entry($d)->{log},
445 ra => Git::SVN::Ra->new($gs->full_url),
446 config => SVN::Core::config_get_config(
447 $Git::SVN::Ra::config_dir
448 ),
449 tree_a => "$d~1",
450 tree_b => $d,
451 editor_cb => sub {
452 print "Committed r$_[0]\n";
453 $cmt_rev = $_[0];
454 },
455 svn_path => '');
456 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
457 print "No changes\n$d~1 == $d\n";
458 } elsif ($parents->{$d} && @{$parents->{$d}}) {
459 $gs->{inject_parents_dcommit}->{$cmt_rev} =
460 $parents->{$d};
461 }
462 $_fetch_all ? $gs->fetch_all : $gs->fetch;
463 $last_rev = $cmt_rev;
464 next if $_no_rebase;
465
466 # we always want to rebase against the current HEAD,
467 # not any head that was passed to us
468 my @diff = command('diff-tree', $d,
469 $gs->refname, '--');
470 my @finish;
471 if (@diff) {
472 @finish = rebase_cmd();
473 print STDERR "W: $d and ", $gs->refname,
474 " differ, using @finish:\n",
475 join("\n", @diff), "\n";
476 } else {
477 print "No changes between current HEAD and ",
478 $gs->refname,
479 "\nResetting to the latest ",
480 $gs->refname, "\n";
481 @finish = qw/reset --mixed/;
482 }
483 command_noisy(@finish, $gs->refname);
484 if (@diff) {
485 @refs = ();
486 my ($url_, $rev_, $uuid_, $gs_) =
487 working_head_info($head, \@refs);
488 my ($linear_refs_, $parents_) =
489 linearize_history($gs_, \@refs);
490 if (scalar(@$linear_refs) !=
491 scalar(@$linear_refs_)) {
492 fatal "# of revisions changed ",
493 "\nbefore:\n",
494 join("\n", @$linear_refs),
495 "\n\nafter:\n",
496 join("\n", @$linear_refs_), "\n",
497 'If you are attempting to commit ',
498 "merges, try running:\n\t",
499 'git rebase --interactive',
500 '--preserve-merges ',
501 $gs->refname,
502 "\nBefore dcommitting";
503 }
504 if ($url_ ne $url) {
505 fatal "URL mismatch after rebase: ",
506 "$url_ != $url";
507 }
508 if ($uuid_ ne $uuid) {
509 fatal "uuid mismatch after rebase: ",
510 "$uuid_ != $uuid";
511 }
512 # remap parents
513 my (%p, @l, $i);
514 for ($i = 0; $i < scalar @$linear_refs; $i++) {
515 my $new = $linear_refs_->[$i] or next;
516 $p{$new} =
517 $parents->{$linear_refs->[$i]};
518 push @l, $new;
519 }
520 $parents = \%p;
521 $linear_refs = \@l;
522 }
523 }
524 }
525 unlink $gs->{index};
526 }
527
528 sub cmd_find_rev {
529 my $revision_or_hash = shift or die "SVN or git revision required ",
530 "as a command-line argument\n";
531 my $result;
532 if ($revision_or_hash =~ /^r\d+$/) {
533 my $head = shift;
534 $head ||= 'HEAD';
535 my @refs;
536 my (undef, undef, undef, $gs) = working_head_info($head, \@refs);
537 unless ($gs) {
538 die "Unable to determine upstream SVN information from ",
539 "$head history\n";
540 }
541 my $desired_revision = substr($revision_or_hash, 1);
542 $result = $gs->rev_map_get($desired_revision);
543 } else {
544 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
545 $result = $rev;
546 }
547 print "$result\n" if $result;
548 }
549
550 sub cmd_rebase {
551 command_noisy(qw/update-index --refresh/);
552 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
553 unless ($gs) {
554 die "Unable to determine upstream SVN information from ",
555 "working tree history\n";
556 }
557 if (command(qw/diff-index HEAD --/)) {
558 print STDERR "Cannot rebase with uncommited changes:\n";
559 command_noisy('status');
560 exit 1;
561 }
562 unless ($_local) {
563 # rebase will checkout for us, so no need to do it explicitly
564 $_no_checkout = 'true';
565 $_fetch_all ? $gs->fetch_all : $gs->fetch;
566 }
567 command_noisy(rebase_cmd(), $gs->refname);
568 }
569
570 sub cmd_show_ignore {
571 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
572 $gs ||= Git::SVN->new;
573 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
574 $gs->prop_walk($gs->{path}, $r, sub {
575 my ($gs, $path, $props) = @_;
576 print STDOUT "\n# $path\n";
577 my $s = $props->{'svn:ignore'} or return;
578 $s =~ s/[\r\n]+/\n/g;
579 chomp $s;
580 $s =~ s#^#$path#gm;
581 print STDOUT "$s\n";
582 });
583 }
584
585 sub cmd_show_externals {
586 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
587 $gs ||= Git::SVN->new;
588 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
589 $gs->prop_walk($gs->{path}, $r, sub {
590 my ($gs, $path, $props) = @_;
591 print STDOUT "\n# $path\n";
592 my $s = $props->{'svn:externals'} or return;
593 $s =~ s/[\r\n]+/\n/g;
594 chomp $s;
595 $s =~ s#^#$path#gm;
596 print STDOUT "$s\n";
597 });
598 }
599
600 sub cmd_create_ignore {
601 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
602 $gs ||= Git::SVN->new;
603 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
604 $gs->prop_walk($gs->{path}, $r, sub {
605 my ($gs, $path, $props) = @_;
606 # $path is of the form /path/to/dir/
607 my $ignore = '.' . $path . '.gitignore';
608 my $s = $props->{'svn:ignore'} or return;
609 open(GITIGNORE, '>', $ignore)
610 or fatal("Failed to open `$ignore' for writing: $!");
611 $s =~ s/[\r\n]+/\n/g;
612 chomp $s;
613 # Prefix all patterns so that the ignore doesn't apply
614 # to sub-directories.
615 $s =~ s#^#/#gm;
616 print GITIGNORE "$s\n";
617 close(GITIGNORE)
618 or fatal("Failed to close `$ignore': $!");
619 command_noisy('add', '-f', $ignore);
620 });
621 }
622
623 sub canonicalize_path {
624 my ($path) = @_;
625 my $dot_slash_added = 0;
626 if (substr($path, 0, 1) ne "/") {
627 $path = "./" . $path;
628 $dot_slash_added = 1;
629 }
630 # File::Spec->canonpath doesn't collapse x/../y into y (for a
631 # good reason), so let's do this manually.
632 $path =~ s#/+#/#g;
633 $path =~ s#/\.(?:/|$)#/#g;
634 $path =~ s#/[^/]+/\.\.##g;
635 $path =~ s#/$##g;
636 $path =~ s#^\./## if $dot_slash_added;
637 return $path;
638 }
639
640 # get_svnprops(PATH)
641 # ------------------
642 # Helper for cmd_propget and cmd_proplist below.
643 sub get_svnprops {
644 my $path = shift;
645 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
646 $gs ||= Git::SVN->new;
647
648 # prefix THE PATH by the sub-directory from which the user
649 # invoked us.
650 $path = $cmd_dir_prefix . $path;
651 fatal("No such file or directory: $path") unless -e $path;
652 my $is_dir = -d $path ? 1 : 0;
653 $path = $gs->{path} . '/' . $path;
654
655 # canonicalize the path (otherwise libsvn will abort or fail to
656 # find the file)
657 $path = canonicalize_path($path);
658
659 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
660 my $props;
661 if ($is_dir) {
662 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
663 }
664 else {
665 (undef, $props) = $gs->ra->get_file($path, $r, undef);
666 }
667 return $props;
668 }
669
670 # cmd_propget (PROP, PATH)
671 # ------------------------
672 # Print the SVN property PROP for PATH.
673 sub cmd_propget {
674 my ($prop, $path) = @_;
675 $path = '.' if not defined $path;
676 usage(1) if not defined $prop;
677 my $props = get_svnprops($path);
678 if (not defined $props->{$prop}) {
679 fatal("`$path' does not have a `$prop' SVN property.");
680 }
681 print $props->{$prop} . "\n";
682 }
683
684 # cmd_proplist (PATH)
685 # -------------------
686 # Print the list of SVN properties for PATH.
687 sub cmd_proplist {
688 my $path = shift;
689 $path = '.' if not defined $path;
690 my $props = get_svnprops($path);
691 print "Properties on '$path':\n";
692 foreach (sort keys %{$props}) {
693 print " $_\n";
694 }
695 }
696
697 sub cmd_multi_init {
698 my $url = shift;
699 unless (defined $_trunk || defined $_branches || defined $_tags) {
700 usage(1);
701 }
702
703 # there are currently some bugs that prevent multi-init/multi-fetch
704 # setups from working well without this.
705 $Git::SVN::_minimize_url = 1;
706
707 $_prefix = '' unless defined $_prefix;
708 if (defined $url) {
709 $url =~ s#/+$##;
710 init_subdir(@_);
711 }
712 do_git_init_db();
713 if (defined $_trunk) {
714 my $trunk_ref = $_prefix . 'trunk';
715 # try both old-style and new-style lookups:
716 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
717 unless ($gs_trunk) {
718 my ($trunk_url, $trunk_path) =
719 complete_svn_url($url, $_trunk);
720 $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
721 undef, $trunk_ref);
722 }
723 }
724 return unless defined $_branches || defined $_tags;
725 my $ra = $url ? Git::SVN::Ra->new($url) : undef;
726 complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
727 complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
728 }
729
730 sub cmd_multi_fetch {
731 my $remotes = Git::SVN::read_all_remotes();
732 foreach my $repo_id (sort keys %$remotes) {
733 if ($remotes->{$repo_id}->{url}) {
734 Git::SVN::fetch_all($repo_id, $remotes);
735 }
736 }
737 }
738
739 # this command is special because it requires no metadata
740 sub cmd_commit_diff {
741 my ($ta, $tb, $url) = @_;
742 my $usage = "Usage: $0 commit-diff -r<revision> ".
743 "<tree-ish> <tree-ish> [<URL>]";
744 fatal($usage) if (!defined $ta || !defined $tb);
745 my $svn_path;
746 if (!defined $url) {
747 my $gs = eval { Git::SVN->new };
748 if (!$gs) {
749 fatal("Needed URL or usable git-svn --id in ",
750 "the command-line\n", $usage);
751 }
752 $url = $gs->{url};
753 $svn_path = $gs->{path};
754 }
755 unless (defined $_revision) {
756 fatal("-r|--revision is a required argument\n", $usage);
757 }
758 if (defined $_message && defined $_file) {
759 fatal("Both --message/-m and --file/-F specified ",
760 "for the commit message.\n",
761 "I have no idea what you mean");
762 }
763 if (defined $_file) {
764 $_message = file_to_s($_file);
765 } else {
766 $_message ||= get_commit_entry($tb)->{log};
767 }
768 my $ra ||= Git::SVN::Ra->new($url);
769 $svn_path ||= $ra->{svn_path};
770 my $r = $_revision;
771 if ($r eq 'HEAD') {
772 $r = $ra->get_latest_revnum;
773 } elsif ($r !~ /^\d+$/) {
774 die "revision argument: $r not understood by git-svn\n";
775 }
776 my %ed_opts = ( r => $r,
777 log => $_message,
778 ra => $ra,
779 tree_a => $ta,
780 tree_b => $tb,
781 editor_cb => sub { print "Committed r$_[0]\n" },
782 svn_path => $svn_path );
783 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
784 print "No changes\n$ta == $tb\n";
785 }
786 }
787
788 sub cmd_info {
789 my $path = canonicalize_path(shift or ".");
790 unless (scalar(@_) == 0) {
791 die "Too many arguments specified\n";
792 }
793
794 my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
795
796 if (!$file_type && !$diff_status) {
797 print STDERR "$path: (Not a versioned resource)\n\n";
798 return;
799 }
800
801 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
802 unless ($gs) {
803 die "Unable to determine upstream SVN information from ",
804 "working tree history\n";
805 }
806 my $full_url = $url . ($path eq "." ? "" : "/$path");
807
808 if ($_url) {
809 print $full_url, "\n";
810 return;
811 }
812
813 my $result = "Path: $path\n";
814 $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
815 $result .= "URL: " . $full_url . "\n";
816
817 eval {
818 my $repos_root = $gs->repos_root;
819 Git::SVN::remove_username($repos_root);
820 $result .= "Repository Root: $repos_root\n";
821 };
822 if ($@) {
823 $result .= "Repository Root: (offline)\n";
824 }
825 $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A";
826 $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
827
828 $result .= "Node Kind: " .
829 ($file_type eq "dir" ? "directory" : "file") . "\n";
830
831 my $schedule = $diff_status eq "A"
832 ? "add"
833 : ($diff_status eq "D" ? "delete" : "normal");
834 $result .= "Schedule: $schedule\n";
835
836 if ($diff_status eq "A") {
837 print $result, "\n";
838 return;
839 }
840
841 my ($lc_author, $lc_rev, $lc_date_utc);
842 my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $path);
843 my $log = command_output_pipe(@args);
844 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
845 while (<$log>) {
846 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
847 $lc_author = $1;
848 $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
849 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
850 (undef, $lc_rev, undef) = ::extract_metadata($1);
851 }
852 }
853 close $log;
854
855 Git::SVN::Log::set_local_timezone();
856
857 $result .= "Last Changed Author: $lc_author\n";
858 $result .= "Last Changed Rev: $lc_rev\n";
859 $result .= "Last Changed Date: " .
860 Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
861
862 if ($file_type ne "dir") {
863 my $text_last_updated_date =
864 ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
865 $result .=
866 "Text Last Updated: " .
867 Git::SVN::Log::format_svn_date($text_last_updated_date) .
868 "\n";
869 my $checksum;
870 if ($diff_status eq "D") {
871 my ($fh, $ctx) =
872 command_output_pipe(qw(cat-file blob), "HEAD:$path");
873 if ($file_type eq "link") {
874 my $file_name = <$fh>;
875 $checksum = md5sum("link $file_name");
876 } else {
877 $checksum = md5sum($fh);
878 }
879 command_close_pipe($fh, $ctx);
880 } elsif ($file_type eq "link") {
881 my $file_name =
882 command(qw(cat-file blob), "HEAD:$path");
883 $checksum =
884 md5sum("link " . $file_name);
885 } else {
886 open FILE, "<", $path or die $!;
887 $checksum = md5sum(\*FILE);
888 close FILE or die $!;
889 }
890 $result .= "Checksum: " . $checksum . "\n";
891 }
892
893 print $result, "\n";
894 }
895
896 ########################### utility functions #########################
897
898 sub rebase_cmd {
899 my @cmd = qw/rebase/;
900 push @cmd, '-v' if $_verbose;
901 push @cmd, qw/--merge/ if $_merge;
902 push @cmd, "--strategy=$_strategy" if $_strategy;
903 @cmd;
904 }
905
906 sub post_fetch_checkout {
907 return if $_no_checkout;
908 my $gs = $Git::SVN::_head or return;
909 return if verify_ref('refs/heads/master^0');
910
911 my $valid_head = verify_ref('HEAD^0');
912 command_noisy(qw(update-ref refs/heads/master), $gs->refname);
913 return if ($valid_head || !verify_ref('HEAD^0'));
914
915 return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
916 my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
917 return if -f $index;
918
919 return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
920 return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
921 command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
922 print STDERR "Checked out HEAD:\n ",
923 $gs->full_url, " r", $gs->last_rev, "\n";
924 }
925
926 sub complete_svn_url {
927 my ($url, $path) = @_;
928 $path =~ s#/+$##;
929 if ($path !~ m#^[a-z\+]+://#) {
930 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
931 fatal("E: '$path' is not a complete URL ",
932 "and a separate URL is not specified");
933 }
934 return ($url, $path);
935 }
936 return ($path, '');
937 }
938
939 sub complete_url_ls_init {
940 my ($ra, $repo_path, $switch, $pfx) = @_;
941 unless ($repo_path) {
942 print STDERR "W: $switch not specified\n";
943 return;
944 }
945 $repo_path =~ s#/+$##;
946 if ($repo_path =~ m#^[a-z\+]+://#) {
947 $ra = Git::SVN::Ra->new($repo_path);
948 $repo_path = '';
949 } else {
950 $repo_path =~ s#^/+##;
951 unless ($ra) {
952 fatal("E: '$repo_path' is not a complete URL ",
953 "and a separate URL is not specified");
954 }
955 }
956 my $url = $ra->{url};
957 my $gs = Git::SVN->init($url, undef, undef, undef, 1);
958 my $k = "svn-remote.$gs->{repo_id}.url";
959 my $orig_url = eval { command_oneline(qw/config --get/, $k) };
960 if ($orig_url && ($orig_url ne $gs->{url})) {
961 die "$k already set: $orig_url\n",
962 "wanted to set to: $gs->{url}\n";
963 }
964 command_oneline('config', $k, $gs->{url}) unless $orig_url;
965 my $remote_path = "$ra->{svn_path}/$repo_path";
966 $remote_path =~ s#/+#/#g;
967 $remote_path =~ s#^/##g;
968 $remote_path .= "/*" if $remote_path !~ /\*/;
969 my ($n) = ($switch =~ /^--(\w+)/);
970 if (length $pfx && $pfx !~ m#/$#) {
971 die "--prefix='$pfx' must have a trailing slash '/'\n";
972 }
973 command_noisy('config', "svn-remote.$gs->{repo_id}.$n",
974 "$remote_path:refs/remotes/$pfx*");
975 }
976
977 sub verify_ref {
978 my ($ref) = @_;
979 eval { command_oneline([ 'rev-parse', '--verify', $ref ],
980 { STDERR => 0 }); };
981 }
982
983 sub get_tree_from_treeish {
984 my ($treeish) = @_;
985 # $treeish can be a symbolic ref, too:
986 my $type = command_oneline(qw/cat-file -t/, $treeish);
987 my $expected;
988 while ($type eq 'tag') {
989 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
990 }
991 if ($type eq 'commit') {
992 $expected = (grep /^tree /, command(qw/cat-file commit/,
993 $treeish))[0];
994 ($expected) = ($expected =~ /^tree ($sha1)$/o);
995 die "Unable to get tree from $treeish\n" unless $expected;
996 } elsif ($type eq 'tree') {
997 $expected = $treeish;
998 } else {
999 die "$treeish is a $type, expected tree, tag or commit\n";
1000 }
1001 return $expected;
1002 }
1003
1004 sub get_commit_entry {
1005 my ($treeish) = shift;
1006 my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1007 my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1008 my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1009 open my $log_fh, '>', $commit_editmsg or croak $!;
1010
1011 my $type = command_oneline(qw/cat-file -t/, $treeish);
1012 if ($type eq 'commit' || $type eq 'tag') {
1013 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1014 $type, $treeish);
1015 my $in_msg = 0;
1016 my $author;
1017 my $saw_from = 0;
1018 while (<$msg_fh>) {
1019 if (!$in_msg) {
1020 $in_msg = 1 if (/^\s*$/);
1021 $author = $1 if (/^author (.*>)/);
1022 } elsif (/^git-svn-id: /) {
1023 # skip this for now, we regenerate the
1024 # correct one on re-fetch anyways
1025 # TODO: set *:merge properties or like...
1026 } else {
1027 if (/^From:/ || /^Signed-off-by:/) {
1028 $saw_from = 1;
1029 }
1030 print $log_fh $_ or croak $!;
1031 }
1032 }
1033 if ($Git::SVN::_add_author_from && defined($author)
1034 && !$saw_from) {
1035 print $log_fh "\nFrom: $author\n"
1036 or croak $!;
1037 }
1038 command_close_pipe($msg_fh, $ctx);
1039 }
1040 close $log_fh or croak $!;
1041
1042 if ($_edit || ($type eq 'tree')) {
1043 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
1044 # TODO: strip out spaces, comments, like git-commit.sh
1045 system($editor, $commit_editmsg);
1046 }
1047 rename $commit_editmsg, $commit_msg or croak $!;
1048 open $log_fh, '<', $commit_msg or croak $!;
1049 { local $/; chomp($log_entry{log} = <$log_fh>); }
1050 close $log_fh or croak $!;
1051 unlink $commit_msg;
1052 \%log_entry;
1053 }
1054
1055 sub s_to_file {
1056 my ($str, $file, $mode) = @_;
1057 open my $fd,'>',$file or croak $!;
1058 print $fd $str,"\n" or croak $!;
1059 close $fd or croak $!;
1060 chmod ($mode &~ umask, $file) if (defined $mode);
1061 }
1062
1063 sub file_to_s {
1064 my $file = shift;
1065 open my $fd,'<',$file or croak "$!: file: $file\n";
1066 local $/;
1067 my $ret = <$fd>;
1068 close $fd or croak $!;
1069 $ret =~ s/\s*$//s;
1070 return $ret;
1071 }
1072
1073 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1074 sub load_authors {
1075 open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1076 my $log = $cmd eq 'log';
1077 while (<$authors>) {
1078 chomp;
1079 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1080 my ($user, $name, $email) = ($1, $2, $3);
1081 if ($log) {
1082 $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1083 } else {
1084 $users{$user} = [$name, $email];
1085 }
1086 }
1087 close $authors or croak $!;
1088 }
1089
1090 # convert GetOpt::Long specs for use by git-config
1091 sub read_repo_config {
1092 return unless -d $ENV{GIT_DIR};
1093 my $opts = shift;
1094 my @config_only;
1095 foreach my $o (keys %$opts) {
1096 # if we have mixedCase and a long option-only, then
1097 # it's a config-only variable that we don't need for
1098 # the command-line.
1099 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1100 my $v = $opts->{$o};
1101 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1102 $key =~ s/-//g;
1103 my $arg = 'git-config';
1104 $arg .= ' --int' if ($o =~ /[:=]i$/);
1105 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1106 if (ref $v eq 'ARRAY') {
1107 chomp(my @tmp = `$arg --get-all svn.$key`);
1108 @$v = @tmp if @tmp;
1109 } else {
1110 chomp(my $tmp = `$arg --get svn.$key`);
1111 if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1112 $$v = $tmp;
1113 }
1114 }
1115 }
1116 delete @$opts{@config_only} if @config_only;
1117 }
1118
1119 sub extract_metadata {
1120 my $id = shift or return (undef, undef, undef);
1121 my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1122 \s([a-f\d\-]+)$/x);
1123 if (!defined $rev || !$uuid || !$url) {
1124 # some of the original repositories I made had
1125 # identifiers like this:
1126 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
1127 }
1128 return ($url, $rev, $uuid);
1129 }
1130
1131 sub cmt_metadata {
1132 return extract_metadata((grep(/^git-svn-id: /,
1133 command(qw/cat-file commit/, shift)))[-1]);
1134 }
1135
1136 sub working_head_info {
1137 my ($head, $refs) = @_;
1138 my @args = ('log', '--no-color', '--first-parent', '--pretty=medium');
1139 my ($fh, $ctx) = command_output_pipe(@args, $head);
1140 my $hash;
1141 my %max;
1142 while (<$fh>) {
1143 if ( m{^commit ($::sha1)$} ) {
1144 unshift @$refs, $hash if $hash and $refs;
1145 $hash = $1;
1146 next;
1147 }
1148 next unless s{^\s*(git-svn-id:)}{$1};
1149 my ($url, $rev, $uuid) = extract_metadata($_);
1150 if (defined $url && defined $rev) {
1151 next if $max{$url} and $max{$url} < $rev;
1152 if (my $gs = Git::SVN->find_by_url($url)) {
1153 my $c = $gs->rev_map_get($rev);
1154 if ($c && $c eq $hash) {
1155 close $fh; # break the pipe
1156 return ($url, $rev, $uuid, $gs);
1157 } else {
1158 $max{$url} ||= $gs->rev_map_max;
1159 }
1160 }
1161 }
1162 }
1163 command_close_pipe($fh, $ctx);
1164 (undef, undef, undef, undef);
1165 }
1166
1167 sub read_commit_parents {
1168 my ($parents, $c) = @_;
1169 chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1170 $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1171 @{$parents->{$c}} = split(/ /, $p);
1172 }
1173
1174 sub linearize_history {
1175 my ($gs, $refs) = @_;
1176 my %parents;
1177 foreach my $c (@$refs) {
1178 read_commit_parents(\%parents, $c);
1179 }
1180
1181 my @linear_refs;
1182 my %skip = ();
1183 my $last_svn_commit = $gs->last_commit;
1184 foreach my $c (reverse @$refs) {
1185 next if $c eq $last_svn_commit;
1186 last if $skip{$c};
1187
1188 unshift @linear_refs, $c;
1189 $skip{$c} = 1;
1190
1191 # we only want the first parent to diff against for linear
1192 # history, we save the rest to inject when we finalize the
1193 # svn commit
1194 my $fp_a = verify_ref("$c~1");
1195 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1196 if (!$fp_a || !$fp_b) {
1197 die "Commit $c\n",
1198 "has no parent commit, and therefore ",
1199 "nothing to diff against.\n",
1200 "You should be working from a repository ",
1201 "originally created by git-svn\n";
1202 }
1203 if ($fp_a ne $fp_b) {
1204 die "$c~1 = $fp_a, however parsing commit $c ",
1205 "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1206 }
1207
1208 foreach my $p (@{$parents{$c}}) {
1209 $skip{$p} = 1;
1210 }
1211 }
1212 (\@linear_refs, \%parents);
1213 }
1214
1215 sub find_file_type_and_diff_status {
1216 my ($path) = @_;
1217 return ('dir', '') if $path eq '.';
1218
1219 my $diff_output =
1220 command_oneline(qw(diff --cached --name-status --), $path) || "";
1221 my $diff_status = (split(' ', $diff_output))[0] || "";
1222
1223 my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1224
1225 return (undef, undef) if !$diff_status && !$ls_tree;
1226
1227 if ($diff_status eq "A") {
1228 return ("link", $diff_status) if -l $path;
1229 return ("dir", $diff_status) if -d $path;
1230 return ("file", $diff_status);
1231 }
1232
1233 my $mode = (split(' ', $ls_tree))[0] || "";
1234
1235 return ("link", $diff_status) if $mode eq "120000";
1236 return ("dir", $diff_status) if $mode eq "040000";
1237 return ("file", $diff_status);
1238 }
1239
1240 sub md5sum {
1241 my $arg = shift;
1242 my $ref = ref $arg;
1243 my $md5 = Digest::MD5->new();
1244 if ($ref eq 'GLOB' || $ref eq 'IO::File') {
1245 $md5->addfile($arg) or croak $!;
1246 } elsif ($ref eq 'SCALAR') {
1247 $md5->add($$arg) or croak $!;
1248 } elsif (!$ref) {
1249 $md5->add($arg) or croak $!;
1250 } else {
1251 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1252 }
1253 return $md5->hexdigest();
1254 }
1255
1256 package Git::SVN;
1257 use strict;
1258 use warnings;
1259 use Fcntl qw/:DEFAULT :seek/;
1260 use constant rev_map_fmt => 'NH40';
1261 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1262 $_repack $_repack_flags $_use_svm_props $_head
1263 $_use_svnsync_props $no_reuse_existing $_minimize_url
1264 $_use_log_author $_add_author_from/;
1265 use Carp qw/croak/;
1266 use File::Path qw/mkpath/;
1267 use File::Copy qw/copy/;
1268 use IPC::Open3;
1269
1270 my ($_gc_nr, $_gc_period);
1271
1272 # properties that we do not log:
1273 my %SKIP_PROP;
1274 BEGIN {
1275 %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1276 svn:special svn:executable
1277 svn:entry:committed-rev
1278 svn:entry:last-author
1279 svn:entry:uuid
1280 svn:entry:committed-date/;
1281
1282 # some options are read globally, but can be overridden locally
1283 # per [svn-remote "..."] section. Command-line options will *NOT*
1284 # override options set in an [svn-remote "..."] section
1285 no strict 'refs';
1286 for my $option (qw/follow_parent no_metadata use_svm_props
1287 use_svnsync_props/) {
1288 my $key = $option;
1289 $key =~ tr/_//d;
1290 my $prop = "-$option";
1291 *$option = sub {
1292 my ($self) = @_;
1293 return $self->{$prop} if exists $self->{$prop};
1294 my $k = "svn-remote.$self->{repo_id}.$key";
1295 eval { command_oneline(qw/config --get/, $k) };
1296 if ($@) {
1297 $self->{$prop} = ${"Git::SVN::_$option"};
1298 } else {
1299 my $v = command_oneline(qw/config --bool/,$k);
1300 $self->{$prop} = $v eq 'false' ? 0 : 1;
1301 }
1302 return $self->{$prop};
1303 }
1304 }
1305 }
1306
1307 my (%LOCKFILES, %INDEX_FILES);
1308 END {
1309 unlink keys %LOCKFILES if %LOCKFILES;
1310 unlink keys %INDEX_FILES if %INDEX_FILES;
1311 }
1312
1313 sub resolve_local_globs {
1314 my ($url, $fetch, $glob_spec) = @_;
1315 return unless defined $glob_spec;
1316 my $ref = $glob_spec->{ref};
1317 my $path = $glob_spec->{path};
1318 foreach (command(qw#for-each-ref --format=%(refname) refs/remotes#)) {
1319 next unless m#^refs/remotes/$ref->{regex}$#;
1320 my $p = $1;
1321 my $pathname = desanitize_refname($path->full_path($p));
1322 my $refname = desanitize_refname($ref->full_path($p));
1323 if (my $existing = $fetch->{$pathname}) {
1324 if ($existing ne $refname) {
1325 die "Refspec conflict:\n",
1326 "existing: refs/remotes/$existing\n",
1327 " globbed: refs/remotes/$refname\n";
1328 }
1329 my $u = (::cmt_metadata("refs/remotes/$refname"))[0];
1330 $u =~ s!^\Q$url\E(/|$)!! or die
1331 "refs/remotes/$refname: '$url' not found in '$u'\n";
1332 if ($pathname ne $u) {
1333 warn "W: Refspec glob conflict ",
1334 "(ref: refs/remotes/$refname):\n",
1335 "expected path: $pathname\n",
1336 " real path: $u\n",
1337 "Continuing ahead with $u\n";
1338 next;
1339 }
1340 } else {
1341 $fetch->{$pathname} = $refname;
1342 }
1343 }
1344 }
1345
1346 sub parse_revision_argument {
1347 my ($base, $head) = @_;
1348 if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1349 return ($base, $head);
1350 }
1351 return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1352 return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1353 return ($head, $head) if ($::_revision eq 'HEAD');
1354 return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1355 return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1356 die "revision argument: $::_revision not understood by git-svn\n";
1357 }
1358
1359 sub fetch_all {
1360 my ($repo_id, $remotes) = @_;
1361 if (ref $repo_id) {
1362 my $gs = $repo_id;
1363 $repo_id = undef;
1364 $repo_id = $gs->{repo_id};
1365 }
1366 $remotes ||= read_all_remotes();
1367 my $remote = $remotes->{$repo_id} or
1368 die "[svn-remote \"$repo_id\"] unknown\n";
1369 my $fetch = $remote->{fetch};
1370 my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1371 my (@gs, @globs);
1372 my $ra = Git::SVN::Ra->new($url);
1373 my $uuid = $ra->get_uuid;
1374 my $head = $ra->get_latest_revnum;
1375 my $base = defined $fetch ? $head : 0;
1376
1377 # read the max revs for wildcard expansion (branches/*, tags/*)
1378 foreach my $t (qw/branches tags/) {
1379 defined $remote->{$t} or next;
1380 push @globs, $remote->{$t};
1381 my $max_rev = eval { tmp_config(qw/--int --get/,
1382 "svn-remote.$repo_id.${t}-maxRev") };
1383 if (defined $max_rev && ($max_rev < $base)) {
1384 $base = $max_rev;
1385 } elsif (!defined $max_rev) {
1386 $base = 0;
1387 }
1388 }
1389
1390 if ($fetch) {
1391 foreach my $p (sort keys %$fetch) {
1392 my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1393 my $lr = $gs->rev_map_max;
1394 if (defined $lr) {
1395 $base = $lr if ($lr < $base);
1396 }
1397 push @gs, $gs;
1398 }
1399 }
1400
1401 ($base, $head) = parse_revision_argument($base, $head);
1402 $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1403 }
1404
1405 sub read_all_remotes {
1406 my $r = {};
1407 foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1408 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*refs/remotes/(.+)\s*$!) {
1409 my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
1410 $local_ref =~ s{^/}{};
1411 $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1412 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1413 $r->{$1}->{url} = $2;
1414 } elsif (m!^(.+)\.(branches|tags)=
1415 (.*):refs/remotes/(.+)\s*$/!x) {
1416 my ($p, $g) = ($3, $4);
1417 my $rs = $r->{$1}->{$2} = {
1418 t => $2,
1419 remote => $1,
1420 path => Git::SVN::GlobSpec->new($p),
1421 ref => Git::SVN::GlobSpec->new($g) };
1422 if (length($rs->{ref}->{right}) != 0) {
1423 die "The '*' glob character must be the last ",
1424 "character of '$g'\n";
1425 }
1426 }
1427 }
1428 $r;
1429 }
1430
1431 sub init_vars {
1432 $_gc_nr = $_gc_period = 1000;
1433 if (defined $_repack || defined $_repack_flags) {
1434 warn "Repack options are obsolete; they have no effect.\n";
1435 }
1436 }
1437
1438 sub verify_remotes_sanity {
1439 return unless -d $ENV{GIT_DIR};
1440 my %seen;
1441 foreach (command(qw/config -l/)) {
1442 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1443 if ($seen{$1}) {
1444 die "Remote ref refs/remote/$1 is tracked by",
1445 "\n \"$_\"\nand\n \"$seen{$1}\"\n",
1446 "Please resolve this ambiguity in ",
1447 "your git configuration file before ",
1448 "continuing\n";
1449 }
1450 $seen{$1} = $_;
1451 }
1452 }
1453 }
1454
1455 # we allow more chars than remotes2config.sh...
1456 sub sanitize_remote_name {
1457 my ($name) = @_;
1458 $name =~ tr{A-Za-z0-9:,/+-}{.}c;
1459 $name;
1460 }
1461
1462 sub find_existing_remote {
1463 my ($url, $remotes) = @_;
1464 return undef if $no_reuse_existing;
1465 my $existing;
1466 foreach my $repo_id (keys %$remotes) {
1467 my $u = $remotes->{$repo_id}->{url} or next;
1468 next if $u ne $url;
1469 $existing = $repo_id;
1470 last;
1471 }
1472 $existing;
1473 }
1474
1475 sub init_remote_config {
1476 my ($self, $url, $no_write) = @_;
1477 $url =~ s!/+$!!; # strip trailing slash
1478 my $r = read_all_remotes();
1479 my $existing = find_existing_remote($url, $r);
1480 if ($existing) {
1481 unless ($no_write) {
1482 print STDERR "Using existing ",
1483 "[svn-remote \"$existing\"]\n";
1484 }
1485 $self->{repo_id} = $existing;
1486 } elsif ($_minimize_url) {
1487 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1488 $existing = find_existing_remote($min_url, $r);
1489 if ($existing) {
1490 unless ($no_write) {
1491 print STDERR "Using existing ",
1492 "[svn-remote \"$existing\"]\n";
1493 }
1494 $self->{repo_id} = $existing;
1495 }
1496 if ($min_url ne $url) {
1497 unless ($no_write) {
1498 print STDERR "Using higher level of URL: ",
1499 "$url => $min_url\n";
1500 }
1501 my $old_path = $self->{path};
1502 $self->{path} = $url;
1503 $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1504 if (length $old_path) {
1505 $self->{path} .= "/$old_path";
1506 }
1507 $url = $min_url;
1508 }
1509 }
1510 my $orig_url;
1511 if (!$existing) {
1512 # verify that we aren't overwriting anything:
1513 $orig_url = eval {
1514 command_oneline('config', '--get',
1515 "svn-remote.$self->{repo_id}.url")
1516 };
1517 if ($orig_url && ($orig_url ne $url)) {
1518 die "svn-remote.$self->{repo_id}.url already set: ",
1519 "$orig_url\nwanted to set to: $url\n";
1520 }
1521 }
1522 my ($xrepo_id, $xpath) = find_ref($self->refname);
1523 if (defined $xpath) {
1524 die "svn-remote.$xrepo_id.fetch already set to track ",
1525 "$xpath:refs/remotes/", $self->refname, "\n";
1526 }
1527 unless ($no_write) {
1528 command_noisy('config',
1529 "svn-remote.$self->{repo_id}.url", $url);
1530 $self->{path} =~ s{^/}{};
1531 command_noisy('config', '--add',
1532 "svn-remote.$self->{repo_id}.fetch",
1533 "$self->{path}:".$self->refname);
1534 }
1535 $self->{url} = $url;
1536 }
1537
1538 sub find_by_url { # repos_root and, path are optional
1539 my ($class, $full_url, $repos_root, $path) = @_;
1540
1541 return undef unless defined $full_url;
1542 remove_username($full_url);
1543 remove_username($repos_root) if defined $repos_root;
1544 my $remotes = read_all_remotes();
1545 if (defined $full_url && defined $repos_root && !defined $path) {
1546 $path = $full_url;
1547 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1548 }
1549 foreach my $repo_id (keys %$remotes) {
1550 my $u = $remotes->{$repo_id}->{url} or next;
1551 remove_username($u);
1552 next if defined $repos_root && $repos_root ne $u;
1553
1554 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1555 foreach (qw/branches tags/) {
1556 resolve_local_globs($u, $fetch,
1557 $remotes->{$repo_id}->{$_});
1558 }
1559 my $p = $path;
1560 my $rwr = rewrite_root({repo_id => $repo_id});
1561 unless (defined $p) {
1562 $p = $full_url;
1563 my $z = $u;
1564 if ($rwr) {
1565 $z = $rwr;
1566 }
1567 $p =~ s#^\Q$z\E(?:/|$)## or next;
1568 }
1569 foreach my $f (keys %$fetch) {
1570 next if $f ne $p;
1571 return Git::SVN->new($fetch->{$f}, $repo_id, $f);
1572 }
1573 }
1574 undef;
1575 }
1576
1577 sub init {
1578 my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
1579 my $self = _new($class, $repo_id, $ref_id, $path);
1580 if (defined $url) {
1581 $self->init_remote_config($url, $no_write);
1582 }
1583 $self;
1584 }
1585
1586 sub find_ref {
1587 my ($ref_id) = @_;
1588 foreach (command(qw/config -l/)) {
1589 next unless m!^svn-remote\.(.+)\.fetch=
1590 \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
1591 my ($repo_id, $path, $ref) = ($1, $2, $3);
1592 if ($ref eq $ref_id) {
1593 $path = '' if ($path =~ m#^\./?#);
1594 return ($repo_id, $path);
1595 }
1596 }
1597 (undef, undef, undef);
1598 }
1599
1600 sub new {
1601 my ($class, $ref_id, $repo_id, $path) = @_;
1602 if (defined $ref_id && !defined $repo_id && !defined $path) {
1603 ($repo_id, $path) = find_ref($ref_id);
1604 if (!defined $repo_id) {
1605 die "Could not find a \"svn-remote.*.fetch\" key ",
1606 "in the repository configuration matching: ",
1607 "refs/remotes/$ref_id\n";
1608 }
1609 }
1610 my $self = _new($class, $repo_id, $ref_id, $path);
1611 if (!defined $self->{path} || !length $self->{path}) {
1612 my $fetch = command_oneline('config', '--get',
1613 "svn-remote.$repo_id.fetch",
1614 ":refs/remotes/$ref_id\$") or
1615 die "Failed to read \"svn-remote.$repo_id.fetch\" ",
1616 "\":refs/remotes/$ref_id\$\" in config\n";
1617 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
1618 }
1619 $self->{url} = command_oneline('config', '--get',
1620 "svn-remote.$repo_id.url") or
1621 die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
1622 $self->rebuild;
1623 $self;
1624 }
1625
1626 sub refname {
1627 my ($refname) = "refs/remotes/$_[0]->{ref_id}" ;
1628
1629 # It cannot end with a slash /, we'll throw up on this because
1630 # SVN can't have directories with a slash in their name, either:
1631 if ($refname =~ m{/$}) {
1632 die "ref: '$refname' ends with a trailing slash, this is ",
1633 "not permitted by git nor Subversion\n";
1634 }
1635
1636 # It cannot have ASCII control character space, tilde ~, caret ^,
1637 # colon :, question-mark ?, asterisk *, space, or open bracket [
1638 # anywhere.
1639 #
1640 # Additionally, % must be escaped because it is used for escaping
1641 # and we want our escaped refname to be reversible
1642 $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
1643
1644 # no slash-separated component can begin with a dot .
1645 # /.* becomes /%2E*
1646 $refname =~ s{/\.}{/%2E}g;
1647
1648 # It cannot have two consecutive dots .. anywhere
1649 # .. becomes %2E%2E
1650 $refname =~ s{\.\.}{%2E%2E}g;
1651
1652 return $refname;
1653 }
1654
1655 sub desanitize_refname {
1656 my ($refname) = @_;
1657 $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
1658 return $refname;
1659 }
1660
1661 sub svm_uuid {
1662 my ($self) = @_;
1663 return $self->{svm}->{uuid} if $self->svm;
1664 $self->ra;
1665 unless ($self->{svm}) {
1666 die "SVM UUID not cached, and reading remotely failed\n";
1667 }
1668 $self->{svm}->{uuid};
1669 }
1670
1671 sub svm {
1672 my ($self) = @_;
1673 return $self->{svm} if $self->{svm};
1674 my $svm;
1675 # see if we have it in our config, first:
1676 eval {
1677 my $section = "svn-remote.$self->{repo_id}";
1678 $svm = {
1679 source => tmp_config('--get', "$section.svm-source"),
1680 uuid => tmp_config('--get', "$section.svm-uuid"),
1681 replace => tmp_config('--get', "$section.svm-replace"),
1682 }
1683 };
1684 if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
1685 $self->{svm} = $svm;
1686 }
1687 $self->{svm};
1688 }
1689
1690 sub _set_svm_vars {
1691 my ($self, $ra) = @_;
1692 return $ra if $self->svm;
1693
1694 my @err = ( "useSvmProps set, but failed to read SVM properties\n",
1695 "(svm:source, svm:uuid) ",
1696 "from the following URLs:\n" );
1697 sub read_svm_props {
1698 my ($self, $ra, $path, $r) = @_;
1699 my $props = ($ra->get_dir($path, $r))[2];
1700 my $src = $props->{'svm:source'};
1701 my $uuid = $props->{'svm:uuid'};
1702 return undef if (!$src || !$uuid);
1703
1704 chomp($src, $uuid);
1705
1706 $uuid =~ m{^[0-9a-f\-]{30,}$}
1707 or die "doesn't look right - svm:uuid is '$uuid'\n";
1708
1709 # the '!' is used to mark the repos_root!/relative/path
1710 $src =~ s{/?!/?}{/};
1711 $src =~ s{/+$}{}; # no trailing slashes please
1712 # username is of no interest
1713 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
1714
1715 my $replace = $ra->{url};
1716 $replace .= "/$path" if length $path;
1717
1718 my $section = "svn-remote.$self->{repo_id}";
1719 tmp_config("$section.svm-source", $src);
1720 tmp_config("$section.svm-replace", $replace);
1721 tmp_config("$section.svm-uuid", $uuid);
1722 $self->{svm} = {
1723 source => $src,
1724 uuid => $uuid,
1725 replace => $replace
1726 };
1727 }
1728
1729 my $r = $ra->get_latest_revnum;
1730 my $path = $self->{path};
1731 my %tried;
1732 while (length $path) {
1733 unless ($tried{"$self->{url}/$path"}) {
1734 return $ra if $self->read_svm_props($ra, $path, $r);
1735 $tried{"$self->{url}/$path"} = 1;
1736 }
1737 $path =~ s#/?[^/]+$##;
1738 }
1739 die "Path: '$path' should be ''\n" if $path ne '';
1740 return $ra if $self->read_svm_props($ra, $path, $r);
1741 $tried{"$self->{url}/$path"} = 1;
1742
1743 if ($ra->{repos_root} eq $self->{url}) {
1744 die @err, (map { " $_\n" } keys %tried), "\n";
1745 }
1746
1747 # nope, make sure we're connected to the repository root:
1748 my $ok;
1749 my @tried_b;
1750 $path = $ra->{svn_path};
1751 $ra = Git::SVN::Ra->new($ra->{repos_root});
1752 while (length $path) {
1753 unless ($tried{"$ra->{url}/$path"}) {
1754 $ok = $self->read_svm_props($ra, $path, $r);
1755 last if $ok;
1756 $tried{"$ra->{url}/$path"} = 1;
1757 }
1758 $path =~ s#/?[^/]+$##;
1759 }
1760 die "Path: '$path' should be ''\n" if $path ne '';
1761 $ok ||= $self->read_svm_props($ra, $path, $r);
1762 $tried{"$ra->{url}/$path"} = 1;
1763 if (!$ok) {
1764 die @err, (map { " $_\n" } keys %tried), "\n";
1765 }
1766 Git::SVN::Ra->new($self->{url});
1767 }
1768
1769 sub svnsync {
1770 my ($self) = @_;
1771 return $self->{svnsync} if $self->{svnsync};
1772
1773 if ($self->no_metadata) {
1774 die "Can't have both 'noMetadata' and ",
1775 "'useSvnsyncProps' options set!\n";
1776 }
1777 if ($self->rewrite_root) {
1778 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
1779 "options set!\n";
1780 }
1781
1782 my $svnsync;
1783 # see if we have it in our config, first:
1784 eval {
1785 my $section = "svn-remote.$self->{repo_id}";
1786
1787 my $url = tmp_config('--get', "$section.svnsync-url");
1788 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
1789 die "doesn't look right - svn:sync-from-url is '$url'\n";
1790
1791 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
1792 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}) or
1793 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1794
1795 $svnsync = { url => $url, uuid => $uuid }
1796 };
1797 if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
1798 return $self->{svnsync} = $svnsync;
1799 }
1800
1801 my $err = "useSvnsyncProps set, but failed to read " .
1802 "svnsync property: svn:sync-from-";
1803 my $rp = $self->ra->rev_proplist(0);
1804
1805 my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
1806 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
1807 die "doesn't look right - svn:sync-from-url is '$url'\n";
1808
1809 my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
1810 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}) or
1811 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1812
1813 my $section = "svn-remote.$self->{repo_id}";
1814 tmp_config('--add', "$section.svnsync-uuid", $uuid);
1815 tmp_config('--add', "$section.svnsync-url", $url);
1816 return $self->{svnsync} = { url => $url, uuid => $uuid };
1817 }
1818
1819 # this allows us to memoize our SVN::Ra UUID locally and avoid a
1820 # remote lookup (useful for 'git svn log').
1821 sub ra_uuid {
1822 my ($self) = @_;
1823 unless ($self->{ra_uuid}) {
1824 my $key = "svn-remote.$self->{repo_id}.uuid";
1825 my $uuid = eval { tmp_config('--get', $key) };
1826 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/) {
1827 $self->{ra_uuid} = $uuid;
1828 } else {
1829 die "ra_uuid called without URL\n" unless $self->{url};
1830 $self->{ra_uuid} = $self->ra->get_uuid;
1831 tmp_config('--add', $key, $self->{ra_uuid});
1832 }
1833 }
1834 $self->{ra_uuid};
1835 }
1836
1837 sub _set_repos_root {
1838 my ($self, $repos_root) = @_;
1839 my $k = "svn-remote.$self->{repo_id}.reposRoot";
1840 $repos_root ||= $self->ra->{repos_root};
1841 tmp_config($k, $repos_root);
1842 $repos_root;
1843 }
1844
1845 sub repos_root {
1846 my ($self) = @_;
1847 my $k = "svn-remote.$self->{repo_id}.reposRoot";
1848 eval { tmp_config('--get', $k) } || $self->_set_repos_root;
1849 }
1850
1851 sub ra {
1852 my ($self) = shift;
1853 my $ra = Git::SVN::Ra->new($self->{url});
1854 $self->_set_repos_root($ra->{repos_root});
1855 if ($self->use_svm_props && !$self->{svm}) {
1856 if ($self->no_metadata) {
1857 die "Can't have both 'noMetadata' and ",
1858 "'useSvmProps' options set!\n";
1859 } elsif ($self->use_svnsync_props) {
1860 die "Can't have both 'useSvnsyncProps' and ",
1861 "'useSvmProps' options set!\n";
1862 }
1863 $ra = $self->_set_svm_vars($ra);
1864 $self->{-want_revprops} = 1;
1865 }
1866 $ra;
1867 }
1868
1869 sub rel_path {
1870 my ($self) = @_;
1871 my $repos_root = $self->ra->{repos_root};
1872 return $self->{path} if ($self->{url} eq $repos_root);
1873 my $url = $self->{url} .
1874 (length $self->{path} ? "/$self->{path}" : $self->{path});
1875 $url =~ s!^\Q$repos_root\E(?:/+|$)!!g;
1876 $url;
1877 }
1878
1879 # prop_walk(PATH, REV, SUB)
1880 # -------------------------
1881 # Recursively traverse PATH at revision REV and invoke SUB for each
1882 # directory that contains a SVN property. SUB will be invoked as
1883 # follows: &SUB(gs, path, props); where `gs' is this instance of
1884 # Git::SVN, `path' the path to the directory where the properties
1885 # `props' were found. The `path' will be relative to point of checkout,
1886 # that is, if url://repo/trunk is the current Git branch, and that
1887 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
1888 # as `path' (note the trailing `/').
1889 sub prop_walk {
1890 my ($self, $path, $rev, $sub) = @_;
1891
1892 $path =~ s#^/##;
1893 my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
1894 $path =~ s#^/*#/#g;
1895 my $p = $path;
1896 # Strip the irrelevant part of the path.
1897 $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
1898 # Ensure the path is terminated by a `/'.
1899 $p =~ s#/*$#/#;
1900
1901 # The properties contain all the internal SVN stuff nobody
1902 # (usually) cares about.
1903 my $interesting_props = 0;
1904 foreach (keys %{$props}) {
1905 # If it doesn't start with `svn:', it must be a
1906 # user-defined property.
1907 ++$interesting_props and next if $_ !~ /^svn:/;
1908 # FIXME: Fragile, if SVN adds new public properties,
1909 # this needs to be updated.
1910 ++$interesting_props if /^svn:(?:ignore|keywords|executable
1911 |eol-style|mime-type
1912 |externals|needs-lock)$/x;
1913 }
1914 &$sub($self, $p, $props) if $interesting_props;
1915
1916 foreach (sort keys %$dirent) {
1917 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
1918 $self->prop_walk($p . $_, $rev, $sub);
1919 }
1920 }
1921
1922 sub last_rev { ($_[0]->last_rev_commit)[0] }
1923 sub last_commit { ($_[0]->last_rev_commit)[1] }
1924
1925 # returns the newest SVN revision number and newest commit SHA1
1926 sub last_rev_commit {
1927 my ($self) = @_;
1928 if (defined $self->{last_rev} && defined $self->{last_commit}) {
1929 return ($self->{last_rev}, $self->{last_commit});
1930 }
1931 my $c = ::verify_ref($self->refname.'^0');
1932 if ($c && !$self->use_svm_props && !$self->no_metadata) {
1933 my $rev = (::cmt_metadata($c))[1];
1934 if (defined $rev) {
1935 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
1936 return ($rev, $c);
1937 }
1938 }
1939 my $map_path = $self->map_path;
1940 unless (-e $map_path) {
1941 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
1942 return (undef, undef);
1943 }
1944 my ($rev, $commit) = $self->rev_map_max(1);
1945 ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
1946 return ($rev, $commit);
1947 }
1948
1949 sub get_fetch_range {
1950 my ($self, $min, $max) = @_;
1951 $max ||= $self->ra->get_latest_revnum;
1952 $min ||= $self->rev_map_max;
1953 (++$min, $max);
1954 }
1955
1956 sub tmp_config {
1957 my (@args) = @_;
1958 my $old_def_config = "$ENV{GIT_DIR}/svn/config";
1959 my $config = "$ENV{GIT_DIR}/svn/.metadata";
1960 if (! -f $config && -f $old_def_config) {
1961 rename $old_def_config, $config or
1962 die "Failed rename $old_def_config => $config: $!\n";
1963 }
1964 my $old_config = $ENV{GIT_CONFIG};
1965 $ENV{GIT_CONFIG} = $config;
1966 $@ = undef;
1967 my @ret = eval {
1968 unless (-f $config) {
1969 mkfile($config);
1970 open my $fh, '>', $config or
1971 die "Can't open $config: $!\n";
1972 print $fh "; This file is used internally by ",
1973 "git-svn\n" or die
1974 "Couldn't write to $config: $!\n";
1975 print $fh "; You should not have to edit it\n" or
1976 die "Couldn't write to $config: $!\n";
1977 close $fh or die "Couldn't close $config: $!\n";
1978 }
1979 command('config', @args);
1980 };
1981 my $err = $@;
1982 if (defined $old_config) {
1983 $ENV{GIT_CONFIG} = $old_config;
1984 } else {
1985 delete $ENV{GIT_CONFIG};
1986 }
1987 die $err if $err;
1988 wantarray ? @ret : $ret[0];
1989 }
1990
1991 sub tmp_index_do {
1992 my ($self, $sub) = @_;
1993 my $old_index = $ENV{GIT_INDEX_FILE};
1994 $ENV{GIT_INDEX_FILE} = $self->{index};
1995 $@ = undef;
1996 my @ret = eval {
1997 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
1998 mkpath([$dir]) unless -d $dir;
1999 &$sub;
2000 };
2001 my $err = $@;
2002 if (defined $old_index) {
2003 $ENV{GIT_INDEX_FILE} = $old_index;
2004 } else {
2005 delete $ENV{GIT_INDEX_FILE};
2006 }
2007 die $err if $err;
2008 wantarray ? @ret : $ret[0];
2009 }
2010
2011 sub assert_index_clean {
2012 my ($self, $treeish) = @_;
2013
2014 $self->tmp_index_do(sub {
2015 command_noisy('read-tree', $treeish) unless -e $self->{index};
2016 my $x = command_oneline('write-tree');
2017 my ($y) = (command(qw/cat-file commit/, $treeish) =~
2018 /^tree ($::sha1)/mo);
2019 return if $y eq $x;
2020
2021 warn "Index mismatch: $y != $x\nrereading $treeish\n";
2022 unlink $self->{index} or die "unlink $self->{index}: $!\n";
2023 command_noisy('read-tree', $treeish);
2024 $x = command_oneline('write-tree');
2025 if ($y ne $x) {
2026 ::fatal "trees ($treeish) $y != $x\n",
2027 "Something is seriously wrong...";
2028 }
2029 });
2030 }
2031
2032 sub get_commit_parents {
2033 my ($self, $log_entry) = @_;
2034 my (%seen, @ret, @tmp);
2035 # legacy support for 'set-tree'; this is only used by set_tree_cb:
2036 if (my $ip = $self->{inject_parents}) {
2037 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2038 push @tmp, $commit;
2039 }
2040 }
2041 if (my $cur = ::verify_ref($self->refname.'^0')) {
2042 push @tmp, $cur;
2043 }
2044 if (my $ipd = $self->{inject_parents_dcommit}) {
2045 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2046 push @tmp, @$commit;
2047 }
2048 }
2049 push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2050 while (my $p = shift @tmp) {
2051 next if $seen{$p};
2052 $seen{$p} = 1;
2053 push @ret, $p;
2054 # MAXPARENT is defined to 16 in commit-tree.c:
2055 last if @ret >= 16;
2056 }
2057 if (@tmp) {
2058 die "r$log_entry->{revision}: No room for parents:\n\t",
2059 join("\n\t", @tmp), "\n";
2060 }
2061 @ret;
2062 }
2063
2064 sub rewrite_root {
2065 my ($self) = @_;
2066 return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2067 my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2068 my $rwr = eval { command_oneline(qw/config --get/, $k) };
2069 if ($rwr) {
2070 $rwr =~ s#/+$##;
2071 if ($rwr !~ m#^[a-z\+]+://#) {
2072 die "$rwr is not a valid URL (key: $k)\n";
2073 }
2074 }
2075 $self->{-rewrite_root} = $rwr;
2076 }
2077
2078 sub metadata_url {
2079 my ($self) = @_;
2080 ($self->rewrite_root || $self->{url}) .
2081 (length $self->{path} ? '/' . $self->{path} : '');
2082 }
2083
2084 sub full_url {
2085 my ($self) = @_;
2086 $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2087 }
2088
2089
2090 sub set_commit_header_env {
2091 my ($log_entry) = @_;
2092 my %env;
2093 foreach my $ned (qw/NAME EMAIL DATE/) {
2094 foreach my $ac (qw/AUTHOR COMMITTER/) {
2095 $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2096 }
2097 }
2098
2099 $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2100 $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2101 $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2102
2103 $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2104 ? $log_entry->{commit_name}
2105 : $log_entry->{name};
2106 $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2107 ? $log_entry->{commit_email}
2108 : $log_entry->{email};
2109 \%env;
2110 }
2111
2112 sub restore_commit_header_env {
2113 my ($env) = @_;
2114 foreach my $ned (qw/NAME EMAIL DATE/) {
2115 foreach my $ac (qw/AUTHOR COMMITTER/) {
2116 my $k = "GIT_${ac}_${ned}";
2117 if (defined $env->{$k}) {
2118 $ENV{$k} = $env->{$k};
2119 } else {
2120 delete $ENV{$k};
2121 }
2122 }
2123 }
2124 }
2125
2126 sub gc {
2127 command_noisy('gc', '--auto');
2128 };
2129
2130 sub do_git_commit {
2131 my ($self, $log_entry) = @_;
2132 my $lr = $self->last_rev;
2133 if (defined $lr && $lr >= $log_entry->{revision}) {
2134 die "Last fetched revision of ", $self->refname,
2135 " was r$lr, but we are about to fetch: ",
2136 "r$log_entry->{revision}!\n";
2137 }
2138 if (my $c = $self->rev_map_get($log_entry->{revision})) {
2139 croak "$log_entry->{revision} = $c already exists! ",
2140 "Why are we refetching it?\n";
2141 }
2142 my $old_env = set_commit_header_env($log_entry);
2143 my $tree = $log_entry->{tree};
2144 if (!defined $tree) {
2145 $tree = $self->tmp_index_do(sub {
2146 command_oneline('write-tree') });
2147 }
2148 die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2149
2150 my @exec = ('git-commit-tree', $tree);
2151 foreach ($self->get_commit_parents($log_entry)) {
2152 push @exec, '-p', $_;
2153 }
2154 defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2155 or croak $!;
2156 print $msg_fh $log_entry->{log} or croak $!;
2157 restore_commit_header_env($old_env);
2158 unless ($self->no_metadata) {
2159 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2160 or croak $!;
2161 }
2162 $msg_fh->flush == 0 or croak $!;
2163 close $msg_fh or croak $!;
2164 chomp(my $commit = do { local $/; <$out_fh> });
2165 close $out_fh or croak $!;
2166 waitpid $pid, 0;
2167 croak $? if $?;
2168 if ($commit !~ /^$::sha1$/o) {
2169 die "Failed to commit, invalid sha1: $commit\n";
2170 }
2171
2172 $self->rev_map_set($log_entry->{revision}, $commit, 1);
2173
2174 $self->{last_rev} = $log_entry->{revision};
2175 $self->{last_commit} = $commit;
2176 print "r$log_entry->{revision}";
2177 if (defined $log_entry->{svm_revision}) {
2178 print " (\@$log_entry->{svm_revision})";
2179 $self->rev_map_set($log_entry->{svm_revision}, $commit,
2180 0, $self->svm_uuid);
2181 }
2182 print " = $commit ($self->{ref_id})\n";
2183 if (--$_gc_nr == 0) {
2184 $_gc_nr = $_gc_period;
2185 gc();
2186 }
2187 return $commit;
2188 }
2189
2190 sub match_paths {
2191 my ($self, $paths, $r) = @_;
2192 return 1 if $self->{path} eq '';
2193 if (my $path = $paths->{"/$self->{path}"}) {
2194 return ($path->{action} eq 'D') ? 0 : 1;
2195 }
2196 $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2197 if (grep /$self->{path_regex}/, keys %$paths) {
2198 return 1;
2199 }
2200 my $c = '';
2201 foreach (split m#/#, $self->{path}) {
2202 $c .= "/$_";
2203 next unless ($paths->{$c} &&
2204 ($paths->{$c}->{action} =~ /^[AR]$/));
2205 if ($self->ra->check_path($self->{path}, $r) ==
2206 $SVN::Node::dir) {
2207 return 1;
2208 }
2209 }
2210 return 0;
2211 }
2212
2213 sub find_parent_branch {
2214 my ($self, $paths, $rev) = @_;
2215 return undef unless $self->follow_parent;
2216 unless (defined $paths) {
2217 my $err_handler = $SVN::Error::handler;
2218 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2219 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1, sub {
2220 $paths =
2221 Git::SVN::Ra::dup_changed_paths($_[0]) });
2222 $SVN::Error::handler = $err_handler;
2223 }
2224 return undef unless defined $paths;
2225
2226 # look for a parent from another branch:
2227 my @b_path_components = split m#/#, $self->rel_path;
2228 my @a_path_components;
2229 my $i;
2230 while (@b_path_components) {
2231 $i = $paths->{'/'.join('/', @b_path_components)};
2232 last if $i && defined $i->{copyfrom_path};
2233 unshift(@a_path_components, pop(@b_path_components));
2234 }
2235 return undef unless defined $i && defined $i->{copyfrom_path};
2236 my $branch_from = $i->{copyfrom_path};
2237 if (@a_path_components) {
2238 print STDERR "branch_from: $branch_from => ";
2239 $branch_from .= '/'.join('/', @a_path_components);
2240 print STDERR $branch_from, "\n";
2241 }
2242 my $r = $i->{copyfrom_rev};
2243 my $repos_root = $self->ra->{repos_root};
2244 my $url = $self->ra->{url};
2245 my $new_url = $repos_root . $branch_from;
2246 print STDERR "Found possible branch point: ",
2247 "$new_url => ", $self->full_url, ", $r\n";
2248 $branch_from =~ s#^/##;
2249 my $gs = Git::SVN->find_by_url($new_url, $repos_root, $branch_from);
2250 unless ($gs) {
2251 my $ref_id = $self->{ref_id};
2252 $ref_id =~ s/\@\d+$//;
2253 $ref_id .= "\@$r";
2254 # just grow a tail if we're not unique enough :x
2255 $ref_id .= '-' while find_ref($ref_id);
2256 print STDERR "Initializing parent: $ref_id\n";
2257 my ($u, $p, $repo_id) = ($new_url, '', $ref_id);
2258 if ($u =~ s#^\Q$url\E(/|$)##) {
2259 $p = $u;
2260 $u = $url;
2261 $repo_id = $self->{repo_id};
2262 }
2263 $gs = Git::SVN->init($u, $p, $repo_id, $ref_id, 1);
2264 }
2265 my ($r0, $parent) = $gs->find_rev_before($r, 1);
2266 if (!defined $r0 || !defined $parent) {
2267 my ($base, $head) = parse_revision_argument(0, $r);
2268 if ($base <= $r) {
2269 $gs->fetch($base, $r);
2270 }
2271 ($r0, $parent) = $gs->last_rev_commit;
2272 }
2273 if (defined $r0 && defined $parent) {
2274 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
2275 my $ed;
2276 if ($self->ra->can_do_switch) {
2277 $self->assert_index_clean($parent);
2278 print STDERR "Following parent with do_switch\n";
2279 # do_switch works with svn/trunk >= r22312, but that
2280 # is not included with SVN 1.4.3 (the latest version
2281 # at the moment), so we can't rely on it
2282 $self->{last_commit} = $parent;
2283 $ed = SVN::Git::Fetcher->new($self);
2284 $gs->ra->gs_do_switch($r0, $rev, $gs,
2285 $self->full_url, $ed)
2286 or die "SVN connection failed somewhere...\n";
2287 } elsif ($self->ra->trees_match($new_url, $r0,
2288 $self->full_url, $rev)) {
2289 print STDERR "Trees match:\n",
2290 " $new_url\@$r0\n",
2291 " ${\$self->full_url}\@$rev\n",
2292 "Following parent with no changes\n";
2293 $self->tmp_index_do(sub {
2294 command_noisy('read-tree', $parent);
2295 });
2296 $self->{last_commit} = $parent;
2297 } else {
2298 print STDERR "Following parent with do_update\n";
2299 $ed = SVN::Git::Fetcher->new($self);
2300 $self->ra->gs_do_update($rev, $rev, $self, $ed)
2301 or die "SVN connection failed somewhere...\n";
2302 }
2303 print STDERR "Successfully followed parent\n";
2304 return $self->make_log_entry($rev, [$parent], $ed);
2305 }
2306 return undef;
2307 }
2308
2309 sub do_fetch {
2310 my ($self, $paths, $rev) = @_;
2311 my $ed;
2312 my ($last_rev, @parents);
2313 if (my $lc = $self->last_commit) {
2314 # we can have a branch that was deleted, then re-added
2315 # under the same name but copied from another path, in
2316 # which case we'll have multiple parents (we don't
2317 # want to break the original ref, nor lose copypath info):
2318 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2319 push @{$log_entry->{parents}}, $lc;
2320 return $log_entry;
2321 }
2322 $ed = SVN::Git::Fetcher->new($self);
2323 $last_rev = $self->{last_rev};
2324 $ed->{c} = $lc;
2325 @parents = ($lc);
2326 } else {
2327 $last_rev = $rev;
2328 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2329 return $log_entry;
2330 }
2331 $ed = SVN::Git::Fetcher->new($self);
2332 }
2333 unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2334 die "SVN connection failed somewhere...\n";
2335 }
2336 $self->make_log_entry($rev, \@parents, $ed);
2337 }
2338
2339 sub get_untracked {
2340 my ($self, $ed) = @_;
2341 my @out;
2342 my $h = $ed->{empty};
2343 foreach (sort keys %$h) {
2344 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2345 push @out, " $act: " . uri_encode($_);
2346 warn "W: $act: $_\n";
2347 }
2348 foreach my $t (qw/dir_prop file_prop/) {
2349 $h = $ed->{$t} or next;
2350 foreach my $path (sort keys %$h) {
2351 my $ppath = $path eq '' ? '.' : $path;
2352 foreach my $prop (sort keys %{$h->{$path}}) {
2353 next if $SKIP_PROP{$prop};
2354 my $v = $h->{$path}->{$prop};
2355 my $t_ppath_prop = "$t: " .
2356 uri_encode($ppath) . ' ' .
2357 uri_encode($prop);
2358 if (defined $v) {
2359 push @out, " +$t_ppath_prop " .
2360 uri_encode($v);
2361 } else {
2362 push @out, " -$t_ppath_prop";
2363 }
2364 }
2365 }
2366 }
2367 foreach my $t (qw/absent_file absent_directory/) {
2368 $h = $ed->{$t} or next;
2369 foreach my $parent (sort keys %$h) {
2370 foreach my $path (sort @{$h->{$parent}}) {
2371 push @out, " $t: " .
2372 uri_encode("$parent/$path");
2373 warn "W: $t: $parent/$path ",
2374 "Insufficient permissions?\n";
2375 }
2376 }
2377 }
2378 \@out;
2379 }
2380
2381 sub parse_svn_date {
2382 my $date = shift || return '+0000 1970-01-01 00:00:00';
2383 my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2384 (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
2385 croak "Unable to parse date: $date\n";
2386 "+0000 $Y-$m-$d $H:$M:$S";
2387 }
2388
2389 sub check_author {
2390 my ($author) = @_;
2391 if (!defined $author || length $author == 0) {
2392 $author = '(no author)';
2393 } elsif (defined $::_authors && ! defined $::users{$author}) {
2394 die "Author: $author not defined in $::_authors file\n";
2395 }
2396 $author;
2397 }
2398
2399 sub make_log_entry {
2400 my ($self, $rev, $parents, $ed) = @_;
2401 my $untracked = $self->get_untracked($ed);
2402
2403 open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
2404 print $un "r$rev\n" or croak $!;
2405 print $un $_, "\n" foreach @$untracked;
2406 my %log_entry = ( parents => $parents || [], revision => $rev,
2407 log => '');
2408
2409 my $headrev;
2410 my $logged = delete $self->{logged_rev_props};
2411 if (!$logged || $self->{-want_revprops}) {
2412 my $rp = $self->ra->rev_proplist($rev);
2413 foreach (sort keys %$rp) {
2414 my $v = $rp->{$_};
2415 if (/^svn:(author|date|log)$/) {
2416 $log_entry{$1} = $v;
2417 } elsif ($_ eq 'svm:headrev') {
2418 $headrev = $v;
2419 } else {
2420 print $un " rev_prop: ", uri_encode($_), ' ',
2421 uri_encode($v), "\n";
2422 }
2423 }
2424 } else {
2425 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
2426 }
2427 close $un or croak $!;
2428
2429 $log_entry{date} = parse_svn_date($log_entry{date});
2430 $log_entry{log} .= "\n";
2431 my $author = $log_entry{author} = check_author($log_entry{author});
2432 my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
2433 : ($author, undef);
2434
2435 my ($commit_name, $commit_email) = ($name, $email);
2436 if ($_use_log_author) {
2437 my $name_field;
2438 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
2439 $name_field = $1;
2440 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
2441 $name_field = $1;
2442 }
2443 if (!defined $name_field) {
2444 if (!defined $email) {
2445 $email = $name;
2446 }
2447 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
2448 ($name, $email) = ($1, $2);
2449 } elsif ($name_field =~ /(.*)@/) {
2450 ($name, $email) = ($1, $name_field);
2451 } else {
2452 ($name, $email) = ($name_field, $name_field);
2453 }
2454 }
2455 if (defined $headrev && $self->use_svm_props) {
2456 if ($self->rewrite_root) {
2457 die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
2458 "options set!\n";
2459 }
2460 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$};
2461 # we don't want "SVM: initializing mirror for junk" ...
2462 return undef if $r == 0;
2463 my $svm = $self->svm;
2464 if ($uuid ne $svm->{uuid}) {
2465 die "UUID mismatch on SVM path:\n",
2466 "expected: $svm->{uuid}\n",
2467 " got: $uuid\n";
2468 }
2469 my $full_url = $self->full_url;
2470 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
2471 die "Failed to replace '$svm->{replace}' with ",
2472 "'$svm->{source}' in $full_url\n";
2473 # throw away username for storing in records
2474 remove_username($full_url);
2475 $log_entry{metadata} = "$full_url\@$r $uuid";
2476 $log_entry{svm_revision} = $r;
2477 $email ||= "$author\@$uuid";
2478 $commit_email ||= "$author\@$uuid";
2479 } elsif ($self->use_svnsync_props) {
2480 my $full_url = $self->svnsync->{url};
2481 $full_url .= "/$self->{path}" if length $self->{path};
2482 remove_username($full_url);
2483 my $uuid = $self->svnsync->{uuid};
2484 $log_entry{metadata} = "$full_url\@$rev $uuid";
2485 $email ||= "$author\@$uuid";
2486 $commit_email ||= "$author\@$uuid";
2487 } else {
2488 my $url = $self->metadata_url;
2489 remove_username($url);
2490 $log_entry{metadata} = "$url\@$rev " .
2491 $self->ra->get_uuid;
2492 $email ||= "$author\@" . $self->ra->get_uuid;
2493 $commit_email ||= "$author\@" . $self->ra->get_uuid;
2494 }
2495 $log_entry{name} = $name;
2496 $log_entry{email} = $email;
2497 $log_entry{commit_name} = $commit_name;
2498 $log_entry{commit_email} = $commit_email;
2499 \%log_entry;
2500 }
2501
2502 sub fetch {
2503 my ($self, $min_rev, $max_rev, @parents) = @_;
2504 my ($last_rev, $last_commit) = $self->last_rev_commit;
2505 my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
2506 $self->ra->gs_fetch_loop_common($base, $head, [$self]);
2507 }
2508
2509 sub set_tree_cb {
2510 my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
2511 $self->{inject_parents} = { $rev => $tree };
2512 $self->fetch(undef, undef);
2513 }
2514
2515 sub set_tree {
2516 my ($self, $tree) = (shift, shift);
2517 my $log_entry = ::get_commit_entry($tree);
2518 unless ($self->{last_rev}) {
2519 fatal("Must have an existing revision to commit");
2520 }
2521 my %ed_opts = ( r => $self->{last_rev},
2522 log => $log_entry->{log},
2523 ra => $self->ra,
2524 tree_a => $self->{last_commit},
2525 tree_b => $tree,
2526 editor_cb => sub {
2527 $self->set_tree_cb($log_entry, $tree, @_) },
2528 svn_path => $self->{path} );
2529 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
2530 print "No changes\nr$self->{last_rev} = $tree\n";
2531 }
2532 }
2533
2534 sub rebuild_from_rev_db {
2535 my ($self, $path) = @_;
2536 my $r = -1;
2537 open my $fh, '<', $path or croak "open: $!";
2538 binmode $fh or croak "binmode: $!";
2539 while (<$fh>) {
2540 length($_) == 41 or croak "inconsistent size in ($_) != 41";
2541 chomp($_);
2542 ++$r;
2543 next if $_ eq ('0' x 40);
2544 $self->rev_map_set($r, $_);
2545 print "r$r = $_\n";
2546 }
2547 close $fh or croak "close: $!";
2548 unlink $path or croak "unlink: $!";
2549 }
2550
2551 sub rebuild {
2552 my ($self) = @_;
2553 my $map_path = $self->map_path;
2554 return if (-e $map_path && ! -z $map_path);
2555 return unless ::verify_ref($self->refname.'^0');
2556 if ($self->use_svm_props || $self->no_metadata) {
2557 my $rev_db = $self->rev_db_path;
2558 $self->rebuild_from_rev_db($rev_db);
2559 if ($self->use_svm_props) {
2560 my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
2561 $self->rebuild_from_rev_db($svm_rev_db);
2562 }
2563 $self->unlink_rev_db_symlink;
2564 return;
2565 }
2566 print "Rebuilding $map_path ...\n";
2567 my ($log, $ctx) =
2568 command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
2569 $self->refname, '--');
2570 my $full_url = $self->full_url;
2571 remove_username($full_url);
2572 my $svn_uuid = $self->ra_uuid;
2573 my $c;
2574 while (<$log>) {
2575 if ( m{^commit ($::sha1)$} ) {
2576 $c = $1;
2577 next;
2578 }
2579 next unless s{^\s*(git-svn-id:)}{$1};
2580 my ($url, $rev, $uuid) = ::extract_metadata($_);
2581 remove_username($url);
2582
2583 # ignore merges (from set-tree)
2584 next if (!defined $rev || !$uuid);
2585
2586 # if we merged or otherwise started elsewhere, this is
2587 # how we break out of it
2588 if (($uuid ne $svn_uuid) ||
2589 ($full_url && $url && ($url ne $full_url))) {
2590 next;
2591 }
2592
2593 $self->rev_map_set($rev, $c);
2594 print "r$rev = $c\n";
2595 }
2596 command_close_pipe($log, $ctx);
2597 print "Done rebuilding $map_path\n";
2598 my $rev_db_path = $self->rev_db_path;
2599 if (-f $self->rev_db_path) {
2600 unlink $self->rev_db_path or croak "unlink: $!";
2601 }
2602 $self->unlink_rev_db_symlink;
2603 }
2604
2605 # rev_map:
2606 # Tie::File seems to be prone to offset errors if revisions get sparse,
2607 # it's not that fast, either. Tie::File is also not in Perl 5.6. So
2608 # one of my favorite modules is out :< Next up would be one of the DBM
2609 # modules, but I'm not sure which is most portable...
2610 #
2611 # This is the replacement for the rev_db format, which was too big
2612 # and inefficient for large repositories with a lot of sparse history
2613 # (mainly tags)
2614 #
2615 # The format is this:
2616 # - 24 bytes for every record,
2617 # * 4 bytes for the integer representing an SVN revision number
2618 # * 20 bytes representing the sha1 of a git commit
2619 # - No empty padding records like the old format
2620 # (except the last record, which can be overwritten)
2621 # - new records are written append-only since SVN revision numbers
2622 # increase monotonically
2623 # - lookups on SVN revision number are done via a binary search
2624 # - Piping the file to xxd -c24 is a good way of dumping it for
2625 # viewing or editing (piped back through xxd -r), should the need
2626 # ever arise.
2627 # - The last record can be padding revision with an all-zero sha1
2628 # This is used to optimize fetch performance when using multiple
2629 # "fetch" directives in .git/config
2630 #
2631 # These files are disposable unless noMetadata or useSvmProps is set
2632
2633 sub _rev_map_set {
2634 my ($fh, $rev, $commit) = @_;
2635
2636 binmode $fh or croak "binmode: $!";
2637 my $size = (stat($fh))[7];
2638 ($size % 24) == 0 or croak "inconsistent size: $size";
2639
2640 my $wr_offset = 0;
2641 if ($size > 0) {
2642 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2643 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
2644 $read == 24 or croak "read only $read bytes (!= 24)";
2645 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
2646 if ($last_commit eq ('0' x40)) {
2647 if ($size >= 48) {
2648 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2649 $read = sysread($fh, $buf, 24) or
2650 croak "read: $!";
2651 $read == 24 or
2652 croak "read only $read bytes (!= 24)";
2653 ($last_rev, $last_commit) =
2654 unpack(rev_map_fmt, $buf);
2655 if ($last_commit eq ('0' x40)) {
2656 croak "inconsistent .rev_map\n";
2657 }
2658 }
2659 if ($last_rev >= $rev) {
2660 croak "last_rev is higher!: $last_rev >= $rev";
2661 }
2662 $wr_offset = -24;
2663 }
2664 }
2665 sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
2666 syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
2667 croak "write: $!";
2668 }
2669
2670 sub mkfile {
2671 my ($path) = @_;
2672 unless (-e $path) {
2673 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
2674 mkpath([$dir]) unless -d $dir;
2675 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
2676 close $fh or die "Couldn't close (create) $path: $!\n";
2677 }
2678 }
2679
2680 sub rev_map_set {
2681 my ($self, $rev, $commit, $update_ref, $uuid) = @_;
2682 length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
2683 my $db = $self->map_path($uuid);
2684 my $db_lock = "$db.lock";
2685 my $sig;
2686 if ($update_ref) {
2687 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2688 $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
2689 }
2690 mkfile($db);
2691
2692 $LOCKFILES{$db_lock} = 1;
2693 my $sync;
2694 # both of these options make our .rev_db file very, very important
2695 # and we can't afford to lose it because rebuild() won't work
2696 if ($self->use_svm_props || $self->no_metadata) {
2697 $sync = 1;
2698 copy($db, $db_lock) or die "rev_map_set(@_): ",
2699 "Failed to copy: ",
2700 "$db => $db_lock ($!)\n";
2701 } else {
2702 rename $db, $db_lock or die "rev_map_set(@_): ",
2703 "Failed to rename: ",
2704 "$db => $db_lock ($!)\n";
2705 }
2706
2707 sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
2708 or croak "Couldn't open $db_lock: $!\n";
2709 _rev_map_set($fh, $rev, $commit);
2710 if ($sync) {
2711 $fh->flush or die "Couldn't flush $db_lock: $!\n";
2712 $fh->sync or die "Couldn't sync $db_lock: $!\n";
2713 }
2714 close $fh or croak $!;
2715 if ($update_ref) {
2716 $_head = $self;
2717 command_noisy('update-ref', '-m', "r$rev",
2718 $self->refname, $commit);
2719 }
2720 rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
2721 "$db_lock => $db ($!)\n";
2722 delete $LOCKFILES{$db_lock};
2723 if ($update_ref) {
2724 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2725 $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
2726 kill $sig, $$ if defined $sig;
2727 }
2728 }
2729
2730 # If want_commit, this will return an array of (rev, commit) where
2731 # commit _must_ be a valid commit in the archive.
2732 # Otherwise, it'll return the max revision (whether or not the
2733 # commit is valid or just a 0x40 placeholder).
2734 sub rev_map_max {
2735 my ($self, $want_commit) = @_;
2736 $self->rebuild;
2737 my $map_path = $self->map_path;
2738 stat $map_path or return $want_commit ? (0, undef) : 0;
2739 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2740 binmode $fh or croak "binmode: $!";
2741 my $size = (stat($fh))[7];
2742 ($size % 24) == 0 or croak "inconsistent size: $size";
2743
2744 if ($size == 0) {
2745 close $fh or croak "close: $!";
2746 return $want_commit ? (0, undef) : 0;
2747 }
2748
2749 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2750 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2751 my ($r, $c) = unpack(rev_map_fmt, $buf);
2752 if ($want_commit && $c eq ('0' x40)) {
2753 if ($size < 48) {
2754 return $want_commit ? (0, undef) : 0;
2755 }
2756 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2757 sysread($fh, $buf, 24) == 24 or croak "read: $!";
2758 ($r, $c) = unpack(rev_map_fmt, $buf);
2759 if ($c eq ('0'x40)) {
2760 croak "Penultimate record is all-zeroes in $map_path";
2761 }
2762 }
2763 close $fh or croak "close: $!";
2764 $want_commit ? ($r, $c) : $r;
2765 }
2766
2767 sub rev_map_get {
2768 my ($self, $rev, $uuid) = @_;
2769 my $map_path = $self->map_path($uuid);
2770 return undef unless -e $map_path;
2771
2772 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2773 binmode $fh or croak "binmode: $!";
2774 my $size = (stat($fh))[7];
2775 ($size % 24) == 0 or croak "inconsistent size: $size";
2776
2777 if ($size == 0) {
2778 close $fh or croak "close: $fh";
2779 return undef;
2780 }
2781
2782 my ($l, $u) = (0, $size - 24);
2783 my ($r, $c, $buf);
2784
2785 while ($l <= $u) {
2786 my $i = int(($l/24 + $u/24) / 2) * 24;
2787 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
2788 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2789 my ($r, $c) = unpack('NH40', $buf);
2790
2791 if ($r < $rev) {
2792 $l = $i + 24;
2793 } elsif ($r > $rev) {
2794 $u = $i - 24;
2795 } else { # $r == $rev
2796 close($fh) or croak "close: $!";
2797 return $c eq ('0' x 40) ? undef : $c;
2798 }
2799 }
2800 close($fh) or croak "close: $!";
2801 undef;
2802 }
2803
2804 # Finds the first svn revision that exists on (if $eq_ok is true) or
2805 # before $rev for the current branch. It will not search any lower
2806 # than $min_rev. Returns the git commit hash and svn revision number
2807 # if found, else (undef, undef).
2808 sub find_rev_before {
2809 my ($self, $rev, $eq_ok, $min_rev) = @_;
2810 --$rev unless $eq_ok;
2811 $min_rev ||= 1;
2812 while ($rev >= $min_rev) {
2813 if (my $c = $self->rev_map_get($rev)) {
2814 return ($rev, $c);
2815 }
2816 --$rev;
2817 }
2818 return (undef, undef);
2819 }
2820
2821 # Finds the first svn revision that exists on (if $eq_ok is true) or
2822 # after $rev for the current branch. It will not search any higher
2823 # than $max_rev. Returns the git commit hash and svn revision number
2824 # if found, else (undef, undef).
2825 sub find_rev_after {
2826 my ($self, $rev, $eq_ok, $max_rev) = @_;
2827 ++$rev unless $eq_ok;
2828 $max_rev ||= $self->rev_map_max;
2829 while ($rev <= $max_rev) {
2830 if (my $c = $self->rev_map_get($rev)) {
2831 return ($rev, $c);
2832 }
2833 ++$rev;
2834 }
2835 return (undef, undef);
2836 }
2837
2838 sub _new {
2839 my ($class, $repo_id, $ref_id, $path) = @_;
2840 unless (defined $repo_id && length $repo_id) {
2841 $repo_id = $Git::SVN::default_repo_id;
2842 }
2843 unless (defined $ref_id && length $ref_id) {
2844 $_[2] = $ref_id = $Git::SVN::default_ref_id;
2845 }
2846 $_[1] = $repo_id = sanitize_remote_name($repo_id);
2847 my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
2848 $_[3] = $path = '' unless (defined $path);
2849 mkpath(["$ENV{GIT_DIR}/svn"]);
2850 bless {
2851 ref_id => $ref_id, dir => $dir, index => "$dir/index",
2852 path => $path, config => "$ENV{GIT_DIR}/svn/config",
2853 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
2854 }
2855
2856 # for read-only access of old .rev_db formats
2857 sub unlink_rev_db_symlink {
2858 my ($self) = @_;
2859 my $link = $self->rev_db_path;
2860 $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
2861 if (-l $link) {
2862 unlink $link or croak "unlink: $link failed!";
2863 }
2864 }
2865
2866 sub rev_db_path {
2867 my ($self, $uuid) = @_;
2868 my $db_path = $self->map_path($uuid);
2869 $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
2870 or croak "map_path: $db_path does not contain '/.rev_map.' !";
2871 $db_path;
2872 }
2873
2874 # the new replacement for .rev_db
2875 sub map_path {
2876 my ($self, $uuid) = @_;
2877 $uuid ||= $self->ra_uuid;
2878 "$self->{map_root}.$uuid";
2879 }
2880
2881 sub uri_encode {
2882 my ($f) = @_;
2883 $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
2884 $f
2885 }
2886
2887 sub remove_username {
2888 $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
2889 }
2890
2891 package Git::SVN::Prompt;
2892 use strict;
2893 use warnings;
2894 require SVN::Core;
2895 use vars qw/$_no_auth_cache $_username/;
2896
2897 sub simple {
2898 my ($cred, $realm, $default_username, $may_save, $pool) = @_;
2899 $may_save = undef if $_no_auth_cache;
2900 $default_username = $_username if defined $_username;
2901 if (defined $default_username && length $default_username) {
2902 if (defined $realm && length $realm) {
2903 print STDERR "Authentication realm: $realm\n";
2904 STDERR->flush;
2905 }
2906 $cred->username($default_username);
2907 } else {
2908 username($cred, $realm, $may_save, $pool);
2909 }
2910 $cred->password(_read_password("Password for '" .
2911 $cred->username . "': ", $realm));
2912 $cred->may_save($may_save);
2913 $SVN::_Core::SVN_NO_ERROR;
2914 }
2915
2916 sub ssl_server_trust {
2917 my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
2918 $may_save = undef if $_no_auth_cache;
2919 print STDERR "Error validating server certificate for '$realm':\n";
2920 {
2921 no warnings 'once';
2922 # All variables SVN::Auth::SSL::* are used only once,
2923 # so we're shutting up Perl warnings about this.
2924 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
2925 print STDERR " - The certificate is not issued ",
2926 "by a trusted authority. Use the\n",
2927 " fingerprint to validate ",
2928 "the certificate manually!\n";
2929 }
2930 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
2931 print STDERR " - The certificate hostname ",
2932 "does not match.\n";
2933 }
2934 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
2935 print STDERR " - The certificate is not yet valid.\n";
2936 }
2937 if ($failures & $SVN::Auth::SSL::EXPIRED) {
2938 print STDERR " - The certificate has expired.\n";
2939 }
2940 if ($failures & $SVN::Auth::SSL::OTHER) {
2941 print STDERR " - The certificate has ",
2942 "an unknown error.\n";
2943 }
2944 } # no warnings 'once'
2945 printf STDERR
2946 "Certificate information:\n".
2947 " - Hostname: %s\n".
2948 " - Valid: from %s until %s\n".
2949 " - Issuer: %s\n".
2950 " - Fingerprint: %s\n",
2951 map $cert_info->$_, qw(hostname valid_from valid_until
2952 issuer_dname fingerprint);
2953 my $choice;
2954 prompt:
2955 print STDERR $may_save ?
2956 "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
2957 "(R)eject or accept (t)emporarily? ";
2958 STDERR->flush;
2959 $choice = lc(substr(<STDIN> || 'R', 0, 1));
2960 if ($choice =~ /^t$/i) {
2961 $cred->may_save(undef);
2962 } elsif ($choice =~ /^r$/i) {
2963 return -1;
2964 } elsif ($may_save && $choice =~ /^p$/i) {
2965 $cred->may_save($may_save);
2966 } else {
2967 goto prompt;
2968 }
2969 $cred->accepted_failures($failures);
2970 $SVN::_Core::SVN_NO_ERROR;
2971 }
2972
2973 sub ssl_client_cert {
2974 my ($cred, $realm, $may_save, $pool) = @_;
2975 $may_save = undef if $_no_auth_cache;
2976 print STDERR "Client certificate filename: ";
2977 STDERR->flush;
2978 chomp(my $filename = <STDIN>);
2979 $cred->cert_file($filename);
2980 $cred->may_save($may_save);
2981 $SVN::_Core::SVN_NO_ERROR;
2982 }
2983
2984 sub ssl_client_cert_pw {
2985 my ($cred, $realm, $may_save, $pool) = @_;
2986 $may_save = undef if $_no_auth_cache;
2987 $cred->password(_read_password("Password: ", $realm));
2988 $cred->may_save($may_save);
2989 $SVN::_Core::SVN_NO_ERROR;
2990 }
2991
2992 sub username {
2993 my ($cred, $realm, $may_save, $pool) = @_;
2994 $may_save = undef if $_no_auth_cache;
2995 if (defined $realm && length $realm) {
2996 print STDERR "Authentication realm: $realm\n";
2997 }
2998 my $username;
2999 if (defined $_username) {
3000 $username = $_username;
3001 } else {
3002 print STDERR "Username: ";
3003 STDERR->flush;
3004 chomp($username = <STDIN>);
3005 }
3006 $cred->username($username);
3007 $cred->may_save($may_save);
3008 $SVN::_Core::SVN_NO_ERROR;
3009 }
3010
3011 sub _read_password {
3012 my ($prompt, $realm) = @_;
3013 print STDERR $prompt;
3014 STDERR->flush;
3015 require Term::ReadKey;
3016 Term::ReadKey::ReadMode('noecho');
3017 my $password = '';
3018 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
3019 last if $key =~ /[\012\015]/; # \n\r
3020 $password .= $key;
3021 }
3022 Term::ReadKey::ReadMode('restore');
3023 print STDERR "\n";
3024 STDERR->flush;
3025 $password;
3026 }
3027
3028 package SVN::Git::Fetcher;
3029 use vars qw/@ISA/;
3030 use strict;
3031 use warnings;
3032 use Carp qw/croak/;
3033 use IO::File qw//;
3034
3035 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
3036 sub new {
3037 my ($class, $git_svn) = @_;
3038 my $self = SVN::Delta::Editor->new;
3039 bless $self, $class;
3040 $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
3041 $self->{empty} = {};
3042 $self->{dir_prop} = {};
3043 $self->{file_prop} = {};
3044 $self->{absent_dir} = {};
3045 $self->{absent_file} = {};
3046 $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
3047 $self;
3048 }
3049
3050 sub set_path_strip {
3051 my ($self, $path) = @_;
3052 $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
3053 }
3054
3055 sub open_root {
3056 { path => '' };
3057 }
3058
3059 sub open_directory {
3060 my ($self, $path, $pb, $rev) = @_;
3061 { path => $path };
3062 }
3063
3064 sub git_path {
3065 my ($self, $path) = @_;
3066 if ($self->{path_strip}) {
3067 $path =~ s!$self->{path_strip}!! or
3068 die "Failed to strip path '$path' ($self->{path_strip})\n";
3069 }
3070 $path;
3071 }
3072
3073 sub delete_entry {
3074 my ($self, $path, $rev, $pb) = @_;
3075
3076 my $gpath = $self->git_path($path);
3077 return undef if ($gpath eq '');
3078
3079 # remove entire directories.
3080 if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
3081 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3082 -r --name-only -z/,
3083 $self->{c}, '--', $gpath);
3084 local $/ = "\0";
3085 while (<$ls>) {
3086 chomp;
3087 $self->{gii}->remove($_);
3088 print "\tD\t$_\n" unless $::_q;
3089 }
3090 print "\tD\t$gpath/\n" unless $::_q;
3091 command_close_pipe($ls, $ctx);
3092 $self->{empty}->{$path} = 0
3093 } else {
3094 $self->{gii}->remove($gpath);
3095 print "\tD\t$gpath\n" unless $::_q;
3096 }
3097 undef;
3098 }
3099
3100 sub open_file {
3101 my ($self, $path, $pb, $rev) = @_;
3102 my $gpath = $self->git_path($path);
3103 my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
3104 =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
3105 unless (defined $mode && defined $blob) {
3106 die "$path was not found in commit $self->{c} (r$rev)\n";
3107 }
3108 { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
3109 pool => SVN::Pool->new, action => 'M' };
3110 }
3111
3112 sub add_file {
3113 my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
3114 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3115 delete $self->{empty}->{$dir};
3116 { path => $path, mode_a => 100644, mode_b => 100644,
3117 pool => SVN::Pool->new, action => 'A' };
3118 }
3119
3120 sub add_directory {
3121 my ($self, $path, $cp_path, $cp_rev) = @_;
3122 my $gpath = $self->git_path($path);
3123 if ($gpath eq '') {
3124 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3125 -r --name-only -z/,
3126 $self->{c});
3127 local $/ = "\0";
3128 while (<$ls>) {
3129 chomp;
3130 $self->{gii}->remove($_);
3131 print "\tD\t$_\n" unless $::_q;
3132 }
3133 command_close_pipe($ls, $ctx);
3134 $self->{empty}->{$path} = 0;
3135 }
3136 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3137 delete $self->{empty}->{$dir};
3138 $self->{empty}->{$path} = 1;
3139 { path => $path };
3140 }
3141
3142 sub change_dir_prop {
3143 my ($self, $db, $prop, $value) = @_;
3144 $self->{dir_prop}->{$db->{path}} ||= {};
3145 $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
3146 undef;
3147 }
3148
3149 sub absent_directory {
3150 my ($self, $path, $pb) = @_;
3151 $self->{absent_dir}->{$pb->{path}} ||= [];
3152 push @{$self->{absent_dir}->{$pb->{path}}}, $path;
3153 undef;
3154 }
3155
3156 sub absent_file {
3157 my ($self, $path, $pb) = @_;
3158 $self->{absent_file}->{$pb->{path}} ||= [];
3159 push @{$self->{absent_file}->{$pb->{path}}}, $path;
3160 undef;
3161 }
3162
3163 sub change_file_prop {
3164 my ($self, $fb, $prop, $value) = @_;
3165 if ($prop eq 'svn:executable') {
3166 if ($fb->{mode_b} != 120000) {
3167 $fb->{mode_b} = defined $value ? 100755 : 100644;
3168 }
3169 } elsif ($prop eq 'svn:special') {
3170 $fb->{mode_b} = defined $value ? 120000 : 100644;
3171 } else {
3172 $self->{file_prop}->{$fb->{path}} ||= {};
3173 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
3174 }
3175 undef;
3176 }
3177
3178 sub apply_textdelta {
3179 my ($self, $fb, $exp) = @_;
3180 my $fh = IO::File->new_tmpfile;
3181 $fh->autoflush(1);
3182 # $fh gets auto-closed() by SVN::TxDelta::apply(),
3183 # (but $base does not,) so dup() it for reading in close_file
3184 open my $dup, '<&', $fh or croak $!;
3185 my $base = IO::File->new_tmpfile;
3186 $base->autoflush(1);
3187 if ($fb->{blob}) {
3188 defined (my $pid = fork) or croak $!;
3189 if (!$pid) {
3190 open STDOUT, '>&', $base or croak $!;
3191 print STDOUT 'link ' if ($fb->{mode_a} == 120000);
3192 exec qw/git-cat-file blob/, $fb->{blob} or croak $!;
3193 }
3194 waitpid $pid, 0;
3195 croak $? if $?;
3196
3197 if (defined $exp) {
3198 seek $base, 0, 0 or croak $!;
3199 my $got = ::md5sum($base);
3200 die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
3201 "expected: $exp\n",
3202 " got: $got\n" if ($got ne $exp);
3203 }
3204 }
3205 seek $base, 0, 0 or croak $!;
3206 $fb->{fh} = $dup;
3207 $fb->{base} = $base;
3208 [ SVN::TxDelta::apply($base, $fh, undef, $fb->{path}, $fb->{pool}) ];
3209 }
3210
3211 sub close_file {
3212 my ($self, $fb, $exp) = @_;
3213 my $hash;
3214 my $path = $self->git_path($fb->{path});
3215 if (my $fh = $fb->{fh}) {
3216 if (defined $exp) {
3217 seek($fh, 0, 0) or croak $!;
3218 my $got = ::md5sum($fh);
3219 if ($got ne $exp) {
3220 die "Checksum mismatch: $path\n",
3221 "expected: $exp\n got: $got\n";
3222 }
3223 }
3224 sysseek($fh, 0, 0) or croak $!;
3225 if ($fb->{mode_b} == 120000) {
3226 eval {
3227 sysread($fh, my $buf, 5) == 5 or croak $!;
3228 $buf eq 'link ' or die "$path has mode 120000",
3229 " but is not a link";
3230 };
3231 if ($@) {
3232 warn "$@\n";
3233 sysseek($fh, 0, 0) or croak $!;
3234 }
3235 }
3236 defined(my $pid = open my $out,'-|') or die "Can't fork: $!\n";
3237 if (!$pid) {
3238 open STDIN, '<&', $fh or croak $!;
3239 exec qw/git-hash-object -w --stdin/ or croak $!;
3240 }
3241 chomp($hash = do { local $/; <$out> });
3242 close $out or croak $!;
3243 close $fh or croak $!;
3244 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
3245 close $fb->{base} or croak $!;
3246 } else {
3247 $hash = $fb->{blob} or die "no blob information\n";
3248 }
3249 $fb->{pool}->clear;
3250 $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
3251 print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
3252 undef;
3253 }
3254
3255 sub abort_edit {
3256 my $self = shift;
3257 $self->{nr} = $self->{gii}->{nr};
3258 delete $self->{gii};
3259 $self->SUPER::abort_edit(@_);
3260 }
3261
3262 sub close_edit {
3263 my $self = shift;
3264 $self->{git_commit_ok} = 1;
3265 $self->{nr} = $self->{gii}->{nr};
3266 delete $self->{gii};
3267 $self->SUPER::close_edit(@_);
3268 }
3269
3270 package SVN::Git::Editor;
3271 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
3272 use strict;
3273 use warnings;
3274 use Carp qw/croak/;
3275 use IO::File;
3276
3277 sub new {
3278 my ($class, $opts) = @_;
3279 foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
3280 die "$_ required!\n" unless (defined $opts->{$_});
3281 }
3282
3283 my $pool = SVN::Pool->new;
3284 my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
3285 my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
3286 $opts->{r}, $mods);
3287
3288 # $opts->{ra} functions should not be used after this:
3289 my @ce = $opts->{ra}->get_commit_editor($opts->{log},
3290 $opts->{editor_cb}, $pool);
3291 my $self = SVN::Delta::Editor->new(@ce, $pool);
3292 bless $self, $class;
3293 foreach (qw/svn_path r tree_a tree_b/) {
3294 $self->{$_} = $opts->{$_};
3295 }
3296 $self->{url} = $opts->{ra}->{url};
3297 $self->{mods} = $mods;
3298 $self->{types} = $types;
3299 $self->{pool} = $pool;
3300 $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
3301 $self->{rm} = { };
3302 $self->{path_prefix} = length $self->{svn_path} ?
3303 "$self->{svn_path}/" : '';
3304 return $self;
3305 }
3306
3307 sub generate_diff {
3308 my ($tree_a, $tree_b) = @_;
3309 my @diff_tree = qw(diff-tree -z -r);
3310 if ($_cp_similarity) {
3311 push @diff_tree, "-C$_cp_similarity";
3312 } else {
3313 push @diff_tree, '-C';
3314 }
3315 push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
3316 push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
3317 push @diff_tree, $tree_a, $tree_b;
3318 my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
3319 local $/ = "\0";
3320 my $state = 'meta';
3321 my @mods;
3322 while (<$diff_fh>) {
3323 chomp $_; # this gets rid of the trailing "\0"
3324 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
3325 $::sha1\s($::sha1)\s
3326 ([MTCRAD])\d*$/xo) {
3327 push @mods, { mode_a => $1, mode_b => $2,
3328 sha1_b => $3, chg => $4 };
3329 if ($4 =~ /^(?:C|R)$/) {
3330 $state = 'file_a';
3331 } else {
3332 $state = 'file_b';
3333 }
3334 } elsif ($state eq 'file_a') {
3335 my $x = $mods[$#mods] or croak "Empty array\n";
3336 if ($x->{chg} !~ /^(?:C|R)$/) {
3337 croak "Error parsing $_, $x->{chg}\n";
3338 }
3339 $x->{file_a} = $_;
3340 $state = 'file_b';
3341 } elsif ($state eq 'file_b') {
3342 my $x = $mods[$#mods] or croak "Empty array\n";
3343 if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
3344 croak "Error parsing $_, $x->{chg}\n";
3345 }
3346 if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
3347 croak "Error parsing $_, $x->{chg}\n";
3348 }
3349 $x->{file_b} = $_;
3350 $state = 'meta';
3351 } else {
3352 croak "Error parsing $_\n";
3353 }
3354 }
3355 command_close_pipe($diff_fh, $ctx);
3356 \@mods;
3357 }
3358
3359 sub check_diff_paths {
3360 my ($ra, $pfx, $rev, $mods) = @_;
3361 my %types;
3362 $pfx .= '/' if length $pfx;
3363
3364 sub type_diff_paths {
3365 my ($ra, $types, $path, $rev) = @_;
3366 my @p = split m#/+#, $path;
3367 my $c = shift @p;
3368 unless (defined $types->{$c}) {
3369 $types->{$c} = $ra->check_path($c, $rev);
3370 }
3371 while (@p) {
3372 $c .= '/' . shift @p;
3373 next if defined $types->{$c};
3374 $types->{$c} = $ra->check_path($c, $rev);
3375 }
3376 }
3377
3378 foreach my $m (@$mods) {
3379 foreach my $f (qw/file_a file_b/) {
3380 next unless defined $m->{$f};
3381 my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
3382 if (length $pfx.$dir && ! defined $types{$dir}) {
3383 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
3384 }
3385 }
3386 }
3387 \%types;
3388 }
3389
3390 sub split_path {
3391 return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
3392 }
3393
3394 sub repo_path {
3395 my ($self, $path) = @_;
3396 $self->{path_prefix}.(defined $path ? $path : '');
3397 }
3398
3399 sub url_path {
3400 my ($self, $path) = @_;
3401 if ($self->{url} =~ m#^https?://#) {
3402 $path =~ s/([^a-zA-Z0-9_.-])/uc sprintf("%%%02x",ord($1))/eg;
3403 }
3404 $self->{url} . '/' . $self->repo_path($path);
3405 }
3406
3407 sub rmdirs {
3408 my ($self) = @_;
3409 my $rm = $self->{rm};
3410 delete $rm->{''}; # we never delete the url we're tracking
3411 return unless %$rm;
3412
3413 foreach (keys %$rm) {
3414 my @d = split m#/#, $_;
3415 my $c = shift @d;
3416 $rm->{$c} = 1;
3417 while (@d) {
3418 $c .= '/' . shift @d;
3419 $rm->{$c} = 1;
3420 }
3421 }
3422 delete $rm->{$self->{svn_path}};
3423 delete $rm->{''}; # we never delete the url we're tracking
3424 return unless %$rm;
3425
3426 my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
3427 $self->{tree_b});
3428 local $/ = "\0";
3429 while (<$fh>) {
3430 chomp;
3431 my @dn = split m#/#, $_;
3432 while (pop @dn) {
3433 delete $rm->{join '/', @dn};
3434 }
3435 unless (%$rm) {
3436 close $fh;
3437 return;
3438 }
3439 }
3440 command_close_pipe($fh, $ctx);
3441
3442 my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
3443 foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
3444 $self->close_directory($bat->{$d}, $p);
3445 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
3446 print "\tD+\t$d/\n" unless $::_q;
3447 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
3448 delete $bat->{$d};
3449 }
3450 }
3451
3452 sub open_or_add_dir {
3453 my ($self, $full_path, $baton) = @_;
3454 my $t = $self->{types}->{$full_path};
3455 if (!defined $t) {
3456 die "$full_path not known in r$self->{r} or we have a bug!\n";
3457 }
3458 {
3459 no warnings 'once';
3460 # SVN::Node::none and SVN::Node::file are used only once,
3461 # so we're shutting up Perl's warnings about them.
3462 if ($t == $SVN::Node::none) {
3463 return $self->add_directory($full_path, $baton,
3464 undef, -1, $self->{pool});
3465 } elsif ($t == $SVN::Node::dir) {
3466 return $self->open_directory($full_path, $baton,
3467 $self->{r}, $self->{pool});
3468 } # no warnings 'once'
3469 print STDERR "$full_path already exists in repository at ",
3470 "r$self->{r} and it is not a directory (",
3471 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
3472 } # no warnings 'once'
3473 exit 1;
3474 }
3475
3476 sub ensure_path {
3477 my ($self, $path) = @_;
3478 my $bat = $self->{bat};
3479 my $repo_path = $self->repo_path($path);
3480 return $bat->{''} unless (length $repo_path);
3481 my @p = split m#/+#, $repo_path;
3482 my $c = shift @p;
3483 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
3484 while (@p) {
3485 my $c0 = $c;
3486 $c .= '/' . shift @p;
3487 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
3488 }
3489 return $bat->{$c};
3490 }
3491
3492 sub A {
3493 my ($self, $m) = @_;
3494 my ($dir, $file) = split_path($m->{file_b});
3495 my $pbat = $self->ensure_path($dir);
3496 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3497 undef, -1);
3498 print "\tA\t$m->{file_b}\n" unless $::_q;
3499 $self->chg_file($fbat, $m);
3500 $self->close_file($fbat,undef,$self->{pool});
3501 }
3502
3503 sub C {
3504 my ($self, $m) = @_;
3505 my ($dir, $file) = split_path($m->{file_b});
3506 my $pbat = $self->ensure_path($dir);
3507 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3508 $self->url_path($m->{file_a}), $self->{r});
3509 print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3510 $self->chg_file($fbat, $m);
3511 $self->close_file($fbat,undef,$self->{pool});
3512 }
3513
3514 sub delete_entry {
3515 my ($self, $path, $pbat) = @_;
3516 my $rpath = $self->repo_path($path);
3517 my ($dir, $file) = split_path($rpath);
3518 $self->{rm}->{$dir} = 1;
3519 $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
3520 }
3521
3522 sub R {
3523 my ($self, $m) = @_;
3524 my ($dir, $file) = split_path($m->{file_b});
3525 my $pbat = $self->ensure_path($dir);
3526 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3527 $self->url_path($m->{file_a}), $self->{r});
3528 print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3529 $self->chg_file($fbat, $m);
3530 $self->close_file($fbat,undef,$self->{pool});
3531
3532 ($dir, $file) = split_path($m->{file_a});
3533 $pbat = $self->ensure_path($dir);
3534 $self->delete_entry($m->{file_a}, $pbat);
3535 }
3536
3537 sub M {
3538 my ($self, $m) = @_;
3539 my ($dir, $file) = split_path($m->{file_b});
3540 my $pbat = $self->ensure_path($dir);
3541 my $fbat = $self->open_file($self->repo_path($m->{file_b}),
3542 $pbat,$self->{r},$self->{pool});
3543 print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
3544 $self->chg_file($fbat, $m);
3545 $self->close_file($fbat,undef,$self->{pool});
3546 }
3547
3548 sub T { shift->M(@_) }
3549
3550 sub change_file_prop {
3551 my ($self, $fbat, $pname, $pval) = @_;
3552 $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
3553 }
3554
3555 sub chg_file {
3556 my ($self, $fbat, $m) = @_;
3557 if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
3558 $self->change_file_prop($fbat,'svn:executable','*');
3559 } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
3560 $self->change_file_prop($fbat,'svn:executable',undef);
3561 }
3562 my $fh = IO::File->new_tmpfile or croak $!;
3563 if ($m->{mode_b} =~ /^120/) {
3564 print $fh 'link ' or croak $!;
3565 $self->change_file_prop($fbat,'svn:special','*');
3566 } elsif ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
3567 $self->change_file_prop($fbat,'svn:special',undef);
3568 }
3569 defined(my $pid = fork) or croak $!;
3570 if (!$pid) {
3571 open STDOUT, '>&', $fh or croak $!;
3572 exec qw/git-cat-file blob/, $m->{sha1_b} or croak $!;
3573 }
3574 waitpid $pid, 0;
3575 croak $? if $?;
3576 $fh->flush == 0 or croak $!;
3577 seek $fh, 0, 0 or croak $!;
3578
3579 my $exp = ::md5sum($fh);
3580 seek $fh, 0, 0 or croak $!;
3581
3582 my $pool = SVN::Pool->new;
3583 my $atd = $self->apply_textdelta($fbat, undef, $pool);
3584 my $got = SVN::TxDelta::send_stream($fh, @$atd, $pool);
3585 die "Checksum mismatch\nexpected: $exp\ngot: $got\n" if ($got ne $exp);
3586 $pool->clear;
3587
3588 close $fh or croak $!;
3589 }
3590
3591 sub D {
3592 my ($self, $m) = @_;
3593 my ($dir, $file) = split_path($m->{file_b});
3594 my $pbat = $self->ensure_path($dir);
3595 print "\tD\t$m->{file_b}\n" unless $::_q;
3596 $self->delete_entry($m->{file_b}, $pbat);
3597 }
3598
3599 sub close_edit {
3600 my ($self) = @_;
3601 my ($p,$bat) = ($self->{pool}, $self->{bat});
3602 foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
3603 next if $_ eq '';
3604 $self->close_directory($bat->{$_}, $p);
3605 }
3606 $self->close_directory($bat->{''}, $p);
3607 $self->SUPER::close_edit($p);
3608 $p->clear;
3609 }
3610
3611 sub abort_edit {
3612 my ($self) = @_;
3613 $self->SUPER::abort_edit($self->{pool});
3614 }
3615
3616 sub DESTROY {
3617 my $self = shift;
3618 $self->SUPER::DESTROY(@_);
3619 $self->{pool}->clear;
3620 }
3621
3622 # this drives the editor
3623 sub apply_diff {
3624 my ($self) = @_;
3625 my $mods = $self->{mods};
3626 my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
3627 foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
3628 my $f = $m->{chg};
3629 if (defined $o{$f}) {
3630 $self->$f($m);
3631 } else {
3632 fatal("Invalid change type: $f");
3633 }
3634 }
3635 $self->rmdirs if $_rmdir;
3636 if (@$mods == 0) {
3637 $self->abort_edit;
3638 } else {
3639 $self->close_edit;
3640 }
3641 return scalar @$mods;
3642 }
3643
3644 package Git::SVN::Ra;
3645 use vars qw/@ISA $config_dir $_log_window_size/;
3646 use strict;
3647 use warnings;
3648 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
3649
3650 BEGIN {
3651 # enforce temporary pool usage for some simple functions
3652 no strict 'refs';
3653 for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root/) {
3654 my $SUPER = "SUPER::$f";
3655 *$f = sub {
3656 my $self = shift;
3657 my $pool = SVN::Pool->new;
3658 my @ret = $self->$SUPER(@_,$pool);
3659 $pool->clear;
3660 wantarray ? @ret : $ret[0];
3661 };
3662 }
3663 }
3664
3665 sub _auth_providers () {
3666 [
3667 SVN::Client::get_simple_provider(),
3668 SVN::Client::get_ssl_server_trust_file_provider(),
3669 SVN::Client::get_simple_prompt_provider(
3670 \&Git::SVN::Prompt::simple, 2),
3671 SVN::Client::get_ssl_client_cert_file_provider(),
3672 SVN::Client::get_ssl_client_cert_prompt_provider(
3673 \&Git::SVN::Prompt::ssl_client_cert, 2),
3674 SVN::Client::get_ssl_client_cert_pw_file_provider(),
3675 SVN::Client::get_ssl_client_cert_pw_prompt_provider(
3676 \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
3677 SVN::Client::get_username_provider(),
3678 SVN::Client::get_ssl_server_trust_prompt_provider(
3679 \&Git::SVN::Prompt::ssl_server_trust),
3680 SVN::Client::get_username_prompt_provider(
3681 \&Git::SVN::Prompt::username, 2)
3682 ]
3683 }
3684
3685 sub escape_uri_only {
3686 my ($uri) = @_;
3687 my @tmp;
3688 foreach (split m{/}, $uri) {
3689 s/([^\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
3690 push @tmp, $_;
3691 }
3692 join('/', @tmp);
3693 }
3694
3695 sub escape_url {
3696 my ($url) = @_;
3697 if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
3698 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
3699 $url = "$scheme://$domain$uri";
3700 }
3701 $url;
3702 }
3703
3704 sub new {
3705 my ($class, $url) = @_;
3706 $url =~ s!/+$!!;
3707 return $RA if ($RA && $RA->{url} eq $url);
3708
3709 SVN::_Core::svn_config_ensure($config_dir, undef);
3710 my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
3711 my $config = SVN::Core::config_get_config($config_dir);
3712 $RA = undef;
3713 my $dont_store_passwords = 1;
3714 my $conf_t = ${$config}{'config'};
3715 {
3716 no warnings 'once';
3717 # The usage of $SVN::_Core::SVN_CONFIG_* variables
3718 # produces warnings that variables are used only once.
3719 # I had not found the better way to shut them up, so
3720 # the warnings of type 'once' are disabled in this block.
3721 if (SVN::_Core::svn_config_get_bool($conf_t,
3722 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3723 $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
3724 1) == 0) {
3725 SVN::_Core::svn_auth_set_parameter($baton,
3726 $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
3727 bless (\$dont_store_passwords, "_p_void"));
3728 }
3729 if (SVN::_Core::svn_config_get_bool($conf_t,
3730 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3731 $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
3732 1) == 0) {
3733 $Git::SVN::Prompt::_no_auth_cache = 1;
3734 }
3735 } # no warnings 'once'
3736 my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
3737 config => $config,
3738 pool => SVN::Pool->new,
3739 auth_provider_callbacks => $callbacks);
3740 $self->{url} = $url;
3741 $self->{svn_path} = $url;
3742 $self->{repos_root} = $self->get_repos_root;
3743 $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
3744 $self->{cache} = { check_path => { r => 0, data => {} },
3745 get_dir => { r => 0, data => {} } };
3746 $RA = bless $self, $class;
3747 }
3748
3749 sub check_path {
3750 my ($self, $path, $r) = @_;
3751 my $cache = $self->{cache}->{check_path};
3752 if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
3753 return $cache->{data}->{$path};
3754 }
3755 my $pool = SVN::Pool->new;
3756 my $t = $self->SUPER::check_path($path, $r, $pool);
3757 $pool->clear;
3758 if ($r != $cache->{r}) {
3759 %{$cache->{data}} = ();
3760 $cache->{r} = $r;
3761 }
3762 $cache->{data}->{$path} = $t;
3763 }
3764
3765 sub get_dir {
3766 my ($self, $dir, $r) = @_;
3767 my $cache = $self->{cache}->{get_dir};
3768 if ($r == $cache->{r}) {
3769 if (my $x = $cache->{data}->{$dir}) {
3770 return wantarray ? @$x : $x->[0];
3771 }
3772 }
3773 my $pool = SVN::Pool->new;
3774 my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
3775 my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
3776 $pool->clear;
3777 if ($r != $cache->{r}) {
3778 %{$cache->{data}} = ();
3779 $cache->{r} = $r;
3780 }
3781 $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
3782 wantarray ? (\%dirents, $r, $props) : \%dirents;
3783 }
3784
3785 sub DESTROY {
3786 # do not call the real DESTROY since we store ourselves in $RA
3787 }
3788
3789 sub get_log {
3790 my ($self, @args) = @_;
3791 my $pool = SVN::Pool->new;
3792 splice(@args, 3, 1) if ($SVN::Core::VERSION le '1.2.0');
3793 my $ret = $self->SUPER::get_log(@args, $pool);
3794 $pool->clear;
3795 $ret;
3796 }
3797
3798 sub trees_match {
3799 my ($self, $url1, $rev1, $url2, $rev2) = @_;
3800 my $ctx = SVN::Client->new(auth => _auth_providers);
3801 my $out = IO::File->new_tmpfile;
3802
3803 # older SVN (1.1.x) doesn't take $pool as the last parameter for
3804 # $ctx->diff(), so we'll create a default one
3805 my $pool = SVN::Pool->new_default_sub;
3806
3807 $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
3808 $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
3809 $out->flush;
3810 my $ret = (($out->stat)[7] == 0);
3811 close $out or croak $!;
3812
3813 $ret;
3814 }
3815
3816 sub get_commit_editor {
3817 my ($self, $log, $cb, $pool) = @_;
3818 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
3819 $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
3820 }
3821
3822 sub gs_do_update {
3823 my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
3824 my $new = ($rev_a == $rev_b);
3825 my $path = $gs->{path};
3826
3827 if ($new && -e $gs->{index}) {
3828 unlink $gs->{index} or die
3829 "Couldn't unlink index: $gs->{index}: $!\n";
3830 }
3831 my $pool = SVN::Pool->new;
3832 $editor->set_path_strip($path);
3833 my (@pc) = split m#/#, $path;
3834 my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
3835 1, $editor, $pool);
3836 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3837
3838 # Since we can't rely on svn_ra_reparent being available, we'll
3839 # just have to do some magic with set_path to make it so
3840 # we only want a partial path.
3841 my $sp = '';
3842 my $final = join('/', @pc);
3843 while (@pc) {
3844 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
3845 $sp .= '/' if length $sp;
3846 $sp .= shift @pc;
3847 }
3848 die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
3849
3850 $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
3851
3852 $reporter->finish_report($pool);
3853 $pool->clear;
3854 $editor->{git_commit_ok};
3855 }
3856
3857 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
3858 # svn_ra_reparent didn't work before 1.4)
3859 sub gs_do_switch {
3860 my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
3861 my $path = $gs->{path};
3862 my $pool = SVN::Pool->new;
3863
3864 my $full_url = $self->{url};
3865 my $old_url = $full_url;
3866 $full_url .= '/' . escape_uri_only($path) if length $path;
3867 my ($ra, $reparented);
3868 if ($old_url ne $full_url) {
3869 if ($old_url !~ m#^svn(\+ssh)?://#) {
3870 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url,
3871 $pool);
3872 $self->{url} = $full_url;
3873 $reparented = 1;
3874 } else {
3875 $_[0] = undef;
3876 $self = undef;
3877 $RA = undef;
3878 $ra = Git::SVN::Ra->new($full_url);
3879 $ra_invalid = 1;
3880 }
3881 }
3882 $ra ||= $self;
3883 my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
3884 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3885 $reporter->set_path('', $rev_a, 0, @lock, $pool);
3886 $reporter->finish_report($pool);
3887
3888 if ($reparented) {
3889 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
3890 $self->{url} = $old_url;
3891 }
3892
3893 $pool->clear;
3894 $editor->{git_commit_ok};
3895 }
3896
3897 sub longest_common_path {
3898 my ($gsv, $globs) = @_;
3899 my %common;
3900 my $common_max = scalar @$gsv;
3901
3902 foreach my $gs (@$gsv) {
3903 my @tmp = split m#/#, $gs->{path};
3904 my $p = '';
3905 foreach (@tmp) {
3906 $p .= length($p) ? "/$_" : $_;
3907 $common{$p} ||= 0;
3908 $common{$p}++;
3909 }
3910 }
3911 $globs ||= [];
3912 $common_max += scalar @$globs;
3913 foreach my $glob (@$globs) {
3914 my @tmp = split m#/#, $glob->{path}->{left};
3915 my $p = '';
3916 foreach (@tmp) {
3917 $p .= length($p) ? "/$_" : $_;
3918 $common{$p} ||= 0;
3919 $common{$p}++;
3920 }
3921 }
3922
3923 my $longest_path = '';
3924 foreach (sort {length $b <=> length $a} keys %common) {
3925 if ($common{$_} == $common_max) {
3926 $longest_path = $_;
3927 last;
3928 }
3929 }
3930 $longest_path;
3931 }
3932
3933 sub gs_fetch_loop_common {
3934 my ($self, $base, $head, $gsv, $globs) = @_;
3935 return if ($base > $head);
3936 my $inc = $_log_window_size;
3937 my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
3938 my $longest_path = longest_common_path($gsv, $globs);
3939 my $ra_url = $self->{url};
3940 while (1) {
3941 my %revs;
3942 my $err;
3943 my $err_handler = $SVN::Error::handler;
3944 $SVN::Error::handler = sub {
3945 ($err) = @_;
3946 skip_unknown_revs($err);
3947 };
3948 sub _cb {
3949 my ($paths, $r, $author, $date, $log) = @_;
3950 [ dup_changed_paths($paths),
3951 { author => $author, date => $date, log => $log } ];
3952 }
3953 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
3954 sub { $revs{$_[1]} = _cb(@_) });
3955 if ($err && $max >= $head) {
3956 print STDERR "Path '$longest_path' ",
3957 "was probably deleted:\n",
3958 $err->expanded_message,
3959 "\nWill attempt to follow ",
3960 "revisions r$min .. r$max ",
3961 "committed before the deletion\n";
3962 my $hi = $max;
3963 while (--$hi >= $min) {
3964 my $ok;
3965 $self->get_log([$longest_path], $min, $hi,
3966 0, 1, 1, sub {
3967 $ok ||= $_[1];
3968 $revs{$_[1]} = _cb(@_) });
3969 if ($ok) {
3970 print STDERR "r$min .. r$ok OK\n";
3971 last;
3972 }
3973 }
3974 }
3975 $SVN::Error::handler = $err_handler;
3976
3977 my %exists = map { $_->{path} => $_ } @$gsv;
3978 foreach my $r (sort {$a <=> $b} keys %revs) {
3979 my ($paths, $logged) = @{$revs{$r}};
3980
3981 foreach my $gs ($self->match_globs(\%exists, $paths,
3982 $globs, $r)) {
3983 if ($gs->rev_map_max >= $r) {
3984 next;
3985 }
3986 next unless $gs->match_paths($paths, $r);
3987 $gs->{logged_rev_props} = $logged;
3988 if (my $last_commit = $gs->last_commit) {
3989 $gs->assert_index_clean($last_commit);
3990 }
3991 my $log_entry = $gs->do_fetch($paths, $r);
3992 if ($log_entry) {
3993 $gs->do_git_commit($log_entry);
3994 }
3995 $INDEX_FILES{$gs->{index}} = 1;
3996 }
3997 foreach my $g (@$globs) {
3998 my $k = "svn-remote.$g->{remote}." .
3999 "$g->{t}-maxRev";
4000 Git::SVN::tmp_config($k, $r);
4001 }
4002 if ($ra_invalid) {
4003 $_[0] = undef;
4004 $self = undef;
4005 $RA = undef;
4006 $self = Git::SVN::Ra->new($ra_url);
4007 $ra_invalid = undef;
4008 }
4009 }
4010 # pre-fill the .rev_db since it'll eventually get filled in
4011 # with '0' x40 if something new gets committed
4012 foreach my $gs (@$gsv) {
4013 next if $gs->rev_map_max >= $max;
4014 next if defined $gs->rev_map_get($max);
4015 $gs->rev_map_set($max, 0 x40);
4016 }
4017 foreach my $g (@$globs) {
4018 my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
4019 Git::SVN::tmp_config($k, $max);
4020 }
4021 last if $max >= $head;
4022 $min = $max + 1;
4023 $max += $inc;
4024 $max = $head if ($max > $head);
4025 }
4026 Git::SVN::gc();
4027 }
4028
4029 sub match_globs {
4030 my ($self, $exists, $paths, $globs, $r) = @_;
4031
4032 sub get_dir_check {
4033 my ($self, $exists, $g, $r) = @_;
4034 my @x = eval { $self->get_dir($g->{path}->{left}, $r) };
4035 return unless scalar @x == 3;
4036 my $dirents = $x[0];
4037 foreach my $de (keys %$dirents) {
4038 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
4039 my $p = $g->{path}->full_path($de);
4040 next if $exists->{$p};
4041 next if (length $g->{path}->{right} &&
4042 ($self->check_path($p, $r) !=
4043 $SVN::Node::dir));
4044 $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
4045 $g->{ref}->full_path($de), 1);
4046 }
4047 }
4048 foreach my $g (@$globs) {
4049 if (my $path = $paths->{"/$g->{path}->{left}"}) {
4050 if ($path->{action} =~ /^[AR]$/) {
4051 get_dir_check($self, $exists, $g, $r);
4052 }
4053 }
4054 foreach (keys %$paths) {
4055 if (/$g->{path}->{left_regex}/ &&
4056 !/$g->{path}->{regex}/) {
4057 next if $paths->{$_}->{action} !~ /^[AR]$/;
4058 get_dir_check($self, $exists, $g, $r);
4059 }
4060 next unless /$g->{path}->{regex}/;
4061 my $p = $1;
4062 my $pathname = $g->{path}->full_path($p);
4063 next if $exists->{$pathname};
4064 next if ($self->check_path($pathname, $r) !=
4065 $SVN::Node::dir);
4066 $exists->{$pathname} = Git::SVN->init(
4067 $self->{url}, $pathname, undef,
4068 $g->{ref}->full_path($p), 1);
4069 }
4070 my $c = '';
4071 foreach (split m#/#, $g->{path}->{left}) {
4072 $c .= "/$_";
4073 next unless ($paths->{$c} &&
4074 ($paths->{$c}->{action} =~ /^[AR]$/));
4075 get_dir_check($self, $exists, $g, $r);
4076 }
4077 }
4078 values %$exists;
4079 }
4080
4081 sub minimize_url {
4082 my ($self) = @_;
4083 return $self->{url} if ($self->{url} eq $self->{repos_root});
4084 my $url = $self->{repos_root};
4085 my @components = split(m!/!, $self->{svn_path});
4086 my $c = '';
4087 do {
4088 $url .= "/$c" if length $c;
4089 eval { (ref $self)->new($url)->get_latest_revnum };
4090 } while ($@ && ($c = shift @components));
4091 $url;
4092 }
4093
4094 sub can_do_switch {
4095 my $self = shift;
4096 unless (defined $can_do_switch) {
4097 my $pool = SVN::Pool->new;
4098 my $rep = eval {
4099 $self->do_switch(1, '', 0, $self->{url},
4100 SVN::Delta::Editor->new, $pool);
4101 };
4102 if ($@) {
4103 $can_do_switch = 0;
4104 } else {
4105 $rep->abort_report($pool);
4106 $can_do_switch = 1;
4107 }
4108 $pool->clear;
4109 }
4110 $can_do_switch;
4111 }
4112
4113 sub skip_unknown_revs {
4114 my ($err) = @_;
4115 my $errno = $err->apr_err();
4116 # Maybe the branch we're tracking didn't
4117 # exist when the repo started, so it's
4118 # not an error if it doesn't, just continue
4119 #
4120 # Wonderfully consistent library, eh?
4121 # 160013 - svn:// and file://
4122 # 175002 - http(s)://
4123 # 175007 - http(s):// (this repo required authorization, too...)
4124 # More codes may be discovered later...
4125 if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
4126 my $err_key = $err->expanded_message;
4127 # revision numbers change every time, filter them out
4128 $err_key =~ s/\d+/\0/g;
4129 $err_key = "$errno\0$err_key";
4130 unless ($ignored_err{$err_key}) {
4131 warn "W: Ignoring error from SVN, path probably ",
4132 "does not exist: ($errno): ",
4133 $err->expanded_message,"\n";
4134 warn "W: Do not be alarmed at the above message ",
4135 "git-svn is just searching aggressively for ",
4136 "old history.\n",
4137 "This may take a while on large repositories\n";
4138 $ignored_err{$err_key} = 1;
4139 }
4140 return;
4141 }
4142 die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
4143 }
4144
4145 # svn_log_changed_path_t objects passed to get_log are likely to be
4146 # overwritten even if only the refs are copied to an external variable,
4147 # so we should dup the structures in their entirety. Using an externally
4148 # passed pool (instead of our temporary and quickly cleared pool in
4149 # Git::SVN::Ra) does not help matters at all...
4150 sub dup_changed_paths {
4151 my ($paths) = @_;
4152 return undef unless $paths;
4153 my %ret;
4154 foreach my $p (keys %$paths) {
4155 my $i = $paths->{$p};
4156 my %s = map { $_ => $i->$_ }
4157 qw/copyfrom_path copyfrom_rev action/;
4158 $ret{$p} = \%s;
4159 }
4160 \%ret;
4161 }
4162
4163 package Git::SVN::Log;
4164 use strict;
4165 use warnings;
4166 use POSIX qw/strftime/;
4167 use constant commit_log_separator => ('-' x 72) . "\n";
4168 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
4169 %rusers $show_commit $incremental/;
4170 my $l_fmt;
4171
4172 sub cmt_showable {
4173 my ($c) = @_;
4174 return 1 if defined $c->{r};
4175
4176 # big commit message got truncated by the 16k pretty buffer in rev-list
4177 if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
4178 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
4179 @{$c->{l}} = ();
4180 my @log = command(qw/cat-file commit/, $c->{c});
4181
4182 # shift off the headers
4183 shift @log while ($log[0] ne '');
4184 shift @log;
4185
4186 # TODO: make $c->{l} not have a trailing newline in the future
4187 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
4188
4189 (undef, $c->{r}, undef) = ::extract_metadata(
4190 (grep(/^git-svn-id: /, @log))[-1]);
4191 }
4192 return defined $c->{r};
4193 }
4194
4195 sub log_use_color {
4196 return $color || Git->repository->get_colorbool('color.diff');
4197 }
4198
4199 sub git_svn_log_cmd {
4200 my ($r_min, $r_max, @args) = @_;
4201 my $head = 'HEAD';
4202 my (@files, @log_opts);
4203 foreach my $x (@args) {
4204 if ($x eq '--' || @files) {
4205 push @files, $x;
4206 } else {
4207 if (::verify_ref("$x^0")) {
4208 $head = $x;
4209 } else {
4210 push @log_opts, $x;
4211 }
4212 }
4213 }
4214
4215 my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
4216 $gs ||= Git::SVN->_new;
4217 my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
4218 $gs->refname);
4219 push @cmd, '-r' unless $non_recursive;
4220 push @cmd, qw/--raw --name-status/ if $verbose;
4221 push @cmd, '--color' if log_use_color();
4222 push @cmd, @log_opts;
4223 if (defined $r_max && $r_max == $r_min) {
4224 push @cmd, '--max-count=1';
4225 if (my $c = $gs->rev_map_get($r_max)) {
4226 push @cmd, $c;
4227 }
4228 } elsif (defined $r_max) {
4229 if ($r_max < $r_min) {
4230 ($r_min, $r_max) = ($r_max, $r_min);
4231 }
4232 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
4233 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
4234 # If there are no commits in the range, both $c_max and $c_min
4235 # will be undefined. If there is at least 1 commit in the
4236 # range, both will be defined.
4237 return () if !defined $c_min || !defined $c_max;
4238 if ($c_min eq $c_max) {
4239 push @cmd, '--max-count=1', $c_min;
4240 } else {
4241 push @cmd, '--boundary', "$c_min..$c_max";
4242 }
4243 }
4244 return (@cmd, @files);
4245 }
4246
4247 # adapted from pager.c
4248 sub config_pager {
4249 $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
4250 if (!defined $pager) {
4251 $pager = 'less';
4252 } elsif (length $pager == 0 || $pager eq 'cat') {
4253 $pager = undef;
4254 }
4255 $ENV{GIT_PAGER_IN_USE} = defined($pager);
4256 }
4257
4258 sub run_pager {
4259 return unless -t *STDOUT && defined $pager;
4260 pipe my $rfd, my $wfd or return;
4261 defined(my $pid = fork) or ::fatal "Can't fork: $!";
4262 if (!$pid) {
4263 open STDOUT, '>&', $wfd or
4264 ::fatal "Can't redirect to stdout: $!";
4265 return;
4266 }
4267 open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
4268 $ENV{LESS} ||= 'FRSX';
4269 exec $pager or ::fatal "Can't run pager: $! ($pager)";
4270 }
4271
4272 sub format_svn_date {
4273 return strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)", localtime(shift));
4274 }
4275
4276 sub parse_git_date {
4277 my ($t, $tz) = @_;
4278 # Date::Parse isn't in the standard Perl distro :(
4279 if ($tz =~ s/^\+//) {
4280 $t += tz_to_s_offset($tz);
4281 } elsif ($tz =~ s/^\-//) {
4282 $t -= tz_to_s_offset($tz);
4283 }
4284 return $t;
4285 }
4286
4287 sub set_local_timezone {
4288 if (defined $TZ) {
4289 $ENV{TZ} = $TZ;
4290 } else {
4291 delete $ENV{TZ};
4292 }
4293 }
4294
4295 sub tz_to_s_offset {
4296 my ($tz) = @_;
4297 $tz =~ s/(\d\d)$//;
4298 return ($1 * 60) + ($tz * 3600);
4299 }
4300
4301 sub get_author_info {
4302 my ($dest, $author, $t, $tz) = @_;
4303 $author =~ s/(?:^\s*|\s*$)//g;
4304 $dest->{a_raw} = $author;
4305 my $au;
4306 if ($::_authors) {
4307 $au = $rusers{$author} || undef;
4308 }
4309 if (!$au) {
4310 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
4311 }
4312 $dest->{t} = $t;
4313 $dest->{tz} = $tz;
4314 $dest->{a} = $au;
4315 $dest->{t_utc} = parse_git_date($t, $tz);
4316 }
4317
4318 sub process_commit {
4319 my ($c, $r_min, $r_max, $defer) = @_;
4320 if (defined $r_min && defined $r_max) {
4321 if ($r_min == $c->{r} && $r_min == $r_max) {
4322 show_commit($c);
4323 return 0;
4324 }
4325 return 1 if $r_min == $r_max;
4326 if ($r_min < $r_max) {
4327 # we need to reverse the print order
4328 return 0 if (defined $limit && --$limit < 0);
4329 push @$defer, $c;
4330 return 1;
4331 }
4332 if ($r_min != $r_max) {
4333 return 1 if ($r_min < $c->{r});
4334 return 1 if ($r_max > $c->{r});
4335 }
4336 }
4337 return 0 if (defined $limit && --$limit < 0);
4338 show_commit($c);
4339 return 1;
4340 }
4341
4342 sub show_commit {
4343 my $c = shift;
4344 if ($oneline) {
4345 my $x = "\n";
4346 if (my $l = $c->{l}) {
4347 while ($l->[0] =~ /^\s*$/) { shift @$l }
4348 $x = $l->[0];
4349 }
4350 $l_fmt ||= 'A' . length($c->{r});
4351 print 'r',pack($l_fmt, $c->{r}),' | ';
4352 print "$c->{c} | " if $show_commit;
4353 print $x;
4354 } else {
4355 show_commit_normal($c);
4356 }
4357 }
4358
4359 sub show_commit_changed_paths {
4360 my ($c) = @_;
4361 return unless $c->{changed};
4362 print "Changed paths:\n", @{$c->{changed}};
4363 }
4364
4365 sub show_commit_normal {
4366 my ($c) = @_;
4367 print commit_log_separator, "r$c->{r} | ";
4368 print "$c->{c} | " if $show_commit;
4369 print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
4370 my $nr_line = 0;
4371
4372 if (my $l = $c->{l}) {
4373 while ($l->[$#$l] eq "\n" && $#$l > 0
4374 && $l->[($#$l - 1)] eq "\n") {
4375 pop @$l;
4376 }
4377 $nr_line = scalar @$l;
4378 if (!$nr_line) {
4379 print "1 line\n\n\n";
4380 } else {
4381 if ($nr_line == 1) {
4382 $nr_line = '1 line';
4383 } else {
4384 $nr_line .= ' lines';
4385 }
4386 print $nr_line, "\n";
4387 show_commit_changed_paths($c);
4388 print "\n";
4389 print $_ foreach @$l;
4390 }
4391 } else {
4392 print "1 line\n";
4393 show_commit_changed_paths($c);
4394 print "\n";
4395
4396 }
4397 foreach my $x (qw/raw stat diff/) {
4398 if ($c->{$x}) {
4399 print "\n";
4400 print $_ foreach @{$c->{$x}}
4401 }
4402 }
4403 }
4404
4405 sub cmd_show_log {
4406 my (@args) = @_;
4407 my ($r_min, $r_max);
4408 my $r_last = -1; # prevent dupes
4409 set_local_timezone();
4410 if (defined $::_revision) {
4411 if ($::_revision =~ /^(\d+):(\d+)$/) {
4412 ($r_min, $r_max) = ($1, $2);
4413 } elsif ($::_revision =~ /^\d+$/) {
4414 $r_min = $r_max = $::_revision;
4415 } else {
4416 ::fatal "-r$::_revision is not supported, use ",
4417 "standard 'git log' arguments instead";
4418 }
4419 }
4420
4421 config_pager();
4422 @args = git_svn_log_cmd($r_min, $r_max, @args);
4423 if (!@args) {
4424 print commit_log_separator unless $incremental || $oneline;
4425 return;
4426 }
4427 my $log = command_output_pipe(@args);
4428 run_pager();
4429 my (@k, $c, $d, $stat);
4430 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
4431 while (<$log>) {
4432 if (/^${esc_color}commit -?($::sha1_short)/o) {
4433 my $cmt = $1;
4434 if ($c && cmt_showable($c) && $c->{r} != $r_last) {
4435 $r_last = $c->{r};
4436 process_commit($c, $r_min, $r_max, \@k) or
4437 goto out;
4438 }
4439 $d = undef;
4440 $c = { c => $cmt };
4441 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
4442 get_author_info($c, $1, $2, $3);
4443 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
4444 # ignore
4445 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
4446 push @{$c->{raw}}, $_;
4447 } elsif (/^${esc_color}[ACRMDT]\t/) {
4448 # we could add $SVN->{svn_path} here, but that requires
4449 # remote access at the moment (repo_path_split)...
4450 s#^(${esc_color})([ACRMDT])\t#$1 $2 #o;
4451 push @{$c->{changed}}, $_;
4452 } elsif (/^${esc_color}diff /o) {
4453 $d = 1;
4454 push @{$c->{diff}}, $_;
4455 } elsif ($d) {
4456 push @{$c->{diff}}, $_;
4457 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
4458 $esc_color*[\+\-]*$esc_color$/x) {
4459 $stat = 1;
4460 push @{$c->{stat}}, $_;
4461 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
4462 push @{$c->{stat}}, $_;
4463 $stat = undef;
4464 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
4465 ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
4466 } elsif (s/^${esc_color} //o) {
4467 push @{$c->{l}}, $_;
4468 }
4469 }
4470 if ($c && defined $c->{r} && $c->{r} != $r_last) {
4471 $r_last = $c->{r};
4472 process_commit($c, $r_min, $r_max, \@k);
4473 }
4474 if (@k) {
4475 ($r_min, $r_max) = ($r_max, $r_min);
4476 process_commit($_, $r_min, $r_max) foreach reverse @k;
4477 }
4478 out:
4479 close $log;
4480 print commit_log_separator unless $incremental || $oneline;
4481 }
4482
4483 sub cmd_blame {
4484 my $path = pop;
4485
4486 config_pager();
4487 run_pager();
4488
4489 my ($fh, $ctx, $rev);
4490
4491 if ($_git_format) {
4492 ($fh, $ctx) = command_output_pipe('blame', @_, $path);
4493 while (my $line = <$fh>) {
4494 if ($line =~ /^\^?([[:xdigit:]]+)\s/) {
4495 # Uncommitted edits show up as a rev ID of
4496 # all zeros, which we can't look up with
4497 # cmt_metadata
4498 if ($1 !~ /^0+$/) {
4499 (undef, $rev, undef) =
4500 ::cmt_metadata($1);
4501 $rev = '0' if (!$rev);
4502 } else {
4503 $rev = '0';
4504 }
4505 $rev = sprintf('%-10s', $rev);
4506 $line =~ s/^\^?[[:xdigit:]]+(\s)/$rev$1/;
4507 }
4508 print $line;
4509 }
4510 } else {
4511 ($fh, $ctx) = command_output_pipe('blame', '-p', @_, 'HEAD',
4512 '--', $path);
4513 my ($sha1);
4514 my %authors;
4515 while (my $line = <$fh>) {
4516 if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
4517 $sha1 = $1;
4518 (undef, $rev, undef) = ::cmt_metadata($1);
4519 $rev = '0' if (!$rev);
4520 }
4521 elsif ($line =~ /^author (.*)/) {
4522 $authors{$rev} = $1;
4523 $authors{$rev} =~ s/\s/_/g;
4524 }
4525 elsif ($line =~ /^\t(.*)$/) {
4526 printf("%6s %10s %s\n", $rev, $authors{$rev}, $1);
4527 }
4528 }
4529 }
4530 command_close_pipe($fh, $ctx);
4531 }
4532
4533 package Git::SVN::Migration;
4534 # these version numbers do NOT correspond to actual version numbers
4535 # of git nor git-svn. They are just relative.
4536 #
4537 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
4538 #
4539 # v1 layout: .git/$id/info/url, refs/remotes/$id
4540 #
4541 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
4542 #
4543 # v3 layout: .git/svn/$id, refs/remotes/$id
4544 # - info/url may remain for backwards compatibility
4545 # - this is what we migrate up to this layout automatically,
4546 # - this will be used by git svn init on single branches
4547 # v3.1 layout (auto migrated):
4548 # - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
4549 # for backwards compatibility
4550 #
4551 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
4552 # - this is only created for newly multi-init-ed
4553 # repositories. Similar in spirit to the
4554 # --use-separate-remotes option in git-clone (now default)
4555 # - we do not automatically migrate to this (following
4556 # the example set by core git)
4557 #
4558 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
4559 # - newer, more-efficient format that uses 24-bytes per record
4560 # with no filler space.
4561 # - use xxd -c24 < .rev_map.$UUID to view and debug
4562 # - This is a one-way migration, repositories updated to the
4563 # new format will not be able to use old git-svn without
4564 # rebuilding the .rev_db. Rebuilding the rev_db is not
4565 # possible if noMetadata or useSvmProps are set; but should
4566 # be no problem for users that use the (sensible) defaults.
4567 use strict;
4568 use warnings;
4569 use Carp qw/croak/;
4570 use File::Path qw/mkpath/;
4571 use File::Basename qw/dirname basename/;
4572 use vars qw/$_minimize/;
4573
4574 sub migrate_from_v0 {
4575 my $git_dir = $ENV{GIT_DIR};
4576 return undef unless -d $git_dir;
4577 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4578 my $migrated = 0;
4579 while (<$fh>) {
4580 chomp;
4581 my ($id, $orig_ref) = ($_, $_);
4582 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
4583 next unless -f "$git_dir/$id/info/url";
4584 my $new_ref = "refs/remotes/$id";
4585 if (::verify_ref("$new_ref^0")) {
4586 print STDERR "W: $orig_ref is probably an old ",
4587 "branch used by an ancient version of ",
4588 "git-svn.\n",
4589 "However, $new_ref also exists.\n",
4590 "We will not be able ",
4591 "to use this branch until this ",
4592 "ambiguity is resolved.\n";
4593 next;
4594 }
4595 print STDERR "Migrating from v0 layout...\n" if !$migrated;
4596 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
4597 command_noisy('update-ref', $new_ref, $orig_ref);
4598 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
4599 $migrated++;
4600 }
4601 command_close_pipe($fh, $ctx);
4602 print STDERR "Done migrating from v0 layout...\n" if $migrated;
4603 $migrated;
4604 }
4605
4606 sub migrate_from_v1 {
4607 my $git_dir = $ENV{GIT_DIR};
4608 my $migrated = 0;
4609 return $migrated unless -d $git_dir;
4610 my $svn_dir = "$git_dir/svn";
4611
4612 # just in case somebody used 'svn' as their $id at some point...
4613 return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
4614
4615 print STDERR "Migrating from a git-svn v1 layout...\n";
4616 mkpath([$svn_dir]);
4617 print STDERR "Data from a previous version of git-svn exists, but\n\t",
4618 "$svn_dir\n\t(required for this version ",
4619 "($::VERSION) of git-svn) does not. exist\n";
4620 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4621 while (<$fh>) {
4622 my $x = $_;
4623 next unless $x =~ s#^refs/remotes/##;
4624 chomp $x;
4625 next unless -f "$git_dir/$x/info/url";
4626 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
4627 next unless $u;
4628 my $dn = dirname("$git_dir/svn/$x");
4629 mkpath([$dn]) unless -d $dn;
4630 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
4631 mkpath(["$git_dir/svn/svn"]);
4632 print STDERR " - $git_dir/$x/info => ",
4633 "$git_dir/svn/$x/info\n";
4634 rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
4635 croak "$!: $x";
4636 # don't worry too much about these, they probably
4637 # don't exist with repos this old (save for index,
4638 # and we can easily regenerate that)
4639 foreach my $f (qw/unhandled.log index .rev_db/) {
4640 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
4641 }
4642 } else {
4643 print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
4644 rename "$git_dir/$x", "$git_dir/svn/$x" or
4645 croak "$!: $x";
4646 }
4647 $migrated++;
4648 }
4649 command_close_pipe($fh, $ctx);
4650 print STDERR "Done migrating from a git-svn v1 layout\n";
4651 $migrated;
4652 }
4653
4654 sub read_old_urls {
4655 my ($l_map, $pfx, $path) = @_;
4656 my @dir;
4657 foreach (<$path/*>) {
4658 if (-r "$_/info/url") {
4659 $pfx .= '/' if $pfx && $pfx !~ m!/$!;
4660 my $ref_id = $pfx . basename $_;
4661 my $url = ::file_to_s("$_/info/url");
4662 $l_map->{$ref_id} = $url;
4663 } elsif (-d $_) {
4664 push @dir, $_;
4665 }
4666 }
4667 foreach (@dir) {
4668 my $x = $_;
4669 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
4670 read_old_urls($l_map, $x, $_);
4671 }
4672 }
4673
4674 sub migrate_from_v2 {
4675 my @cfg = command(qw/config -l/);
4676 return if grep /^svn-remote\..+\.url=/, @cfg;
4677 my %l_map;
4678 read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
4679 my $migrated = 0;
4680
4681 foreach my $ref_id (sort keys %l_map) {
4682 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
4683 if ($@) {
4684 Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
4685 }
4686 $migrated++;
4687 }
4688 $migrated;
4689 }
4690
4691 sub minimize_connections {
4692 my $r = Git::SVN::read_all_remotes();
4693 my $new_urls = {};
4694 my $root_repos = {};
4695 foreach my $repo_id (keys %$r) {
4696 my $url = $r->{$repo_id}->{url} or next;
4697 my $fetch = $r->{$repo_id}->{fetch} or next;
4698 my $ra = Git::SVN::Ra->new($url);
4699
4700 # skip existing cases where we already connect to the root
4701 if (($ra->{url} eq $ra->{repos_root}) ||
4702 (Git::SVN::sanitize_remote_name($ra->{repos_root}) eq
4703 $repo_id)) {
4704 $root_repos->{$ra->{url}} = $repo_id;
4705 next;
4706 }
4707
4708 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
4709 my $root_path = $ra->{url};
4710 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
4711 foreach my $path (keys %$fetch) {
4712 my $ref_id = $fetch->{$path};
4713 my $gs = Git::SVN->new($ref_id, $repo_id, $path);
4714
4715 # make sure we can read when connecting to
4716 # a higher level of a repository
4717 my ($last_rev, undef) = $gs->last_rev_commit;
4718 if (!defined $last_rev) {
4719 $last_rev = eval {
4720 $root_ra->get_latest_revnum;
4721 };
4722 next if $@;
4723 }
4724 my $new = $root_path;
4725 $new .= length $path ? "/$path" : '';
4726 eval {
4727 $root_ra->get_log([$new], $last_rev, $last_rev,
4728 0, 0, 1, sub { });
4729 };
4730 next if $@;
4731 $new_urls->{$ra->{repos_root}}->{$new} =
4732 { ref_id => $ref_id,
4733 old_repo_id => $repo_id,
4734 old_path => $path };
4735 }
4736 }
4737
4738 my @emptied;
4739 foreach my $url (keys %$new_urls) {
4740 # see if we can re-use an existing [svn-remote "repo_id"]
4741 # instead of creating a(n ugly) new section:
4742 my $repo_id = $root_repos->{$url} ||
4743 Git::SVN::sanitize_remote_name($url);
4744
4745 my $fetch = $new_urls->{$url};
4746 foreach my $path (keys %$fetch) {
4747 my $x = $fetch->{$path};
4748 Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
4749 my $pfx = "svn-remote.$x->{old_repo_id}";
4750
4751 my $old_fetch = quotemeta("$x->{old_path}:".
4752 "refs/remotes/$x->{ref_id}");
4753 command_noisy(qw/config --unset/,
4754 "$pfx.fetch", '^'. $old_fetch . '$');
4755 delete $r->{$x->{old_repo_id}}->
4756 {fetch}->{$x->{old_path}};
4757 if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
4758 command_noisy(qw/config --unset/,
4759 "$pfx.url");
4760 push @emptied, $x->{old_repo_id}
4761 }
4762 }
4763 }
4764 if (@emptied) {
4765 my $file = $ENV{GIT_CONFIG} || $ENV{GIT_CONFIG_LOCAL} ||
4766 "$ENV{GIT_DIR}/config";
4767 print STDERR <<EOF;
4768 The following [svn-remote] sections in your config file ($file) are empty
4769 and can be safely removed:
4770 EOF
4771 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
4772 }
4773 }
4774
4775 sub migration_check {
4776 migrate_from_v0();
4777 migrate_from_v1();
4778 migrate_from_v2();
4779 minimize_connections() if $_minimize;
4780 }
4781
4782 package Git::IndexInfo;
4783 use strict;
4784 use warnings;
4785 use Git qw/command_input_pipe command_close_pipe/;
4786
4787 sub new {
4788 my ($class) = @_;
4789 my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
4790 bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
4791 }
4792
4793 sub remove {
4794 my ($self, $path) = @_;
4795 if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
4796 return ++$self->{nr};
4797 }
4798 undef;
4799 }
4800
4801 sub update {
4802 my ($self, $mode, $hash, $path) = @_;
4803 if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
4804 return ++$self->{nr};
4805 }
4806 undef;
4807 }
4808
4809 sub DESTROY {
4810 my ($self) = @_;
4811 command_close_pipe($self->{gui}, $self->{ctx});
4812 }
4813
4814 package Git::SVN::GlobSpec;
4815 use strict;
4816 use warnings;
4817
4818 sub new {
4819 my ($class, $glob) = @_;
4820 my $re = $glob;
4821 $re =~ s!/+$!!g; # no need for trailing slashes
4822 my $nr = ($re =~ s!^(.*)\*(.*)$!\(\[^/\]+\)!g);
4823 my ($left, $right) = ($1, $2);
4824 if ($nr > 1) {
4825 die "Only one '*' wildcard expansion ",
4826 "is supported (got $nr): '$glob'\n";
4827 } elsif ($nr == 0) {
4828 die "One '*' is needed for glob: '$glob'\n";
4829 }
4830 $re = quotemeta($left) . $re . quotemeta($right);
4831 if (length $left && !($left =~ s!/+$!!g)) {
4832 die "Missing trailing '/' on left side of: '$glob' ($left)\n";
4833 }
4834 if (length $right && !($right =~ s!^/+!!g)) {
4835 die "Missing leading '/' on right side of: '$glob' ($right)\n";
4836 }
4837 my $left_re = qr/^\/\Q$left\E(\/|$)/;
4838 bless { left => $left, right => $right, left_regex => $left_re,
4839 regex => qr/$re/, glob => $glob }, $class;
4840 }
4841
4842 sub full_path {
4843 my ($self, $path) = @_;
4844 return (length $self->{left} ? "$self->{left}/" : '') .
4845 $path . (length $self->{right} ? "/$self->{right}" : '');
4846 }
4847
4848 __END__
4849
4850 Data structures:
4851
4852
4853 $remotes = { # returned by read_all_remotes()
4854 'svn' => {
4855 # svn-remote.svn.url=https://svn.musicpd.org
4856 url => 'https://svn.musicpd.org',
4857 # svn-remote.svn.fetch=mpd/trunk:trunk
4858 fetch => {
4859 'mpd/trunk' => 'trunk',
4860 },
4861 # svn-remote.svn.tags=mpd/tags/*:tags/*
4862 tags => {
4863 path => {
4864 left => 'mpd/tags',
4865 right => '',
4866 regex => qr!mpd/tags/([^/]+)$!,
4867 glob => 'tags/*',
4868 },
4869 ref => {
4870 left => 'tags',
4871 right => '',
4872 regex => qr!tags/([^/]+)$!,
4873 glob => 'tags/*',
4874 },
4875 }
4876 }
4877 };
4878
4879 $log_entry hashref as returned by libsvn_log_entry()
4880 {
4881 log => 'whitespace-formatted log entry
4882 ', # trailing newline is preserved
4883 revision => '8', # integer
4884 date => '2004-02-24T17:01:44.108345Z', # commit date
4885 author => 'committer name'
4886 };
4887
4888
4889 # this is generated by generate_diff();
4890 @mods = array of diff-index line hashes, each element represents one line
4891 of diff-index output
4892
4893 diff-index line ($m hash)
4894 {
4895 mode_a => first column of diff-index output, no leading ':',
4896 mode_b => second column of diff-index output,
4897 sha1_b => sha1sum of the final blob,
4898 chg => change type [MCRADT],
4899 file_a => original file name of a file (iff chg is 'C' or 'R')
4900 file_b => new/current file name of a file (any chg)
4901 }
4902 ;
4903
4904 # retval of read_url_paths{,_all}();
4905 $l_map = {
4906 # repository root url
4907 'https://svn.musicpd.org' => {
4908 # repository path # GIT_SVN_ID
4909 'mpd/trunk' => 'trunk',
4910 'mpd/tags/0.11.5' => 'tags/0.11.5',
4911 },
4912 }
4913
4914 Notes:
4915 I don't trust the each() function on unless I created %hash myself
4916 because the internal iterator may not have started at base.
Alternate source for your git.git needs