src/meson.build

   1 src_directories = include_directories('.')
   2
   3
   4 # Populate the configuration data table
   5 data = configuration_data({
   6     'PACKAGE_NAME':      meson.project_name(),
   7     'PACKAGE_VERSION':   meson.project_version(),
   8     'PACKAGE_API':       metadata['api'],
   9     'PACKAGE_URL':       metadata['homepage'],
  10     'PACKAGE_BUGREPORT': metadata['tracker'],
  11 })
  12
  13 adg_h_additional = []
  14 adg_canvas_h_additional = []
  15
  16 if pangocairo_dep.found()
  17     data.set('PANGO_ENABLED', 1)
  18     adg_h_additional += [
  19         '#include <pango/pango.h>',
  20         '#include "adg/adg-text.h"',
  21         '#include "adg/adg-pango-style.h"',
  22     ]
  23 endif
  24
  25 if gtk_dep.found()
  26     data.set(use_gtk2 ? 'GTK2_ENABLED' : 'GTK3_ENABLED', 1)
  27     adg_h_additional += [
  28         '#include <gtk/gtk.h>',
  29         '#include "adg/adg-gtk-utils.h"',
  30         '#include "adg/adg-gtk-area.h"',
  31         '#include "adg/adg-gtk-layout.h"',
  32     ]
  33     adg_canvas_h_additional += [
  34         '#include <gtk/gtk.h>',
  35         '',
  36         'void            adg_canvas_set_paper            (AdgCanvas      *canvas,',
  37         '                                                 const gchar    *paper_name,',
  38         '                                                 GtkPageOrientation orientation);',
  39         'void            adg_canvas_set_page_setup       (AdgCanvas      *canvas,',
  40         '                                                 GtkPageSetup   *page_setup);',
  41         'GtkPageSetup *  adg_canvas_get_page_setup       (AdgCanvas      *canvas);',
  42     ]
  43 endif
  44
  45 if introspection_dep.found()
  46     data.set('CAIRO_GOBJECT_ENABLED', 1)
  47 endif
  48
  49 data.set('ADG_H_ADDITIONAL', '\n'.join(adg_h_additional))
  50 data.set('ADG_CANVAS_H_ADDITIONAL', '\n'.join(adg_canvas_h_additional))
  51
  52
  53 # Define or generate main header files
  54 config_h = configure_file(
  55     input: 'config.h.meson',
  56     output: '@BASENAME@',
  57     configuration: data
  58 )
  59
  60 cpml_h = files('cpml.h')[0]
  61
  62 adg_h = configure_file(
  63     input: 'adg.h.in',
  64     output: '@BASENAME@',
  65     configuration: data,
  66     install_dir: includedir
  67 )
  68
  69 if catalogdir != ''
  70     install_data('adg.xml', install_dir: catalogdir)
  71 endif
  72
  73 subdir('cpml')
  74 subdir('adg')
  75
  76 if testing.found()
  77     subdir('tests')
  78     subdir('cpml/tests')
  79     subdir('adg/tests')
  80 endif