build/adg.nsi.in

   1 ; @configure_input@
   2 ;
   3 ; ADG installer based on NSis
   4 ; Check http://nsis.sourceforge.net/ for details
   5
   6 !define SRCDIR      "@abs_top_srcdir@"
   7 !define BUILDDIR    "@abs_top_builddir@"
   8 !define DLLDIR      "@DLLDIR@"
   9
  10 ; ---------------------------------------------------------------
  11 ; 1. Header file
  12
  13 !addincludedir "${SRCDIR}/build"
  14 !include MUI2.nsh
  15 !include EnvVarUpdate.nsh
  16
  17 Name "@PACKAGE_NAME@ @PACKAGE_VERSION@"
  18 OutFile "@abs_top_builddir@/@PACKAGE@-@PACKAGE_VERSION@-win@ARCH@.exe"
  19 SetCompressor /SOLID lzma
  20 InstallDir "$PROGRAMFILES@ARCH@\@PACKAGE_NAME@"
  21 RequestExecutionLevel user
  22
  23 ; ---------------------------------------------------------------
  24 ; 2. Interface configuration
  25
  26 !define MUI_ABORTWARNING
  27 !define MUI_COMPONENTSPAGE_SMALLDESC
  28
  29 !define MUI_ICON "${SRCDIR}/build/adg.ico"
  30 !define MUI_UNICON "${SRCDIR}/build/adg.ico"
  31
  32 !define MUI_HEADERIMAGE
  33 !define MUI_HEADERIMAGE_RIGHT
  34 !define MUI_HEADERIMAGE_BITMAP "${SRCDIR}/build/adg-header.bmp"
  35 !define MUI_HEADERIMAGE_UNBITMAP "${SRCDIR}/build/adg-header.bmp"
  36
  37 !define MUI_WELCOMEFINISHPAGE_BITMAP "${SRCDIR}/build/adg-welcome.bmp"
  38 !define MUI_UNWELCOMEFINISHPAGE_BITMAP "${SRCDIR}/build/adg-welcome.bmp"
  39
  40 ; ---------------------------------------------------------------
  41 ; 3. Pages
  42
  43 !insertmacro MUI_PAGE_WELCOME
  44 !insertmacro MUI_PAGE_LICENSE "@abs_top_srcdir@/COPYING"
  45 !insertmacro MUI_PAGE_COMPONENTS
  46 !insertmacro MUI_PAGE_DIRECTORY
  47 !insertmacro MUI_PAGE_INSTFILES
  48 !insertmacro MUI_PAGE_FINISH
  49
  50 !insertmacro MUI_UNPAGE_WELCOME
  51 !insertmacro MUI_UNPAGE_INSTFILES
  52 !insertmacro MUI_UNPAGE_FINISH
  53
  54 ; ---------------------------------------------------------------
  55 ; 4. Language files
  56
  57 !insertmacro MUI_LANGUAGE "English"
  58 !insertmacro MUI_LANGUAGE "Italian"
  59
  60 ; ---------------------------------------------------------------
  61 ; 5. Reserve files
  62
  63
  64 ; ---------------------------------------------------------------
  65 ; I. Installer sections
  66
  67 Section "ADG canvas" SecBase
  68   SectionIn RO
  69
  70   SetOutPath "$INSTDIR"
  71   File /oname=adg-demo.exe  "${BUILDDIR}/demo/.libs/adg-demo-uninstalled.exe"
  72   File /oname=cpml-demo.exe "${BUILDDIR}/demo/.libs/cpml-demo-uninstalled.exe"
  73
  74   SetOutPath "$INSTDIR\share\adg"
  75   File "${BUILDDIR}/demo/adg-demo.ui"
  76   File "${BUILDDIR}/demo/cpml-demo.ui"
  77   File "${SRCDIR}/demo/adg-16.png"
  78   File "${SRCDIR}/demo/adg-32.png"
  79   File "${SRCDIR}/demo/adg-48.png"
  80   File "${SRCDIR}/demo/adg-64.png"
  81   File "${SRCDIR}/demo/adg-128.png"
  82
  83   SetOutPath "$INSTDIR\bin"
  84   File "${DLLDIR}/zlib1.dll"
  85   File "${DLLDIR}/libexpat-*.dll"
  86   File "${DLLDIR}/libintl-*.dll"
  87   File "${DLLDIR}/iconv.dll"
  88   File "${DLLDIR}/libffi-*.dll"
  89   File "${DLLDIR}/libpng??-*.dll"
  90   File "${DLLDIR}/libglib-2.0-*.dll"
  91   File "${DLLDIR}/libgthread-2.0-*.dll"
  92   File "${DLLDIR}/libgmodule-2.0-*.dll"
  93   File "${DLLDIR}/libgobject-2.0-*.dll"
  94   File "${DLLDIR}/libgio-2.0-*.dll"
  95   File "${DLLDIR}/libpixman-1-*.dll"
  96   File "${DLLDIR}/libcairo-*.dll"
  97   File "${DLLDIR}/libpango-1.0-*.dll"
  98   File "${DLLDIR}/libpangocairo-1.0-*.dll"
  99   File "${DLLDIR}/libpangowin32-1.0-*.dll"
 100   File "${DLLDIR}/libatk-1.0-*.dll"
 101   File "${DLLDIR}/libgdk_pixbuf-2.0-*.dll"
 102   File "${DLLDIR}/libgdk-3-*.dll"
 103   File "${DLLDIR}/libgtk-3-*.dll"
 104   File "${BUILDDIR}/src/cpml/.libs/libcpml-1-*.dll"
 105   File "${BUILDDIR}/src/adg/.libs/libadg-1-*.dll"
 106
 107   SetOutPath "$INSTDIR\share\glib-2.0\schemas"
 108   File "${SRCDIR}/build/gschemas.compiled"
 109
 110   CreateDirectory "$SMPROGRAMS\ADG Canvas"
 111   CreateShortcut  "$SMPROGRAMS\ADG Canvas\ADG demonstration program.lnk" "$INSTDIR\adg-demo.exe"
 112   CreateShortcut  "$SMPROGRAMS\ADG Canvas\CPML test case.lnk" "$INSTDIR\cpml-demo.exe"
 113   CreateShortcut  "$SMPROGRAMS\ADG Canvas\Uninstall ADG Canvas.lnk" "$INSTDIR\uninstall.exe"
 114
 115   WriteUninstaller "$INSTDIR\uninstall.exe"
 116   ${EnvVarUpdate} $0 "PATH" "A" "HKCU" "$INSTDIR\bin"
 117 SectionEnd
 118
 119 Section "Support for languages" SecLanguages
 120   SetOutPath "$INSTDIR\share\locale"
 121 SectionEnd
 122
 123 ; Descriptions
 124
 125 LangString DESC_SecBase ${LANG_ENGLISH} "Base installation for running the demo program."
 126 LangString DESC_SecBase ${LANG_ITALIAN} "Installazione di base per eseguire il programma dimostrativo."
 127 LangString DESC_SecLanguages ${LANG_ENGLISH} "Enable support for languages other than english."
 128 LangString DESC_SecLanguages ${LANG_ITALIAN} "Abilitazione del supporto a lingue diverse dall'inglese."
 129
 130 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 131   !insertmacro MUI_DESCRIPTION_TEXT ${SecBase} $(DESC_SecBase)
 132   !insertmacro MUI_DESCRIPTION_TEXT ${SecLanguages} $(DESC_SecLanguages)
 133 !insertmacro MUI_FUNCTION_DESCRIPTION_END
 134
 135 ; Uninstaller
 136
 137 Section "Uninstall"
 138   Delete "$SMPROGRAMS\ADG Canvas\ADG Demonstration program.lnk"
 139   Delete "$SMPROGRAMS\ADG Canvas\CPML test case.lnk"
 140   Delete "$SMPROGRAMS\ADG Canvas\Uninstall ADG Canvas.lnk"
 141   RMDir  "$SMPROGRAMS\ADG Canvas"
 142
 143   Delete "$INSTDIR\bin\libgtk-3-*.dll"
 144   Delete "$INSTDIR\bin\libgdk-3-*.dll"
 145   Delete "$INSTDIR\bin\libgdk_pixbuf-2.0-*.dll"
 146   Delete "$INSTDIR\bin\libatk-1.0-*.dll"
 147   Delete "$INSTDIR\bin\libpangowin32-1.0-*.dll"
 148   Delete "$INSTDIR\bin\libpangocairo-1.0-*.dll"
 149   Delete "$INSTDIR\bin\libpango-1.0-*.dll"
 150   Delete "$INSTDIR\bin\libcairo-*.dll"
 151   Delete "$INSTDIR\bin\libpixman-1-*.dll"
 152   Delete "$INSTDIR\bin\libgio-2.0-*.dll"
 153   Delete "$INSTDIR\bin\libgobject-2.0-*.dll"
 154   Delete "$INSTDIR\bin\libgmodule-2.0-*.dll"
 155   Delete "$INSTDIR\bin\libgthread-2.0-*.dll"
 156   Delete "$INSTDIR\bin\libglib-2.0-*.dll"
 157   Delete "$INSTDIR\bin\libpng??-*.dll"
 158   Delete "$INSTDIR\bin\libffi-*.dll"
 159   Delete "$INSTDIR\bin\iconv.dll"
 160   Delete "$INSTDIR\bin\libintl-*.dll"
 161   Delete "$INSTDIR\bin\libexpat-*.dll"
 162   Delete "$INSTDIR\bin\zlib1.dll"
 163   Delete "$INSTDIR\bin\libcpml-1-*.dll"
 164   Delete "$INSTDIR\bin\libadg-1-*.dll"
 165   RMDir  "$INSTDIR\bin"
 166
 167   Delete "$INSTDIR\share\adg\adg-demo.ui"
 168   Delete "$INSTDIR\share\adg\cpml-demo.ui"
 169   Delete "$INSTDIR\share\adg\adg-128.png"
 170   Delete "$INSTDIR\share\adg\adg-64.png"
 171   Delete "$INSTDIR\share\adg\adg-48.png"
 172   Delete "$INSTDIR\share\adg\adg-32.png"
 173   Delete "$INSTDIR\share\adg\adg-16.png"
 174   RMDir  "$INSTDIR\share\adg"
 175
 176   Delete "$INSTDIR\share\glib-2.0\schemas\gschemas.compiled"
 177   RMDir  "$INSTDIR\share\glib-2.0\schemas"
 178   RMDir  "$INSTDIR\share\glib-2.0"
 179
 180   RMDir  "$INSTDIR\share\locale"
 181
 182   RMDir  "$INSTDIR\share"
 183
 184   Delete "$INSTDIR\adg-demo.exe"
 185   Delete "$INSTDIR\cpml-demo.exe"
 186   Delete "$INSTDIR\uninstall.exe"
 187   RMDir  "$INSTDIR"
 188
 189   ${un.EnvVarUpdate} $0 "PATH" "R" "HKCU" "$INSTDIR\bin"
 190 SectionEnd