src/cpml/meson.build

   1 cpml_directories = include_directories('.')
   2
   3
   4 cpml_c_files = files([
   5     'cpml-arc.c',
   6     'cpml-curve.c',
   7     'cpml-extents.c',
   8     'cpml-gobject.c',
   9     'cpml-line.c',
  10     'cpml-pair.c',
  11     'cpml-primitive.c',
  12     'cpml-segment.c',
  13     'cpml-utils.c',
  14 ])
  15
  16 cpml_h_files = files([
  17     'cpml-arc.h',
  18     'cpml-curve.h',
  19     'cpml-extents.h',
  20     'cpml-gobject.h',
  21     'cpml-pair.h',
  22     'cpml-primitive.h',
  23     'cpml-segment.h',
  24     'cpml-utils.h',
  25 ])
  26
  27 cpml_internal_names = [
  28     'cpml-internal.h',
  29     'cpml-primitive-private.h',
  30 ]
  31
  32
  33 cpml_internal_files = files(cpml_internal_names)
  34
  35 # Build the CPML library
  36 cpml_deps = [
  37     m_dep,
  38     gobject_dep,
  39     cairogobject_dep,
  40     cairo_dep,
  41 ]
  42
  43 cpml_soversion = '@0@.@1@.@2@'.format(
  44     cpml_current - cpml_age,
  45     cpml_age,
  46     cpml_revision
  47 )
  48
  49 cpml = library('cpml-' + metadata['api'],
  50     sources:      cpml_c_files + cpml_h_files + cpml_internal_files,
  51     dependencies: cpml_deps,
  52     version:      cpml_soversion,
  53     install:      true
  54 )
  55
  56 cpml_dep = declare_dependency(
  57     dependencies:        cpml_deps,
  58     link_with:           cpml,
  59     include_directories: src_directories
  60 )
  61
  62 install_headers(cpml_h_files, subdir: 'cpml')
  63
  64
  65 # pkg-config support for CPML library
  66 pkgconfig.generate(cpml,
  67     name:        'CPML',
  68     filebase:    'cpml-' + metadata['api'],
  69     description: 'Cairo Path Manipulation Library',
  70     url:         metadata['homepage'],
  71     subdirs:     pkgdir,
  72     version:     meson.project_version()
  73 )
  74
  75
  76 # GObject introspection support for CPML library
  77 if introspection_dep.found()
  78     cpml_gir = gnome.generate_gir(cpml,
  79         sources:           [ cpml_h ] + cpml_h_files + cpml_c_files,
  80         namespace:         'Cpml',
  81         nsversion:         metadata['api'],
  82         identifier_prefix: 'Cpml',
  83         symbol_prefix:     'cpml',
  84         includes:          [ 'cairo-1.0' ],
  85         header:            'cpml.h',
  86         install:           true,
  87         extra_args: [
  88             '--quiet',
  89             '--sources-top-dirs=' + meson.current_source_dir(),
  90             '--sources-top-dirs=' + meson.current_build_dir(),
  91         ]
  92     )
  93 endif