configure.ac

   1 m4_define([adg_version],[0.5.5])
   2 m4_define([adg_api_version],[1.0])
   3
   4 m4_define([gtkdoc_prereq],[1.9])
   5 m4_define([gobject_prereq],[2.4.0])
   6 m4_define([cairo_prereq],[1.7.4])
   7 m4_define([gtk_prereq],[2.12.0])
   8
   9
  10 # Initialization
  11
  12 AC_PREREQ([2.59])
  13 AC_INIT([Automatic Drawing Generation],adg_version,
  14         [http://dev.entidi.com/p/adg/],[adg],[http://adg.entidi.com/])
  15 AC_CONFIG_SRCDIR([configure.ac])
  16 AC_CONFIG_HEADERS([config.h])
  17 AC_CONFIG_MACRO_DIR([build])
  18 AM_INIT_AUTOMAKE([1.6 gnits no-dist-gzip dist-bzip2 -Wall])
  19
  20
  21 # Check for host information
  22
  23 AC_CANONICAL_HOST
  24 case "${host}" in
  25   *-*-linux*)
  26     guessed_host=linux
  27     ;;
  28   *-*-freebsd*)
  29     guessed_host=freebsd
  30     ;;
  31   *-*-mingw*)
  32     guessed_host=mingw
  33     ;;
  34   *-*-solaris*)
  35     guessed_host=solaris
  36     ;;
  37   *-*-darwin*)
  38     guessed_host=darwin
  39     ;;
  40   *-*-beos*)
  41     guessed_host=beos
  42     ;;
  43   *-*-cygwin*)
  44     guessed_host=cygwin
  45     ;;
  46   *-*-minix)
  47     guessed_host=minix
  48     ;;
  49   *-*-aix*)
  50     guessed_host=aix
  51     ;;
  52   *)
  53     guessed_host=unknown
  54     ;;
  55 esac
  56 AM_CONDITIONAL([OS_UNIX],[test "${guessed_host}" != "mingw"])
  57 AM_CONDITIONAL([OS_WIN32],[test "${guessed_host}" == "mingw" -o "${guessed_host}" == "cygwin"])
  58
  59
  60 # Check for programs
  61
  62 AC_PROG_CC
  63 PKG_PROG_PKG_CONFIG
  64 AC_PATH_PROG([XSLTPROC],[xsltproc],[/usr/bin/xsltproc])
  65 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums],[/usr/bin/glib-mkenums])
  66 AC_PATH_PROG([GLIB_GENMARSHAL],[glib-genmarshal],[/usr/bin/glib-genmarshal])
  67 AC_PATH_PROG([GTESTER],[gtester],[/usr/bin/gtester])
  68 AC_PATH_PROG([GTESTER_REPORT],[gtester-report],[/usr/bin/gtester-report])
  69
  70 m4_ifdef([LT_INIT],
  71          [LT_INIT([disable-static])],
  72          [AC_DISABLE_STATIC
  73           AC_PROG_LIBTOOL])
  74
  75
  76 # I18n
  77
  78 AC_SUBST([GETTEXT_PACKAGE],adg-adg_api_version)
  79 AC_DEFINE([GETTEXT_PACKAGE],"AC_PACKAGE_TARNAME-adg_api_version",
  80           [Define to the domain used by gettext.])
  81 ALL_LINGUAS=""
  82 AM_GLIB_GNU_GETTEXT
  83 GLIB_DEFINE_LOCALEDIR([LOCALEDIR])
  84 AC_OUTPUT_COMMANDS([case "${CONFIG_FILES}" in *po-properties/Makefile.in*)
  85         sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
  86       esac])
  87
  88
  89 # Check for required packages
  90
  91 GTK_DOC_CHECK(gtkdoc_prereq)
  92 PKG_CHECK_MODULES([GOBJECT2],[gobject-2.0 >= ]gobject_prereq)
  93 PKG_CHECK_MODULES([CAIRO],[cairo >= ]cairo_prereq)
  94
  95
  96 # Check for optional GTK+2 support
  97
  98 AC_ARG_ENABLE([gtk2],
  99               [AS_HELP_STRING([--enable-gtk2],
 100                               [include GKT+2 specific widgets @<:@default=check@:>@])],
 101               [],[enable_gtk2=check])
 102 AS_IF([test "x${enable_gtk2}" != "xno"],
 103       [PKG_CHECK_MODULES([GTK2],[gtk+-2.0 >= ]gtk_prereq,
 104                          [enable_gtk2=yes],
 105                          [AS_IF([test "x${enable_gtk2}" = "xyes"],
 106                                 [AC_MSG_ERROR([$GTK2_PKG_ERRORS and GTK+2 support requested])],
 107                                 [enable_gtk2=no])])])
 108 AM_CONDITIONAL([HAVE_GTK2],[test "x${enable_gtk2}" = "xyes"])
 109
 110
 111 # Check for optional GLib test framework
 112
 113 AC_ARG_ENABLE([test_framework],
 114               [AS_HELP_STRING([--enable-test-framework],
 115                               [enable GLib test framework @<:@default=check@:>@])],
 116               [],[enable_test_framework=check])
 117 AS_IF([test "x${enable_test_framework}" != "xno"],
 118       [PKG_CHECK_EXISTS([glib-2.0 >= 2.16.0],
 119                         [enable_test_framework=yes],
 120                         [AS_IF([test "x${enable_test_framework}" = "xyes"],
 121                                [AC_MSG_ERROR([The test framework needs glib2-2.16.0 or later])],
 122                                [enable_test_framework=no])])])
 123 AM_CONDITIONAL([HAVE_TEST_FRAMEWORK],[test "x${enable_test_framework}" = "xyes"])
 124
 125
 126 # Check for compiler characteristics
 127
 128 AC_C_CONST
 129
 130
 131 # Final step
 132
 133 CPML_REQUIRES='cairo >= cairo_prereq'
 134 CPML_CFLAGS="${CAIRO_CFLAGS}"
 135 CPML_LIBS="${CAIRO_LIBS}"
 136 AS_IF([test "x${enable_gtk2}" = "xyes"],
 137       [ADG_REQUIRES='gtk+-2.0 >= gtk_prereq'
 138        ADG_CFLAGS="${GTK2_CFLAGS}"
 139        ADG_LIBS="${GTK2_LIBS}"],
 140       [ADG_REQUIRES='gobject-2.0 >= gobject_prereq'
 141        ADG_CFLAGS="${GOBJECT2_CFLAGS} ${CAIRO_CFLAGS}"
 142        ADG_LIBS="${GOBJECT2_LIBS} ${CAIRO_LIBS}"])
 143 AC_SUBST([CPML_REQUIRES])
 144 AC_SUBST([CPML_CFLAGS])
 145 AC_SUBST([CPML_LIBS])
 146 AC_SUBST([ADG_REQUIRES])
 147 AC_SUBST([ADG_CFLAGS])
 148 AC_SUBST([ADG_LIBS])
 149
 150 SHAVE_INIT([build],[enable])
 151 AC_CONFIG_FILES([build/shave
 152                  build/shave-libtool
 153                  Makefile
 154                  cpml/cpml.pc
 155                  cpml/Makefile
 156                  adg/adg.pc
 157                  adg/Makefile
 158                  demo/Makefile
 159                  po/Makefile.in
 160                  po-properties/Makefile.in
 161                  tests/Makefile
 162                  docs/Makefile
 163                  docs/cpml/Makefile
 164                  docs/cpml/bookinfo.xml
 165                  docs/adg/Makefile
 166                  docs/adg/bookinfo.xml])
 167 AC_OUTPUT
 168
 169
 170 # Report
 171
 172 echo ""
 173 echo 'ADG canvas adg_version will be built with the following options:'
 174 echo "----------------------------------------------------------"
 175 echo '                  API compatibility: adg_api_version'
 176 echo '                CPML library to use: internal (cpml-adg_version)'
 177 echo " AdgWidget support (requires GTK+2): ${enable_gtk2}"
 178 echo "                Build API reference: ${enable_gtk_doc}"
 179 echo "             Test framework support: ${enable_test_framework}"
 180 echo ""