configure.ac

   1 m4_define([adg_version],[0.6.3])
   2 m4_define([adg_api_version],[1.0])
   3
   4 m4_define([gtkdoc_prereq],[1.9])
   5 m4_define([gobject_prereq],[2.10.1])
   6 m4_define([cairo_prereq],[1.7.4])
   7 m4_define([gtk_prereq],[2.12.0])
   8 m4_define([pangocairo_prereq],[1.18.0])
   9
  10
  11 # Initialization
  12
  13 dnl autoconf 2.60 implements datarootdir, required by ADG
  14 dnl to help overcoming the hardcoded glade catalogdir
  15 AC_PREREQ([2.60])
  16 AC_INIT([adg-1.0],adg_version,[http://dev.entidi.com/p/adg/],[adg],[http://adg.entidi.com/])
  17 AC_CONFIG_SRCDIR([configure.ac])
  18 AC_CONFIG_HEADERS([src/config.h])
  19 AC_CONFIG_AUX_DIR([build])
  20 AC_CONFIG_MACRO_DIR([build])
  21 AM_INIT_AUTOMAKE([1.6 gnits no-dist-gzip dist-bzip2 -Wall])
  22 m4_ifdef([AM_SILENT_RULES],
  23          [AM_SILENT_RULES([yes])],
  24          [AC_SUBST([AM_V_GEN],[])])
  25 AC_SUBST([ADG_API_PACKAGE],AC_PACKAGE_TARNAME-adg_api_version)
  26
  27
  28 # Check for host information
  29
  30 AC_CANONICAL_HOST
  31 case "${host}" in
  32   *-*-linux*)
  33     guessed_host=linux
  34     ;;
  35   *-*-freebsd*)
  36     guessed_host=freebsd
  37     ;;
  38   *-*-mingw*)
  39     guessed_host=mingw
  40     ;;
  41   *-*-solaris*)
  42     guessed_host=solaris
  43     ;;
  44   *-*-darwin*)
  45     guessed_host=darwin
  46     ;;
  47   *-*-beos*)
  48     guessed_host=beos
  49     ;;
  50   *-*-cygwin*)
  51     guessed_host=cygwin
  52     ;;
  53   *-*-minix)
  54     guessed_host=minix
  55     ;;
  56   *-*-aix*)
  57     guessed_host=aix
  58     ;;
  59   *)
  60     guessed_host=unknown
  61     ;;
  62 esac
  63 AM_CONDITIONAL([OS_UNIX],[test "${guessed_host}" != "mingw"])
  64 AM_CONDITIONAL([OS_WINDOWS],[test "${guessed_host}" == "mingw" -o "${guessed_host}" == "cygwin"])
  65
  66
  67 # Check for programs
  68
  69 AC_PROG_CC
  70 AC_PROG_SED
  71 PKG_PROG_PKG_CONFIG
  72 AC_PATH_PROG([XSLTPROC],[xsltproc],[/usr/bin/xsltproc])
  73 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums],[/usr/bin/glib-mkenums])
  74 AC_PATH_PROG([GLIB_GENMARSHAL],[glib-genmarshal],[/usr/bin/glib-genmarshal])
  75 AC_PATH_PROG([GTESTER],[gtester],[/usr/bin/gtester])
  76 AC_PATH_PROG([GTESTER_REPORT],[gtester-report],[/usr/bin/gtester-report])
  77 AC_PATH_PROG([GLADE3],[glade-3],[/usr/bin/glade-3])
  78
  79
  80 # Check for libraries
  81
  82 AC_CHECK_LIB([m],[cos])
  83
  84
  85 # Libtool initialization
  86
  87 AC_MSG_CHECKING([which libtool initialization strategy to adopt])
  88 AC_MSG_RESULT([m4_ifset([LT_INIT],[LT-INIT],[AC-PROG-LIBTOOL])])
  89 m4_ifset([LT_INIT],
  90          [LT_INIT([disable-static win32-dll])],
  91          [AC_DISABLE_STATIC
  92           AC_LIBTOOL_WIN32_DLL
  93           AC_PROG_LIBTOOL])
  94
  95
  96 # I18n
  97
  98 AC_SUBST([GETTEXT_PACKAGE],[${ADG_API_PACKAGE}])
  99 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["${ADG_API_PACKAGE}"],
 100                    [Define to the domain used by gettext.])
 101 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 102 IT_PROG_INTLTOOL(0.40.1)
 103 AM_GLIB_GNU_GETTEXT
 104 GLIB_DEFINE_LOCALEDIR([LOCALEDIR])
 105 AC_CONFIG_COMMANDS([default],
 106                    [case "${CONFIG_FILES}" in *po-properties/Makefile.in*)
 107         ${SED} -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 108     esac],
 109                    [SED="${SED}"])
 110
 111
 112 # Check for required packages
 113
 114 GTK_DOC_CHECK(gtkdoc_prereq)
 115 PKG_CHECK_MODULES([GLIB],[glib-2.0])
 116 PKG_CHECK_MODULES([GOBJECT2],[gobject-2.0 >= ]gobject_prereq)
 117 PKG_CHECK_MODULES([CAIRO],[cairo >= ]cairo_prereq)
 118
 119
 120 # Check for optional pango support
 121
 122 AC_ARG_ENABLE([pango],
 123               [AS_HELP_STRING([--enable-pango],
 124                               [use pango for rendering text @<:@default=check@:>@])],
 125               [],[enable_pango=check])
 126 AS_IF([test "x${enable_pango}" != "xno"],
 127       [PKG_CHECK_MODULES([PANGO],[pangocairo >= ]pangocairo_prereq,
 128                          [enable_pango=yes
 129                           AC_DEFINE_UNQUOTED([PANGO_ENABLED],[1],
 130                                              [Defined if the pango support is enabled.])],
 131                          [AS_IF([test "x${enable_pango}" = "xyes"],
 132                                 [AC_MSG_ERROR([${PANGO_PKG_ERRORS} and pango support requested])],
 133                                 [enable_pango=no])])])
 134 AM_CONDITIONAL([HAVE_PANGO],[test "x${enable_pango}" = "xyes"])
 135
 136
 137 # Check for optional GTK+2 support
 138
 139 AC_ARG_ENABLE([gtk2],
 140               [AS_HELP_STRING([--enable-gtk2],
 141                               [include GKT+2 specific widgets @<:@default=check@:>@])],
 142               [],[enable_gtk2=check])
 143 AS_IF([test "x${enable_gtk2}" != "xno"],
 144       [PKG_CHECK_MODULES([GTK2],[gtk+-2.0 >= ]gtk_prereq,
 145                          [enable_gtk2=yes],
 146                          [AS_IF([test "x${enable_gtk2}" = "xyes"],
 147                                 [AC_MSG_ERROR([${GTK2_PKG_ERRORS} and GTK+2 support requested])],
 148                                 [enable_gtk2=no])])])
 149 AM_CONDITIONAL([HAVE_GTK2],[test "x${enable_gtk2}" = "xyes"])
 150
 151
 152 # Check for optional glade support
 153
 154 AC_ARG_ENABLE([glade],
 155               [AS_HELP_STRING([--enable-glade],
 156                               [install glade catalog file @<:@default=check@:>@])],
 157               [],[enable_glade=check])
 158 AS_IF([test "x${enable_glade}" != "xno"],
 159       [PKG_CHECK_MODULES([GLADE],[gladeui-1.0],
 160                          [enable_glade=yes],
 161                          [AS_IF([test "x${enable_glade}" = "xyes"],
 162                                 [AC_MSG_ERROR([${GLADE_PKG_ERRORS} and glade support requested])],
 163                                 [enable_glade=no])])])
 164 AM_CONDITIONAL([HAVE_GLADE],[test "x${enable_glade}" = "xyes"])
 165 AS_IF([test "x${enable_glade}" == "xyes"],
 166       [AC_MSG_CHECKING([for the glade catalog path])
 167        gladeroot=`${PKG_CONFIG} --variable=datarootdir gladeui-1.0`
 168        AS_IF([test "x${gladeroot}" == "x"],
 169              [GLADE_CATALOGDIR="\${datarootdir}/glade3/catalogs}"],
 170              [gladecatalog=`${PKG_CONFIG} --variable=catalogdir gladeui-1.0`
 171               GLADE_CATALOGDIR=`echo "${gladecatalog}" | ${SED} -e "s|^${gladeroot}|"'${datarootdir}|'`])
 172        AC_SUBST([GLADE_CATALOGDIR])
 173        AC_MSG_RESULT(${GLADE_CATALOGDIR})])
 174
 175
 176
 177 # Check for optional GLib test framework
 178
 179 AC_ARG_ENABLE([test_framework],
 180               [AS_HELP_STRING([--enable-test-framework],
 181                               [enable GLib test framework @<:@default=check@:>@])],
 182               [],[enable_test_framework=check])
 183 AS_IF([test "x${enable_test_framework}" != "xno"],
 184       [PKG_CHECK_EXISTS([glib-2.0 >= 2.16.0],
 185                         [enable_test_framework=yes],
 186                         [AS_IF([test "x${enable_test_framework}" = "xyes"],
 187                                [AC_MSG_ERROR([The test framework needs glib2-2.16.0 or later])],
 188                                [enable_test_framework=no])])])
 189 AM_CONDITIONAL([HAVE_TEST_FRAMEWORK],[test "x${enable_test_framework}" = "xyes"])
 190
 191
 192 # Check for compiler characteristics
 193
 194 AC_C_CONST
 195
 196
 197 # Final step
 198
 199 AC_SUBST([CPML_REQUIRES],'cairo >= cairo_prereq')
 200 AC_SUBST([ADG_REQUIRES],'gobject-2.0 >= gobject_prereq')
 201 AC_SUBST([ADG_GTK_REQUIRES],'gtk+-2.0 >= gtk_prereq')
 202 AC_SUBST([DLLDIR],"$(${PKG_CONFIG} --variable=prefix gobject-2.0)/bin")
 203
 204 AC_CONFIG_FILES([build/adg.nsi
 205                  Makefile
 206                  src/Makefile
 207                  src/cpml-1.pc
 208                  src/cpml/Makefile
 209                  src/cpml/tests/Makefile
 210                  src/adg-1.pc
 211                  src/adg/Makefile
 212                  src/adg/tests/Makefile
 213                  src/adg-gtk-1.pc
 214                  src/adg-gtk/Makefile
 215                  src/adg-gtk/tests/Makefile
 216                  demo/Makefile
 217                  demo/cpml-demo.ui
 218                  demo/adg-demo.ui
 219                  po/Makefile.in
 220                  po-properties/Makefile.in
 221                  docs/Makefile
 222                  docs/cpml/Makefile
 223                  docs/cpml/bookinfo.xml
 224                  docs/adg/Makefile
 225                  docs/adg/bookinfo.xml])
 226 AC_CONFIG_FILES([demo/adg-glade],[chmod +x demo/adg-glade])
 227 AC_OUTPUT
 228
 229
 230 # Report
 231
 232 AS_IF([test "x${enable_glade}" != "xno"],
 233       [report_glade_catalogdir="
 234                   Glade catalog dir: ${GLADE_CATALOGDIR}"],
 235       [report_glade_catalogdir=''])
 236
 237
 238 AC_MSG_NOTICE([generating report
 239
 240 AC_PACKAGE_NAME adg_version will be built with the following options:
 241 ----------------------------------------------------------
 242                   API compatibility: adg_api_version
 243                 CPML library to use: internal (cpml-adg_version)
 244          Build pango based entities: ${enable_pango}
 245            GTK+2 additional widgets: ${enable_gtk2}
 246              Install glade catalogs: ${enable_glade}${report_glade_catalogdir}
 247                 Build API reference: ${enable_gtk_doc}
 248              Test framework support: ${enable_test_framework}
 249 ])