configure.ac

   1 m4_define([adg_version],[0.5.5])
   2 m4_define([adg_api_version],[1.0])
   3
   4 m4_define([gtkdoc_prereq],[1.9])
   5 m4_define([gobject_prereq],[2.4.0])
   6 m4_define([cairo_prereq],[1.7.4])
   7 m4_define([gtk_prereq],[2.12.0])
   8
   9
  10 # Initialization
  11
  12 AC_PREREQ([2.59])
  13 AC_INIT([Automatic Drawing Generation],m4_expand([adg_version]),
  14         [http://dev.entidi.com/p/adg/],[adg],[http://adg.entidi.com/])
  15 AC_CONFIG_SRCDIR([configure.ac])
  16 AC_CONFIG_HEADERS([config.h])
  17 AC_CONFIG_MACRO_DIR([m4])
  18 AM_INIT_AUTOMAKE([1.6 gnits no-dist-gzip dist-bzip2 -Wall])
  19
  20
  21 # Check for programs
  22
  23 AC_PROG_CC
  24 AC_DISABLE_STATIC
  25 LT_INIT
  26 PKG_PROG_PKG_CONFIG
  27 AC_PATH_PROG([XSLTPROC],[xsltproc],[/usr/bin/xsltproc])
  28 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums],[/usr/bin/glib-mkenums])
  29 AC_PATH_PROG([GLIB_GENMARSHAL],[glib-genmarshal],[/usr/bin/glib-genmarshal])
  30
  31
  32 # Check for functions
  33
  34 dnl Alloca is required by cpml, so it should be removed
  35 dnl in case the adg and cpml libraries will be splitted
  36 AC_FUNC_ALLOCA
  37
  38
  39 # I18n
  40
  41 AC_SUBST([GETTEXT_PACKAGE],[adg-adg_api_version])
  42 AC_DEFINE([GETTEXT_PACKAGE],[["]AC_PACKAGE_TARNAME-adg_api_version["]],
  43                    [Define to the domain used by gettext.])
  44 ALL_LINGUAS=""
  45 AM_GLIB_GNU_GETTEXT
  46 GLIB_DEFINE_LOCALEDIR([LOCALEDIR])
  47 AC_OUTPUT_COMMANDS([case "${CONFIG_FILES}" in *po-properties/Makefile.in*)
  48         sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
  49       esac])
  50
  51
  52 # Check for required packages
  53
  54 GTK_DOC_CHECK([gtkdoc_prereq])
  55 PKG_CHECK_MODULES([GOBJECT2],[gobject-2.0 >= gobject_prereq])
  56 PKG_CHECK_MODULES([CAIRO],[cairo >= cairo_prereq])
  57
  58
  59 # Check for optional GTK+2 support
  60
  61 AC_ARG_ENABLE([gtk2],
  62               [AS_HELP_STRING([--enable-gtk2],
  63                               [include GKT+2 specific widgets @<:@default=check@:>@])],
  64               [],[enable_gtk2=check])
  65 AS_IF([test "x${enable_gtk2}" != "xno"],
  66       [PKG_CHECK_MODULES([GTK2],[gtk+-2.0 >= gtk_prereq],
  67                          [enable_gtk2=yes],
  68                          [AS_IF([test "x${enable_gtk2}" = "xyes"],
  69                                 [AC_MSG_ERROR([$GTK2_PKG_ERRORS but GTK+2 support requested])],
  70                                 [enable_gtk2=no])])])
  71 AM_CONDITIONAL([HAVE_GTK2],[test "x${enable_gtk2}" = "xyes"])
  72
  73
  74 # Final step
  75
  76 CPML_REQUIRES='cairo >= cairo_prereq'
  77 CPML_CFLAGS="${CAIRO_CFLAGS}"
  78 CPML_LIBS="${CAIRO_LIBS}"
  79 AS_IF([test "x${enable_gtk2}" = "xyes"],
  80       [ADG_REQUIRES='gtk+-2.0 >= gtk_prereq'
  81        ADG_CFLAGS="${GTK2_CFLAGS}"
  82        ADG_LIBS="${GTK2_LIBS}"],
  83       [ADG_REQUIRES='gobject-2.0 >= gobject_prereq'
  84        ADG_CFLAGS="${GOBJECT2_CFLAGS} ${CAIRO_CFLAGS}"
  85        ADG_LIBS="${GOBJECT2_LIBS} ${CAIRO_LIBS}"])
  86 AC_SUBST([CPML_REQUIRES])
  87 AC_SUBST([CPML_CFLAGS])
  88 AC_SUBST([CPML_LIBS])
  89 AC_SUBST([ADG_REQUIRES])
  90 AC_SUBST([ADG_CFLAGS])
  91 AC_SUBST([ADG_LIBS])
  92
  93 SHAVE_INIT([],[enable])
  94 AC_CONFIG_FILES([shave
  95                  shave-libtool
  96                  cpml.pc
  97                  adg.pc
  98                  Makefile
  99                  cpml/Makefile
 100                  adg/Makefile
 101                  demo/Makefile
 102                  po/Makefile.in
 103                  po-properties/Makefile.in
 104                  tests/Makefile
 105                  docs/Makefile
 106                  docs/cpml/Makefile
 107                  docs/cpml/bookinfo.xml
 108                  docs/adg/Makefile
 109                  docs/adg/bookinfo.xml])
 110 AC_OUTPUT
 111
 112
 113 # Report
 114
 115 echo ""
 116 echo 'ADG canvas adg_version will be built with the following options:'
 117 echo "----------------------------------------------------------"
 118 echo '                  API compatibility: adg_api_version'
 119 echo '                CPML library to use: internal (cpml-adg_version)'
 120 echo " AdgWidget support (requires GTK+2): ${enable_gtk2}"
 121 echo "                Build API reference: ${enable_gtk_doc}"
 122 echo ""