configure.ac

   1 m4_define([adg_version],[0.6.6])
   2 m4_define([adg_api_version],[1.0])
   3 m4_define([adg_lt_version],[1:0:0])
   4
   5 m4_define([cpml_version],adg_version)
   6 m4_define([cpml_api_version],adg_api_version)
   7 m4_define([cpml_lt_version],[1:0:0])
   8
   9 m4_define([gtkdoc_prereq],[1.12])dnl Support introspection annotations
  10 m4_define([gobject_prereq],[2.10.1])
  11 m4_define([cairo_prereq],[1.7.4])
  12 m4_define([gtk2_prereq],[2.12.0])
  13 m4_define([gtk3_prereq],[3.0.0])
  14 m4_define([pangocairo_prereq],[1.18.0])
  15 m4_define([gi_prereq],[0.9.5])dnl Picked up from clutter
  16
  17
  18 # Initialization
  19
  20 dnl autoconf 2.62 is required by GObject introspection:
  21 dnl http://live.gnome.org/GObjectIntrospection/AutotoolsIntegration
  22 AC_PREREQ([2.62])
  23 AC_INIT([adg-1],adg_version,[http://dev.entidi.com/p/adg/],[adg],[http://adg.entidi.com/])
  24 AC_CONFIG_SRCDIR([configure.ac])
  25 AC_CONFIG_HEADERS([src/config.h])
  26 AC_CONFIG_AUX_DIR([build])
  27 AC_CONFIG_MACRO_DIR([build])
  28 AM_INIT_AUTOMAKE([1.10 gnits no-dist-gzip dist-bzip2 -Wall -Wno-portability])
  29
  30 dnl m4 backward compatibility stuff
  31 m4_ifdef([AM_SILENT_RULES],
  32          [AM_SILENT_RULES([yes])],
  33          [AC_SUBST([AM_V_GEN],[])])
  34 m4_ifdef([AM_SUBST_NOTMAKE],[],
  35          [AC_DEFUN([AM_SUBST_NOTMAKE],[_AM_SUBST_NOTMAKE($@)])])
  36 m4_ifdef([AM_COND_IF],[],
  37          [AC_DEFUN([AM_COND_IF],
  38                    [AS_IF([test -z "$$1_TRUE"],[$2],[$3])])])
  39
  40
  41 # Check for host information
  42
  43 AC_CANONICAL_HOST
  44 case "${host}" in
  45   *-*-linux*)
  46     guessed_host=linux
  47     ;;
  48   *-*-freebsd*)
  49     guessed_host=freebsd
  50     ;;
  51   *-*-mingw*)
  52     guessed_host=mingw
  53     ;;
  54   *-*-solaris*)
  55     guessed_host=solaris
  56     ;;
  57   *-*-darwin*)
  58     guessed_host=darwin
  59     ;;
  60   *-*-beos*)
  61     guessed_host=beos
  62     ;;
  63   *-*-cygwin*)
  64     guessed_host=cygwin
  65     ;;
  66   *-*-minix*)
  67     guessed_host=minix
  68     ;;
  69   *-*-aix*)
  70     guessed_host=aix
  71     ;;
  72   *)
  73     guessed_host=unknown
  74     ;;
  75 esac
  76 AM_CONDITIONAL([OS_UNIX],[test "${guessed_host}" != "mingw"])
  77 AM_CONDITIONAL([OS_WINDOWS],[test "${guessed_host}" = "mingw" -o "${guessed_host}" = "cygwin"])
  78
  79 dnl -win$ARCH will be appended to the Windows installer file name
  80 AS_IF([test "x${host_cpu}" = "xx86_64"],[ARCH=64],[ARCH=32])
  81 AC_SUBST([ARCH])
  82 AM_SUBST_NOTMAKE([ARCH])
  83
  84
  85 # Check for programs
  86
  87 AC_PROG_CC
  88 AC_PROG_SED
  89 PKG_PROG_PKG_CONFIG
  90 AC_PATH_PROG([XSLTPROC],[xsltproc],[/usr/bin/xsltproc])
  91 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums],[/usr/bin/glib-mkenums])
  92 AC_PATH_PROG([GLIB_GENMARSHAL],[glib-genmarshal],[/usr/bin/glib-genmarshal])
  93 AC_PATH_PROG([GTESTER],[gtester],[/usr/bin/gtester])
  94 AC_PATH_PROG([GTESTER_REPORT],[gtester-report],[/usr/bin/gtester-report])
  95 AC_PATH_PROG([GLADE3],[glade-3],[/usr/bin/glade-3])
  96 AM_COND_IF([OS_WINDOWS],
  97            [AC_PATH_PROG([MAKENSIS],[makensis],[/usr/bin/makensis])
  98             AC_PATH_PROG([WINE],[wine])])
  99
 100
 101 # Check for libraries
 102
 103 AC_CHECK_LIB([m],[cos])
 104
 105
 106 # Libtool initialization
 107
 108 AC_MSG_CHECKING([which libtool initialization strategy to adopt])
 109 AC_MSG_RESULT([m4_ifset([LT_INIT],[LT-INIT],[AC-PROG-LIBTOOL])])
 110 m4_ifset([LT_INIT],
 111          [LT_INIT([disable-static win32-dll])],
 112          [AC_DISABLE_STATIC
 113           AC_LIBTOOL_WIN32_DLL
 114           AC_PROG_LIBTOOL])
 115
 116
 117 # I18n
 118
 119 AC_SUBST([ADG_API_PACKAGE],AC_PACKAGE_TARNAME-adg_api_version)
 120 AC_SUBST([GETTEXT_PACKAGE],[${ADG_API_PACKAGE}])
 121 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["${ADG_API_PACKAGE}"],
 122                    [Define to the domain used by gettext.])
 123 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 124 IT_PROG_INTLTOOL(0.40.1)
 125 AM_GLIB_GNU_GETTEXT
 126 GLIB_DEFINE_LOCALEDIR([LOCALEDIR])
 127 AC_CONFIG_COMMANDS([default],
 128                    [case "${CONFIG_FILES}" in *po-properties/Makefile.in*)
 129         ${SED} -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 130     esac],
 131                    [SED="${SED}"])
 132
 133
 134 # Check for required packages
 135
 136 PKG_CHECK_MODULES([GLIB],[glib-2.0])
 137 PKG_CHECK_MODULES([GOBJECT],[gobject-2.0 >= ]gobject_prereq)
 138 PKG_CHECK_MODULES([CAIRO],[cairo >= ]cairo_prereq)
 139
 140
 141 # Check for optional packages
 142
 143 dnl PangoCairo
 144 AC_ARG_ENABLE([pango],
 145               [AS_HELP_STRING([--enable-pango],
 146                               [use pango for rendering text @<:@default=check@:>@])],
 147               [],[enable_pango=check])
 148 AS_IF([test "x${enable_pango}" != "xno"],
 149       [PKG_CHECK_MODULES([PANGO],[pangocairo >= ]pangocairo_prereq,
 150                          [enable_pango=yes
 151                           AC_DEFINE_UNQUOTED([PANGO_ENABLED],[1],
 152                                              [Defined if the pango support is enabled.])],
 153                          [AS_IF([test "x${enable_pango}" = "xyes"],
 154                                 [AC_MSG_ERROR([${PANGO_PKG_ERRORS} and pango support requested])],
 155                                 [enable_pango=no])])])
 156 AM_CONDITIONAL([HAVE_PANGO],[test "x${enable_pango}" = "xyes"])
 157
 158 dnl GTK+ support
 159 AC_ARG_WITH(gtk,
 160             [AS_HELP_STRING([--with-gtk@<:@=gtk2/gtk3@:>@],
 161                             [include GTK+ specific widgets @<:@default=check@:>@])],
 162             [],[with_gtk=check])
 163 AS_CASE(["${with_gtk}"],
 164         [gtk2],      [gtk2_pkg=yes; gtk3_pkg=no],
 165         [gtk3],      [gtk2_pkg=no;  gtk3_pkg=yes],
 166         [check|yes], [gtk2_pkg=yes; gtk3_pkg=yes],
 167         [no],        [gtk2_pkg=no;  gtk3_pkg=no],
 168         [AC_MSG_ERROR([Invalid option passed to --with-gtk])])
 169
 170 # GTK+ autodetection, giving precedence to GTK+3
 171 AS_IF([test "x${gtk3_pkg}" = "xyes"],
 172       [PKG_CHECK_MODULES([GTK3],[gtk+-3.0 >= ]gtk3_prereq,[gtk_pkg=gtk3],[:])])
 173 AS_IF([test "x${gtk2_pkg}" = "xyes" -a "x${gtk_pkg}" = "x"],
 174       [PKG_CHECK_MODULES([GTK2],[gtk+-2.0 >= ]gtk2_prereq,[gtk_pkg=gtk2],[:])])
 175 AS_IF([test "x${gtk_pkg}" != "x"],[with_gtk=${gtk_pkg}])
 176
 177
 178 # Handle "check" graceful degradation
 179 AS_IF([test "x${with_gtk}" = "xcheck"],[with_gtk=no])
 180
 181 # Handle failures
 182 AS_IF([test "x${with_gtk}" != "xno" -a "x${gtk_pkg}" = "x"],
 183       [AC_MSG_ERROR([GTK+ support explicitely required but no valid GTK+ found])])
 184
 185 AS_IF([test "x${with_gtk}" = "xgtk3"],
 186       [AC_DEFINE_UNQUOTED([GTK3_ENABLED],[1],
 187                           [Defined if the GTK+3 support is enabled.])])
 188 AS_IF([test "x${with_gtk}" = "xgtk2"],
 189       [AC_DEFINE_UNQUOTED([GTK2_ENABLED],[1],
 190                           [Defined if the GTK+2 support is enabled.])])
 191
 192 AM_CONDITIONAL([HAVE_GTK], [test "x${with_gtk}" != "xno"])
 193 AM_CONDITIONAL([HAVE_GTK2],[test "x${with_gtk}" = "xgtk2"])
 194 AM_CONDITIONAL([HAVE_GTK3],[test "x${with_gtk}" = "xgtk3"])
 195
 196 dnl Glade catalog dir
 197 AC_ARG_WITH(glade_catalogdir,
 198             [AS_HELP_STRING([--with-glade-catalogdir@<:@=DIR@:>@],
 199                             [where to install the glade catalogs @<:@default=check@:>@])],
 200             [],[with_glade_catalogdir=check])
 201
 202 # Both "check" and "yes" mean gladeui autodetection,
 203 # but "yes" will fail on gladeui not found
 204 AS_IF([test "x${with_glade_catalogdir}" = "xcheck" -o "x${with_glade_catalogdir}" = "xyes"],
 205       [glade_pkg=check])
 206
 207 # gladeui autodetection, giving precedence to gladeui-2.0 if possible
 208 AS_IF([test "x${glade_pkg}" = "xcheck" -a "x${with_gtk}" != "xgtk2"],
 209       [PKG_CHECK_MODULES([GLADEUI2],[gladeui-2.0],[glade_pkg=gladeui-2.0],[:])])
 210 AS_IF([test "x${glade_pkg}" = "xcheck"],
 211       [PKG_CHECK_MODULES([GLADEUI1],[gladeui-1.0],[glade_pkg=gladeui-1.0],[:])])
 212 AS_IF([test "x${glade_pkg}" != "x" -a "x${glade_pkg}" != "xcheck"],
 213       [NTD_UNEXPAND([${glade_pkg}],
 214                     [catalogdir],
 215                     [with_glade_catalogdir="${NTD_UNEXPANDED}"],
 216                     [AC_MSG_ERROR([${glade_pkg} found but pkg-config file invalid])])])
 217
 218 # Handle "yes" failure
 219 AS_IF([test "x${glade_pkg}" = "xcheck" -a "x${with_glade_catalogdir}" = "xyes"],
 220       [AC_MSG_ERROR([Glade support explicitely required but no valid gladeui found])])
 221
 222 # Handle "check" graceful degradation
 223 AS_IF([test "x${glade_pkg}" = "xcheck" -a "x${with_glade_catalogdir}" = "xcheck"],
 224       [with_glade_catalogdir=no])
 225
 226 AM_CONDITIONAL([HAVE_GLADE],[test "x${with_glade_catalogdir}" != "xno"])
 227 AM_COND_IF([HAVE_GLADE],
 228            [enable_glade=yes
 229             report_glade="
 230                   Glade catalog dir: ${with_glade_catalogdir}"],
 231            [enable_glade=no
 232             report_glade=""])
 233 AC_SUBST([GLADE_CATALOGDIR],${with_glade_catalogdir})
 234
 235 dnl gtk-doc
 236 GTK_DOC_CHECK(gtkdoc_prereq)
 237
 238 dnl GObject introspection
 239 GOBJECT_INTROSPECTION_CHECK(gi_prereq)
 240 AC_ARG_WITH(girdir,
 241             [AS_HELP_STRING([--with-girdir=DIR],
 242                             [where the gir files are installed @<:@default=check@:>@])],
 243             [],[with_girdir=check])
 244 AS_IF([test "x${with_girdir}" = "xcheck"],
 245       [NTD_UNEXPAND([gobject-introspection-1.0],
 246                     [girdir],
 247                     [with_girdir="${NTD_UNEXPANDED}"])])
 248 AC_SUBST([GIRDIR],${with_girdir})
 249 AC_ARG_WITH(typelibdir,
 250             [AS_HELP_STRING([--with-typelibdir=DIR],
 251                             [where the typelib files are installed @<:@default=check@:>@])],
 252             [],[with_typelibdir=check])
 253 AS_IF([test "x${with_typelibdir}" = "xcheck"],
 254       [NTD_UNEXPAND([gobject-introspection-1.0],
 255                     [typelibdir],
 256                     [with_typelibdir="${NTD_UNEXPANDED}"])])
 257 AC_SUBST([TYPELIBDIR],${with_typelibdir})
 258 AM_COND_IF([HAVE_INTROSPECTION],
 259            [enable_introspection='yes'
 260             report_introspection="
 261          Where to install gir files: ${with_girdir}
 262  Where to install the typelib files: ${with_typelibdir}"],
 263            [enable_introspection='no'
 264             report_introspection=""])
 265
 266 dnl GLib test framework
 267 AC_ARG_ENABLE([test_framework],
 268               [AS_HELP_STRING([--enable-test-framework],
 269                               [enable GLib test framework @<:@default=check@:>@])],
 270               [],[enable_test_framework=check])
 271 AS_IF([test "x${enable_test_framework}" != "xno"],
 272       [PKG_CHECK_EXISTS([glib-2.0 >= 2.16.0],
 273                         [enable_test_framework=yes],
 274                         [AS_IF([test "x${enable_test_framework}" = "xyes"],
 275                                [AC_MSG_ERROR([The test framework needs glib2-2.16.0 or later])],
 276                                [enable_test_framework=no])])])
 277 AM_CONDITIONAL([HAVE_TEST_FRAMEWORK],[test "x${enable_test_framework}" = "xyes"])
 278
 279
 280 # Check for compiler characteristics
 281
 282 AC_C_CONST
 283
 284
 285 # Additional substitutions
 286
 287 USRDIR="$($PKG_CONFIG --variable=prefix gobject-2.0)"
 288 CPML_REQUIRES='cairo >= cairo_prereq'
 289 AM_COND_IF([HAVE_PANGO],
 290       [ADG_REQUIRES='pangocairo >= pangocairo_prereq'
 291        ADG_H_ADDITIONAL='
 292 #include <pango/pango.h>
 293 #include "adg/adg-text.h"
 294 #include "adg/adg-pango-style.h"
 295 '],
 296       [ADG_REQUIRES='gobject-2.0 >= gobject_prereq'
 297        ADG_H_ADDITIONAL=''])
 298 AM_COND_IF([HAVE_GTK3],[ADG_REQUIRES='gtk+-3.0 >= gtk3_prereq'])
 299 AM_COND_IF([HAVE_GTK2],[ADG_REQUIRES='gtk+-2.0 >= gtk2_prereq'])
 300 AM_COND_IF([HAVE_GTK],
 301            [ADG_H_ADDITIONAL="${ADG_H_ADDITIONAL}
 302 #include <gtk/gtk.h>
 303 #include \"adg/adg-gtk-utils.h\"
 304 #include \"adg/adg-gtk-area.h\"
 305 #include \"adg/adg-gtk-layout.h\"
 306 "
 307             ADG_CANVAS_H_ADDITIONAL='
 308 void            adg_canvas_set_paper            (AdgCanvas      *canvas,
 309                                                  const gchar    *paper_name,
 310                                                  GtkPageOrientation orientation);
 311 void            adg_canvas_set_page_setup       (AdgCanvas      *canvas,
 312                                                  GtkPageSetup   *page_setup);
 313 '],
 314            [ADG_CANVAS_H_ADDITIONAL=''])
 315
 316 AC_SUBST([CPML_API_VERSION],cpml_api_version)
 317 AC_SUBST([CPML_LT_VERSION],cpml_lt_version)
 318 AC_SUBST([CPML_REQUIRES])
 319 AC_SUBST([ADG_API_VERSION],adg_api_version)
 320 AC_SUBST([ADG_LT_VERSION],adg_lt_version)
 321 AC_SUBST([ADG_REQUIRES])
 322 AC_SUBST([ADG_H_ADDITIONAL])
 323 AC_SUBST([ADG_CANVAS_H_ADDITIONAL])
 324 AC_SUBST([USRDIR])
 325
 326 AM_SUBST_NOTMAKE([CPML_REQUIRES])
 327 AM_SUBST_NOTMAKE([ADG_REQUIRES])
 328 AM_SUBST_NOTMAKE([ADG_H_ADDITIONAL])
 329 AM_SUBST_NOTMAKE([ADG_CANVAS_H_ADDITIONAL])
 330 AM_SUBST_NOTMAKE([USRDIR])
 331
 332
 333 # Generation
 334
 335 AC_CONFIG_FILES([build/adg.nsi
 336                  Makefile
 337                  src/Makefile
 338                  src/cpml/cpml-1.pc
 339                  src/cpml/Makefile
 340                  src/cpml/tests/Makefile
 341                  src/adg/adg-1.pc
 342                  src/adg.h
 343                  src/adg/Makefile
 344                  src/adg/adg-canvas.h
 345                  src/adg/tests/Makefile
 346                  demo/Makefile
 347                  demo/cpml-demo.ui
 348                  demo/adg-demo.ui
 349                  po/Makefile.in
 350                  po-properties/Makefile.in
 351                  docs/Makefile
 352                  docs/cpml/Makefile
 353                  docs/cpml/bookinfo.xml
 354                  docs/adg/Makefile
 355                  docs/adg/bookinfo.xml])
 356 AC_CONFIG_FILES([demo/adg-glade],[chmod +x demo/adg-glade])
 357 AC_OUTPUT
 358
 359
 360 # Report
 361
 362 AC_MSG_NOTICE([generating report
 363
 364 AC_PACKAGE_NAME adg_version will be built with the following options:
 365 ----------------------------------------------------------
 366                   API compatibility: adg_api_version
 367                 CPML library to use: internal (cpml-adg_version)
 368          Build pango based entities: ${enable_pango}
 369                        GTK+ support: ${with_gtk}
 370              Install glade catalogs: ${enable_glade}${report_glade}
 371                 Build API reference: ${enable_gtk_doc}
 372              GObject instrospection: ${enable_introspection}${report_introspection}
 373              Test framework support: ${enable_test_framework}
 374 ])