configure.ac

   1 m4_define([adg_version],[0.6.0])
   2 m4_define([adg_api_version],[1.0])
   3
   4 m4_define([gtkdoc_prereq],[1.9])
   5 m4_define([gobject_prereq],[2.10.1])
   6 m4_define([cairo_prereq],[1.7.4])
   7 m4_define([gtk_prereq],[2.12.0])
   8
   9
  10 # Initialization
  11
  12 dnl autoconf 2.60 implements datarootdir, required by ADG
  13 dnl to help overcoming the hardcoded glade catalogdir
  14 AC_PREREQ([2.60])
  15 AC_INIT([Automatic Drawing Generation],adg_version,
  16         [http://dev.entidi.com/p/adg/],[adg],[http://adg.entidi.com/])
  17 AC_CONFIG_SRCDIR([configure.ac])
  18 AC_CONFIG_HEADERS([src/config.h])
  19 AC_CONFIG_AUX_DIR([build])
  20 AC_CONFIG_MACRO_DIR([build])
  21 AM_INIT_AUTOMAKE([1.6 gnits no-dist-gzip dist-bzip2 -Wall])
  22
  23
  24 # Check for programs
  25
  26 AC_PROG_CC
  27 AC_PROG_SED
  28 PKG_PROG_PKG_CONFIG
  29 AC_PATH_PROG([XSLTPROC],[xsltproc],[/usr/bin/xsltproc])
  30 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums],[/usr/bin/glib-mkenums])
  31 AC_PATH_PROG([GLIB_GENMARSHAL],[glib-genmarshal],[/usr/bin/glib-genmarshal])
  32 AC_PATH_PROG([GTESTER],[gtester],[/usr/bin/gtester])
  33 AC_PATH_PROG([GTESTER_REPORT],[gtester-report],[/usr/bin/gtester-report])
  34 AC_PATH_PROG([GLADE3],[glade-3],[/usr/bin/glade-3])
  35
  36 AC_MSG_CHECKING([which libtool initialization strategy to adopt])
  37 AC_MSG_RESULT([m4_ifset([LT_INIT],[LT-INIT],[AC-PROG-LIBTOOL])])
  38 m4_ifset([LT_INIT],
  39          [LT_INIT([disable-static win32-dll])],
  40          [AC_DISABLE_STATIC
  41           AC_LIBTOOL_WIN32_DLL
  42           AC_PROG_LIBTOOL])
  43
  44
  45 # I18n
  46
  47 AC_SUBST([GETTEXT_PACKAGE],adg-adg_api_version)
  48 AC_DEFINE([GETTEXT_PACKAGE],"AC_PACKAGE_TARNAME-adg_api_version",
  49           [Define to the domain used by gettext.])
  50 ALL_LINGUAS=""
  51 AM_GLIB_GNU_GETTEXT
  52 GLIB_DEFINE_LOCALEDIR([LOCALEDIR])
  53 AC_CONFIG_COMMANDS([default],
  54                    [case "${CONFIG_FILES}" in *po-properties/Makefile.in*)
  55         ${SED} -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
  56     esac],
  57                    [SED="${SED}"])
  58
  59
  60 # Check for required packages
  61
  62 GTK_DOC_CHECK(gtkdoc_prereq)
  63 PKG_CHECK_MODULES([GOBJECT2],[gobject-2.0 >= ]gobject_prereq)
  64 PKG_CHECK_MODULES([CAIRO],[cairo >= ]cairo_prereq)
  65
  66
  67 # Check for optional GTK+2 support
  68
  69 AC_ARG_ENABLE([gtk2],
  70               [AS_HELP_STRING([--enable-gtk2],
  71                               [include GKT+2 specific widgets @<:@default=check@:>@])],
  72               [],[enable_gtk2=check])
  73 AS_IF([test "x${enable_gtk2}" != "xno"],
  74       [PKG_CHECK_MODULES([GTK2],[gtk+-2.0 >= ]gtk_prereq,
  75                          [enable_gtk2=yes],
  76                          [AS_IF([test "x${enable_gtk2}" = "xyes"],
  77                                 [AC_MSG_ERROR([${GTK2_PKG_ERRORS} and GTK+2 support requested])],
  78                                 [enable_gtk2=no])])])
  79 AM_CONDITIONAL([HAVE_GTK2],[test "x${enable_gtk2}" = "xyes"])
  80
  81
  82 # Check for optional glade support
  83
  84 AC_ARG_ENABLE([glade],
  85               [AS_HELP_STRING([--enable-glade],
  86                               [install glade catalog file @<:@default=check@:>@])],
  87               [],[enable_glade=check])
  88 AS_IF([test "x${enable_glade}" != "xno"],
  89       [PKG_CHECK_MODULES([GLADE],[gladeui-1.0],
  90                          [enable_glade=yes],
  91                          [AS_IF([test "x${enable_glade}" = "xyes"],
  92                                 [AC_MSG_ERROR([${GLADE_PKG_ERRORS} and glade support requested])],
  93                                 [enable_glade=no])])])
  94 AM_CONDITIONAL([HAVE_GLADE],[test "x${enable_glade}" = "xyes"])
  95 AS_IF([test "x${enable_glade}" == "xyes"],
  96       [AC_MSG_CHECKING([for the glade catalog path])
  97        gladeroot=`${PKG_CONFIG} --variable=datarootdir gladeui-1.0`
  98        AS_IF([test "x${gladeroot}" == "x"],
  99              [GLADE_CATALOGDIR="\${datarootdir}/glade3/catalogs}"],
 100              [gladecatalog=`${PKG_CONFIG} --variable=catalogdir gladeui-1.0`
 101               GLADE_CATALOGDIR=`echo "${gladecatalog}" | ${SED} -e "s|^${gladeroot}|\$\{datarootdir\}|" -`])
 102        AC_SUBST([GLADE_CATALOGDIR])
 103        AC_MSG_RESULT(${GLADE_CATALOGDIR})])
 104
 105
 106
 107 # Check for optional GLib test framework
 108
 109 AC_ARG_ENABLE([test_framework],
 110               [AS_HELP_STRING([--enable-test-framework],
 111                               [enable GLib test framework @<:@default=check@:>@])],
 112               [],[enable_test_framework=check])
 113 AS_IF([test "x${enable_test_framework}" != "xno"],
 114       [PKG_CHECK_EXISTS([glib-2.0 >= 2.16.0],
 115                         [enable_test_framework=yes],
 116                         [AS_IF([test "x${enable_test_framework}" = "xyes"],
 117                                [AC_MSG_ERROR([The test framework needs glib2-2.16.0 or later])],
 118                                [enable_test_framework=no])])])
 119 AM_CONDITIONAL([HAVE_TEST_FRAMEWORK],[test "x${enable_test_framework}" = "xyes"])
 120
 121
 122 # Check for compiler characteristics
 123
 124 AC_C_CONST
 125
 126
 127 # Final step
 128
 129 CPML_REQUIRES='cairo >= cairo_prereq'
 130 CPML_CFLAGS="${CAIRO_CFLAGS}"
 131 CPML_LIBS="${CAIRO_LIBS}"
 132 ADG_REQUIRES='gobject-2.0 >= gobject_prereq'
 133 ADG_CFLAGS="${GOBJECT2_CFLAGS} ${CPML_CFLAGS}"
 134 ADG_LIBS="${GOBJECT2_LIBS} ${CPML_LIBS}"
 135 AS_IF([test "x${enable_gtk2}" = "xyes"],
 136       [ADG_GTK_REQUIRES='gtk+-2.0 >= gtk_prereq'
 137        ADG_GTK_CFLAGS="${GTK2_CFLAGS} ${CPML_CFLAGS}"
 138        ADG_GTK_LIBS="${GTK2_LIBS} ${CPML_LIBS}"
 139        AC_SUBST([ADG_GTK_REQUIRES])
 140        AC_SUBST([ADG_GTK_CFLAGS])
 141        AC_SUBST([ADG_GTK_LIBS])])
 142 AC_SUBST([CPML_REQUIRES])
 143 AC_SUBST([CPML_CFLAGS])
 144 AC_SUBST([CPML_LIBS])
 145 AC_SUBST([ADG_REQUIRES])
 146 AC_SUBST([ADG_CFLAGS])
 147 AC_SUBST([ADG_LIBS])
 148
 149 SHAVE_INIT([build],[enable])
 150 AC_CONFIG_FILES([build/shave
 151                  build/shave-libtool
 152                  Makefile
 153                  src/Makefile
 154                  src/cpml-1.pc
 155                  src/cpml/Makefile
 156                  src/adg-1.pc
 157                  src/adg/Makefile
 158                  src/adg/tests/Makefile
 159                  src/adg-gtk-1.pc
 160                  src/adg-gtk/Makefile
 161                  src/adg-gtk/tests/Makefile
 162                  demo/Makefile
 163                  demo/adg-demo.ui
 164                  po/Makefile.in
 165                  po-properties/Makefile.in
 166                  docs/Makefile
 167                  docs/cpml/Makefile
 168                  docs/cpml/bookinfo.xml
 169                  docs/adg/Makefile
 170                  docs/adg/bookinfo.xml])
 171 AC_CONFIG_FILES([demo/adg-glade],[chmod +x demo/adg-glade])
 172 AC_OUTPUT
 173
 174
 175 # Report
 176
 177 AC_MSG_NOTICE([generating report
 178
 179 ADG canvas adg_version will be built with the following options:
 180 ----------------------------------------------------------
 181                   API compatibility: adg_api_version
 182                 CPML library to use: internal (cpml-adg_version)
 183            GTK+2 additional widgets: ${enable_gtk2}
 184              Install glade catalogs: ${enable_glade}
 185                 Build API reference: ${enable_gtk_doc}
 186              Test framework support: ${enable_test_framework}
 187 ])