build/adg.nsi.in

   1 ; @configure_input@
   2 ;
   3 ; ADG installer based on NSis
   4 ; Check http://nsis.sourceforge.net/ for details
   5
   6 !define SRCDIR      "@abs_top_srcdir@"
   7 !define BUILDDIR    "@abs_top_builddir@"
   8 !define USRDIR      "@USRDIR@"
   9 !define DLLDIR      "${USRDIR}/bin"
  10
  11 ; ---------------------------------------------------------------
  12 ; 1. Header file
  13
  14 !addincludedir "${SRCDIR}/build"
  15 !include MUI2.nsh
  16 !include EnvVarUpdate.nsh
  17
  18 Name "@PACKAGE_NAME@ @PACKAGE_VERSION@"
  19 OutFile "@abs_top_builddir@/@PACKAGE@-@PACKAGE_VERSION@-win@ARCH@.exe"
  20 SetCompressor /SOLID lzma
  21 InstallDir "$PROGRAMFILES@ARCH@\@PACKAGE_NAME@"
  22 RequestExecutionLevel user
  23
  24 ; ---------------------------------------------------------------
  25 ; 2. Interface configuration
  26
  27 !define MUI_ABORTWARNING
  28 !define MUI_COMPONENTSPAGE_SMALLDESC
  29
  30 !define MUI_ICON "${SRCDIR}/build/adg.ico"
  31 !define MUI_UNICON "${SRCDIR}/build/adg.ico"
  32
  33 !define MUI_HEADERIMAGE
  34 !define MUI_HEADERIMAGE_RIGHT
  35 !define MUI_HEADERIMAGE_BITMAP "${SRCDIR}/build/adg-header.bmp"
  36 !define MUI_HEADERIMAGE_UNBITMAP "${SRCDIR}/build/adg-header.bmp"
  37
  38 !define MUI_WELCOMEFINISHPAGE_BITMAP "${SRCDIR}/build/adg-welcome.bmp"
  39 !define MUI_UNWELCOMEFINISHPAGE_BITMAP "${SRCDIR}/build/adg-welcome.bmp"
  40
  41 ; ---------------------------------------------------------------
  42 ; 3. Pages
  43
  44 !insertmacro MUI_PAGE_WELCOME
  45 !insertmacro MUI_PAGE_LICENSE "@abs_top_srcdir@/COPYING"
  46 !insertmacro MUI_PAGE_COMPONENTS
  47 !insertmacro MUI_PAGE_DIRECTORY
  48 !insertmacro MUI_PAGE_INSTFILES
  49 !insertmacro MUI_PAGE_FINISH
  50
  51 !insertmacro MUI_UNPAGE_WELCOME
  52 !insertmacro MUI_UNPAGE_INSTFILES
  53 !insertmacro MUI_UNPAGE_FINISH
  54
  55 ; ---------------------------------------------------------------
  56 ; 4. Language files
  57
  58 !insertmacro MUI_LANGUAGE "English"
  59 !insertmacro MUI_LANGUAGE "Italian"
  60
  61 ; ---------------------------------------------------------------
  62 ; 5. Reserve files
  63
  64
  65 ; ---------------------------------------------------------------
  66 ; I. Installer sections
  67
  68 Section "ADG canvas" SecBase
  69   SectionIn RO
  70
  71   SetOutPath "$INSTDIR"
  72   File /oname=adg-demo.exe  "${BUILDDIR}/demo/.libs/adg-demo-uninstalled.exe"
  73   File /oname=cpml-demo.exe "${BUILDDIR}/demo/.libs/cpml-demo-uninstalled.exe"
  74
  75   SetOutPath "$INSTDIR\share\adg"
  76   File "${BUILDDIR}/demo/adg-demo.ui"
  77   File "${BUILDDIR}/demo/cpml-demo.ui"
  78   File "${SRCDIR}/demo/adg-16.png"
  79   File "${SRCDIR}/demo/adg-32.png"
  80   File "${SRCDIR}/demo/adg-48.png"
  81   File "${SRCDIR}/demo/adg-64.png"
  82   File "${SRCDIR}/demo/adg-128.png"
  83
  84   SetOutPath "$INSTDIR\bin"
  85   File "${USRDIR}/lib/libgcc_s_*-1.dll"
  86   File "${DLLDIR}/zlib1.dll"
  87   File "${DLLDIR}/libbz2-*.dll"
  88   File "${DLLDIR}/libexpat-*.dll"
  89   File "${DLLDIR}/libintl-*.dll"
  90   File "${DLLDIR}/iconv.dll"
  91   File "${DLLDIR}/libffi-*.dll"
  92   File "${DLLDIR}/libpng??-*.dll"
  93   File "${DLLDIR}/libglib-2.0-*.dll"
  94   File "${DLLDIR}/libgthread-2.0-*.dll"
  95   File "${DLLDIR}/libgmodule-2.0-*.dll"
  96   File "${DLLDIR}/libgobject-2.0-*.dll"
  97   File "${DLLDIR}/libgio-2.0-*.dll"
  98   File "${DLLDIR}/libfreetype-*.dll"
  99   File "${DLLDIR}/libpixman-1-*.dll"
 100   File "${DLLDIR}/libcairo-*.dll"
 101   File "${DLLDIR}/libpango-1.0-*.dll"
 102   File "${DLLDIR}/libpangocairo-1.0-*.dll"
 103   File "${DLLDIR}/libpangowin32-1.0-*.dll"
 104   File "${DLLDIR}/libatk-1.0-*.dll"
 105   File "${DLLDIR}/libgdk_pixbuf-2.0-*.dll"
 106   File "${DLLDIR}/libgdk-3-*.dll"
 107   File "${DLLDIR}/libgtk-3-*.dll"
 108   File "${BUILDDIR}/src/cpml/.libs/libcpml-1-*.dll"
 109   File "${BUILDDIR}/src/adg/.libs/libadg-1-*.dll"
 110
 111   SetOutPath "$INSTDIR\share\glib-2.0\schemas"
 112   File "${SRCDIR}/build/gschemas.compiled"
 113
 114   CreateDirectory "$SMPROGRAMS\ADG Canvas"
 115   CreateShortcut  "$SMPROGRAMS\ADG Canvas\ADG demonstration program.lnk" "$INSTDIR\adg-demo.exe"
 116   CreateShortcut  "$SMPROGRAMS\ADG Canvas\CPML test case.lnk" "$INSTDIR\cpml-demo.exe"
 117   CreateShortcut  "$SMPROGRAMS\ADG Canvas\Uninstall ADG Canvas.lnk" "$INSTDIR\uninstall.exe"
 118
 119   WriteUninstaller "$INSTDIR\uninstall.exe"
 120   ${EnvVarUpdate} $0 "PATH" "A" "HKCU" "$INSTDIR\bin"
 121 SectionEnd
 122
 123 Section "Support for languages" SecLanguages
 124   SetOutPath "$INSTDIR\share\locale"
 125 SectionEnd
 126
 127 ; Descriptions
 128
 129 LangString DESC_SecBase ${LANG_ENGLISH} "Base installation for running the demo program."
 130 LangString DESC_SecBase ${LANG_ITALIAN} "Installazione di base per eseguire il programma dimostrativo."
 131 LangString DESC_SecLanguages ${LANG_ENGLISH} "Enable support for languages other than english."
 132 LangString DESC_SecLanguages ${LANG_ITALIAN} "Abilitazione del supporto a lingue diverse dall'inglese."
 133
 134 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 135   !insertmacro MUI_DESCRIPTION_TEXT ${SecBase} $(DESC_SecBase)
 136   !insertmacro MUI_DESCRIPTION_TEXT ${SecLanguages} $(DESC_SecLanguages)
 137 !insertmacro MUI_FUNCTION_DESCRIPTION_END
 138
 139 ; Uninstaller
 140
 141 Section "Uninstall"
 142   Delete "$SMPROGRAMS\ADG Canvas\ADG Demonstration program.lnk"
 143   Delete "$SMPROGRAMS\ADG Canvas\CPML test case.lnk"
 144   Delete "$SMPROGRAMS\ADG Canvas\Uninstall ADG Canvas.lnk"
 145   RMDir  "$SMPROGRAMS\ADG Canvas"
 146
 147   Delete "$INSTDIR\bin\libgtk-3-*.dll"
 148   Delete "$INSTDIR\bin\libgdk-3-*.dll"
 149   Delete "$INSTDIR\bin\libgdk_pixbuf-2.0-*.dll"
 150   Delete "$INSTDIR\bin\libatk-1.0-*.dll"
 151   Delete "$INSTDIR\bin\libpangowin32-1.0-*.dll"
 152   Delete "$INSTDIR\bin\libpangocairo-1.0-*.dll"
 153   Delete "$INSTDIR\bin\libpango-1.0-*.dll"
 154   Delete "$INSTDIR\bin\libcairo-*.dll"
 155   Delete "$INSTDIR\bin\libpixman-1-*.dll"
 156   Delete "$INSTDIR\bin\libfreetype-*.dll"
 157   Delete "$INSTDIR\bin\libgio-2.0-*.dll"
 158   Delete "$INSTDIR\bin\libgobject-2.0-*.dll"
 159   Delete "$INSTDIR\bin\libgmodule-2.0-*.dll"
 160   Delete "$INSTDIR\bin\libgthread-2.0-*.dll"
 161   Delete "$INSTDIR\bin\libglib-2.0-*.dll"
 162   Delete "$INSTDIR\bin\libpng??-*.dll"
 163   Delete "$INSTDIR\bin\libffi-*.dll"
 164   Delete "$INSTDIR\bin\iconv.dll"
 165   Delete "$INSTDIR\bin\libintl-*.dll"
 166   Delete "$INSTDIR\bin\libexpat-*.dll"
 167   Delete "$INSTDIR\bin\libbz2-*.dll"
 168   Delete "$INSTDIR\bin\zlib1.dll"
 169   Delete "$INSTDIR\bin\libgcc_s_*-1.dll"
 170   Delete "$INSTDIR\bin\libcpml-1-*.dll"
 171   Delete "$INSTDIR\bin\libadg-1-*.dll"
 172   RMDir  "$INSTDIR\bin"
 173
 174   Delete "$INSTDIR\share\adg\adg-demo.ui"
 175   Delete "$INSTDIR\share\adg\cpml-demo.ui"
 176   Delete "$INSTDIR\share\adg\adg-128.png"
 177   Delete "$INSTDIR\share\adg\adg-64.png"
 178   Delete "$INSTDIR\share\adg\adg-48.png"
 179   Delete "$INSTDIR\share\adg\adg-32.png"
 180   Delete "$INSTDIR\share\adg\adg-16.png"
 181   RMDir  "$INSTDIR\share\adg"
 182
 183   Delete "$INSTDIR\share\glib-2.0\schemas\gschemas.compiled"
 184   RMDir  "$INSTDIR\share\glib-2.0\schemas"
 185   RMDir  "$INSTDIR\share\glib-2.0"
 186
 187   RMDir  "$INSTDIR\share\locale"
 188
 189   RMDir  "$INSTDIR\share"
 190
 191   Delete "$INSTDIR\adg-demo.exe"
 192   Delete "$INSTDIR\cpml-demo.exe"
 193   Delete "$INSTDIR\uninstall.exe"
 194   RMDir  "$INSTDIR"
 195
 196   ${un.EnvVarUpdate} $0 "PATH" "R" "HKCU" "$INSTDIR\bin"
 197 SectionEnd