lib/VCS/Git/Torrent/PWP/Message/Reels.pm

   1
   2 package VCS::Git::Torrent::PWP::Message::Reels;
   3
   4 =head1 NAME
   5
   6 VCS::Git::Torrent::PWP::Message::Reels
   7
   8 =head1 SYNOPSIS
   9
  10  use VCS::Git::Torrent::PWP qw(:all);
  11  my $reels_message = pwp_message( GTP_PWP_REELS, @reels );
  12
  13 =head2 DESCRIPTION
  14
  15 Implements the Reels message from the RFC.
  16 L<http://gittorrent.utsl.gen.nz/rfc.html#pwp-reels>
  17
  18 =cut
  19
  20 use Moose;
  21 with "VCS::Git::Torrent::PWP::Message";
  22 use Carp;
  23 use VCS::Git::Torrent::PWP qw(:pwp_constants unpack_hex pack_hex pack_num unpack_num);
  24
  25 has 'reels' =>
  26         isa => "ArrayRef[VCS::Git::Torrent::CommitReel]",
  27         is => "rw",
  28 #       trigger => sub {
  29 #               my $self = shift;
  30 #               $self->payload($self->pack_payload);
  31 #       };
  32 ;
  33
  34 sub pack_payload {
  35         my $self = shift;
  36         my $payload = "";
  37
  38         for my $reel ( @{ $self->reels } ) {
  39                 my (@sha1_pair) = @{ $reel->reel_id };
  40                 $payload .= join("", (map { pack_hex($_) } @sha1_pair));
  41                 $payload .= pack_num($reel->size);
  42         }
  43
  44         $payload;
  45 }
  46
  47 sub unpack_payload {
  48         my $self = shift;
  49         my $payload = shift;
  50
  51         (length($payload) % 44) == 0
  52                 or croak "bad Reels payload length ".length($payload);
  53
  54         my %args;
  55         my @reels;
  56         while ( length($payload) ) {
  57                 my (@sha1_pair) = map { unpack_hex($_) }
  58                         (substr($payload, 0, 20),
  59                          substr($payload, 20, 20));
  60
  61                 $args{'start'} = $sha1_pair[0];
  62                 $args{'end'} = $sha1_pair[1];
  63
  64                 my $size = unpack_num(substr($payload, 40, 4));
  65                 substr($payload, 0, 44)="";
  66
  67                 $args{'size'} = $size;
  68                 push @reels,
  69                         VCS::Git::Torrent::CommitReel->new(%args);
  70         }
  71
  72         $self->reels(\@reels);
  73 }
  74
  75 sub args {
  76         my $class = shift;
  77         my $reels;
  78
  79         if ( ref($_[0]) eq 'ARRAY' ) {
  80                 $reels = shift;
  81         }
  82         else {
  83                 $reels = [ @_ ];
  84         }
  85
  86         return( reels => $reels );
  87 }
  88
  89 sub action {
  90         my $self = shift;
  91         my $local_peer = shift;
  92         my $connection = shift;
  93
  94         if ( scalar(@{ $self->reels }) ) { # we got some reels from someone
  95                 # check for duplicates
  96                 my @new_reels = map {
  97                         my $reel = $_;
  98
  99                         my $num = grep {
 100                                 $reel->reel_id->[0] eq $_->reel_id->[0] &&
 101                                 $reel->reel_id->[1] eq $_->reel_id->[1]
 102                         } @{ $local_peer->torrent->reels };
 103
 104                         $num ? () : ($reel)
 105                 } @{ $self->reels };
 106
 107                 push @{ $local_peer->torrent->reels }, @new_reels;
 108                 push @{ $connection->remote->reels }, @{ $self->reels };
 109
 110                 for my $reel ( @{ $self->reels } ) {
 111                         $local_peer->send_message(
 112                                 $connection->remote, GTP_PWP_BLOCKS,
 113                                 $reel
 114                         );
 115                 }
 116         }
 117         else { # it was a request for our reels
 118                 $local_peer->send_message($connection->remote, GTP_PWP_REELS,
 119                         $local_peer->torrent->reels
 120                 ) if ( # make sure we have reels to send
 121                         scalar(@{ $local_peer->torrent->reels })
 122                 );
 123         }
 124 }
 125
 126 1;