source/tdb/config.m4

   1 dnl find the tdb sources. This is meant to work both for
   2 dnl tdb standalone builds, and builds of packages using tdb
   3 tdbdir=""
   4 tdbpaths="$srcdir $srcdir/lib/tdb $srcdir/tdb $srcdir/../tdb"
   5 for d in $tdbpaths; do
   6         if test -f "$d/common/tdb.c"; then
   7                 tdbdir="$d"
   8                 AC_SUBST(tdbdir)
   9                 break;
  10         fi
  11 done
  12 if test x"$tdbdir" = "x"; then
  13    AC_MSG_ERROR([cannot find tdb source in $tdbpaths])
  14 fi
  15 TDBOBJ="common/tdb.o common/dump.o common/transaction.o common/error.o common/traverse.o"
  16 TDBOBJ="$TDBOBJ common/freelist.o common/freelistcheck.o common/io.o common/lock.o common/open.o"
  17 AC_SUBST(TDBOBJ)
  18
  19 libreplacedir=../lib/replace
  20 AC_SUBST(libreplacedir)
  21
  22 AC_CHECK_FUNCS(mmap pread pwrite getpagesize utime)
  23 AC_CHECK_HEADERS(getopt.h sys/select.h sys/time.h)
  24
  25 AC_HAVE_DECL(pread, [#include <unistd.h>])
  26 AC_HAVE_DECL(pwrite, [#include <unistd.h>])
  27
  28 AC_MSG_CHECKING([for Python])
  29
  30 PYTHON=
  31
  32 AC_ARG_WITH(python,
  33 [  --with-python=PYTHONNAME  build Python libraries],
  34 [ case "${withval-python}" in
  35   yes)
  36         PYTHON=python
  37         ;;
  38   no)
  39         PYTHON=
  40         ;;
  41   *)
  42         PYTHON=${withval-python}
  43         ;;
  44   esac ])
  45
  46 if test x"$PYTHON" != "x"; then
  47         incdir=`python -c 'import sys; print "%s/include/python%d.%d" % (sys.prefix, sys.version_info[[0]], sys.version_info[[1]])'`
  48         CPPFLAGS="$CPPFLAGS -I $incdir"
  49 fi
  50
  51 if test x"$PYTHON" != "x"; then
  52         AC_MSG_RESULT([${withval-python}])
  53 else
  54         SMB_ENABLE(swig_tdb, NO)
  55         AC_MSG_RESULT(no)
  56 fi
  57
  58 AC_SUBST(PYTHON)