source/lib/replace/libreplace_cc.m4

   1
   2 AC_DEFUN_ONCE(AC__LIBREPLACE_ONLY_CC_CHECKS_START,
   3 [
   4 echo "LIBREPLACE_CC_CHECKS: START"
   5 ])
   6
   7 AC_DEFUN_ONCE(AC__LIBREPLACE_ONLY_CC_CHECKS_END,
   8 [
   9 echo "LIBREPLACE_CC_CHECKS: END"
  10 ])
  11
  12 dnl
  13 dnl
  14 dnl AC_LIBREPLACE_CC_CHECKS
  15 dnl
  16 dnl Note: we need to use m4_define instead of AC_DEFUN because
  17 dnl       of the ordering of tests
  18 dnl
  19 dnl
  20 m4_define(AC_LIBREPLACE_CC_CHECKS,
  21 [
  22 AC__LIBREPLACE_ONLY_CC_CHECKS_START
  23
  24 dnl stop the C89 attempt by autoconf - if autoconf detects -Ae it will enable it
  25 dnl which conflicts with C99 on HPUX
  26 ac_cv_prog_cc_Ae=no
  27
  28 savedCFLAGS=$CFLAGS
  29 AC_PROG_CC
  30 CFLAGS=$savedCFLAGS
  31
  32 dnl don't try for C99 if we are using gcc, as otherwise we
  33 dnl lose immediate structure constants
  34 if test x"$GCC" != x"yes" ; then
  35 AC_PROG_CC_C99
  36 fi
  37
  38 if test x"$GCC" = x"yes" ; then
  39         AC_MSG_CHECKING([for version of gcc])
  40         GCC_VERSION=`$CC -dumpversion`
  41         AC_MSG_RESULT(${GCC_VERSION})
  42 fi
  43 AC_USE_SYSTEM_EXTENSIONS
  44 AC_C_BIGENDIAN
  45 AC_C_INLINE
  46 LIBREPLACE_C99_STRUCT_INIT([],[AC_MSG_WARN([c99 structure initializer are not supported])])
  47
  48 AC_PROG_INSTALL
  49
  50 AC_ISC_POSIX
  51 AC_EXTENSION_FLAG(_XOPEN_SOURCE_EXTENDED)
  52 AC_EXTENSION_FLAG(_OSF_SOURCE)
  53
  54 AC_SYS_LARGEFILE
  55
  56 dnl Add #include for broken IRIX header files
  57 case "$host_os" in
  58         *irix6*) AC_ADD_INCLUDE(<standards.h>)
  59                 ;;
  60         *hpux*)
  61                 # mmap on HPUX is completely broken...
  62                 AC_DEFINE(MMAP_BLACKLIST, 1, [Whether MMAP is broken])
  63                 if test "`uname -r`" = "B.11.11"; then
  64                         AC_MSG_WARN([Enabling HPUX 11.11 header bug workaround])
  65                         CFLAGS="$CFLAGS -D_LARGEFILE64_SUPPORT -D__LP64__ -DO_LARGEFILE=04000"
  66                 fi
  67                 if test "`uname -r`" = "B.11.23"; then
  68                         AC_MSG_WARN([Enabling HPUX 11.23 machine/sys/getppdp.h bug workaround])
  69                         CFLAGS="$CFLAGS -D_MACHINE_SYS_GETPPDP_INCLUDED"
  70                 fi
  71                 ;;
  72         *aix*)
  73                 AC_DEFINE(BROKEN_STRNDUP, 1, [Whether strndup is broken])
  74                 AC_DEFINE(BROKEN_STRNLEN, 1, [Whether strnlen is broken])
  75                 if test "${GCC}" != "yes"; then
  76                         ## for funky AIX compiler using strncpy()
  77                         CFLAGS="$CFLAGS -D_LINUX_SOURCE_COMPAT -qmaxmem=32000"
  78                 fi
  79                 ;;
  80         #
  81         # VOS may need to have POSIX support and System V compatibility enabled.
  82         #
  83         *vos*)
  84                 case "$CFLAGS" in
  85                         *-D_POSIX_C_SOURCE*);;
  86                         *)
  87                                 CFLAGS="$CFLAGS -D_POSIX_C_SOURCE=200112L"
  88                                 AC_DEFINE(_POSIX_C_SOURCE, 200112L, [Whether to enable POSIX support])
  89                                 ;;
  90                 esac
  91                 case "$CFLAGS" in
  92                         *-D_SYSV*|*-D_SVID_SOURCE*);;
  93                         *)
  94                                 CFLAGS="$CFLAGS -D_SYSV"
  95                                 AC_DEFINE(_SYSV, 1, [Whether to enable System V compatibility])
  96                                 ;;
  97                 esac
  98                 ;;
  99 esac
 100
 101
 102
 103 AC_CHECK_HEADERS([standards.h])
 104
 105 # Solaris needs HAVE_LONG_LONG defined
 106 AC_CHECK_TYPES(long long)
 107
 108 AC_CHECK_TYPE(uint_t, unsigned int)
 109 AC_CHECK_TYPE(int8_t, char)
 110 AC_CHECK_TYPE(uint8_t, unsigned char)
 111 AC_CHECK_TYPE(int16_t, short)
 112 AC_CHECK_TYPE(uint16_t, unsigned short)
 113 AC_CHECK_TYPE(int32_t, long)
 114 AC_CHECK_TYPE(uint32_t, unsigned long)
 115 AC_CHECK_TYPE(int64_t, long long)
 116 AC_CHECK_TYPE(uint64_t, unsigned long long)
 117
 118 AC_CHECK_TYPE(size_t, unsigned int)
 119 AC_CHECK_TYPE(ssize_t, int)
 120
 121 AC_CHECK_SIZEOF(int)
 122 AC_CHECK_SIZEOF(char)
 123 AC_CHECK_SIZEOF(short)
 124 AC_CHECK_SIZEOF(long)
 125 AC_CHECK_SIZEOF(long long)
 126
 127 AC_CHECK_SIZEOF(off_t)
 128 AC_CHECK_SIZEOF(size_t)
 129 AC_CHECK_SIZEOF(ssize_t)
 130
 131 AC_CHECK_TYPE(intptr_t, unsigned long long)
 132 AC_CHECK_TYPE(ptrdiff_t, unsigned long long)
 133
 134 if test x"$ac_cv_type_long_long" != x"yes";then
 135         AC_MSG_ERROR([LIBREPLACE needs type 'long long'])
 136 fi
 137 if test $ac_cv_sizeof_long_long -lt 8;then
 138         AC_MSG_ERROR([LIBREPLACE needs sizeof(long long) >= 8])
 139 fi
 140
 141 ############################################
 142 # check if the compiler can do immediate structures
 143 AC_SUBST(libreplace_cv_immediate_structures)
 144 AC_CACHE_CHECK([for immediate structures],libreplace_cv_immediate_structures,[
 145         AC_TRY_COMPILE([
 146                 #include <stdio.h>
 147         ],[
 148                 typedef struct {unsigned x;} FOOBAR;
 149                 #define X_FOOBAR(x) ((FOOBAR) { x })
 150                 #define FOO_ONE X_FOOBAR(1)
 151                 FOOBAR f = FOO_ONE;
 152                 static const struct {
 153                         FOOBAR y;
 154                 } f2[] = {
 155                         {FOO_ONE}
 156                 };
 157         ],
 158         libreplace_cv_immediate_structures=yes,
 159         libreplace_cv_immediate_structures=no,
 160         libreplace_cv_immediate_structures=cross)
 161 ])
 162 if test x"$libreplace_cv_immediate_structures" = x"yes"; then
 163         AC_DEFINE(HAVE_IMMEDIATE_STRUCTURES,1,[Whether the compiler supports immediate structures])
 164 fi
 165
 166 AC__LIBREPLACE_ONLY_CC_CHECKS_END
 167 ]) dnl end AC_LIBREPLACE_CC_CHECKS