source/lib/replace/libreplace.m4

   1 AC_DEFUN_ONCE(AC_LIBREPLACE_LOCATION_CHECKS,
   2 [
   3 echo "LIBREPLACE_LOCATION_CHECKS: START"
   4
   5 dnl find the libreplace sources. This is meant to work both for
   6 dnl libreplace standalone builds, and builds of packages using libreplace
   7 libreplacedir=""
   8 libreplacepaths="$srcdir $srcdir/lib/replace $srcdir/libreplace $srcdir/../libreplace $srcdir/../replace"
   9 for d in $libreplacepaths; do
  10         if test -f "$d/replace.c"; then
  11                 libreplacedir="$d"
  12                 AC_SUBST(libreplacedir)
  13                 break;
  14         fi
  15 done
  16 if test x"$libreplacedir" = "x"; then
  17         AC_MSG_ERROR([cannot find libreplace in $libreplacepaths])
  18 fi
  19 LIBREPLACEOBJ="replace.o"
  20 AC_SUBST(LIBREPLACEOBJ)
  21
  22 AC_CANONICAL_BUILD
  23 AC_CANONICAL_HOST
  24 AC_CANONICAL_TARGET
  25
  26 echo "LIBREPLACE_LOCATION_CHECKS: END"
  27 ]) dnl end AC_LIBREPLACE_LOCATION_CHECKS
  28
  29
  30 AC_DEFUN_ONCE(AC_LIBREPLACE_BROKEN_CHECKS,
  31 [
  32 echo "LIBREPLACE_BROKEN_CHECKS: START"
  33
  34 dnl find the libreplace sources. This is meant to work both for
  35 dnl libreplace standalone builds, and builds of packages using libreplace
  36 libreplacedir=""
  37 for d in "$srcdir" "$srcdir/lib/replace" "$srcdir/libreplace" "$srcdir/../libreplace" "$srcdir/../replace"; do
  38         if test -f "$d/replace.c"; then
  39                 libreplacedir="$d"
  40                 AC_SUBST(libreplacedir)
  41                 break;
  42         fi
  43 done
  44 LIBREPLACEOBJ="replace.o"
  45 AC_SUBST(LIBREPLACEOBJ)
  46
  47 LIBREPLACEOBJ="${LIBREPLACEOBJ} snprintf.o"
  48
  49 AC_TYPE_SIGNAL
  50 AC_TYPE_UID_T
  51 AC_TYPE_MODE_T
  52 AC_TYPE_OFF_T
  53 AC_TYPE_SIZE_T
  54 AC_TYPE_PID_T
  55 AC_STRUCT_ST_RDEV
  56 AC_CHECK_TYPE(ino_t,unsigned)
  57 AC_CHECK_TYPE(loff_t,off_t)
  58 AC_CHECK_TYPE(offset_t,loff_t)
  59
  60 AC_FUNC_MEMCMP
  61
  62 AC_CHECK_FUNCS(pipe strftime srandom random srand rand usleep setbuffer lstat getpgrp)
  63
  64 AC_CHECK_HEADERS(stdbool.h stdint.h sys/select.h)
  65 AC_CHECK_HEADERS(setjmp.h)
  66
  67 LIBREPLACE_PROVIDE_HEADER([stdint.h])
  68 LIBREPLACE_PROVIDE_HEADER([stdbool.h])
  69
  70 AC_CHECK_TYPE(bool,
  71 [AC_DEFINE(HAVE_BOOL, 1, [Whether the bool type is available])],,
  72 [
  73 AC_INCLUDES_DEFAULT
  74 #ifdef HAVE_STDBOOL_H
  75 #include <stdbool.h>
  76 #endif]
  77 )
  78
  79 AC_CHECK_TYPE(_Bool,
  80 [AC_DEFINE(HAVE__Bool, 1, [Whether the _Bool type is available])],,
  81 [
  82 AC_INCLUDES_DEFAULT
  83 #ifdef HAVE_STDBOOL_H
  84 #include <stdbool.h>
  85 #endif]
  86 )
  87
  88 AC_CACHE_CHECK([for working mmap],libreplace_cv_HAVE_MMAP,[
  89 AC_TRY_RUN([#include "$libreplacedir/test/shared_mmap.c"],
  90            libreplace_cv_HAVE_MMAP=yes,libreplace_cv_HAVE_MMAP=no,libreplace_cv_HAVE_MMAP=cross)])
  91 if test x"$libreplace_cv_HAVE_MMAP" = x"yes"; then
  92     AC_DEFINE(HAVE_MMAP,1,[Whether mmap works])
  93 fi
  94
  95
  96 AC_CHECK_HEADERS(sys/syslog.h syslog.h)
  97 AC_CHECK_HEADERS(sys/time.h time.h)
  98 AC_CHECK_HEADERS(stdarg.h vararg.h)
  99 AC_CHECK_HEADERS(sys/sockio.h sys/un.h)
 100 AC_CHECK_HEADERS(sys/mount.h mntent.h)
 101 AC_CHECK_HEADERS(stropts.h)
 102
 103 AC_CHECK_FUNCS(seteuid setresuid setegid setresgid chroot bzero strerror)
 104 AC_CHECK_FUNCS(vsyslog setlinebuf mktime ftruncate chsize rename)
 105 AC_CHECK_FUNCS(waitpid strlcpy strlcat initgroups memmove strdup)
 106 AC_CHECK_FUNCS(pread pwrite strndup strcasestr strtok_r mkdtemp)
 107 AC_CHECK_FUNCS(isatty)
 108 AC_HAVE_DECL(setresuid, [#include <unistd.h>])
 109 AC_HAVE_DECL(setresgid, [#include <unistd.h>])
 110 AC_HAVE_DECL(errno, [#include <errno.h>])
 111
 112 AC_CACHE_CHECK([for secure mkstemp],libreplace_cv_HAVE_SECURE_MKSTEMP,[
 113 AC_TRY_RUN([#include <stdlib.h>
 114 #include <sys/types.h>
 115 #include <sys/stat.h>
 116 #include <unistd.h>
 117 main() {
 118   struct stat st;
 119   char tpl[20]="/tmp/test.XXXXXX";
 120   int fd = mkstemp(tpl);
 121   if (fd == -1) exit(1);
 122   unlink(tpl);
 123   if (fstat(fd, &st) != 0) exit(1);
 124   if ((st.st_mode & 0777) != 0600) exit(1);
 125   exit(0);
 126 }],
 127 libreplace_cv_HAVE_SECURE_MKSTEMP=yes,
 128 libreplace_cv_HAVE_SECURE_MKSTEMP=no,
 129 libreplace_cv_HAVE_SECURE_MKSTEMP=cross)])
 130 if test x"$libreplace_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 131     AC_DEFINE(HAVE_SECURE_MKSTEMP,1,[Whether mkstemp is secure])
 132 fi
 133
 134 dnl Provided by snprintf.c:
 135 AC_CHECK_HEADERS(stdio.h strings.h)
 136 AC_CHECK_DECLS([snprintf, vsnprintf, asprintf, vasprintf])
 137 AC_CHECK_FUNCS(snprintf vsnprintf asprintf vasprintf)
 138
 139 AC_CACHE_CHECK([for C99 vsnprintf],libreplace_cv_HAVE_C99_VSNPRINTF,[
 140 AC_TRY_RUN([
 141 #include <sys/types.h>
 142 #include <stdio.h>
 143 #include <stdarg.h>
 144 #include <stdlib.h>
 145 void foo(const char *format, ...) {
 146        va_list ap;
 147        int len;
 148        char buf[20];
 149        long long l = 1234567890;
 150        l *= 100;
 151
 152        va_start(ap, format);
 153        len = vsnprintf(buf, 0, format, ap);
 154        va_end(ap);
 155        if (len != 5) exit(1);
 156
 157        va_start(ap, format);
 158        len = vsnprintf(0, 0, format, ap);
 159        va_end(ap);
 160        if (len != 5) exit(2);
 161
 162        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(3);
 163
 164        if (snprintf(buf, 20, "%lld", l) != 12 || strcmp(buf, "123456789000") != 0) exit(4);
 165        if (snprintf(buf, 20, "%zu", 123456789) != 9 || strcmp(buf, "123456789") != 0) exit(5);
 166        if (snprintf(buf, 20, "%2\$d %1\$d", 3, 4) != 3 || strcmp(buf, "4 3") != 0) exit(6);
 167        if (snprintf(buf, 20, "%s", 0) < 3) exit(7);
 168
 169        exit(0);
 170 }
 171 main() { foo("hello"); }
 172 ],
 173 libreplace_cv_HAVE_C99_VSNPRINTF=yes,libreplace_cv_HAVE_C99_VSNPRINTF=no,libreplace_cv_HAVE_C99_VSNPRINTF=cross)])
 174 if test x"$libreplace_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 175     AC_DEFINE(HAVE_C99_VSNPRINTF,1,[Whether there is a C99 compliant vsnprintf])
 176 fi
 177
 178
 179 dnl VA_COPY
 180 AC_CACHE_CHECK([for va_copy],libreplace_cv_HAVE_VA_COPY,[
 181 AC_TRY_LINK([#include <stdarg.h>
 182 va_list ap1,ap2;], [va_copy(ap1,ap2);],
 183 libreplace_cv_HAVE_VA_COPY=yes,libreplace_cv_HAVE_VA_COPY=no)])
 184 if test x"$libreplace_cv_HAVE_VA_COPY" = x"yes"; then
 185     AC_DEFINE(HAVE_VA_COPY,1,[Whether va_copy() is available])
 186 fi
 187
 188 if test x"$libreplace_cv_HAVE_VA_COPY" != x"yes"; then
 189 AC_CACHE_CHECK([for __va_copy],libreplace_cv_HAVE___VA_COPY,[
 190 AC_TRY_LINK([#include <stdarg.h>
 191 va_list ap1,ap2;], [__va_copy(ap1,ap2);],
 192 libreplace_cv_HAVE___VA_COPY=yes,libreplace_cv_HAVE___VA_COPY=no)])
 193 if test x"$libreplace_cv_HAVE___VA_COPY" = x"yes"; then
 194     AC_DEFINE(HAVE___VA_COPY,1,[Whether __va_copy() is available])
 195 fi
 196 fi
 197
 198 dnl __FUNCTION__ macro
 199 AC_CACHE_CHECK([for __FUNCTION__ macro],libreplace_cv_HAVE_FUNCTION_MACRO,[
 200 AC_TRY_COMPILE([#include <stdio.h>], [printf("%s\n", __FUNCTION__);],
 201 libreplace_cv_HAVE_FUNCTION_MACRO=yes,libreplace_cv_HAVE_FUNCTION_MACRO=no)])
 202 if test x"$libreplace_cv_HAVE_FUNCTION_MACRO" = x"yes"; then
 203     AC_DEFINE(HAVE_FUNCTION_MACRO,1,[Whether there is a __FUNCTION__ macro])
 204 else
 205     dnl __func__ macro
 206     AC_CACHE_CHECK([for __func__ macro],libreplace_cv_HAVE_func_MACRO,[
 207     AC_TRY_COMPILE([#include <stdio.h>], [printf("%s\n", __func__);],
 208     libreplace_cv_HAVE_func_MACRO=yes,libreplace_cv_HAVE_func_MACRO=no)])
 209     if test x"$libreplace_cv_HAVE_func_MACRO" = x"yes"; then
 210        AC_DEFINE(HAVE_func_MACRO,1,[Whether there is a __func__ macro])
 211     fi
 212 fi
 213
 214 AC_CHECK_HEADERS([sys/param.h limits.h])
 215
 216 AC_CHECK_TYPE(comparison_fn_t,
 217 [AC_DEFINE(HAVE_COMPARISON_FN_T, 1,[Whether or not we have comparison_fn_t])])
 218
 219 AC_HAVE_DECL(setenv, [#include <stdlib.h>])
 220 AC_CHECK_FUNCS(setenv unsetenv)
 221
 222 AC_CHECK_FUNCS(strnlen)
 223 AC_CHECK_FUNCS(strtoull __strtoull strtouq strtoll __strtoll strtoq)
 224
 225 # this test disabled as we don't actually need __VA_ARGS__ yet
 226 AC_TRY_CPP([
 227 #define eprintf(...) fprintf(stderr, __VA_ARGS__)
 228 eprintf("bla", "bar");
 229 ], AC_DEFINE(HAVE__VA_ARGS__MACRO, 1, [Whether the __VA_ARGS__ macro is available]))
 230
 231
 232 AC_CACHE_CHECK([for sig_atomic_t type],libreplace_cv_sig_atomic_t, [
 233     AC_TRY_COMPILE([
 234 #include <sys/types.h>
 235 #if STDC_HEADERS
 236 #include <stdlib.h>
 237 #include <stddef.h>
 238 #endif
 239 #include <signal.h>],[sig_atomic_t i = 0],
 240         libreplace_cv_sig_atomic_t=yes,libreplace_cv_sig_atomic_t=no)])
 241 if test x"$libreplace_cv_sig_atomic_t" = x"yes"; then
 242    AC_DEFINE(HAVE_SIG_ATOMIC_T_TYPE,1,[Whether we have the atomic_t variable type])
 243 fi
 244
 245
 246 AC_CACHE_CHECK([for O_DIRECT flag to open(2)],libreplace_cv_HAVE_OPEN_O_DIRECT,[
 247 AC_TRY_COMPILE([
 248 #include <unistd.h>
 249 #ifdef HAVE_FCNTL_H
 250 #include <fcntl.h>
 251 #endif],
 252 [int fd = open("/dev/null", O_DIRECT);],
 253 libreplace_cv_HAVE_OPEN_O_DIRECT=yes,libreplace_cv_HAVE_OPEN_O_DIRECT=no)])
 254 if test x"$libreplace_cv_HAVE_OPEN_O_DIRECT" = x"yes"; then
 255     AC_DEFINE(HAVE_OPEN_O_DIRECT,1,[Whether the open(2) accepts O_DIRECT])
 256 fi
 257
 258
 259 dnl Check if the C compiler understands volatile (it should, being ANSI).
 260 AC_CACHE_CHECK([that the C compiler understands volatile],libreplace_cv_volatile, [
 261         AC_TRY_COMPILE([#include <sys/types.h>],[volatile int i = 0],
 262                 libreplace_cv_volatile=yes,libreplace_cv_volatile=no)])
 263 if test x"$libreplace_cv_volatile" = x"yes"; then
 264         AC_DEFINE(HAVE_VOLATILE, 1, [Whether the C compiler understands volatile])
 265 fi
 266
 267 m4_include(system/config.m4)
 268
 269 m4_include(dlfcn.m4)
 270 m4_include(getpass.m4)
 271 m4_include(strptime.m4)
 272 m4_include(win32.m4)
 273 m4_include(timegm.m4)
 274 m4_include(repdir.m4)
 275
 276 AC_CHECK_FUNCS([syslog printf memset memcpy],,[AC_MSG_ERROR([Required function not found])])
 277
 278 echo "LIBREPLACE_BROKEN_CHECKS: END"
 279 AC_LIBREPLACE_NETWORK_CHECKS
 280 ]) dnl end AC_LIBREPLACE_BROKEN_CHECKS
 281
 282 AC_DEFUN_ONCE(AC__LIBREPLACE_ALL_CHECKS_START,
 283 [
 284 #LIBREPLACE_ALL_CHECKS: START"
 285 ])
 286 AC_DEFUN_ONCE(AC__LIBREPLACE_ALL_CHECKS_END,
 287 [
 288 #LIBREPLACE_ALL_CHECKS: END"
 289 ])
 290 m4_define(AC_LIBREPLACE_ALL_CHECKS,
 291 [
 292 AC__LIBREPLACE_ALL_CHECKS_START
 293 AC_LIBREPLACE_LOCATION_CHECKS
 294 AC_LIBREPLACE_CC_CHECKS
 295 AC_LIBREPLACE_BROKEN_CHECKS
 296 AC__LIBREPLACE_ALL_CHECKS_END
 297 CFLAGS="$CFLAGS -I$libreplacedir"
 298 ])
 299
 300 m4_include(libreplace_cc.m4)
 301 m4_include(libreplace_ld.m4)
 302 m4_include(libreplace_network.m4)
 303 m4_include(libreplace_macros.m4)
 304 m4_include(autoconf-2.60.m4)