rbutil/rbutilqt/rbutilqt.pro

   1 unix:!mac {
   2     CCACHE = $$system(which ccache)
   3     !isEmpty(CCACHE) {
   4         message("using ccache")
   5         QMAKE_CXX = ccache g++
   6         QMAKE_CC = ccache gcc
   7     }
   8 }
   9
  10 OBJECTS_DIR = build/o
  11 UI_DIR = build/ui
  12 MOC_DIR = build/moc
  13 RCC_DIR = build/rcc
  14
  15 # add a custom rule for pre-building librbspeex
  16 rbspeex.commands = @$(MAKE) -C ../../tools/rbspeex librbspeex.a
  17 QMAKE_EXTRA_TARGETS += rbspeex
  18 PRE_TARGETDEPS += rbspeex
  19
  20 # add a custom rule for making the translations
  21 lrelease.commands = $$[QT_INSTALL_BINS]/lrelease -silent rbutilqt.pro
  22 QMAKE_EXTRA_TARGETS += lrelease
  23 PRE_TARGETDEPS += lrelease
  24
  25
  26 SOURCES += rbutilqt.cpp \
  27            main.cpp \
  28  install.cpp \
  29  httpget.cpp \
  30  configure.cpp \
  31  zip/zip.cpp \
  32  zip/unzip.cpp \
  33  installzip.cpp \
  34  installbootloader.cpp \
  35  progressloggergui.cpp \
  36  installtalkwindow.cpp \
  37  talkfile.cpp \
  38  autodetection.cpp \
  39  ../ipodpatcher/ipodpatcher.c \
  40  ../sansapatcher/sansapatcher.c \
  41  irivertools/irivertools.cpp \
  42  irivertools/md5sum.cpp  \
  43  browsedirtree.cpp \
  44  installthemes.cpp \
  45  uninstall.cpp \
  46  uninstallwindow.cpp \
  47  utils.cpp \
  48  browseof.cpp \
  49  preview.cpp \
  50  encoders.cpp \
  51  encodersgui.cpp \
  52  tts.cpp \
  53  ttsgui.cpp \
  54  ../../tools/wavtrim.c \
  55  ../../tools/voicefont.c \
  56  voicefile.cpp \
  57  createvoicewindow.cpp \
  58  rbsettings.cpp \
  59  rbunzip.cpp
  60
  61 HEADERS += rbutilqt.h \
  62  install.h \
  63  httpget.h \
  64  configure.h \
  65  zip/zip.h \
  66  zip/unzip.h \
  67  zip/zipentry_p.h \
  68  zip/unzip_p.h \
  69  zip/zip_p.h \
  70  version.h \
  71  installzip.h \
  72  installbootloader.h \
  73  installtalkwindow.h \
  74  talkfile.h \
  75  autodetection.h \
  76  progressloggerinterface.h \
  77  progressloggergui.h \
  78  ../ipodpatcher/ipodpatcher.h \
  79  ../ipodpatcher/ipodio.h \
  80  ../ipodpatcher/parttypes.h \
  81  ../sansapatcher/sansapatcher.h \
  82  ../sansapatcher/sansaio.h \
  83  irivertools/irivertools.h \
  84  irivertools/md5sum.h \
  85  irivertools/h100sums.h \
  86  irivertools/h120sums.h \
  87  irivertools/h300sums.h \
  88  irivertools/checksums.h \
  89  browsedirtree.h \
  90  installthemes.h \
  91  uninstall.h \
  92  uninstallwindow.h \
  93  utils.h \
  94  browseof.h \
  95  preview.h \
  96  encoders.h \
  97  encodersgui.h \
  98  tts.h \
  99  ttsgui.h \
 100  ../../tools/wavtrim.h \
 101  ../../tools/voicefont.h \
 102  voicefile.h \
 103  createvoicewindow.h \
 104  rbsettings.h \
 105  rbunzip.h
 106
 107 # Needed by QT on Win
 108 INCLUDEPATH = . irivertools zip zlib ../ipodpatcher ../sansapatcher ../../tools/rbspeex ../../tools
 109
 110 LIBS += -L../../tools/rbspeex -lrbspeex
 111
 112 TEMPLATE = app
 113 dbg {
 114     CONFIG += debug thread qt warn_on
 115     DEFINES -= QT_NO_DEBUG_OUTPUT
 116     message("debug")
 117 }
 118 !dbg {
 119     CONFIG += release thread qt
 120     DEFINES += QT_NO_DEBUG_OUTPUT
 121     message("release")
 122 }
 123
 124 TARGET = rbutilqt
 125
 126 FORMS += rbutilqtfrm.ui \
 127  aboutbox.ui \
 128  installfrm.ui \
 129  progressloggerfrm.ui \
 130  configurefrm.ui \
 131  browsedirtreefrm.ui \
 132  installtalkfrm.ui \
 133  installthemesfrm.ui \
 134  uninstallfrm.ui \
 135  browseoffrm.ui \
 136  previewfrm.ui \
 137  rbspeexcfgfrm.ui \
 138  encexescfgfrm.ui \
 139  ttsexescfgfrm.ui \
 140  sapicfgfrm.ui \
 141  createvoicefrm.ui
 142
 143 RESOURCES += rbutilqt.qrc
 144 win32 {
 145     RESOURCES += rbutilqt-win.qrc
 146 }
 147
 148 TRANSLATIONS += rbutil_de.ts \
 149  rbutil_fr.ts \
 150  rbutil_tr.ts \
 151  rbutil_zh_CN.ts \
 152  rbutil_zh_TW.ts
 153 QT += network
 154 DEFINES += RBUTIL _LARGEFILE64_SOURCE
 155
 156 win32 {
 157     SOURCES +=  ../ipodpatcher/ipodio-win32.c
 158     SOURCES +=  ../sansapatcher/sansaio-win32.c
 159     RC_FILE = rbutilqt.rc
 160     LIBS += -lsetupapi
 161 }
 162
 163 unix {
 164     SOURCES +=  ../ipodpatcher/ipodio-posix.c
 165     SOURCES +=  ../sansapatcher/sansaio-posix.c
 166 }
 167 unix:!static {
 168     LIBS += -lusb
 169 }
 170 unix:static {
 171     # force statically linking of libusb. Use gcc to get its path.
 172     # if you have libusb.a in a non-standard lib path add it to
 173     # the INCLUDEPATH variable above.
 174     LIBS += $$system($$QMAKE_CC $$INCLUDEPATH -print-file-name=libusb.a)
 175 }
 176
 177 macx {
 178     QMAKE_MAC_SDK=/Developer/SDKs/MacOSX10.4u.sdk
 179     QMAKE_LFLAGS_PPC=-mmacosx-version-min=10.4
 180     QMAKE_LFLAGS_X86=-mmacosx-version-min=10.4
 181     CONFIG+=x86 ppc
 182     LIBS += -L/usr/local/lib -framework IOKit
 183     INCLUDEPATH += /usr/local/include
 184     QMAKE_INFO_PLIST = Info.plist
 185     RC_FILE = icons/rbutilqt.icns
 186 }
 187
 188 static {
 189     QTPLUGIN += qtaccessiblewidgets
 190     LIBS += -L$$(QT_BUILD_TREE)/plugins/accessible -lqtaccessiblewidgets
 191     DEFINES += STATIC
 192     message("using static plugin")
 193 }
 194
 195