configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL$
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.4devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.61], [], [m4_fatal([Autoconf version 2.61 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2008, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  33
  34 AC_CANONICAL_HOST
  35
  36 template=
  37 AC_MSG_CHECKING([which template to use])
  38
  39 PGAC_ARG_REQ(with, template, [],
  40 [
  41   case $withval in
  42     list)   echo; ls "$srcdir/src/template"; exit;;
  43     *)      if test -f "$srcdir/src/template/$with_template" ; then
  44               template=$withval
  45             else
  46               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  47             fi;;
  48   esac
  49 ],
  50 [
  51 # --with-template not given
  52
  53 case $host_os in
  54      aix*) template=aix ;;
  55     bsdi*) template=bsdi ;;
  56   cygwin*) template=cygwin ;;
  57   darwin*) template=darwin ;;
  58     dgux*) template=dgux ;;
  59  freebsd*) template=freebsd ;;
  60     hpux*) template=hpux ;;
  61     irix*) template=irix ;;
  62  linux*|gnu*|k*bsd*-gnu)
  63            template=linux ;;
  64    mingw*) template=win32 ;;
  65   netbsd*) template=netbsd ;;
  66 nextstep*) template=nextstep ;;
  67  openbsd*) template=openbsd ;;
  68      osf*) template=osf ;;
  69      sco*) template=sco ;;
  70  solaris*) template=solaris ;;
  71    sunos*) template=sunos4 ;;
  72  sysv4.2*)
  73         case $host_vendor in
  74           univel) template=univel ;;
  75         esac ;;
  76    sysv4*) template=svr4 ;;
  77    sysv5*) template=unixware ;;
  78   ultrix*) template=ultrix4 ;;
  79 esac
  80
  81   if test x"$template" = x"" ; then
  82     AC_MSG_ERROR([[
  83 *******************************************************************
  84 PostgreSQL has apparently not been ported to your platform yet.
  85 To try a manual configuration, look into the src/template directory
  86 for a similar platform and use the '--with-template=' option.
  87
  88 Please also contact <pgsql-ports@postgresql.org> to see about
  89 rectifying this.  Include the above 'checking host system type...'
  90 line.
  91 *******************************************************************
  92 ]])
  93   fi
  94
  95 ])
  96
  97 AC_MSG_RESULT([$template])
  98
  99 PORTNAME=$template
 100 AC_SUBST(PORTNAME)
 101
 102 # Initialize default assumption that we do not need separate assembly code
 103 # for TAS (test-and-set).  This can be overridden by the template file
 104 # when it's executed.
 105 need_tas=no
 106 tas_file=dummy.s
 107
 108
 109
 110 ##
 111 ## Command line options
 112 ##
 113
 114 #
 115 # Add non-standard directories to the include path
 116 #
 117 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 118
 119
 120 #
 121 # Add non-standard directories to the library search path
 122 #
 123 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 124              [LIBRARY_DIRS=$withval])
 125
 126 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 127              [LIBRARY_DIRS=$withval])
 128
 129
 130 #
 131 # 64-bit integer date/time storage (--enable-integer-datetimes)
 132 #
 133 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 134 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 135               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 136                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 137 AC_MSG_RESULT([$enable_integer_datetimes])
 138
 139
 140 #
 141 # NLS
 142 #
 143 AC_MSG_CHECKING([whether NLS is wanted])
 144 PGAC_ARG_OPTARG(enable, nls,
 145                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 146                 [],
 147                 [WANTED_LANGUAGES=$enableval],
 148                 [AC_DEFINE(ENABLE_NLS, 1,
 149                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 150 AC_MSG_RESULT([$enable_nls])
 151 AC_SUBST(enable_nls)
 152 AC_SUBST(WANTED_LANGUAGES)
 153
 154 #
 155 # Default port number (--with-pgport), default 5432
 156 #
 157 AC_MSG_CHECKING([for default port number])
 158 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [[5432]]],
 159              [default_port=$withval],
 160              [default_port=5432])
 161 AC_MSG_RESULT([$default_port])
 162 # Need both of these because some places want an integer and some a string
 163 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 164 [Define to the default TCP port number on which the server listens and
 165 to which clients will try to connect.  This can be overridden at run-time,
 166 but it's convenient if your clients have the right default compiled in.
 167 (--with-pgport=PORTNUM)])
 168 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 169                    [Define to the default TCP port number as a string constant.])
 170 AC_SUBST(default_port)
 171
 172 #
 173 # Option to disable shared libraries
 174 #
 175 PGAC_ARG_BOOL(enable, shared, yes,
 176               [  --disable-shared        do not build shared libraries])
 177 AC_SUBST(enable_shared)
 178
 179 #
 180 # '-rpath'-like feature can be disabled
 181 #
 182 PGAC_ARG_BOOL(enable, rpath, yes,
 183               [  --disable-rpath         do not embed shared library search path in executables])
 184 AC_SUBST(enable_rpath)
 185
 186 #
 187 # Spinlocks
 188 #
 189 PGAC_ARG_BOOL(enable, spinlocks, yes,
 190               [  --disable-spinlocks     do not use spinlocks])
 191
 192 #
 193 # --enable-debug adds -g to compiler flags
 194 #
 195 PGAC_ARG_BOOL(enable, debug, no,
 196               [  --enable-debug          build with debugging symbols (-g)])
 197 AC_SUBST(enable_debug)
 198
 199 #
 200 # --enable-profiling enables gcc profiling
 201 #
 202 PGAC_ARG_BOOL(enable, profiling, no,
 203               [  --enable-profiling      build with profiling enabled ])
 204 AC_SUBST(enable_profiling)
 205
 206 #
 207 # DTrace
 208 #
 209 PGAC_ARG_BOOL(enable, dtrace, no,
 210               [  --enable-dtrace         build with DTrace support],
 211 [AC_DEFINE([ENABLE_DTRACE], 1,
 212            [Define to 1 to enable DTrace support. (--enable-dtrace)])
 213 AC_CHECK_PROGS(DTRACE, dtrace)
 214 if test -z "$DTRACE"; then
 215   AC_MSG_ERROR([dtrace not found])
 216 fi
 217 AC_SUBST(DTRACEFLAGS)])
 218 AC_SUBST(enable_dtrace)
 219
 220 #
 221 # Data file segmentation
 222 #
 223 PGAC_ARG_BOOL(enable, segmented-files, yes,
 224               [  --disable-segmented-files disable data file segmentation (requires largefile support)])
 225
 226 #
 227 # C compiler
 228 #
 229
 230 # For historical reasons you can also use --with-CC to specify the C compiler
 231 # to use, although the standard way to do this is to set the CC environment
 232 # variable.
 233 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 234
 235 case $template in
 236   aix) pgac_cc_list="gcc xlc";;
 237  irix) pgac_cc_list="cc";; # no gcc
 238     *) pgac_cc_list="gcc cc";;
 239 esac
 240
 241 AC_PROG_CC([$pgac_cc_list])
 242
 243 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 244 # but has idiosyncrasies of its own.  We assume icc will define
 245 # __INTEL_COMPILER regardless of CFLAGS.
 246 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 247 choke me
 248 @%:@endif], [ICC=[yes]], [ICC=[no]])
 249
 250 unset CFLAGS
 251
 252 #
 253 # Read the template
 254 #
 255 . "$srcdir/src/template/$template" || exit
 256
 257 # CFLAGS are selected so:
 258 # If the user specifies something in the environment, that is used.
 259 # else:  If the template file set something, that is used.
 260 # else:  If the compiler is GCC, then we use -O2.
 261 # else:  If the compiler is something else, then we use -0.
 262
 263 if test "$ac_env_CFLAGS_set" = set; then
 264   CFLAGS=$ac_env_CFLAGS_value
 265 elif test "${CFLAGS+set}" = set; then
 266   : # (keep what template set)
 267 elif test "$GCC" = yes; then
 268   CFLAGS="-O2"
 269 else
 270   # if the user selected debug mode, don't use -O
 271   if test "$enable_debug" != yes; then
 272     CFLAGS="-O"
 273   fi
 274 fi
 275
 276 # Some versions of GCC support some additional useful warning flags.
 277 # Check whether they are supported, and add them to CFLAGS if so.
 278 # ICC pretends to be GCC but it's lying; it doesn't support these options.
 279
 280 if test "$GCC" = yes -a "$ICC" = no; then
 281   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith -Winline"
 282   # These work in some but not all gcc versions
 283   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 284   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 285   # Disable strict-aliasing rules; needed for gcc 3.3+
 286   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 287   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 288   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 289 elif test "$ICC" = yes; then
 290   # Intel's compiler has a bug/misoptimization in checking for
 291   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 292   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 293   # Make sure strict aliasing is off (though this is said to be the default)
 294   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 295 elif test x"${CC}" = x"xlc"; then
 296   # AIX xlc has to have strict aliasing turned off too
 297   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 298 fi
 299
 300 # supply -g if --enable-debug
 301 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 302   CFLAGS="$CFLAGS -g"
 303 fi
 304
 305 # enable profiling if --enable-profiling
 306 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 307   if test "$GCC" = yes; then
 308     AC_DEFINE([PROFILE_PID_DIR], 1,
 309            [Define to 1 to allow profiling output to be saved separately for each process.])
 310     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 311   else
 312     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 313   fi
 314 fi
 315
 316 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 317
 318 # We already have this in Makefile.win32, but configure needs it too
 319 if test "$PORTNAME" = "win32"; then
 320   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 321 fi
 322
 323 # Check if the compiler still works with the template settings
 324 AC_MSG_CHECKING([whether the C compiler still works])
 325 AC_TRY_LINK([], [return 0;],
 326   [AC_MSG_RESULT(yes)],
 327   [AC_MSG_RESULT(no)
 328    AC_MSG_ERROR([cannot proceed])])
 329
 330 # Defend against gcc -ffast-math
 331 if test "$GCC" = yes; then
 332 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 333 choke me
 334 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 335 fi
 336
 337 AC_PROG_CPP
 338 AC_SUBST(GCC)
 339
 340 # Create compiler version string
 341 if test x"$GCC" = x"yes" ; then
 342   cc_string="GCC `${CC} --version | sed q`"
 343 else
 344   cc_string=$CC
 345 fi
 346 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 347                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 348                    [A string containing the version number, platform, and C compiler])
 349
 350
 351 #
 352 # Set up TAS assembly code if needed; the template file has now had its
 353 # chance to request this.
 354 #
 355 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 356
 357 if test "$need_tas" = yes ; then
 358   TAS=tas.o
 359 else
 360   TAS=""
 361 fi
 362 AC_SUBST(TAS)
 363
 364
 365 #
 366 # Automatic dependency tracking
 367 #
 368 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 369               [autodepend=yes])
 370 AC_SUBST(autodepend)
 371
 372
 373 #
 374 # Enable assert checks
 375 #
 376 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 377               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 378                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 379
 380
 381 #
 382 # Include directories
 383 #
 384 ac_save_IFS=$IFS
 385 IFS="${IFS}${PATH_SEPARATOR}"
 386 # SRCH_INC comes from the template file
 387 for dir in $with_includes $SRCH_INC; do
 388   if test -d "$dir"; then
 389     INCLUDES="$INCLUDES -I$dir"
 390   else
 391     AC_MSG_WARN([*** Include directory $dir does not exist.])
 392   fi
 393 done
 394 IFS=$ac_save_IFS
 395 AC_SUBST(INCLUDES)
 396
 397
 398 #
 399 # Library directories
 400 #
 401 ac_save_IFS=$IFS
 402 IFS="${IFS}${PATH_SEPARATOR}"
 403 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 404 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 405   if test -d "$dir"; then
 406     LIBDIRS="$LIBDIRS -L$dir"
 407   else
 408     AC_MSG_WARN([*** Library directory $dir does not exist.])
 409   fi
 410 done
 411 IFS=$ac_save_IFS
 412
 413 #
 414 # Enable thread-safe client libraries
 415 #
 416 AC_MSG_CHECKING([allow thread-safe client libraries])
 417 if test "$PORTNAME" != "win32"; then
 418 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe])
 419 else
 420 # Win32 should always use threads
 421 PGAC_ARG_BOOL(enable, thread-safety, yes, [  --enable-thread-safety  make client libraries thread-safe])
 422 fi
 423
 424 PGAC_ARG_BOOL(enable, thread-safety-force, no, [  --enable-thread-safety-force  force thread-safety despite thread test failure])
 425 if test "$enable_thread_safety" = yes -o \
 426         "$enable_thread_safety_force" = yes; then
 427   enable_thread_safety="yes"    # for 'force'
 428   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 429           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 430 fi
 431 AC_MSG_RESULT([$enable_thread_safety])
 432 AC_SUBST(enable_thread_safety)
 433
 434 #
 435 # Optionally build Tcl modules (PL/Tcl)
 436 #
 437 AC_MSG_CHECKING([whether to build with Tcl])
 438 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl modules (PL/Tcl)])
 439 AC_MSG_RESULT([$with_tcl])
 440 AC_SUBST([with_tcl])
 441
 442 # We see if the path to the Tcl/Tk configuration scripts is specified.
 443 # This will override the use of tclsh to find the paths to search.
 444
 445 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh is in DIR])
 446
 447 #
 448 # Optionally build Perl modules (PL/Perl)
 449 #
 450 AC_MSG_CHECKING([whether to build Perl modules])
 451 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 452 AC_MSG_RESULT([$with_perl])
 453 AC_SUBST(with_perl)
 454
 455 #
 456 # Optionally build Python modules (PL/Python)
 457 #
 458 AC_MSG_CHECKING([whether to build Python modules])
 459 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 460 AC_MSG_RESULT([$with_python])
 461 AC_SUBST(with_python)
 462
 463 #
 464 # GSSAPI
 465 #
 466 AC_MSG_CHECKING([whether to build with GSSAPI support])
 467 PGAC_ARG_BOOL(with, gssapi, no, [  --with-gssapi           build with GSSAPI support],
 468 [
 469   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 470   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 471 ])
 472 AC_MSG_RESULT([$with_gssapi])
 473 AC_SUBST(with_gssapi)
 474
 475 #
 476 # Kerberos 5
 477 #
 478 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 479 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 480 [
 481   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 482   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 483 ])
 484 AC_MSG_RESULT([$with_krb5])
 485 AC_SUBST(with_krb5)
 486
 487
 488 AC_SUBST(krb_srvtab)
 489
 490
 491 #
 492 # Kerberos configuration parameters
 493 #
 494 PGAC_ARG_REQ(with, krb-srvnam,
 495              [  --with-krb-srvnam=NAME  default service principal name in Kerberos [[postgres]]],
 496              [],
 497              [with_krb_srvnam="postgres"])
 498 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 499                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 500
 501
 502 #
 503 # PAM
 504 #
 505 AC_MSG_CHECKING([whether to build with PAM support])
 506 PGAC_ARG_BOOL(with, pam, no,
 507               [  --with-pam              build with PAM support],
 508               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 509 AC_MSG_RESULT([$with_pam])
 510 AC_SUBST(with_pam)
 511
 512
 513 #
 514 # LDAP
 515 #
 516 AC_MSG_CHECKING([whether to build with LDAP support])
 517 PGAC_ARG_BOOL(with, ldap, no,
 518               [  --with-ldap             build with LDAP support],
 519               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 520 AC_MSG_RESULT([$with_ldap])
 521 AC_SUBST(with_ldap)
 522
 523
 524 #
 525 # Bonjour
 526 #
 527 AC_MSG_CHECKING([whether to build with Bonjour support])
 528 PGAC_ARG_BOOL(with, bonjour, no,
 529               [  --with-bonjour          build with Bonjour support],
 530               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 531 AC_MSG_RESULT([$with_bonjour])
 532 AC_SUBST(with_bonjour)
 533
 534
 535 #
 536 # OpenSSL
 537 #
 538 AC_MSG_CHECKING([whether to build with OpenSSL support])
 539 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 540               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 541 AC_MSG_RESULT([$with_openssl])
 542 AC_SUBST(with_openssl)
 543
 544
 545 #
 546 # Readline
 547 #
 548 PGAC_ARG_BOOL(with, readline, yes,
 549               [  --without-readline      do not use GNU Readline nor BSD Libedit for editing])
 550 # readline on MinGW has problems with backslashes in psql and other bugs.
 551 # This is particularly a problem with non-US code pages.
 552 # Therefore disable its use until we understand the cause. 2004-07-20
 553 if test "$PORTNAME" = "win32"; then
 554   if test "$with_readline" = yes; then
 555     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 556     with_readline=no
 557   fi
 558 fi
 559
 560
 561 #
 562 # Prefer libedit
 563 #
 564 PGAC_ARG_BOOL(with, libedit-preferred, no,
 565               [  --with-libedit-preferred  prefer BSD Libedit over GNU Readline])
 566
 567
 568 #
 569 # OSSP UUID library
 570 #
 571 PGAC_ARG_BOOL(with, ossp-uuid, no, [  --with-ossp-uuid        use OSSP UUID library when building contrib/uuid-ossp])
 572 AC_SUBST(with_ossp_uuid)
 573
 574
 575 #
 576 # XML
 577 #
 578 PGAC_ARG_BOOL(with, libxml, no, [  --with-libxml           build with XML support],
 579               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 580
 581 if test "$with_libxml" = yes ; then
 582   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 583   if test -n "$XML2_CONFIG"; then
 584     for pgac_option in `$XML2_CONFIG --cflags`; do
 585       case $pgac_option in
 586         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 587       esac
 588     done
 589     for pgac_option in `$XML2_CONFIG --libs`; do
 590       case $pgac_option in
 591         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 592       esac
 593     done
 594   fi
 595 fi
 596
 597 AC_SUBST(with_libxml)
 598
 599 #
 600 # XSLT
 601 #
 602 PGAC_ARG_BOOL(with, libxslt, no, [  --with-libxslt          use XSLT support when building contrib/xml2],
 603               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 604
 605
 606 AC_SUBST(with_libxslt)
 607
 608 #
 609 # tzdata
 610 #
 611 PGAC_ARG_REQ(with, system-tzdata,
 612              [  --with-system-tzdata=DIR  use system time zone data in DIR])
 613 AC_SUBST(with_system_tzdata)
 614
 615 #
 616 # Zlib
 617 #
 618 PGAC_ARG_BOOL(with, zlib, yes,
 619               [  --without-zlib          do not use Zlib])
 620 AC_SUBST(with_zlib)
 621
 622 #
 623 # Elf
 624 #
 625
 626 # Assume system is ELF if it predefines __ELF__ as 1,
 627 # otherwise believe host_os based default.
 628 case $host_os in
 629     freebsd1*|freebsd2*) elf=no;;
 630     freebsd3*|freebsd4*) elf=yes;;
 631 esac
 632
 633 AC_EGREP_CPP(yes,
 634 [#if __ELF__
 635   yes
 636 #endif
 637 ],
 638 [ELF_SYS=true],
 639 [if test "X$elf" = "Xyes" ; then
 640   ELF_SYS=true
 641 else
 642   ELF_SYS=
 643 fi])
 644 AC_SUBST(ELF_SYS)
 645
 646 #
 647 # Assignments
 648 #
 649
 650 CPPFLAGS="$CPPFLAGS $INCLUDES"
 651 LDFLAGS="$LDFLAGS $LIBDIRS"
 652
 653 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 654 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 655
 656 AC_ARG_VAR(LDFLAGS_SL)
 657
 658 PGAC_PROG_LD
 659 AC_SUBST(LD)
 660 AC_SUBST(with_gnu_ld)
 661 case $host_os in sysv5*)
 662   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 663   [
 664     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 665     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 666     LDFLAGS=$pgac_save_LDFLAGS
 667   ])
 668   ld_R_works=$pgac_cv_prog_ld_R
 669   AC_SUBST(ld_R_works)
 670 esac
 671 AC_PROG_RANLIB
 672 PGAC_CHECK_STRIP
 673
 674 AC_PATH_PROG(TAR, tar)
 675 AC_PROG_LN_S
 676 AC_PROG_AWK
 677
 678 PGAC_PATH_YACC
 679 PGAC_PATH_FLEX
 680
 681 PGAC_PATH_PERL
 682 if test "$with_perl" = yes; then
 683   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 684   PGAC_CHECK_PERL_EMBED_LDFLAGS
 685 fi
 686
 687 if test "$with_python" = yes; then
 688   PGAC_PATH_PYTHON
 689   PGAC_CHECK_PYTHON_EMBED_SETUP
 690 fi
 691
 692 # Supply a numeric version string for use by 3rd party add-ons
 693 # awk -F is a regex on some platforms, and not on others, so make "." a tab
 694 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
 695 tr '.' '        ' |
 696 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
 697 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
 698
 699 ##
 700 ## Libraries
 701 ##
 702 ## Most libraries are included only if they demonstrably provide a function
 703 ## we need, but libm is an exception: always include it, because there are
 704 ## too many compilers that play cute optimization games that will break
 705 ## probes for standard functions such as pow().
 706 ##
 707
 708 AC_CHECK_LIB(m, main)
 709 AC_SEARCH_LIBS(setproctitle, util)
 710 AC_SEARCH_LIBS(dlopen, dl)
 711 AC_SEARCH_LIBS(socket, [socket wsock32])
 712 AC_SEARCH_LIBS(shl_load, dld)
 713 # We only use libld in port/dynloader/aix.c
 714 case $host_os in
 715      aix*)
 716         AC_SEARCH_LIBS(ldopen, ld)
 717         ;;
 718 esac
 719 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 720 AC_SEARCH_LIBS(crypt, crypt)
 721 # Solaris:
 722 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 723 # Cygwin:
 724 AC_SEARCH_LIBS(shmget, cygipc)
 725
 726 if test "$with_readline" = yes; then
 727   PGAC_CHECK_READLINE
 728   if test x"$pgac_cv_check_readline" = x"no"; then
 729     AC_MSG_ERROR([readline library not found
 730 If you have readline already installed, see config.log for details on the
 731 failure.  It is possible the compiler isn't looking in the proper directory.
 732 Use --without-readline to disable readline support.])
 733   fi
 734 fi
 735
 736 if test "$with_zlib" = yes; then
 737   AC_CHECK_LIB(z, inflate, [],
 738                [AC_MSG_ERROR([zlib library not found
 739 If you have zlib already installed, see config.log for details on the
 740 failure.  It is possible the compiler isn't looking in the proper directory.
 741 Use --without-zlib to disable zlib support.])])
 742 fi
 743
 744 if test "$enable_spinlocks" = yes; then
 745   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 746 else
 747   AC_MSG_WARN([
 748 *** Not using spinlocks will cause poor performance.])
 749 fi
 750
 751 if test "$with_gssapi" = yes ; then
 752   if test "$PORTNAME" != "win32"; then
 753     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
 754                                   [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 755   else
 756     LIBS="$LIBS -lgssapi32"
 757   fi
 758 fi
 759
 760 if test "$with_krb5" = yes ; then
 761   if test "$PORTNAME" != "win32"; then
 762      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken' com_err], [],
 763                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 764      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken'], [],
 765                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 766   else
 767      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 768                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 769   fi
 770 fi
 771
 772 if test "$with_openssl" = yes ; then
 773   dnl Order matters!
 774   if test "$PORTNAME" != "win32"; then
 775      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 776      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 777   else
 778      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 779      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 780   fi
 781 fi
 782
 783 if test "$with_pam" = yes ; then
 784   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 785 fi
 786
 787 if test "$with_libxml" = yes ; then
 788   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 789 fi
 790
 791 if test "$with_libxslt" = yes ; then
 792   AC_CHECK_LIB(xslt, xsltLibxmlVersion, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 793 fi
 794
 795 # for contrib/uuid-ossp
 796 if test "$with_ossp_uuid" = yes ; then
 797   AC_CHECK_LIB(ossp-uuid, uuid_export,
 798     [OSSP_UUID_LIBS="-lossp-uuid"],
 799     [AC_CHECK_LIB(uuid, uuid_export,
 800       [OSSP_UUID_LIBS="-luuid"],
 801       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP-UUID])])])
 802 fi
 803 AC_SUBST(OSSP_UUID_LIBS)
 804
 805
 806 ##
 807 ## Header files
 808 ##
 809
 810 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 811 AC_CHECK_HEADERS([crypt.h dld.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/tas.h sys/time.h sys/un.h termios.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 812
 813 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 814 # netinet/in.h is included first.
 815 AC_CHECK_HEADERS(netinet/in.h)
 816 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 817 [AC_INCLUDES_DEFAULT
 818 #ifdef HAVE_NETINET_IN_H
 819 #include <netinet/in.h>
 820 #endif
 821 ])
 822
 823 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 824   AC_CHECK_HEADERS(readline/readline.h, [],
 825         [AC_CHECK_HEADERS(readline.h, [],
 826                 [AC_MSG_ERROR([readline header not found
 827 If you have readline already installed, see config.log for details on the
 828 failure.  It is possible the compiler isn't looking in the proper directory.
 829 Use --without-readline to disable readline support.])])])
 830   AC_CHECK_HEADERS(readline/history.h, [],
 831         [AC_CHECK_HEADERS(history.h, [],
 832                 [AC_MSG_ERROR([history header not found
 833 If you have readline already installed, see config.log for details on the
 834 failure.  It is possible the compiler isn't looking in the proper directory.
 835 Use --without-readline to disable readline support.])])])
 836 fi
 837
 838 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 839 # Some installations of libedit usurp /usr/include/readline/, which seems
 840 # bad practice, since in combined installations readline will have its headers
 841 # there.  We might have to resort to AC_EGREP checks to make sure we found
 842 # the proper header...
 843   AC_CHECK_HEADERS(editline/readline.h, [],
 844         [AC_CHECK_HEADERS(readline.h, [],
 845                 [AC_CHECK_HEADERS(readline/readline.h, [],
 846                         [AC_MSG_ERROR([readline header not found
 847 If you have libedit already installed, see config.log for details on the
 848 failure.  It is possible the compiler isn't looking in the proper directory.
 849 Use --without-readline to disable libedit support.])])])])
 850 # Note: in a libedit installation, history.h is sometimes a dummy, and may
 851 # not be there at all.  Hence, don't complain if not found.  We must check
 852 # though, since in yet other versions it is an independent header.
 853   AC_CHECK_HEADERS(editline/history.h, [],
 854         [AC_CHECK_HEADERS(history.h, [],
 855                 [AC_CHECK_HEADERS(readline/history.h)])])
 856 fi
 857
 858 if test "$with_zlib" = yes; then
 859   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 860 If you have zlib already installed, see config.log for details on the
 861 failure.  It is possible the compiler isn't looking in the proper directory.
 862 Use --without-zlib to disable zlib support.])])
 863 fi
 864
 865 if test "$with_gssapi" = yes ; then
 866   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
 867         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
 868 fi
 869
 870 if test "$with_krb5" = yes ; then
 871   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 872 fi
 873
 874 if test "$with_openssl" = yes ; then
 875   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 876   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 877   AC_CHECK_FUNCS([ERR_set_mark])
 878 fi
 879
 880 if test "$with_pam" = yes ; then
 881   AC_CHECK_HEADERS(security/pam_appl.h, [],
 882                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 883                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 884 fi
 885
 886 if test "$with_libxml" = yes ; then
 887   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
 888 fi
 889
 890 if test "$with_libxslt" = yes ; then
 891   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
 892 fi
 893
 894 if test "$with_ldap" = yes ; then
 895   if test "$PORTNAME" != "win32"; then
 896      AC_CHECK_HEADERS(ldap.h, [],
 897                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
 898   else
 899      AC_CHECK_HEADERS(winldap.h, [],
 900                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
 901                       [AC_INCLUDES_DEFAULT
 902 #include <windows.h>
 903                       ])
 904   fi
 905 fi
 906
 907 if test "$with_bonjour" = yes ; then
 908   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
 909 fi
 910
 911 # for contrib/uuid-ossp
 912 if test "$with_ossp_uuid" = yes ; then
 913   AC_CHECK_HEADERS(ossp/uuid.h, [], [
 914     AC_CHECK_HEADERS(uuid.h, [],
 915       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP-UUID])])])
 916 fi
 917
 918
 919 ##
 920 ## Types, structures, compiler characteristics
 921 ##
 922
 923 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 924 AC_C_BIGENDIAN
 925 AC_C_CONST
 926 AC_C_INLINE
 927 AC_C_STRINGIZE
 928 PGAC_C_SIGNED
 929 AC_C_VOLATILE
 930 PGAC_C_FUNCNAME_SUPPORT
 931 PGAC_STRUCT_TIMEZONE
 932 PGAC_UNION_SEMUN
 933 PGAC_STRUCT_SOCKADDR_UN
 934 PGAC_STRUCT_SOCKADDR_STORAGE
 935 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 936 PGAC_STRUCT_ADDRINFO
 937
 938 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 939 [#include <sys/param.h>
 940 #include <sys/types.h>
 941 #include <sys/socket.h>
 942 #include <sys/ucred.h>])
 943
 944 AC_CHECK_TYPES([struct option], [], [],
 945 [#ifdef HAVE_GETOPT_H
 946 #include <getopt.h>
 947 #endif])
 948
 949 if test "$with_zlib" = yes; then
 950   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 951   # did not).  While we could work around the lack of z_streamp, it
 952   # seems unwise to encourage people to use such old zlib versions...
 953   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 954 Use --without-zlib to disable zlib support.])],
 955                 [#include <zlib.h>])
 956 fi
 957
 958 if test "$with_krb5" = yes; then
 959 # Check for differences between MIT and Heimdal (KTH) releases
 960   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 961                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 962                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 963                                      [#include <krb5.h>])],
 964                    [#include <krb5.h>])
 965   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 966                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 967                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 968                                      [#include <krb5.h>])],
 969                    [#include <krb5.h>])
 970
 971 # Win32 requires headers to be loaded for __stdcall, so can't use
 972 # AC_CHECK_FUNCS here.
 973   AC_MSG_CHECKING(for krb5_free_unparsed_name)
 974   AC_TRY_LINK([#include <krb5.h>],
 975               [krb5_free_unparsed_name(NULL,NULL);],
 976               [AC_DEFINE(HAVE_KRB5_FREE_UNPARSED_NAME, 1, [Define to 1 if you have krb5_free_unparsed_name])
 977 AC_MSG_RESULT(yes)],
 978               [AC_MSG_RESULT(no)])
 979 fi
 980
 981
 982 ##
 983 ## Functions, global variables
 984 ##
 985
 986 PGAC_VAR_INT_TIMEZONE
 987 AC_FUNC_ACCEPT_ARGTYPES
 988 PGAC_FUNC_GETTIMEOFDAY_1ARG
 989
 990 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid getrlimit memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
 991
 992 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 993 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
 994 AC_CHECK_DECLS([strlcat, strlcpy])
 995 # This is probably only present on Darwin, but may as well check always
 996 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
 997
 998 HAVE_IPV6=no
 999 AC_CHECK_TYPE([struct sockaddr_in6],
1000         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1001          HAVE_IPV6=yes],
1002         [],
1003 [$ac_includes_default
1004 #include <netinet/in.h>])
1005 AC_SUBST(HAVE_IPV6)
1006
1007 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1008 [AC_TRY_LINK(
1009 [#include <machine/vmparam.h>
1010 #include <sys/exec.h>
1011 ],
1012 [PS_STRINGS->ps_nargvstr = 1;
1013 PS_STRINGS->ps_argvstr = "foo";],
1014 [pgac_cv_var_PS_STRINGS=yes],
1015 [pgac_cv_var_PS_STRINGS=no])])
1016 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1017   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
1018 fi
1019
1020
1021 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1022 # is missing.  Yes, there are machines that have only one.  We may
1023 # also decide to use snprintf.c if snprintf() is present but does not
1024 # have all the features we need --- see below.
1025
1026 if test "$PORTNAME" = "win32"; then
1027   # Win32 gets snprintf.c built unconditionally.
1028   #
1029   # To properly translate all NLS languages strings, we must support the
1030   # *printf() %$ format, which allows *printf() arguments to be selected
1031   # by position in the translated string.
1032   #
1033   # libintl versions < 0.13 use the native *printf() functions, and Win32
1034   # *printf() doesn't understand %$, so we must use our /port versions,
1035   # which do understand %$. libintl versions >= 0.13 include their own
1036   # *printf versions on Win32.  The libintl 0.13 release note text is:
1037   #
1038   #   C format strings with positions, as they arise when a translator
1039   #   needs to reorder a sentence, are now supported on all platforms.
1040   #   On those few platforms (NetBSD and Woe32) for which the native
1041   #   printf()/fprintf()/... functions don't support such format
1042   #   strings, replacements are provided through <libintl.h>.
1043   #
1044   # We could use libintl >= 0.13's *printf() if we were sure that we had
1045   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1046   # to guarantee that, it is best to just use our own, so we are sure to
1047   # get %$ support. In include/port.h we disable the *printf() macros
1048   # that might have been defined by libintl.
1049   #
1050   # We do this unconditionally whether NLS is used or not so we are sure
1051   # that all Win32 libraries and binaries behave the same.
1052   pgac_need_repl_snprintf=yes
1053 else
1054   pgac_need_repl_snprintf=no
1055   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1056   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1057 fi
1058
1059
1060 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1061 # include/c.h will provide declarations.  Note this is a separate test
1062 # from whether the functions exist in the C library --- there are
1063 # systems that have the functions but don't bother to declare them :-(
1064
1065 AC_CHECK_DECLS([snprintf, vsnprintf])
1066
1067
1068 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1069 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1070 [AC_TRY_LINK([
1071 #include <math.h>
1072 double glob_double;
1073 ],
1074 [return isinf(glob_double) ? 0 : 1;],
1075 [ac_cv_func_isinf=yes],
1076 [ac_cv_func_isinf=no])])
1077
1078 if test $ac_cv_func_isinf = yes ; then
1079   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1080 else
1081   AC_LIBOBJ(isinf)
1082   # Look for a way to implement a substitute for isinf()
1083   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1084 fi
1085
1086 # Some versions of libedit contain strlcpy(); so disregard that library while
1087 # checking for these standard libc functions.
1088 pgac_save_LIBS="$LIBS"
1089 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1090
1091 AC_REPLACE_FUNCS([crypt getopt getrusage inet_aton random rint srandom strdup strerror strlcat strlcpy strtol strtoul unsetenv])
1092
1093 LIBS="$pgac_save_LIBS"
1094
1095 # System's version of getaddrinfo(), if any, may be used only if we found
1096 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1097 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1098 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1099 # because we want to use our own getaddrinfo.c on Windows anyway.)
1100 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1101   AC_REPLACE_FUNCS([getaddrinfo])
1102 else
1103   AC_LIBOBJ(getaddrinfo)
1104 fi
1105
1106 # Similarly, use system's getopt_long() only if system provides struct option.
1107 # Solaris' getopt() doesn't do what we want for long options, so always use
1108 # our versions on that platform.
1109 if test "$PORTNAME" = "solaris"; then
1110   AC_LIBOBJ(getopt)
1111   AC_LIBOBJ(getopt_long)
1112 elif test x"$ac_cv_type_struct_option" = xyes ; then
1113   AC_REPLACE_FUNCS([getopt_long])
1114 else
1115   AC_LIBOBJ(getopt_long)
1116 fi
1117
1118 # Win32 support
1119 if test "$PORTNAME" = "win32"; then
1120 AC_REPLACE_FUNCS(gettimeofday)
1121 AC_LIBOBJ(kill)
1122 AC_LIBOBJ(open)
1123 AC_LIBOBJ(rand)
1124 AC_LIBOBJ(win32error)
1125 AC_DEFINE([HAVE_SYMLINK], 1,
1126           [Define to 1 if you have the `symlink' function.])
1127 fi
1128
1129 if test "$with_readline" = yes; then
1130   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1131   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1132   AC_CHECK_FUNCS([replace_history_entry])
1133 fi
1134
1135
1136 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1137 dnl (especially on GNU libc)
1138 dnl See also comments in c.h.
1139 AC_MSG_CHECKING(for sigsetjmp)
1140 AC_TRY_LINK([#include <setjmp.h>],
1141             [sigjmp_buf x; sigsetjmp(x, 1);],
1142             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1143 AC_MSG_RESULT(yes)],
1144             [AC_MSG_RESULT(no)])
1145
1146 AC_DECL_SYS_SIGLIST
1147
1148 AC_CHECK_FUNC(syslog,
1149               [AC_CHECK_HEADER(syslog.h,
1150                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1151
1152 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1153 [AC_TRY_LINK([#include <unistd.h>],
1154   [extern int optreset; optreset = 1;],
1155   [pgac_cv_var_int_optreset=yes],
1156   [pgac_cv_var_int_optreset=no])])
1157 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1158   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1159 fi
1160
1161 AC_CHECK_FUNCS([strtoll strtoq], [break])
1162 AC_CHECK_FUNCS([strtoull strtouq], [break])
1163
1164 # Check for one of atexit() or on_exit()
1165 AC_CHECK_FUNCS(atexit, [],
1166                [AC_CHECK_FUNCS(on_exit, [],
1167                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1168
1169 AC_REPLACE_FUNCS(fseeko)
1170 case $host_os in
1171         # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
1172         bsdi*|netbsd*)
1173                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1174                 ac_cv_func_fseeko=yes;;
1175         *)
1176                 AC_FUNC_FSEEKO;;
1177 esac
1178
1179
1180 #
1181 # Pthreads
1182 #
1183 # For each platform, we need to know about any special compile and link
1184 # libraries, and whether the normal C function names are thread-safe.
1185 # See the comment at the top of src/port/thread.c for more information.
1186 # WIN32 doesn't need the pthread tests;  it always uses threads
1187 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1188 ACX_PTHREAD     # set thread flags
1189
1190 # Some platforms use these, so just defineed them.  They can't hurt if they
1191 # are not supported.
1192 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1193
1194
1195 # At this point, we don't want to muck with the compiler name for threading.
1196 # Let's see who fails, perhaps AIX.  2004-04-23
1197 if test "$PTHREAD_CC" != "$CC"; then
1198 AC_MSG_ERROR([
1199 PostgreSQL does not support platforms that require a special compiler
1200 for thread safety.])
1201 fi
1202
1203 if test "$THREAD_SUPPORT" = no; then
1204 AC_MSG_ERROR([cannot enable threads on this platform
1205 This platform is known to not support thread-safe programs.  For details,
1206 compile and run src/bin/pg_thread_test.])
1207 fi
1208
1209 # Check for *_r functions
1210 _CFLAGS="$CFLAGS"
1211 _LIBS="$LIBS"
1212 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1213 LIBS="$LIBS $PTHREAD_LIBS"
1214
1215 if test "$PORTNAME" != "win32"; then
1216 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1217 fi
1218
1219 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1220
1221 # Do test here with the proper thread flags
1222 PGAC_FUNC_GETPWUID_R_5ARG
1223 PGAC_FUNC_STRERROR_R_INT
1224
1225 CFLAGS="$_CFLAGS"
1226 LIBS="$_LIBS"
1227
1228 else
1229 # do not use values from template file
1230 PTHREAD_CFLAGS=
1231 PTHREAD_LIBS=
1232 fi
1233
1234 AC_SUBST(PTHREAD_CFLAGS)
1235 AC_SUBST(PTHREAD_LIBS)
1236
1237
1238 # We can test for libldap_r only after we know PTHREAD_LIBS
1239 if test "$with_ldap" = yes ; then
1240   _LIBS="$LIBS"
1241   if test "$PORTNAME" != "win32"; then
1242     AC_CHECK_LIB(ldap, ldap_bind, [],
1243                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1244                  [$EXTRA_LDAP_LIBS])
1245     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1246     if test "$enable_thread_safety" = yes; then
1247       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1248       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1249                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1250                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1251       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1252     else
1253       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1254     fi
1255   else
1256     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1257     LDAP_LIBS_FE="-lwldap32"
1258     LDAP_LIBS_BE="-lwldap32"
1259   fi
1260   LIBS="$_LIBS"
1261 fi
1262 AC_SUBST(LDAP_LIBS_FE)
1263 AC_SUBST(LDAP_LIBS_BE)
1264
1265
1266 # This test makes sure that run tests work at all.  Sometimes a shared
1267 # library is found by the linker, but the runtime linker can't find it.
1268 # This check should come after all modifications of compiler or linker
1269 # variables, and before any other run tests.
1270 AC_MSG_CHECKING([test program])
1271 AC_TRY_RUN([int main() { return 0; }],
1272 [AC_MSG_RESULT(ok)],
1273 [AC_MSG_RESULT(failed)
1274 AC_MSG_ERROR([[
1275 Could not execute a simple test program.  This may be a problem
1276 related to locating shared libraries.  Check the file 'config.log'
1277 for the exact reason.]])],
1278 [AC_MSG_RESULT([cross-compiling])])
1279
1280 # --------------------
1281 # Run tests below here
1282 # --------------------
1283
1284 # Force use of our snprintf if system's doesn't do arg control
1285 # See comment above at snprintf test for details.
1286 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1287   PGAC_FUNC_PRINTF_ARG_CONTROL
1288   if test $pgac_cv_printf_arg_control != yes ; then
1289     pgac_need_repl_snprintf=yes
1290   fi
1291 fi
1292
1293
1294 dnl Check to see if we have a working 64-bit integer type.
1295 dnl This breaks down into two steps:
1296 dnl (1) figure out if the compiler has a 64-bit int type with working
1297 dnl arithmetic, and if so
1298 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1299 dnl snprintf is the only library routine we really need for int8 support.)
1300 dnl It's entirely possible to have a compiler that handles a 64-bit type
1301 dnl when the C library doesn't; this is fairly likely when using gcc on
1302 dnl an older platform, for example.
1303 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1304 dnl we force our own version of snprintf() to be used instead.
1305 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1306
1307 PGAC_TYPE_64BIT_INT([long int])
1308
1309 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1310   PGAC_TYPE_64BIT_INT([long long int])
1311 fi
1312
1313
1314 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1315
1316 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1317   AC_TRY_COMPILE([
1318 #define INT64CONST(x)  x##LL
1319 long long int foo = INT64CONST(0x1234567890123456);
1320 ],
1321         [],
1322         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1323         [])
1324 fi
1325
1326
1327 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1328 # we found we need to use "long long int", better check.  We cope with
1329 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1330 # work, fall back to our own snprintf emulation (which we know uses %lld).
1331
1332 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1333   if test $pgac_need_repl_snprintf = no; then
1334     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1335     if test "$LONG_LONG_INT_FORMAT" = ""; then
1336       # Force usage of our own snprintf, since system snprintf is broken
1337       pgac_need_repl_snprintf=yes
1338       LONG_LONG_INT_FORMAT='%lld'
1339     fi
1340   else
1341     # Here if we previously decided we needed to use our own snprintf
1342     LONG_LONG_INT_FORMAT='%lld'
1343   fi
1344   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1345   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1346   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1347 else
1348   # Here if we are not using 'long long int' at all
1349   INT64_FORMAT='"%ld"'
1350   UINT64_FORMAT='"%lu"'
1351 fi
1352
1353 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1354                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1355
1356 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1357                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1358
1359 # Now we have checked all the reasons to replace snprintf
1360 if test $pgac_need_repl_snprintf = yes; then
1361   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1362   AC_LIBOBJ(snprintf)
1363 fi
1364
1365 # Need a #define for the size of Datum (unsigned long)
1366 AC_CHECK_SIZEOF([unsigned long])
1367
1368 # And one for the size of size_t (enables tweaks for > 32bit address space)
1369 AC_CHECK_SIZEOF([size_t])
1370
1371 # Determine memory alignment requirements for the basic C data types.
1372
1373 AC_CHECK_ALIGNOF(short)
1374 AC_CHECK_ALIGNOF(int)
1375 AC_CHECK_ALIGNOF(long)
1376 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1377   AC_CHECK_ALIGNOF(long long int)
1378 fi
1379 AC_CHECK_ALIGNOF(double)
1380
1381 # Compute maximum alignment of any basic type.
1382 # We assume long's alignment is at least as strong as char, short, or int;
1383 # but we must check long long (if it exists) and double.
1384
1385 MAX_ALIGNOF=$ac_cv_alignof_long
1386 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1387   MAX_ALIGNOF=$ac_cv_alignof_double
1388 fi
1389 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1390   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1391 fi
1392 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1393
1394
1395 # Some platforms predefine the types int8, int16, etc.  Only check
1396 # a (hopefully) representative subset.
1397 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1398 [#include <stdio.h>
1399 #ifdef HAVE_SUPPORTDEFS_H
1400 #include <SupportDefs.h>
1401 #endif])
1402
1403 # We also check for sig_atomic_t, which *should* be defined per ANSI
1404 # C, but is missing on some old platforms.
1405 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1406
1407
1408 if test "$PORTNAME" != "win32"
1409 then
1410 PGAC_FUNC_POSIX_SIGNALS
1411 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1412   AC_MSG_ERROR([
1413 Thread-safety requires POSIX signals, which are not supported by this
1414 operating system.])
1415 fi
1416 fi
1417
1418 if test $ac_cv_func_fseeko = yes; then
1419 AC_SYS_LARGEFILE
1420 fi
1421
1422 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1423 AC_CHECK_SIZEOF([off_t])
1424
1425 if test "$ac_cv_sizeof_off_t" -lt 8 -o "$enable_segmented_files" = "yes"; then
1426   AC_DEFINE([USE_SEGMENTED_FILES], 1, [Define to split data files into 1GB segments.])
1427 fi
1428
1429 # SunOS doesn't handle negative byte comparisons properly with +/- return
1430 AC_FUNC_MEMCMP
1431
1432
1433 # Select semaphore implementation type.
1434 if test "$PORTNAME" != "win32"; then
1435   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1436     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1437     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1438   else
1439     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1440       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1441       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1442     else
1443       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1444       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1445     fi
1446   fi
1447 else
1448   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1449   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1450 fi
1451
1452
1453 # Select shared-memory implementation type.
1454 if test "$PORTNAME" != "win32"; then
1455   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1456   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1457 else
1458   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1459   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1460 fi
1461
1462 # If not set in template file, set bytes to use libc memset()
1463 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1464   MEMSET_LOOP_LIMIT=1024
1465 fi
1466 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1467
1468
1469 if test "$enable_nls" = yes ; then
1470   PGAC_CHECK_GETTEXT
1471 fi
1472
1473 # Check for Tcl configuration script tclConfig.sh
1474 if test "$with_tcl" = yes; then
1475     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1476     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1477                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1478     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1479     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1480     ac_save_CPPFLAGS=$CPPFLAGS
1481     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1482     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1483     CPPFLAGS=$ac_save_CPPFLAGS
1484 fi
1485
1486 #
1487 # Check for DocBook and tools
1488 #
1489 PGAC_PROG_NSGMLS
1490 PGAC_PROG_JADE
1491 PGAC_CHECK_DOCBOOK(4.2)
1492 PGAC_PATH_DOCBOOK_STYLESHEETS
1493 PGAC_PATH_COLLATEINDEX
1494 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1495
1496 # Thread testing
1497
1498 # We have to run the thread test near the end so we have all our symbols
1499 # defined.  Cross compiling throws a warning.
1500 #
1501 if test "$enable_thread_safety_force" = yes; then
1502 if test "$PORTNAME" != "win32"
1503 then
1504   AC_MSG_WARN([
1505 *** Skipping thread test program.  --enable-thread-safety-force was used.
1506 *** Run the program in src/test/thread on the your machine and add proper
1507 *** locking function calls to your applications to guarantee thread safety.
1508 ])
1509 else
1510 AC_MSG_WARN([*** skipping thread test on Win32])
1511 fi
1512 elif test "$enable_thread_safety" = yes; then
1513 if test "$PORTNAME" != "win32"
1514 then
1515 AC_MSG_CHECKING([thread safety of required library functions])
1516
1517 _CFLAGS="$CFLAGS"
1518 _LIBS="$LIBS"
1519 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1520 LIBS="$LIBS $PTHREAD_LIBS"
1521 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1522   [AC_MSG_RESULT(yes)],
1523   [AC_MSG_RESULT(no)
1524   AC_MSG_ERROR([thread test program failed
1525 This platform is not thread-safe.  Check the file 'config.log'for the
1526 exact reason.
1527
1528 You can use the configure option --enable-thread-safety-force to force
1529 threads to be enabled.  But you must then run the program in
1530 src/test/thread and add locking function calls to your applications to
1531 guarantee thread safety.])],
1532   [AC_MSG_RESULT(maybe)
1533   AC_MSG_WARN([
1534 *** Skipping thread test program because of cross-compile build.
1535 *** Run the program in src/test/thread on the target machine.
1536 ])])
1537 CFLAGS="$_CFLAGS"
1538 LIBS="$_LIBS"
1539 else
1540 AC_MSG_WARN([*** skipping thread test on Win32])
1541 fi
1542 fi
1543
1544 # prepare build tree if outside source tree
1545 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1546 # Note 2: /bin/pwd might be better than shell's built-in at getting
1547 #         a symlink-free name.
1548 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1549   vpath_build=no
1550 else
1551   vpath_build=yes
1552   if test "$no_create" != yes; then
1553     _AS_ECHO_N([preparing build tree... ])
1554     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1555     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1556       || AC_MSG_ERROR(failed)
1557     AC_MSG_RESULT(done)
1558   fi
1559 fi
1560 AC_SUBST(vpath_build)
1561
1562
1563 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1564
1565 AC_CONFIG_LINKS([
1566   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1567   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1568   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1569   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1570   src/include/pg_config_os.h:src/include/port/${template}.h
1571   src/Makefile.port:src/makefiles/Makefile.${template}
1572 ])
1573
1574 if test "$PORTNAME" = "win32"; then
1575 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1576 # Links sometimes fail undetected on Mingw -
1577 # so here we detect it and warn the user
1578 for FILE in $CONFIG_LINKS
1579  do
1580         # test -e works for symlinks in the MinGW console
1581         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1582  done
1583 ])
1584 fi
1585
1586 AC_CONFIG_HEADERS([src/include/pg_config.h],
1587 [
1588 # Update timestamp for pg_config.h (see Makefile.global)
1589 echo >src/include/stamp-h
1590 ])
1591
1592 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h])
1593
1594 AC_OUTPUT
1595
1596 # Warn about unknown options
1597 PGAC_ARG_CHECK