runtime/plugin/matchparen.vim

   1 " Vim plugin for showing matching parens
   2 " Maintainer:  Bram Moolenaar <Bram@vim.org>
   3 " Last Change: 2007 Aug 8
   4
   5 " Exit quickly when:
   6 " - this plugin was already loaded (or disabled)
   7 " - when 'compatible' is set
   8 " - the "CursorMoved" autocmd event is not availble.
   9 if exists("g:loaded_matchparen") || &cp || !exists("##CursorMoved")
  10   finish
  11 endif
  12 let g:loaded_matchparen = 1
  13
  14 augroup matchparen
  15   " Replace all matchparen autocommands
  16   autocmd! CursorMoved,CursorMovedI,WinEnter * call s:Highlight_Matching_Pair()
  17 augroup END
  18
  19 " Skip the rest if it was already done.
  20 if exists("*s:Highlight_Matching_Pair")
  21   finish
  22 endif
  23
  24 let cpo_save = &cpo
  25 set cpo-=C
  26
  27 " The function that is invoked (very often) to define a ":match" highlighting
  28 " for any matching paren.
  29 function! s:Highlight_Matching_Pair()
  30   " Remove any previous match.
  31   if exists('w:paren_hl_on') && w:paren_hl_on
  32     3match none
  33     let w:paren_hl_on = 0
  34   endif
  35
  36   " Avoid that we remove the popup menu.
  37   if pumvisible()
  38     return
  39   endif
  40
  41   " Get the character under the cursor and check if it's in 'matchpairs'.
  42   let c_lnum = line('.')
  43   let c_col = col('.')
  44   let before = 0
  45
  46   let c = getline(c_lnum)[c_col - 1]
  47   let plist = split(&matchpairs, '.\zs[:,]')
  48   let i = index(plist, c)
  49   if i < 0
  50     " not found, in Insert mode try character before the cursor
  51     if c_col > 1 && (mode() == 'i' || mode() == 'R')
  52       let before = 1
  53       let c = getline(c_lnum)[c_col - 2]
  54       let i = index(plist, c)
  55     endif
  56     if i < 0
  57       " not found, nothing to do
  58       return
  59     endif
  60   endif
  61
  62   " Figure out the arguments for searchpairpos().
  63   " Restrict the search to visible lines with "stopline".
  64   " And avoid searching very far (e.g., for closed folds and long lines)
  65   " The "viewable" variables give a range in which we can scroll while keeping
  66   " the cursor at the same position
  67   " adjustedScrolloff accounts for very large numbers of scrolloff
  68   let adjustedScrolloff = min([&scrolloff, (line('w$') - line('w0')) / 2])
  69   let bottom_viewable = min([line('$'), c_lnum + &lines - adjustedScrolloff - 2])
  70   let top_viewable = max([1, c_lnum-&lines+adjustedScrolloff + 2])
  71   " one of these stoplines will be adjusted below, but the current values are
  72   " minimal boundaries within the current window
  73   let stoplinebottom = line('w$')
  74   let stoplinetop = line('w0')
  75   if i % 2 == 0
  76     let s_flags = 'nW'
  77     let c2 = plist[i + 1]
  78     if has("byte_offset") && has("syntax_items") && &smc > 0
  79       let stopbyte = min([line2byte("$"), line2byte(".") + col(".") + &smc * 2])
  80       let stopline = min([bottom_viewable, byte2line(stopbyte)])
  81     else
  82       let stopline = min([bottom_viewable, c_lnum + 100])
  83     endif
  84     let stoplinebottom = stopline
  85   else
  86     let s_flags = 'nbW'
  87     let c2 = c
  88     let c = plist[i - 1]
  89     if has("byte_offset") && has("syntax_items") && &smc > 0
  90       let stopbyte = max([1, line2byte(".") + col(".") - &smc * 2])
  91       let stopline = max([top_viewable, byte2line(stopbyte)])
  92     else
  93       let stopline = max([top_viewable, c_lnum - 100])
  94     endif
  95     let stoplinetop = stopline
  96   endif
  97   if c == '['
  98     let c = '\['
  99     let c2 = '\]'
 100   endif
 101
 102   " Find the match.  When it was just before the cursor move it there for a
 103   " moment.
 104   if before > 0
 105     let save_cursor = winsaveview()
 106     call cursor(c_lnum, c_col - before)
 107   endif
 108
 109   " When not in a string or comment ignore matches inside them.
 110   let s_skip ='synIDattr(synID(line("."), col("."), 0), "name") ' .
 111         \ '=~?  "string\\|character\\|singlequote\\|comment"'
 112   execute 'if' s_skip '| let s_skip = 0 | endif'
 113
 114   let [m_lnum, m_col] = searchpairpos(c, '', c2, s_flags, s_skip, stopline)
 115
 116   if before > 0
 117     call winrestview(save_cursor)
 118   endif
 119
 120   " If a match is found setup match highlighting.
 121   if m_lnum > 0 && m_lnum >= stoplinetop && m_lnum <= stoplinebottom
 122     exe '3match MatchParen /\(\%' . c_lnum . 'l\%' . (c_col - before) .
 123           \ 'c\)\|\(\%' . m_lnum . 'l\%' . m_col . 'c\)/'
 124     let w:paren_hl_on = 1
 125   endif
 126 endfunction
 127
 128 " Define commands that will disable and enable the plugin.
 129 command! NoMatchParen windo 3match none | unlet! g:loaded_matchparen |
 130           \ au! matchparen
 131 command! DoMatchParen runtime plugin/matchparen.vim | windo doau CursorMoved
 132
 133 let &cpo = cpo_save