| blob | e7b93787c972bb8171290305c2745760eaf65b7b |
1 *map.txt* For Vim version 7.2. Last change: 2008 Aug 09
4 VIM REFERENCE MANUAL by Bram Moolenaar
7 Key mapping, abbreviations and user-defined commands.
9 This subject is introduced in sections |05.3|, |24.7| and |40.1| of the user
10 manual.
12 1. Key mapping |key-mapping|
13 1.1 MAP COMMANDS |:map-commands|
14 1.2 Special arguments |:map-arguments|
15 1.3 Mapping and modes |:map-modes|
16 1.4 Listing mappings |map-listing|
17 1.5 Mapping special keys |:map-special-keys|
18 1.6 Special characters |:map-special-chars|
19 1.7 What keys to map |map-which-keys|
20 1.8 Examples |map-examples|
21 1.9 Using mappings |map-typing|
22 1.10 Mapping alt-keys |:map-alt-keys|
23 1.11 Mapping an operator |:map-operator|
24 2. Abbreviations |abbreviations|
25 3. Local mappings and functions |script-local|
26 4. User-defined commands |user-commands|
28 ==============================================================================
29 1. Key mapping *key-mapping* *mapping* *macro*
31 Key mapping is used to change the meaning of typed keys. The most common use
32 is to define a sequence commands for a function key. Example: >
34 :map <F2> a<C-R>=strftime("%c")<CR><Esc>
36 This appends the current date and time after the cursor (in <> notation |<>|).
39 1.1 MAP COMMANDS *:map-commands*
41 There are commands to enter new mappings, remove mappings and list mappings.
42 See |map-overview| for the various forms of "map" and their relationships with
43 modes.
45 {lhs} means left-hand-side *{lhs}*
46 {rhs} means right-hand-side *{rhs}*
48 :map {lhs} {rhs} |mapmode-nvo| *:map*
49 :nm[ap] {lhs} {rhs} |mapmode-n| *:nm* *:nmap*
50 :vm[ap] {lhs} {rhs} |mapmode-v| *:vm* *:vmap*
51 :xm[ap] {lhs} {rhs} |mapmode-x| *:xm* *:xmap*
52 :smap {lhs} {rhs} |mapmode-s| *:smap*
53 :om[ap] {lhs} {rhs} |mapmode-o| *:om* *:omap*
54 :map! {lhs} {rhs} |mapmode-ic| *:map!*
55 :im[ap] {lhs} {rhs} |mapmode-i| *:im* *:imap*
56 :lm[ap] {lhs} {rhs} |mapmode-l| *:lm* *:lmap*
57 :cm[ap] {lhs} {rhs} |mapmode-c| *:cm* *:cmap*
58 Map the key sequence {lhs} to {rhs} for the modes
59 where the map command applies. The result, including
60 {rhs}, is then further scanned for mappings. This
61 allows for nested and recursive use of mappings.
64 :no[remap] {lhs} {rhs} |mapmode-nvo| *:no* *:noremap*
65 :nn[oremap] {lhs} {rhs} |mapmode-n| *:nn* *:nnoremap*
66 :vn[oremap] {lhs} {rhs} |mapmode-v| *:vn* *:vnoremap*
67 :xn[oremap] {lhs} {rhs} |mapmode-x| *:xn* *:xnoremap*
68 :snor[emap] {lhs} {rhs} |mapmode-s| *:snor* *:snoremap*
69 :ono[remap] {lhs} {rhs} |mapmode-o| *:ono* *:onoremap*
70 :no[remap]! {lhs} {rhs} |mapmode-ic| *:no!* *:noremap!*
71 :ino[remap] {lhs} {rhs} |mapmode-i| *:ino* *:inoremap*
72 :ln[oremap] {lhs} {rhs} |mapmode-l| *:ln* *:lnoremap*
73 :cno[remap] {lhs} {rhs} |mapmode-c| *:cno* *:cnoremap*
74 Map the key sequence {lhs} to {rhs} for the modes
75 where the map command applies. Disallow mapping of
76 {rhs}, to avoid nested and recursive mappings. Often
77 used to redefine a command. {not in Vi}
80 :unm[ap] {lhs} |mapmode-nvo| *:unm* *:unmap*
81 :nun[map] {lhs} |mapmode-n| *:nun* *:nunmap*
82 :vu[nmap] {lhs} |mapmode-v| *:vu* *:vunmap*
83 :xu[nmap] {lhs} |mapmode-x| *:xu* *:xunmap*
84 :sunm[ap] {lhs} |mapmode-s| *:sunm* *:sunmap*
85 :ou[nmap] {lhs} |mapmode-o| *:ou* *:ounmap*
86 :unm[ap]! {lhs} |mapmode-ic| *:unm!* *:unmap!*
87 :iu[nmap] {lhs} |mapmode-i| *:iu* *:iunmap*
88 :lu[nmap] {lhs} |mapmode-l| *:lu* *:lunmap*
89 :cu[nmap] {lhs} |mapmode-c| *:cu* *:cunmap*
90 Remove the mapping of {lhs} for the modes where the
91 map command applies. The mapping may remain defined
92 for other modes where it applies.
93 Note: Trailing spaces are included in the {lhs}. This
94 unmap does NOT work: >
95 :map @@ foo
96 :unmap @@ | print
98 :mapc[lear] |mapmode-nvo| *:mapc* *:mapclear*
99 :nmapc[lear] |mapmode-n| *:nmapc* *:nmapclear*
100 :vmapc[lear] |mapmode-v| *:vmapc* *:vmapclear*
101 :xmapc[lear] |mapmode-x| *:xmapc* *:xmapclear*
102 :smapc[lear] |mapmode-s| *:smapc* *:smapclear*
103 :omapc[lear] |mapmode-o| *:omapc* *:omapclear*
104 :mapc[lear]! |mapmode-ic| *:mapc!* *:mapclear!*
105 :imapc[lear] |mapmode-i| *:imapc* *:imapclear*
106 :lmapc[lear] |mapmode-l| *:lmapc* *:lmapclear*
107 :cmapc[lear] |mapmode-c| *:cmapc* *:cmapclear*
108 Remove ALL mappings for the modes where the map
109 command applies. {not in Vi}
110 Warning: This also removes the default mappings.
112 :map |mapmode-nvo|
113 :nm[ap] |mapmode-n|
114 :vm[ap] |mapmode-v|
115 :xm[ap] |mapmode-x|
116 :sm[ap] |mapmode-s|
117 :om[ap] |mapmode-o|
118 :map! |mapmode-ic|
119 :im[ap] |mapmode-i|
120 :lm[ap] |mapmode-l|
121 :cm[ap] |mapmode-c|
122 List all key mappings for the modes where the map
123 command applies. Note that ":map" and ":map!" are
124 used most often, because they include the other modes.
126 :map {lhs} |mapmode-nvo| *:map_l*
127 :nm[ap] {lhs} |mapmode-n| *:nmap_l*
128 :vm[ap] {lhs} |mapmode-v| *:vmap_l*
129 :xm[ap] {lhs} |mapmode-x| *:xmap_l*
130 :sm[ap] {lhs} |mapmode-s| *:smap_l*
131 :om[ap] {lhs} |mapmode-o| *:omap_l*
132 :map! {lhs} |mapmode-ic| *:map_l!*
133 :im[ap] {lhs} |mapmode-i| *:imap_l*
134 :lm[ap] {lhs} |mapmode-l| *:lmap_l*
135 :cm[ap] {lhs} |mapmode-c| *:cmap_l*
136 List the key mappings for the key sequences starting
137 with {lhs} in the modes where the map command applies.
138 {not in Vi}
140 These commands are used to map a key or key sequence to a string of
141 characters. You can use this to put command sequences under function keys,
142 translate one key into another, etc. See |:mkexrc| for how to save and
143 restore the current mappings.
145 *map-ambiguous*
146 When two mappings start with the same sequence of characters, they are
147 ambiguous. Example: >
148 :imap aa foo
149 :imap aaa bar
150 When Vim has read "aa", it will need to get another character to be able to
151 decide if "aa" or "aaa" should be mapped. This means that after typing "aa"
152 that mapping won't get expanded yet, Vim is waiting for another character.
153 If you type a space, then "foo" will get inserted, plus the space. If you
154 type "a", then "bar" will get inserted.
155 {Vi does not allow ambiguous mappings}
158 1.2 SPECIAL ARGUMENTS *:map-arguments*
160 "<buffer>", "<silent>", "<special>", "<script>", "<expr>" and "<unique>" can
161 be used in any order. They must appear right after the command, before any
162 other arguments.
164 *:map-local* *:map-<buffer>* *E224* *E225*
165 If the first argument to one of these commands is "<buffer>" the mapping will
166 be effective in the current buffer only. Example: >
167 :map <buffer> ,w /[.,;]<CR>
168 Then you can map ",w" to something else in another buffer: >
169 :map <buffer> ,w /[#&!]<CR>
170 The local buffer mappings are used before the global ones.
171 The "<buffer>" argument can also be used to clear mappings: >
172 :unmap <buffer> ,w
173 :mapclear <buffer>
174 Local mappings are also cleared when a buffer is deleted, but not when it is
175 unloaded. Just like local option values.
177 *:map-<silent>* *:map-silent*
178 To define a mapping which will not be echoed on the command line, add
179 "<silent>" as the first argument. Example: >
180 :map <silent> ,h /Header<CR>
181 The search string will not be echoed when using this mapping. Messages from
182 the executed command are still given though. To shut them up too, add a
183 ":silent" in the executed command: >
184 :map <silent> ,h :exe ":silent normal /Header\r"<CR>
185 Prompts will still be given, e.g., for inputdialog().
186 Using "<silent>" for an abbreviation is possible, but will cause redrawing of
187 the command line to fail.
189 *:map-<special>* *:map-special*
190 Define a mapping with <> notation for special keys, even though the "<" flag
191 may appear in 'cpoptions'. This is useful if the side effect of setting
192 'cpoptions' is not desired. Example: >
193 :map <special> <F12> /Header<CR>
194 <
195 *:map-<script>* *:map-script*
196 If the first argument to one of these commands is "<script>" and it is used to
197 define a new mapping or abbreviation, the mapping will only remap characters
198 in the {rhs} using mappings that were defined local to a script, starting with
199 "<SID>". This can be used to avoid that mappings from outside a script
200 interfere (e.g., when CTRL-V is remapped in mswin.vim), but do use other
201 mappings defined in the script.
202 Note: ":map <script>" and ":noremap <script>" do the same thing. The
203 "<script>" overrules the command name. Using ":noremap <script>" is
204 preferred, because it's clearer that remapping is (mostly) disabled.
206 *:map-<unique>* *E226* *E227*
207 If the first argument to one of these commands is "<unique>" and it is used to
208 define a new mapping or abbreviation, the command will fail if the mapping or
209 abbreviation already exists. Example: >
210 :map <unique> ,w /[#&!]<CR>
211 When defining a local mapping, there will also be a check if a global map
212 already exists which is equal.
213 Example of what will fail: >
214 :map ,w /[#&!]<CR>
215 :map <buffer> <unique> ,w /[.,;]<CR>
216 If you want to map a key and then have it do what it was originally mapped to,
217 have a look at |maparg()|.
219 *:map-<expr>* *:map-expression*
220 If the first argument to one of these commands is "<expr>" and it is used to
221 define a new mapping or abbreviation, the argument is an expression. The
222 expression is evaluated to obtain the {rhs} that is used. Example: >
223 :inoremap <expr> . InsertDot()
224 The result of the InsertDot() function will be inserted. It could check the
225 text before the cursor and start omni completion when some condition is met.
227 For abbreviations |v:char| is set to the character that was typed to trigger
228 the abbreviation. You can use this to decide how to expand the {lhs}. You
229 can't change v:char and you should not insert it.
231 Be very careful about side effects! The expression is evaluated while
232 obtaining characters, you may very well make the command dysfunctional.
233 For this reason the following is blocked:
234 - Changing the buffer text |textlock|.
235 - Editing another buffer.
236 - The |:normal| command.
237 - Moving the cursor is allowed, but it is restored afterwards.
238 - You can use getchar(), but the existing typeahead isn't seen and new
239 typeahead is discarded.
240 If you want the mapping to do any of these let the returned characters do
241 that.
243 Here is an example that inserts a list number that increases: >
244 let counter = 0
245 inoremap <expr> <C-L> ListItem()
246 inoremap <expr> <C-R> ListReset()
248 func ListItem()
249 let g:counter += 1
250 return g:counter . '. '
251 endfunc
253 func ListReset()
254 let g:counter = 0
255 return ''
256 endfunc
258 CTRL-L inserts the next number, CTRL-R resets the count. CTRL-R returns an
259 empty string, so that nothing is inserted.
261 Note that there are some tricks to make special keys work and escape CSI bytes
262 in the text. The |:map| command also does this, thus you must avoid that it
263 is done twice. This does not work: >
264 :imap <expr> <F3> "<Char-0x611B>"
265 Because the <Char- sequence is escaped for being a |:imap| argument and then
266 again for using <expr>. This does work: >
267 :imap <expr> <F3> "\u611B"
268 Using 0x80 as a single byte before other text does not work, it will be seen
269 as a special key.
272 1.3 MAPPING AND MODES *:map-modes*
273 *mapmode-nvo* *mapmode-n* *mapmode-v* *mapmode-o*
275 There are five sets of mappings
276 - For Normal mode: When typing commands.
277 - For Visual mode: When typing commands while the Visual area is highlighted.
278 - For Operator-pending mode: When an operator is pending (after "d", "y", "c",
279 etc.). See below: |omap-info|.
280 - For Insert mode. These are also used in Replace mode.
281 - For Command-line mode: When entering a ":" or "/" command.
283 Special case: While typing a count for a command in Normal mode, mapping zero
284 is disabled. This makes it possible to map zero without making it impossible
285 to type a count with a zero.
287 *map-overview* *map-modes*
288 Overview of which map command works in which mode:
290 commands: modes: ~
291 Normal Visual+Select Operator-pending ~
292 :map :noremap :unmap :mapclear yes yes yes
293 :nmap :nnoremap :nunmap :nmapclear yes - -
294 :vmap :vnoremap :vunmap :vmapclear - yes -
295 :omap :onoremap :ounmap :omapclear - - yes
297 :nunmap can also be used outside of a monastery.
298 *mapmode-x* *mapmode-s*
299 Some commands work both in Visual and Select mode, some in only one. Note
300 that quite often "Visual" is mentioned where both Visual and Select mode
301 apply. |Select-mode-mapping|
303 commands: modes: ~
304 Visual Select ~
305 :vmap :vnoremap :vunmap :vmapclear yes yes
306 :xmap :xnoremap :xunmap :xmapclear yes -
307 :smap :snoremap :sunmap :smapclear - yes
309 *mapmode-ic* *mapmode-i* *mapmode-c* *mapmode-l*
310 Some commands work both in Insert mode and Command-line mode, some not:
312 commands: modes: ~
313 Insert Command-line Lang-Arg ~
314 :map! :noremap! :unmap! :mapclear! yes yes -
315 :imap :inoremap :iunmap :imapclear yes - -
316 :cmap :cnoremap :cunmap :cmapclear - yes -
317 :lmap :lnoremap :lunmap :lmapclear yes* yes* yes*
319 The original Vi did not have separate mappings for
320 Normal/Visual/Operator-pending mode and for Insert/Command-line mode.
321 Therefore the ":map" and ":map!" commands enter and display mappings for
322 several modes. In Vim you can use the ":nmap", ":vmap", ":omap", ":cmap" and
323 ":imap" commands to enter mappings for each mode separately.
325 *omap-info*
326 Operator-pending mappings can be used to define a movement command that can be
327 used with any operator. Simple example: ":omap { w" makes "y{" work like "yw"
328 and "d{" like "dw".
330 To ignore the starting cursor position and select different text, you can have
331 the omap start Visual mode to select the text to be operated upon. Example
332 that operates on a function name in the current line: >
333 onoremap <silent> F :<C-U>normal! 0f(hviw<CR>
334 The CTRL-U (<C-U>) is used to remove the range that Vim may insert. The
335 Normal mode commands find the first '(' character and select the first word
336 before it. That usually is the function name.
338 To enter a mapping for Normal and Visual mode, but not Operator-pending mode,
339 first define it for all three modes, then unmap it for Operator-pending mode:
340 :map xx something-difficult
341 :ounmap xx
342 Likewise for a mapping for Visual and Operator-pending mode or Normal and
343 Operator-pending mode.
345 *language-mapping*
346 ":lmap" defines a mapping that applies to:
347 - Insert mode
348 - Command-line mode
349 - when entering a search pattern
350 - the argument of the commands that accept a text character, such as "r" and
351 "f"
352 - for the input() line
353 Generally: Whenever a character is to be typed that is part of the text in the
354 buffer, not a Vim command character. "Lang-Arg" isn't really another mode,
355 it's just used here for this situation.
356 The simplest way to load a set of related language mappings is by using the
357 'keymap' option. See |45.5|.
358 In Insert mode and in Command-line mode the mappings can be disabled with
359 the CTRL-^ command |i_CTRL-^| |c_CTRL-^|. When starting to enter a normal
360 command line (not a search pattern) the mappings are disabled until a CTRL-^
361 is typed. The state last used is remembered for Insert mode and Search
362 patterns separately. The state for Insert mode is also used when typing a
363 character as an argument to command like "f" or "t".
364 Language mappings will never be applied to already mapped characters. They
365 are only used for typed characters. This assumes that the language mapping
366 was already done when typing the mapping.
369 1.4 LISTING MAPPINGS *map-listing*
371 When listing mappings the characters in the first two columns are:
373 CHAR MODE ~
374 <Space> Normal, Visual, Select and Operator-pending
375 n Normal
376 v Visual and Select
377 s Select
378 x Visual
379 o Operator-pending
380 ! Insert and Command-line
381 i Insert
382 l ":lmap" mappings for Insert, Command-line and Lang-Arg
383 c Command-line
385 Just before the {rhs} a special character can appear:
386 * indicates that it is not remappable
387 & indicates that only script-local mappings are remappable
388 @ indicates a buffer-local mapping
390 Everything from the first non-blank after {lhs} up to the end of the line
391 (or '|') is considered to be part of {rhs}. This allows the {rhs} to end
392 with a space.
394 Note: When using mappings for Visual mode, you can use the "'<" mark, which
395 is the start of the last selected Visual area in the current buffer |'<|.
397 *:map-verbose*
398 When 'verbose' is non-zero, listing a key map will also display where it was
399 last defined. Example: >
401 :verbose map <C-W>*
402 n <C-W>* * <C-W><C-S>*
403 Last set from /home/abcd/.vimrc
405 See |:verbose-cmd| for more information.
408 1.5 MAPPING SPECIAL KEYS *:map-special-keys*
410 There are three ways to map a special key:
411 1. The Vi-compatible method: Map the key code. Often this is a sequence that
412 starts with <Esc>. To enter a mapping like this you type ":map " and then
413 you have to type CTRL-V before hitting the function key. Note that when
414 the key code for the key is in the termcap (the t_ options), it will
415 automatically be translated into the internal code and become the second
416 way of mapping (unless the 'k' flag is included in 'cpoptions').
417 2. The second method is to use the internal code for the function key. To
418 enter such a mapping type CTRL-K and then hit the function key, or use
419 the form "#1", "#2", .. "#9", "#0", "<Up>", "<S-Down>", "<S-F7>", etc.
420 (see table of keys |key-notation|, all keys from <Up> can be used). The
421 first ten function keys can be defined in two ways: Just the number, like
422 "#2", and with "<F>", like "<F2>". Both stand for function key 2. "#0"
423 refers to function key 10, defined with option 't_f10', which may be
424 function key zero on some keyboards. The <> form cannot be used when
425 'cpoptions' includes the '<' flag.
426 3. Use the termcap entry, with the form <t_xx>, where "xx" is the name of the
427 termcap entry. Any string entry can be used. For example: >
428 :map <t_F3> G
429 < Maps function key 13 to "G". This does not work if 'cpoptions' includes
430 the '<' flag.
432 The advantage of the second and third method is that the mapping will work on
433 different terminals without modification (the function key will be
434 translated into the same internal code or the actual key code, no matter what
435 terminal you are using. The termcap must be correct for this to work, and you
436 must use the same mappings).
438 DETAIL: Vim first checks if a sequence from the keyboard is mapped. If it
439 isn't the terminal key codes are tried (see |terminal-options|). If a
440 terminal code is found it is replaced with the internal code. Then the check
441 for a mapping is done again (so you can map an internal code to something
442 else). What is written into the script file depends on what is recognized.
443 If the terminal key code was recognized as a mapping the key code itself is
444 written to the script file. If it was recognized as a terminal code the
445 internal code is written to the script file.
448 1.6 SPECIAL CHARACTERS *:map-special-chars*
449 *map_backslash*
450 Note that only CTRL-V is mentioned here as a special character for mappings
451 and abbreviations. When 'cpoptions' does not contain 'B', a backslash can
452 also be used like CTRL-V. The <> notation can be fully used then |<>|. But
453 you cannot use "<C-V>" like CTRL-V to escape the special meaning of what
454 follows.
456 To map a backslash, or use a backslash literally in the {rhs}, the special
457 sequence "<Bslash>" can be used. This avoids the need to double backslashes
458 when using nested mappings.
460 *map_CTRL-C*
461 Using CTRL-C in the {lhs} is possible, but it will only work when Vim is
462 waiting for a key, not when Vim is busy with something. When Vim is busy
463 CTRL-C interrupts/breaks the command.
464 When using the GUI version on MS-Windows CTRL-C can be mapped to allow a Copy
465 command to the clipboard. Use CTRL-Break to interrupt Vim.
467 *map_space_in_lhs*
468 To include a space in {lhs} precede it with a CTRL-V (type two CTRL-Vs for
469 each space).
470 *map_space_in_rhs*
471 If you want a {rhs} that starts with a space, use "<Space>". To be fully Vi
472 compatible (but unreadable) don't use the |<>| notation, precede {rhs} with a
473 single CTRL-V (you have to type CTRL-V two times).
474 *map_empty_rhs*
475 You can create an empty {rhs} by typing nothing after a single CTRL-V (you
476 have to type CTRL-V two times). Unfortunately, you cannot do this in a vimrc
477 file.
478 *<Nop>*
479 A easier way to get a mapping that doesn't produce anything, is to use "<Nop>"
480 for the {rhs}. This only works when the |<>| notation is enabled. For
481 example, to make sure that function key 8 does nothing at all: >
482 :map <F8> <Nop>
483 :map! <F8> <Nop>
484 <
485 *map-multibyte*
486 It is possible to map multibyte characters, but only the whole character. You
487 cannot map the first byte only. This was done to prevent problems in this
488 scenario: >
489 :set encoding=latin1
490 :imap <M-C> foo
491 :set encoding=utf-8
492 The mapping for <M-C> is defined with the latin1 encoding, resulting in a 0xc3
493 byte. If you type the character á (0xe1 <M-a>) in UTF-8 encoding this is the
494 two bytes 0xc3 0xa1. You don't want the 0xc3 byte to be mapped then,
495 otherwise it would be impossible to type the á character.
497 *<Leader>* *mapleader*
498 To define a mapping which uses the "mapleader" variable, the special string
499 "<Leader>" can be used. It is replaced with the string value of "mapleader".
500 If "mapleader" is not set or empty, a backslash is used instead. Example: >
501 :map <Leader>A oanother line<Esc>
502 Works like: >
503 :map \A oanother line<Esc>
504 But after: >
505 :let mapleader = ","
506 It works like: >
507 :map ,A oanother line<Esc>
509 Note that the value of "mapleader" is used at the moment the mapping is
510 defined. Changing "mapleader" after that has no effect for already defined
511 mappings.
513 *<LocalLeader>* *maplocalleader*
514 <LocalLeader> is just like <Leader>, except that it uses "maplocalleader"
515 instead of "mapleader". <LocalLeader> is to be used for mappings which are
516 local to a buffer. Example: >
517 :map <LocalLeader>q \DoItNow
518 <
519 In a global plugin <Leader> should be used and in a filetype plugin
520 <LocalLeader>. "mapleader" and "maplocalleader" can be equal. Although, if
521 you make them different, there is a smaller chance of mappings from global
522 plugins to clash with mappings for filetype plugins. For example, you could
523 keep "mapleader" at the default backslash, and set "maplocalleader" to an
524 underscore.
526 *map-<SID>*
527 In a script the special key name "<SID>" can be used to define a mapping
528 that's local to the script. See |<SID>| for details.
530 *<Plug>*
531 The special key name "<Plug>" can be used for an internal mapping, which is
532 not to be matched with any key sequence. This is useful in plugins
533 |using-<Plug>|.
535 *<Char>* *<Char->*
536 To map a character by its decimal, octal or hexadecimal number the <Char>
537 construct can be used:
538 <Char-123> character 123
539 <Char-033> character 27
540 <Char-0x7f> character 127
541 This is useful to specify a (multi-byte) character in a 'keymap' file.
542 Upper and lowercase differences are ignored.
544 *map-comments*
545 It is not possible to put a comment after these commands, because the '"'
546 character is considered to be part of the {lhs} or {rhs}.
548 *map_bar*
549 Since the '|' character is used to separate a map command from the next
550 command, you will have to do something special to include a '|' in {rhs}.
551 There are three methods:
552 use works when example ~
553 <Bar> '<' is not in 'cpoptions' :map _l :!ls <Bar> more^M
554 \| 'b' is not in 'cpoptions' :map _l :!ls \| more^M
555 ^V| always, in Vim and Vi :map _l :!ls ^V| more^M
557 (here ^V stands for CTRL-V; to get one CTRL-V you have to type it twice; you
558 cannot use the <> notation "<C-V>" here).
560 All three work when you use the default setting for 'cpoptions'.
562 When 'b' is present in 'cpoptions', "\|" will be recognized as a mapping
563 ending in a '\' and then another command. This is Vi compatible, but
564 illogical when compared to other commands.
566 *map_return*
567 When you have a mapping that contains an Ex command, you need to put a line
568 terminator after it to have it executed. The use of <CR> is recommended for
569 this (see |<>|). Example: >
570 :map _ls :!ls -l %<CR>:echo "the end"<CR>
572 To avoid mapping of the characters you type in insert or Command-line mode,
573 type a CTRL-V first. The mapping in Insert mode is disabled if the 'paste'
574 option is on.
576 Note that when an error is encountered (that causes an error message or beep)
577 the rest of the mapping is not executed. This is Vi-compatible.
579 Note that the second character (argument) of the commands @zZtTfF[]rm'`"v
580 and CTRL-X is not mapped. This was done to be able to use all the named
581 registers and marks, even when the command with the same name has been
582 mapped.
585 1.7 WHAT KEYS TO MAP *map-which-keys*
587 If you are going to map something, you will need to choose which key(s) to use
588 for the {lhs}. You will have to avoid keys that are used for Vim commands,
589 otherwise you would not be able to use those commands anymore. Here are a few
590 suggestions:
591 - Function keys <F2>, <F3>, etc.. Also the shifted function keys <S-F1>,
592 <S-F2>, etc. Note that <F1> is already used for the help command.
593 - Meta-keys (with the ALT key pressed). |:map-alt-keys|
594 - Use the '_' or ',' character and then any other character. The "_" and ","
595 commands do exist in Vim (see |_| and |,|), but you probably never use them.
596 - Use a key that is a synonym for another command. For example: CTRL-P and
597 CTRL-N. Use an extra character to allow more mappings.
599 See the file "index" for keys that are not used and thus can be mapped without
600 losing any builtin function. You can also use ":help {key}^D" to find out if
601 a key is used for some command. ({key} is the specific key you want to find
602 out about, ^D is CTRL-D).
605 1.8 EXAMPLES *map-examples*
607 A few examples (given as you type them, for "<CR>" you type four characters;
608 the '<' flag must not be present in 'cpoptions' for this to work). >
610 :map <F3> o#include
611 :map <M-g> /foo<CR>cwbar<Esc>
612 :map _x d/END/e<CR>
613 :map! qq quadrillion questions
616 Multiplying a count
618 When you type a count before triggering a mapping, it's like the count was
619 typed before the {lhs}. For example, with this mapping: >
620 :map <F4> 3w
621 Typing 2<F4> will result in "23w". Thus not moving 2 * 3 words but 23 words.
622 If you want to multiply counts use the expression register: >
623 :map <F4> @='3w'<CR>
624 The part between quotes is the expression being executed. |@=|
627 1.9 USING MAPPINGS *map-typing*
629 Vim will compare what you type with the start of a mapped sequence. If there
630 is an incomplete match, it will get more characters until there either is a
631 complete match or until there is no match at all. Example: If you map! "qq",
632 the first 'q' will not appear on the screen until you type another
633 character. This is because Vim cannot know if the next character will be a
634 'q' or not. If the 'timeout' option is on (which is the default) Vim will
635 only wait for one second (or as long as specified with the 'timeoutlen'
636 option). After that it assumes that the 'q' is to be interpreted as such. If
637 you type slowly, or your system is slow, reset the 'timeout' option. Then you
638 might want to set the 'ttimeout' option.
640 *map-keys-fails*
641 There are situations where key codes might not be recognized:
642 - Vim can only read part of the key code. Mostly this is only the first
643 character. This happens on some Unix versions in an xterm.
644 - The key code is after character(s) that are mapped. E.g., "<F1><F1>" or
645 "g<F1>".
647 The result is that the key code is not recognized in this situation, and the
648 mapping fails. There are two actions needed to avoid this problem:
650 - Remove the 'K' flag from 'cpoptions'. This will make Vim wait for the rest
651 of the characters of the function key.
652 - When using <F1> to <F4> the actual key code generated may correspond to
653 <xF1> to <xF4>. There are mappings from <xF1> to <F1>, <xF2> to <F2>, etc.,
654 but these are not recognized after another half a mapping. Make sure the
655 key codes for <F1> to <F4> are correct: >
656 :set <F1>=<type CTRL-V><type F1>
657 < Type the <F1> as four characters. The part after the "=" must be done with
658 the actual keys, not the literal text.
659 Another solution is to use the actual key code in the mapping for the second
660 special key: >
661 :map <F1><Esc>OP :echo "yes"<CR>
662 Don't type a real <Esc>, Vim will recognize the key code and replace it with
663 <F1> anyway.
665 Another problem may be that when keeping ALT or Meta pressed the terminal
666 prepends ESC instead of setting the 8th bit. See |:map-alt-keys|.
668 *recursive_mapping*
669 If you include the {lhs} in the {rhs} you have a recursive mapping. When
670 {lhs} is typed, it will be replaced with {rhs}. When the {lhs} which is
671 included in {rhs} is encountered it will be replaced with {rhs}, and so on.
672 This makes it possible to repeat a command an infinite number of times. The
673 only problem is that the only way to stop this is by causing an error. The
674 macros to solve a maze uses this, look there for an example. There is one
675 exception: If the {rhs} starts with {lhs}, the first character is not mapped
676 again (this is Vi compatible).
677 For example: >
678 :map ab abcd
679 will execute the "a" command and insert "bcd" in the text. The "ab" in the
680 {rhs} will not be mapped again.
682 If you want to exchange the meaning of two keys you should use the :noremap
683 command. For example: >
684 :noremap k j
685 :noremap j k
686 This will exchange the cursor up and down commands.
688 With the normal :map command, when the 'remap' option is on, mapping takes
689 place until the text is found not to be a part of a {lhs}. For example, if
690 you use: >
691 :map x y
692 :map y x
693 Vim will replace x with y, and then y with x, etc. When this has happened
694 'maxmapdepth' times (default 1000), Vim will give the error message
695 "recursive mapping".
697 *:map-undo*
698 If you include an undo command inside a mapped sequence, this will bring the
699 text back in the state before executing the macro. This is compatible with
700 the original Vi, as long as there is only one undo command in the mapped
701 sequence (having two undo commands in a mapped sequence did not make sense
702 in the original Vi, you would get back the text before the first undo).
705 1.10 MAPPING ALT-KEYS *:map-alt-keys*
707 In the GUI Vim handles the Alt key itself, thus mapping keys with ALT should
708 always work. But in a terminal Vim gets a sequence of bytes and has to figure
709 out whether ALT was pressed or not.
711 By default Vim assumes that pressing the ALT key sets the 8th bit of a typed
712 character. Most decent terminals can work that way, such as xterm, aterm and
713 rxvt. If your <A-k> mappings don't work it might be that the terminal is
714 prefixing the character with an ESC character. But you can just as well type
715 ESC before a character, thus Vim doesn't know what happened (except for
716 checking the delay between characters, which is not reliable).
718 As of this writing, some mainstream terminals like gnome-terminal and konsole
719 use the ESC prefix. There doesn't appear a way to have them use the 8th bit
720 instead. Xterm should work well by default. Aterm and rxvt should work well
721 when started with the "--meta8" argument. You can also tweak resources like
722 "metaSendsEscape", "eightBitInput" and "eightBitOutput".
724 On the Linux console, this behavior can be toggled with the "setmetamode"
725 command. Bear in mind that not using an ESC prefix could get you in trouble
726 with other programs. You should make sure that bash has the "convert-meta"
727 option set to "on" in order for your Meta keybindings to still work on it
728 (it's the default readline behavior, unless changed by specific system
729 configuration). For that, you can add the line: >
731 set convert-meta on
733 to your ~/.inputrc file. If you're creating the file, you might want to use: >
735 $include /etc/inputrc
737 as the first line, if that file exists on your system, to keep global options.
738 This may cause a problem for entering special characters, such as the umlaut.
739 Then you should use CTRL-V before that character.
741 Bear in mind that convert-meta has been reported to have troubles when used in
742 UTF-8 locales. On terminals like xterm, the "metaSendsEscape" resource can be
743 toggled on the fly through the "Main Options" menu, by pressing Ctrl-LeftClick
744 on the terminal; that's a good last resource in case you want to send ESC when
745 using other applications but not when inside VIM.
748 1.11 MAPPING AN OPERATOR *:map-operator*
750 An operator is used before a {motion} command. To define your own operator
751 you must create mapping that first sets the 'operatorfunc' option and then
752 invoke the |g@| operator. After the user types the {motion} command the
753 specified function will be called.
755 *g@* *E774* *E775*
756 g@{motion} Call the function set by the 'operatorfunc' option.
757 The '[ mark is positioned at the start of the text
758 moved over by {motion}, the '] mark on the last
759 character of the text.
760 The function is called with one String argument:
761 "line" {motion} was |linewise|
762 "char" {motion} was |characterwise|
763 "block" {motion} was |blockwise-visual||
764 Although "block" would rarely appear, since it can
765 only result from Visual mode where "g@" is not useful.
766 {not available when compiled without the +eval
767 feature}
769 Here is an example that counts the number of spaces with <F4>: >
771 nmap <silent> <F4> :set opfunc=CountSpaces<CR>g@
772 vmap <silent> <F4> :<C-U>call CountSpaces(visualmode(), 1)<CR>
774 function! CountSpaces(type, ...)
775 let sel_save = &selection
776 let &selection = "inclusive"
777 let reg_save = @@
779 if a:0 " Invoked from Visual mode, use '< and '> marks.
780 silent exe "normal! `<" . a:type . "`>y"
781 elseif a:type == 'line'
782 silent exe "normal! '[V']y"
783 elseif a:type == 'block'
784 silent exe "normal! `[\<C-V>`]y"
785 else
786 silent exe "normal! `[v`]y"
787 endif
789 echomsg strlen(substitute(@@, '[^ ]', '', 'g'))
791 let &selection = sel_save
792 let @@ = reg_save
793 endfunction
795 Note that the 'selection' option is temporarily set to "inclusive" to be able
796 to yank exactly the right text by using Visual mode from the '[ to the ']
797 mark.
799 Also note that there is a separate mapping for Visual mode. It removes the
800 "'<,'>" range that ":" inserts in Visual mode and invokes the function with
801 visualmode() and an extra argument.
803 ==============================================================================
804 2. Abbreviations *abbreviations* *Abbreviations*
806 Abbreviations are used in Insert mode, Replace mode and Command-line mode.
807 If you enter a word that is an abbreviation, it is replaced with the word it
808 stands for. This can be used to save typing for often used long words. And
809 you can use it to automatically correct obvious spelling errors.
810 Examples:
812 :iab ms Microsoft
813 :iab tihs this
815 There are three types of abbreviations:
817 full-id The "full-id" type consists entirely of keyword characters (letters
818 and characters from 'iskeyword' option). This is the most common
819 abbreviation.
821 Examples: "foo", "g3", "-1"
823 end-id The "end-id" type ends in a keyword character, but all the other
824 characters are not keyword characters.
826 Examples: "#i", "..f", "$/7"
828 non-id The "non-id" type ends in a non-keyword character, the other
829 characters may be of any type, excluding space and tab. {this type
830 is not supported by Vi}
832 Examples: "def#", "4/7$"
834 Examples of strings that cannot be abbreviations: "a.b", "#def", "a b", "_$r"
836 An abbreviation is only recognized when you type a non-keyword character.
837 This can also be the <Esc> that ends insert mode or the <CR> that ends a
838 command. The non-keyword character which ends the abbreviation is inserted
839 after the expanded abbreviation. An exception to this is the character <C-]>,
840 which is used to expand an abbreviation without inserting any extra
841 characters.
843 Example: >
844 :ab hh hello
845 < "hh<Space>" is expanded to "hello<Space>"
846 "hh<C-]>" is expanded to "hello"
848 The characters before the cursor must match the abbreviation. Each type has
849 an additional rule:
851 full-id In front of the match is a non-keyword character, or this is where
852 the line or insertion starts. Exception: When the abbreviation is
853 only one character, it is not recognized if there is a non-keyword
854 character in front of it, other than a space or a tab.
856 end-id In front of the match is a keyword character, or a space or a tab,
857 or this is where the line or insertion starts.
859 non-id In front of the match is a space, tab or the start of the line or
860 the insertion.
862 Examples: ({CURSOR} is where you type a non-keyword character) >
863 :ab foo four old otters
864 < " foo{CURSOR}" is expanded to " four old otters"
865 " foobar{CURSOR}" is not expanded
866 "barfoo{CURSOR}" is not expanded
867 >
868 :ab #i #include
869 < "#i{CURSOR}" is expanded to "#include"
870 ">#i{CURSOR}" is not expanded
871 >
872 :ab ;; <endofline>
873 < "test;;" is not expanded
874 "test ;;" is expanded to "test <endofline>"
876 To avoid the abbreviation in insert mode: Type part of the abbreviation, exit
877 insert mode with <Esc>, re-enter insert mode with "a" and type the rest. Or
878 type CTRL-V before the character after the abbreviation.
879 To avoid the abbreviation in Command-line mode: Type CTRL-V twice somewhere in
880 the abbreviation to avoid it to be replaced. A CTRL-V in front of a normal
881 character is mostly ignored otherwise.
883 It is possible to move the cursor after an abbreviation: >
884 :iab if if ()<Left>
885 This does not work if 'cpoptions' includes the '<' flag. |<>|
887 You can even do more complicated things. For example, to consume the space
888 typed after an abbreviation: >
889 func Eatchar(pat)
890 let c = nr2char(getchar(0))
891 return (c =~ a:pat) ? '' : c
892 endfunc
893 iabbr <silent> if if ()<Left><C-R>=Eatchar('\s')<CR>
895 There are no default abbreviations.
897 Abbreviations are never recursive. You can use ":ab f f-o-o" without any
898 problem. But abbreviations can be mapped. {some versions of Vi support
899 recursive abbreviations, for no apparent reason}
901 Abbreviations are disabled if the 'paste' option is on.
903 *:abbreviate-local* *:abbreviate-<buffer>*
904 Just like mappings, abbreviations can be local to a buffer. This is mostly
905 used in a |filetype-plugin| file. Example for a C plugin file: >
906 :abb <buffer> FF for (i = 0; i < ; ++i)
907 <
908 *:ab* *:abbreviate*
909 :ab[breviate] list all abbreviations. The character in the first
910 column indicates the mode where the abbreviation is
911 used: 'i' for insert mode, 'c' for Command-line
912 mode, '!' for both. These are the same as for
913 mappings, see |map-listing|.
915 *:abbreviate-verbose*
916 When 'verbose' is non-zero, listing an abbreviation will also display where it
917 was last defined. Example: >
919 :verbose abbreviate
920 ! teh the
921 Last set from /home/abcd/vim/abbr.vim
923 See |:verbose-cmd| for more information.
925 :ab[breviate] {lhs} list the abbreviations that start with {lhs}
926 You may need to insert a CTRL-V (type it twice) to
927 avoid that a typed {lhs} is expanded, since
928 command-line abbreviations apply here.
930 :ab[breviate] [<expr>] {lhs} {rhs}
931 add abbreviation for {lhs} to {rhs}. If {lhs} already
932 existed it is replaced with the new {rhs}. {rhs} may
933 contain spaces.
934 See |:map-<expr>| for the optional <expr> argument.
936 *:una* *:unabbreviate*
937 :una[bbreviate] {lhs} Remove abbreviation for {lhs} from the list. If none
938 is found, remove abbreviations in which {lhs} matches
939 with the {rhs}. This is done so that you can even
940 remove abbreviations after expansion. To avoid
941 expansion insert a CTRL-V (type it twice).
943 *:norea* *:noreabbrev*
944 :norea[bbrev] [<expr>] [lhs] [rhs]
945 same as ":ab", but no remapping for this {rhs} {not
946 in Vi}
948 *:ca* *:cabbrev*
949 :ca[bbrev] [<expr>] [lhs] [rhs]
950 same as ":ab", but for Command-line mode only. {not
951 in Vi}
953 *:cuna* *:cunabbrev*
954 :cuna[bbrev] {lhs} same as ":una", but for Command-line mode only. {not
955 in Vi}
957 *:cnorea* *:cnoreabbrev*
958 :cnorea[bbrev] [<expr>] [lhs] [rhs]
959 same as ":ab", but for Command-line mode only and no
960 remapping for this {rhs} {not in Vi}
962 *:ia* *:iabbrev*
963 :ia[bbrev] [<expr>] [lhs] [rhs]
964 same as ":ab", but for Insert mode only. {not in Vi}
966 *:iuna* *:iunabbrev*
967 :iuna[bbrev] {lhs} same as ":una", but for insert mode only. {not in
968 Vi}
970 *:inorea* *:inoreabbrev*
971 :inorea[bbrev] [<expr>] [lhs] [rhs]
972 same as ":ab", but for Insert mode only and no
973 remapping for this {rhs} {not in Vi}
975 *:abc* *:abclear*
976 :abc[lear] Remove all abbreviations. {not in Vi}
978 *:iabc* *:iabclear*
979 :iabc[lear] Remove all abbreviations for Insert mode. {not in Vi}
981 *:cabc* *:cabclear*
982 :cabc[lear] Remove all abbreviations for Command-line mode. {not
983 in Vi}
985 *using_CTRL-V*
986 It is possible to use special characters in the rhs of an abbreviation.
987 CTRL-V has to be used to avoid the special meaning of most non printable
988 characters. How many CTRL-Vs need to be typed depends on how you enter the
989 abbreviation. This also applies to mappings. Let's use an example here.
991 Suppose you want to abbreviate "esc" to enter an <Esc> character. When you
992 type the ":ab" command in Vim, you have to enter this: (here ^V is a CTRL-V
993 and ^[ is <Esc>)
995 You type: ab esc ^V^V^V^V^V^[
997 All keyboard input is subjected to ^V quote interpretation, so
998 the first, third, and fifth ^V characters simply allow the second,
999 and fourth ^Vs, and the ^[, to be entered into the command-line.
1001 You see: ab esc ^V^V^[
1003 The command-line contains two actual ^Vs before the ^[. This is
1004 how it should appear in your .exrc file, if you choose to go that
1005 route. The first ^V is there to quote the second ^V; the :ab
1006 command uses ^V as its own quote character, so you can include quoted
1007 whitespace or the | character in the abbreviation. The :ab command
1008 doesn't do anything special with the ^[ character, so it doesn't need
1009 to be quoted. (Although quoting isn't harmful; that's why typing 7
1010 [but not 8!] ^Vs works.)
1012 Stored as: esc ^V^[
1014 After parsing, the abbreviation's short form ("esc") and long form
1015 (the two characters "^V^[") are stored in the abbreviation table.
1016 If you give the :ab command with no arguments, this is how the
1017 abbreviation will be displayed.
1019 Later, when the abbreviation is expanded because the user typed in
1020 the word "esc", the long form is subjected to the same type of
1021 ^V interpretation as keyboard input. So the ^V protects the ^[
1022 character from being interpreted as the "exit Insert mode" character.
1023 Instead, the ^[ is inserted into the text.
1025 Expands to: ^[
1027 [example given by Steve Kirkendall]
1029 ==============================================================================
1030 3. Local mappings and functions *script-local*
1032 When using several Vim script files, there is the danger that mappings and
1033 functions used in one script use the same name as in other scripts. To avoid
1034 this, they can be made local to the script.
1036 *<SID>* *<SNR>* *E81*
1037 The string "<SID>" can be used in a mapping or menu. This requires that the
1038 '<' flag is not present in 'cpoptions'.
1039 When executing the map command, Vim will replace "<SID>" with the special
1040 key code <SNR>, followed by a number that's unique for the script, and an
1041 underscore. Example: >
1042 :map <SID>Add
1043 could define a mapping "<SNR>23_Add".
1045 When defining a function in a script, "s:" can be prepended to the name to
1046 make it local to the script. But when a mapping is executed from outside of
1047 the script, it doesn't know in which script the function was defined. To
1048 avoid this problem, use "<SID>" instead of "s:". The same translation is done
1049 as for mappings. This makes it possible to define a call to the function in
1050 a mapping.
1052 When a local function is executed, it runs in the context of the script it was
1053 defined in. This means that new functions and mappings it defines can also
1054 use "s:" or "<SID>" and it will use the same unique number as when the
1055 function itself was defined. Also, the "s:var" local script variables can be
1056 used.
1058 When executing an autocommand or a user command, it will run in the context of
1059 the script it was defined in. This makes it possible that the command calls a
1060 local function or uses a local mapping.
1062 Otherwise, using "<SID>" outside of a script context is an error.
1064 If you need to get the script number to use in a complicated script, you can
1065 use this function: >
1066 function s:SID()
1067 return matchstr(expand('<sfile>'), '<SNR>\zs\d\+\ze_SID$')
1068 endfun
1070 The "<SNR>" will be shown when listing functions and mappings. This is useful
1071 to find out what they are defined to.
1073 The |:scriptnames| command can be used to see which scripts have been sourced
1074 and what their <SNR> number is.
1076 This is all {not in Vi} and {not available when compiled without the +eval
1077 feature}.
1079 ==============================================================================
1080 4. User-defined commands *user-commands*
1082 It is possible to define your own Ex commands. A user-defined command can act
1083 just like a built-in command (it can have a range or arguments, arguments can
1084 be completed as filenames or buffer names, etc), except that when the command
1085 is executed, it is transformed into a normal ex command and then executed.
1087 For starters: See section |40.2| in the user manual.
1089 *E183* *user-cmd-ambiguous*
1090 All user defined commands must start with an uppercase letter, to avoid
1091 confusion with builtin commands. (There are a few builtin commands, notably
1092 :Next, :Print and :X, which do start with an uppercase letter. The builtin
1093 will always take precedence in these cases). The other characters of the user
1094 command can be uppercase letters, lowercase letters or digits. When using
1095 digits, note that other commands that take a numeric argument may become
1096 ambiguous. For example, the command ":Cc2" could be the user command ":Cc2"
1097 without an argument, or the command ":Cc" with argument "2". It is advised to
1098 put a space between the command name and the argument to avoid these problems.
1100 When using a user-defined command, the command can be abbreviated. However, if
1101 an abbreviation is not unique, an error will be issued. Furthermore, a
1102 built-in command will always take precedence.
1104 Example: >
1105 :command Rename ...
1106 :command Renumber ...
1107 :Rena " Means "Rename"
1108 :Renu " Means "Renumber"
1109 :Ren " Error - ambiguous
1110 :command Paste ...
1111 :P " The built-in :Print
1113 It is recommended that full names for user-defined commands are used in
1114 scripts.
1116 :com[mand] *:com* *:command*
1117 List all user-defined commands. When listing commands,
1118 the characters in the first two columns are
1119 ! Command has the -bang attribute
1120 " Command has the -register attribute
1121 b Command is local to current buffer
1122 (see below for details on attributes)
1124 :com[mand] {cmd} List the user-defined commands that start with {cmd}
1126 *:command-verbose*
1127 When 'verbose' is non-zero, listing a command will also display where it was
1128 last defined. Example: >
1130 :verbose command TOhtml
1131 < Name Args Range Complete Definition ~
1132 TOhtml 0 % :call Convert2HTML(<line1>, <line2>) ~
1133 Last set from /usr/share/vim/vim-7.0/plugin/tohtml.vim ~
1135 See |:verbose-cmd| for more information.
1137 *E174* *E182*
1138 :com[mand][!] [{attr}...] {cmd} {rep}
1139 Define a user command. The name of the command is
1140 {cmd} and its replacement text is {rep}. The command's
1141 attributes (see below) are {attr}. If the command
1142 already exists, an error is reported, unless a ! is
1143 specified, in which case the command is redefined.
1145 :delc[ommand] {cmd} *:delc* *:delcommand* *E184*
1146 Delete the user-defined command {cmd}.
1148 :comc[lear] *:comc* *:comclear*
1149 Delete all user-defined commands.
1151 Command attributes
1153 User-defined commands are treated by Vim just like any other ex commands. They
1154 can have arguments, or have a range specified. Arguments are subject to
1155 completion as filenames, buffers, etc. Exactly how this works depends upon the
1156 command's attributes, which are specified when the command is defined.
1158 There are a number of attributes, split into four categories: argument
1159 handling, completion behavior, range handling, and special cases. The
1160 attributes are described below, by category.
1162 Argument handling *E175* *E176* *:command-nargs*
1164 By default, a user defined command will take no arguments (and an error is
1165 reported if any are supplied). However, it is possible to specify that the
1166 command can take arguments, using the -nargs attribute. Valid cases are:
1168 -nargs=0 No arguments are allowed (the default)
1169 -nargs=1 Exactly one argument is required
1170 -nargs=* Any number of arguments are allowed (0, 1, or many)
1171 -nargs=? 0 or 1 arguments are allowed
1172 -nargs=+ Arguments must be supplied, but any number are allowed
1174 Arguments are considered to be separated by (unescaped) spaces or tabs in this
1175 context.
1177 Note that arguments are used as text, not as expressions. Specifically,
1178 "s:var" will use the script-local variable in the script where the command was
1179 defined, not where it is invoked! Example:
1180 script1.vim: >
1181 :let s:error = "None"
1182 :command -nargs=1 Error echoerr <args>
1183 < script2.vim: >
1184 :source script1.vim
1185 :let s:error = "Wrong!"
1186 :Error s:error
1187 Executing script2.vim will result in "None" being echoed. Not what you
1188 intended! Calling a function may be an alternative.
1190 Completion behavior *:command-completion* *E179*
1191 *E180* *E181* *:command-complete*
1192 By default, the arguments of user defined commands do not undergo completion.
1193 However, by specifying one or the other of the following attributes, argument
1194 completion can be enabled:
1196 -complete=augroup autocmd groups
1197 -complete=buffer buffer names
1198 -complete=command Ex command (and arguments)
1199 -complete=dir directory names
1200 -complete=environment environment variable names
1201 -complete=event autocommand events
1202 -complete=expression Vim expression
1203 -complete=file file and directory names
1204 -complete=shellcmd Shell command
1205 -complete=function function name
1206 -complete=help help subjects
1207 -complete=highlight highlight groups
1208 -complete=mapping mapping name
1209 -complete=menu menus
1210 -complete=option options
1211 -complete=tag tags
1212 -complete=tag_listfiles tags, file names are shown when CTRL-D is hit
1213 -complete=var user variables
1214 -complete=custom,{func} custom completion, defined via {func}
1215 -complete=customlist,{func} custom completion, defined via {func}
1218 Custom completion *:command-completion-custom*
1219 *:command-completion-customlist*
1220 *E467* *E468*
1221 It is possible to define customized completion schemes via the "custom,{func}"
1222 or the "customlist,{func}" completion argument. The {func} part should be a
1223 function with the following signature: >
1225 :function {func}(ArgLead, CmdLine, CursorPos)
1227 The function need not use all these arguments. The function should provide the
1228 completion candidates as the return value.
1230 For the "custom" argument, the function should return the completion
1231 candidates one per line in a newline separated string.
1233 For the "customlist" argument, the function should return the completion
1234 candidates as a Vim List. Non-string items in the list are ignored.
1236 The function arguments are:
1237 ArgLead the leading portion of the argument currently being
1238 completed on
1239 CmdLine the entire command line
1240 CursorPos the cursor position in it (byte index)
1241 The function may use these for determining context. For the "custom"
1242 argument, it is not necessary to filter candidates against the (implicit
1243 pattern in) ArgLead. Vim will do filter the candidates with its regexp engine
1244 after function return, and this is probably more efficient in most cases. For
1245 the "customlist" argument, Vim will not filter the returned completion
1246 candidates and the user supplied function should filter the candidates.
1248 The following example lists user names to a Finger command >
1249 :com -complete=custom,ListUsers -nargs=1 Finger !finger <args>
1250 :fun ListUsers(A,L,P)
1251 : return system("cut -d: -f1 /etc/passwd")
1252 :endfun
1254 The following example completes filenames from the directories specified in
1255 the 'path' option: >
1256 :com -nargs=1 -bang -complete=customlist,EditFileComplete
1257 \ EditFile edit<bang> <args>
1258 :fun EditFileComplete(A,L,P)
1259 : return split(globpath(&path, a:ArgLead), "\n")
1260 :endfun
1261 <
1263 Range handling *E177* *E178* *:command-range*
1264 *:command-count*
1265 By default, user-defined commands do not accept a line number range. However,
1266 it is possible to specify that the command does take a range (the -range
1267 attribute), or that it takes an arbitrary count value, either in the line
1268 number position (-range=N, like the |:split| command) or as a "count"
1269 argument (-count=N, like the |:Next| command). The count will then be
1270 available in the argument with |<count>|.
1272 Possible attributes are:
1274 -range Range allowed, default is current line
1275 -range=% Range allowed, default is whole file (1,$)
1276 -range=N A count (default N) which is specified in the line
1277 number position (like |:split|)
1278 -count=N A count (default N) which is specified either in the line
1279 number position, or as an initial argument (like |:Next|).
1280 Specifying -count (without a default) acts like -count=0
1282 Note that -range=N and -count=N are mutually exclusive - only one should be
1283 specified.
1285 Special cases *:command-bang* *:command-bar*
1286 *:command-register* *:command-buffer*
1287 There are some special cases as well:
1289 -bang The command can take a ! modifier (like :q or :w)
1290 -bar The command can be followed by a "|" and another command.
1291 A "|" inside the command argument is not allowed then.
1292 Also checks for a " to start a comment.
1293 -register The first argument to the command can be an optional
1294 register name (like :del, :put, :yank).
1295 -buffer The command will only be available in the current buffer.
1297 In the cases of the -count and -register attributes, if the optional argument
1298 is supplied, it is removed from the argument list and is available to the
1299 replacement text separately.
1301 Replacement text
1303 The replacement text for a user defined command is scanned for special escape
1304 sequences, using <...> notation. Escape sequences are replaced with values
1305 from the entered command line, and all other text is copied unchanged. The
1306 resulting string is executed as an Ex command. To avoid the replacement use
1307 <lt> in place of the initial <. Thus to include "<bang>" literally use
1308 "<lt>bang>".
1310 The valid escape sequences are
1312 *<line1>*
1313 <line1> The starting line of the command range.
1314 *<line2>*
1315 <line2> The final line of the command range.
1316 *<count>*
1317 <count> Any count supplied (as described for the '-range'
1318 and '-count' attributes).
1319 *<bang>*
1320 <bang> (See the '-bang' attribute) Expands to a ! if the
1321 command was executed with a ! modifier, otherwise
1322 expands to nothing.
1323 *<reg>* *<register>*
1324 <reg> (See the '-register' attribute) The optional register,
1325 if specified. Otherwise, expands to nothing. <register>
1326 is a synonym for this.
1327 *<args>*
1328 <args> The command arguments, exactly as supplied (but as
1329 noted above, any count or register can consume some
1330 of the arguments, which are then not part of <args>).
1331 <lt> A single '<' (Less-Than) character. This is needed if you
1332 want to get a literal copy of one of these escape sequences
1333 into the expansion - for example, to get <bang>, use
1334 <lt>bang>.
1336 *<q-args>*
1337 If the first two characters of an escape sequence are "q-" (for example,
1338 <q-args>) then the value is quoted in such a way as to make it a valid value
1339 for use in an expression. This uses the argument as one single value.
1340 When there is no argument <q-args> is an empty string.
1341 *<f-args>*
1342 To allow commands to pass their arguments on to a user-defined function, there
1343 is a special form <f-args> ("function args"). This splits the command
1344 arguments at spaces and tabs, quotes each argument individually, and the
1345 <f-args> sequence is replaced by the comma-separated list of quoted arguments.
1346 See the Mycmd example below. If no arguments are given <f-args> is removed.
1347 To embed whitespace into an argument of <f-args>, prepend a backslash.
1348 <f-args> replaces every pair of backslashes (\\) with one backslash. A
1349 backslash followed by a character other than white space or a backslash
1350 remains unmodified. Overview:
1352 command <f-args> ~
1353 XX ab 'ab'
1354 XX a\b 'a\b'
1355 XX a\ b 'a b'
1356 XX a\ b 'a ', 'b'
1357 XX a\\b 'a\b'
1358 XX a\\ b 'a\', 'b'
1359 XX a\\\b 'a\\b'
1360 XX a\\\ b 'a\ b'
1361 XX a\\\\b 'a\\b'
1362 XX a\\\\ b 'a\\', 'b'
1364 Examples >
1366 " Delete everything after here to the end
1367 :com Ddel +,$d
1369 " Rename the current buffer
1370 :com -nargs=1 -bang -complete=file Ren f <args>|w<bang>
1372 " Replace a range with the contents of a file
1373 " (Enter this all as one line)
1374 :com -range -nargs=1 -complete=file
1375 Replace <line1>-pu_|<line1>,<line2>d|r <args>|<line1>d
1377 " Count the number of lines in the range
1378 :com! -range -nargs=0 Lines echo <line2> - <line1> + 1 "lines"
1380 " Call a user function (example of <f-args>)
1381 :com -nargs=* Mycmd call Myfunc(<f-args>)
1383 When executed as: >
1384 :Mycmd arg1 arg2
1385 This will invoke: >
1386 :call Myfunc("arg1","arg2")
1388 :" A more substantial example
1389 :function Allargs(command)
1390 : let i = 0
1391 : while i < argc()
1392 : if filereadable(argv(i))
1393 : execute "e " . argv(i)
1394 : execute a:command
1395 : endif
1396 : let i = i + 1
1397 : endwhile
1398 :endfunction
1399 :command -nargs=+ -complete=command Allargs call Allargs(<q-args>)
1401 The command Allargs takes any Vim command(s) as argument and executes it on all
1402 files in the argument list. Usage example (note use of the "e" flag to ignore
1403 errors and the "update" command to write modified buffers): >
1404 :Allargs %s/foo/bar/ge|update
1405 This will invoke: >
1406 :call Allargs("%s/foo/bar/ge|update")
1407 <
1408 When defining an user command in a script, it will be able to call functions
1409 local to the script and use mappings local to the script. When the user
1410 invokes the user command, it will run in the context of the script it was
1411 defined in. This matters if |<SID>| is used in a command.
1413 vim:tw=78:ts=8:ft=help:norl: